GDIPlus-HoverButton Problem

NO1 :-)

Hallo,

es tut mir leid, dass ich euch schon wieder nerven muss, aber ich komm einfach nicht weiter.
Hab eine Funktion _CheckHoverButton(...), die überprüfen soll, ob sich die Maus über dem "Button" befindet, funktioniert aber nur in eine Richtung.
Das Problem ist schwer zu beschreiben, wenn ihr das Skript ausführt, erkennt ihr aber glaube ich das Problem.

AutoIt

OnAutoItExitRegister("_Exit")


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <WindowsConstants.au3>


Local $iBtnState = 0


$hGui = GUICreate("", 300, 150, -1, -1, $WS_SYSMENU+$WS_POPUP)
GUISetBkColor(0xFFFFFF, $hGui)
$idBtn = GUICtrlCreatePic("", 105, 30, 90, 30)
GUICtrlSetCursor($idBtn, 0)
GUISetState(@SW_SHOW, $hGui)


_GDIPlus_Startup()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
$hBrush = _GDIPlus_BrushCreateSolid(0xFFFF0000)
$hBrush_Hover = _GDIPlus_BrushCreateSolid(0xFF00FF00)


_Redraw()


While 1
	_CheckHoverButton($idBtn, $iBtnState, $hGraphics, "Test", "Arial", 18, 128, 34, 105, 30, 90, 30)
	$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				Exit
			Case $GUI_EVENT_RESTORE
				_Redraw()
			Case $idBtn
				MsgBox(0, "", "Button pressed!")
		EndSwitch
WEnd


Func _Exit()
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_BrushDispose($hBrush_Hover)
	_GDIPlus_GraphicsDispose($hGraphics)
	_GDIPlus_Shutdown()
EndFunc


Func _Redraw()
	_GDIPlus_GraphicsFillRect($hGraphics, 105, 30, 90, 30, $hBrush)
	_DrawLabel($hGraphics, "Test", 128, 34, "Arial", 18, 0xFFFFFFFF)
EndFunc


Func _DrawLabel($hGraphics, $sText, $iLeft, $iTop, $sFont, $iPx, $Color)
	$hFontFamily = _GDIPlus_FontFamilyCreate($sFont)
	$hFont = _GDIPlus_FontCreate($hFontFamily, $iPx, 0, 2)
	$tLayout = _GDIPlus_RectFCreate($iLeft, $iTop, 0, 0)
	$hFormat = _GDIPlus_StringFormatCreate()
	$aInfo = _GDIPlus_GraphicsMeasureString($hGraphics, $sText, $hFont, $tLayout, $hFormat)
	$hBrush = _GDIPlus_BrushCreateSolid($Color)
	_GDIPlus_GraphicsDrawStringEx($hGraphics, $sText, $hFont, $aInfo[0], $hFormat, $hBrush)
	_GDIPlus_FontFamilyDispose($hFontFamily)
	_GDIPlus_FontDispose($hFont)
	_GDIPlus_StringFormatDispose($hFormat)
	_GDIPlus_BrushDispose($hBrush)
EndFunc


Func _CheckHoverButton($idControl, $iState, $hGraphics, $sText, $sFont, $iFontSize, $iLeftString, $iTopString, $iLeft, $iTop, $iWidth, $iHeight)
	$aMousePos = GUIGetCursorInfo($hGui)
	If $aMousePos[4] = $idControl Then
		If $iState = 0 Then
			_GDIPlus_GraphicsFillRect($hGraphics, $iLeft, $iTop, $iWidth, $iHeight, $hBrush_Hover)
			_DrawLabel($hGraphics, $sText, $iLeftString, $iTopString, $sFont, $iFontSize, 0xFFFFFFFF)
			$iState = 1
		EndIf
	Else
		If $iState = 1 Then
			_GDIPlus_GraphicsFillRect($hGraphics, $iLeft, $iTop, $iWidth, $iHeight, $hBrush)
			_DrawLabel($hGraphics, $sText, $iLeftString, $iTopString, $sFont, $iFontSize, 0xFFFFFFFF)
			$iState = 0
		EndIf
	EndIf
EndFunc

Alles anzeigen

Bin dankbar um Antworten.

Lg NO1

**autoiter**

Hallo @NO1 :-),

Du rufst die Funktion in Schleife auf und gibst als Parameter $iBtnState mit. In der Funktion wertest du das als $iState aus. Das macht deine Prüfung $iState 1 oder 0 ist natürlich sinnlos. Beim Aufruf der Funktion ist $iState immer 0.

Ersetze $iBtnState = 0 durch $iState = 0 (globale Variable) und lass $iBtnState und auch $iState als Funktionsparameter weg. Dann müsste auch deine Abfrage funktionieren.

AutoIt

Local $iBtnState = 0	


...


_CheckHoverButton($idBtn, $iBtnState, $hGraphics, "Test", "Arial", 18, 128, 34, 105, 30, 90, 30)

Edit: Wenn du die Variable nur in dieser Funktion auswerten musst, kannst du statt einer globalen Variable $iState auch in der Funktion (vllt. erste Zeile) die Variable local zu deklarieren: Local Static $iState = 0

Friesel

Hi!

Wenn du es so machst, wie autoiter es empfiehlt (ich würde allerdings ein Local Static Flag verwenden), wirst du feststellen, daß der Aufruf von _GDIPlus_GraphicsFillRect im else Zweig einen Fehler wirft.

Da ich aber im Moment weder Zeit, noch Lust habe, den Fehler zu ergründen und außerdem kein großer Fan von GDI bin, hier ein Vorschlag zur Umsetzung des Hover Buttons mit Labels:

Spoiler anzeigen

AutoIt

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>


Global $hGui = GUICreate("Hover Label", 400, 70)
Global $idLabelBackground = GUICtrlCreateLabel("", 17, 17, 366, 36)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0xF0F0F0)
Global $idLabelFrame = GUICtrlCreateLabel("", 19, 19, 362, 32, $SS_BLACKFRAME)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $idLabelHover = GUICtrlCreateLabel("Please hover brother!", 20, 20, 360, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlSetFont(-1, 12, 400)


GUISetState()


Global $bHoverFlag = 0
Do
	$idMsg = GUIGetMsg()
	Switch $idMsg
		Case $idLabelHover
			MsgBox(0, "", "Successfully hovered!")
	EndSwitch
	$aMousePos = GUIGetCursorInfo($hGui)
	Switch IsArray($aMousePos)
		Case True
			Select
				Case $aMousePos[4] = $idLabelHover And $bHoverFlag = 0
					GUICtrlSetBkColor($idLabelHover, 0x00FF00)
					GUICtrlSetBkColor($idLabelBackground, 0x000000)
					GUICtrlSetData($idLabelHover, "Click me now!")
					GUICtrlSetFont($idLabelHover, 16, 800)
					$bHoverFlag = 1
				Case $aMousePos[4] <> $idLabelHover And $bHoverFlag = 1
					GUICtrlSetBkColor($idLabelHover, 0xFF0000)
					GUICtrlSetBkColor($idLabelBackground, 0xF0F0F0)
					GUICtrlSetData($idLabelHover, "Please hover brother!")
					GUICtrlSetFont($idLabelHover, 12, 400)
					$bHoverFlag = 0
			EndSelect
	EndSwitch
Until $idMsg = $GUI_EVENT_CLOSE

Alles anzeigen

Ist ganz flott in 10 Minuten runtergeschrieben und läßt sich vermutlich eleganter lösen, aber es sollte gut verständlich sein und zeigen, wie einfach man es sich machen kann...ganz ohne GDI
Erweiterte Animationen, wie bei "OnClick" sind mit Labels auch kein Problem...

Beste Grüße, Friesel

**Bitnugger**

Zitat von autoiter

Dann müsste auch deine Abfrage funktionieren.

Was es aber nicht tut...

Für "ButtonHover" gibt es übrigens mindestens zwei UDFs... im Anhang findest du die, die ich dafür verwende...

@Friesel
Dein Ansatz ist sehr kurz und einfach, aber "Polling" ist immer eine schlechte Lösung... viel besser (effizienter) ist es, die entsprechende Message auszuwerten, so wie es die UDF macht.

NO1 :-)

Also ich hab Eure Antworten erst jetzt lesen können.

Erst einmal viiieeelen Dank.
Manchmal bleibt man bei den einfachsten Problemen hängen. Hab den State in der Funktion mitgegeben wollen, da ich die Funktion öfters benutze und dann einfach nur die Parameter ändern muss.
Ich verwende jetzt autoiter's Lösung. Nix gegen Eure Lösungen, aber die passt halt in diesem Fall am Besten.

Um einer Funktion eine globale Variable zu übergeben kann ich aber ByRef verwenden, oder?

MfG NO1

**Bitnugger**

Kannst du, ist aber nicht notwendig, da globale Variablen an jeder beliebigen Stelle im Script geändert werden können.

Byref ist sehr empfehlenswert, wenn große Datenmengen (Strings/Arrays) an eine Funktion übergeben werden, da in diesem Fall lediglich eine Referenz (ein Zeiger) auf die Variable an die Funktion übergeben wird. Ohne ByRef wird eine Kopie der Variable erstellt und an die Funktion übergeben, was vor allem bei sehr großen Arrays extrem viel Zeit kostet.

Hier kannst du es selbst auf Deutsch nachlesen: https://autoit.de/onlinehilfe/keywords/Func.htm

Du solltest dir allerdings dringend angewöhnen, globale Variablen auch als solche erkenntlich zu machen. Das ist vor allem bei einer späteren Fehlersuche ungemein hilfreich! (Huhu @Oscar )

Global $g_hGUI, $g_iBtnState = 0, ...

NO1 :-)

Ok, vielen Dank.