Tray Recycler

ICE Tec 82

Hallo, ich möchte ein Programm vorstellen! TrayRecycler.exe ist ein Papierkorb im System-Tray von Microsoft (Benachrichtigungsfeld). TrayRecycler.exe räumt auch den Computer auf (Datenträger bereinigen und Säubere Temp Ordner). Ihr könnt jetzt den Papierkorb vom Desktop verstecken.

ich beantworte aber keine Fragen und so Sachen, ich habe Aphasie durch Schlaganfall!
Über Änderungsvorschläge würde ich mich schon freuen!

AutoIt: Papierkorb.au3

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=D:\Meine Apps\tools\gfx\trash.ico
#AutoIt3Wrapper_Outfile=TrayRecycler.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_Comment=Tray Recycler
#AutoIt3Wrapper_Res_Description=Tray Recycler
#AutoIt3Wrapper_Res_Fileversion=1.0.0.1
#AutoIt3Wrapper_Res_LegalCopyright=© ICE Tec. All rights reserved.
#AutoIt3Wrapper_Res_Language=1031
#AutoIt3Wrapper_Res_Field=CompanyName|ICE Tec
#AutoIt3Wrapper_Res_Field=OriginalFileName|TrayRecycler.exe
#AutoIt3Wrapper_Res_Field=ProductName|Tray Recycler
#AutoIt3Wrapper_Res_Field=ProductVersion|1.0.0.1
#AutoIt3Wrapper_Run_Tidy=y
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <Constants.au3>


Opt('MustDeclareVars', 1)
Opt("TrayMenuMode", 1)


Global $Recycle, $option, $cleanmgr, $cleantempdir, $aboutitem, $exititem, $i, $autorun, $Diskclean
Global $iRecycleBin_Items, $SHQUERYRBINFO, $Query, $OpenRecycle, $Recyclerdel, $var, $msg
Global Const $hdd = DriveGetDrive("FIXED")
Global Const $path = @ScriptFullPath
Global Const $reg1 = "HKLM\Software\Microsoft\Windows\CurrentVersion\Run"
Global Const $reg2 = "Tray Recycler"
Global Const $MIM_APPLYTOSUBMENUS = 0x80000000, $MIM_BACKGROUND = 0x00000002


$aboutitem = TrayCreateItem("Tray Recycler")
TrayCreateItem("")
$option = TrayCreateMenu("Optionen")
$autorun = TrayCreateItem("Mit Windows starten", $option)
TrayCreateItem("")
$Diskclean = TrayCreateMenu("Datenträger aufräumen")
$cleanmgr = TrayCreateItem("Datenträger bereinigen", $Diskclean)
TrayCreateItem("", $Diskclean)
$cleantempdir = TrayCreateItem("Säubere Temp Ordner", $Diskclean)
TrayCreateItem("")
$Recycle = TrayCreateMenu("Papierkorb")
$OpenRecycle = TrayCreateItem("Papierkorb öffnen", $Recycle)
TrayCreateItem("", $Recycle)
$Recyclerdel = TrayCreateItem("Papierkorb leeren", $Recycle)
TrayCreateItem("")
$exititem = TrayCreateItem("Beenden")
autostartcheck()
itemcheck()
SetMenuColor(0, 0xEEBB99) ; BGR Farbwert, '0' bedeutet, dass das Tray Kontext-Menü dies selbst regelt
SetMenuColor($option, 0x0099FF) ; BGR Farbwert
SetMenuColor($Diskclean, 0x0099FF) ; BGR Farbwert
SetMenuColor($Recycle, 0x0099FF) ; BGR Farbwert
TraySetClick(2)
TraySetToolTip("Tray Recycler")
TraySetState($TRAY_ICONSTATE_SHOW)




While 1
	itemcheck()
	$msg = TrayGetMsg()
	Select
		Case $msg = $autorun
			autostart()
		Case $msg = $OpenRecycle
			TrayItemSetState($OpenRecycle, $TRAY_UNCHECKED)
			RecycleOpen()
		Case $msg = $cleanmgr
			TrayItemSetState($cleanmgr, $TRAY_UNCHECKED)
			CleanDisc()
		Case $msg = $cleantempdir
			TrayItemSetState($cleantempdir, $TRAY_UNCHECKED)
			SplashTextOn("Tray Recycler", "" & @LF & "Säubere Temp Ordner", 200, 85, -1, -1, 0, "", 12, 600)
			tempdir()
			SplashOff()
		Case $msg = $Recyclerdel
			TrayItemSetState($Recyclerdel, $TRAY_UNCHECKED)
			Recycle()
		Case $msg = $aboutitem
			TrayItemSetState($aboutitem, $TRAY_UNCHECKED)
			MsgBox(8256, "Tray Recycler", StringReplace("           Why go you to High School, when you can go High to School _ _ _                                             Tray Recycler v1.0.0.1 _ _                     Copyrights: © ICE Technologie. All rights reserved. _                     Greetings from GERMANY (Singen am Hohentwiel)", "_", @CR))
		Case $msg = $exititem
			ExitLoop
	EndSelect
WEnd


Func autostartcheck()
	RegRead($reg1, $reg2)
	If @error Then
		TrayItemSetState($autorun, $TRAY_UNCHECKED)
	Else
		TrayItemSetState($autorun, $TRAY_CHECKED)
	EndIf
EndFunc   ;==>autostartcheck


Func autostart()
	RegRead($reg1, $reg2)
	If @error Then
		RegWrite($reg1, $reg2, "REG_SZ", $path)
		TrayItemSetState($autorun, $TRAY_CHECKED)
	Else
		RegDelete($reg1, $reg2)
		TrayItemSetState($autorun, $TRAY_UNCHECKED)
	EndIf
EndFunc   ;==>autostart


Func itemcheck()
	If ProcessExists("DeviceDisplayObjectProvider.exe") Then Return
	$SHQUERYRBINFO = DllStructCreate("align 1;int;int64;int64")
	DllStructSetData($SHQUERYRBINFO, 1, DllStructGetSize($SHQUERYRBINFO))
	$Query = DllCall("shell32.dll", "int", "SHQueryRecycleBin", "str", $hdd & "\", "ptr", DllStructGetPtr($SHQUERYRBINFO))
	If DllStructGetData($SHQUERYRBINFO, 3) = 0 Then
		TraySetIcon(@SystemDir & "\shell32.dll", 32)
	Else
		TraySetIcon(@SystemDir & "\shell32.dll", 33)
	EndIf
EndFunc   ;==>itemcheck


Func Recycle()
	FileRecycleEmpty($hdd)
	SoundPlay(@WindowsDir & "\media\recycle.wav")
EndFunc   ;==>Recycle


Func RecycleOpen()
	Run("explorer.exe ::{645FF040-5081-101B-9F08-00AA002F954E}")
EndFunc   ;==>RecycleOpen


Func CleanDisc()
	For $i = 1 To 1000
		Local $var = RegEnumKey("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches", $i)
		If @error <> 0 Then ExitLoop
		Local $regread = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\" & $var, "StateFlags1488")
		If $regread = False Then
			RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\" & $var, "StateFlags1488", "REG_DWORD", "2")
		EndIf
	Next
	Run(@SystemDir & "\cleanmgr.exe /sagerun:1488")
EndFunc   ;==>CleanDisc


Func tempdir()


	Local $search = FileFindFirstFile(@UserProfileDir & "\AppData\Local\Temp\*.*")
	While 1
		Local $file = FileFindNextFile($search)
		If @error Then Return True
		DirRemove(@UserProfileDir & "\AppData\Local\Temp\" & $file, 1)
		FileDelete(@UserProfileDir & "\AppData\Local\Temp\" & $file)
	WEnd
	FileClose($search)


	Local $search4 = FileFindFirstFile(@WindowsDir & "\Temp\*.*")
	While 1
		Local $file4 = FileFindNextFile($search4)
		If @error Then Return
		DirRemove(@WindowsDir & "\Temp\" & $file4, 1)
		FileDelete(@WindowsDir & "\Temp\" & $file4)
	WEnd
	FileClose($search4)


	Local $search3 = FileFindFirstFile(@TempDir & "\*.*")
	While 1
		Local $file3 = FileFindNextFile($search3)
		If @error Then Return
		DirRemove(@TempDir & "\" & $file3, 1)
		FileDelete(@TempDir & "\" & $file3)
	WEnd
	FileClose($search3)


EndFunc   ;==>tempdir


Func SetMenuColor($nMenuID, $nColor)
	Local $hMenu = TrayItemGetHandle($nMenuID) ; Holt den internen Menü-Handle


	Local $hBrush = DllCall("gdi32.dll", "hwnd", "CreateSolidBrush", "int", $nColor)
	$hBrush = $hBrush[0]


	Local $stMenuInfo = DllStructCreate("dword;dword;dword;uint;dword;dword;ptr")
	DllStructSetData($stMenuInfo, 1, DllStructGetSize($stMenuInfo))
	DllStructSetData($stMenuInfo, 2, BitOR($MIM_APPLYTOSUBMENUS, $MIM_BACKGROUND))
	DllStructSetData($stMenuInfo, 5, $hBrush)


	DllCall("user32.dll", "int", "SetMenuInfo", "hwnd", $hMenu, "ptr", DllStructGetPtr($stMenuInfo))
EndFunc   ;==>SetMenuColor

Alles anzeigen

**Bitnugger**

Zeile 2: Das Icon kann nicht gefunden werden!
Zeile 24: $hdd ist ein Array, in Zeile 109 und 118 verwendest du dieses aber als String-Variable... das kann so natürlich NICHT funktionieren.
Zeile 47 und 58... so kurz hintereinander dieselbe Funktion ausfühen?
Diese Funktion mit in die While-Schleife einzubauen, sollte mit 3x Lebenslänglich bestraft werden!
In der While-Schleife wäre ein Switch...Case...EndSwitch viel praktischer!

Die Funktion tempdir() ist grau...
Zeile 140 z. B.:
~~DirRemove(@UserProfileDir & "\AppData\Local\Temp\" & $file, 1)~~
DirRemove(@LocalAppDataDir & "\Temp\" & $file, 1)

Hehe... und du kannst in ..\TEMP\.. doch nicht einfach auf Teufelkommaraus alles löschen... das hat wenig bis gar keinen Mehrwert und mich würde es auch absolut nicht wundern, wenn sich dein Windows in absehbarer Zeit verabschiedet!

Viele Dinge erledigst du wie ein "Profi" mit DllCall... obwohl du noch mit den Grundlagen zu kämpfen hast. Wenn du z. B. mit CreateSolidBrush einen Brush erzeugst, musst du ihn später auch irgendwann wieder entsorgen.

Übrigens... nur die *.EXE in das Archiv zu packen, ist auch keine feine Art!!!

Na, egal... ist ja nicht mein PC... ich habe es mal eben ein wenig umgeschrieben... damit du sehen kannst, wie ich das von der Struktur her in etwa angehen würde... allerdings habe ich das Script bei mir NICHT getestet und zudem verwende ich dafür eh den CCleaner.

Die Benutzung des Scripts ohne vorherige Überprüfung geschieht also auf eigene Gefahr!

Tray Recycler

AutoIt

;-- TIME_STAMP   2017-06-28 16:25:34   v 0.1


#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=D:\Meine Apps\tools\gfx\trash.ico
#AutoIt3Wrapper_Outfile=TrayRecycler.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_Comment=Tray Recycler
#AutoIt3Wrapper_Res_Description=Tray Recycler
#AutoIt3Wrapper_Res_Fileversion=1.0.0.1
#AutoIt3Wrapper_Res_LegalCopyright=© ICE Tec. All rights reserved.
#AutoIt3Wrapper_Res_Language=1031
#AutoIt3Wrapper_Res_Field=CompanyName|ICE Tec
#AutoIt3Wrapper_Res_Field=OriginalFileName|TrayRecycler.exe
#AutoIt3Wrapper_Res_Field=ProductName|Tray Recycler
#AutoIt3Wrapper_Res_Field=ProductVersion|1.0.0.1
#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7 ; Uncomment this line to Au3Check!
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#Region ;************ Includes ************
#include <WinAPI.au3>
#include <TrayConstants.au3>
#include <File.au3>
;~ #include <Constants.au3>;~~~
#EndRegion ;************ Includes ************


#Region ;************ Global ************
Opt('MustDeclareVars', 1)
Opt("TrayMenuMode", 1)


Global $tagSHQUERYRBINFO = DllStructCreate("align 1;int;int64;int64")
DllStructSetData($tagSHQUERYRBINFO, 1, DllStructGetSize($tagSHQUERYRBINFO))


Global Const $MIM_APPLYTOSUBMENUS = 0x80000000, $MIM_BACKGROUND = 0x00000002
; https://autoit.de/onlinehilfe/functions/FileRecycleEmpty.htm
Global Const $g_sRegRunKey = "HKLM\Software\Microsoft\Windows\CurrentVersion\Run", $g_sRegRunValue = "Tray Recycler"
Global $g_idTrayAboutItem, $g_idTrayOptionMenu, $g_idTrayAutoRun, $g_idTrayDiskCleanMenu, $g_idTrayCleanMgr, $g_idTrayCleanTempDirItem, $g_idTrayRecycleMenu, $g_idTrayOpenRecycleItem, $g_idTrayRecyclerCleanItem, $g_idTrayExitItem
#EndRegion ;************ Global ************


_Main()


Func _Main()
	#Region ;************ TrayMenu ************
	Local $iStart, $iColor = 0x0099FF, $hBrush = _CreateSolidBrush($iColor) ; BGR Farbwert


	$g_idTrayAboutItem = TrayCreateItem("Tray Recycler")
	TrayCreateItem("")
	$g_idTrayOptionMenu = TrayCreateMenu("Optionen")
	$g_idTrayAutoRun = TrayCreateItem("Mit Windows starten", $g_idTrayOptionMenu)
	TrayCreateItem("")
	$g_idTrayDiskCleanMenu = TrayCreateMenu("Datenträger aufräumen")
	$g_idTrayCleanMgr = TrayCreateItem("Datenträger bereinigen", $g_idTrayDiskCleanMenu)
	TrayCreateItem("", $g_idTrayDiskCleanMenu)
	$g_idTrayCleanTempDirItem = TrayCreateItem("Säubere Temp Ordner", $g_idTrayDiskCleanMenu)
	TrayCreateItem("")
	$g_idTrayRecycleMenu = TrayCreateMenu("Papierkorb")
	$g_idTrayOpenRecycleItem = TrayCreateItem("Papierkorb öffnen", $g_idTrayRecycleMenu)
	TrayCreateItem("", $g_idTrayRecycleMenu)
	$g_idTrayRecyclerCleanItem = TrayCreateItem("Papierkorb leeren", $g_idTrayRecycleMenu)
	TrayCreateItem("")
	$g_idTrayExitItem = TrayCreateItem("Beenden")


	; '0' bedeutet, dass das Tray Kontext-Menü dies selbst regelt
	Local $aMenus = [0, $g_idTrayOptionMenu, $g_idTrayDiskCleanMenu, $g_idTrayRecycleMenu]
	For $i = 0 To UBound($aMenus) - 1 Step 1
		_SetMenuColor($aMenus[$i], $hBrush)
	Next
	TraySetClick(2)
	TraySetToolTip("Tray Recycler")
	TraySetState($TRAY_ICONSTATE_SHOW)
	#EndRegion ;************ TrayMenu ************


	_AutoStart() ; Check


	AdlibRegister(_RecycleCheck, 30 * 1000) ; Alle 30 min Papierkörbe überprüfen...


	#Region ;************ SwitchLoop ************
	While 1
		Switch TrayGetMsg()
			Case $g_idTrayAutoRun
				$iStart = _AutoStart() ; prüfen
				_AutoStart(($iStart = 1) ? 2 : 1)
			Case $g_idTrayOpenRecycleItem
				TrayItemSetState($g_idTrayOpenRecycleItem, $TRAY_UNCHECKED)
				_RecycleOpen()
			Case $g_idTrayCleanMgr
				TrayItemSetState($g_idTrayCleanMgr, $TRAY_UNCHECKED)
				_CleanDisc()
			Case $g_idTrayCleanTempDirItem
				TrayItemSetState($g_idTrayCleanTempDirItem, $TRAY_UNCHECKED)
				SplashTextOn("Tray Recycler", "" & @LF & "Säubere Temp Ordner", 200, 85, -1, -1, 0, "", 12, 600)
				_CleanTempDirs()
				SplashOff()
			Case $g_idTrayRecyclerCleanItem
				TrayItemSetState($g_idTrayRecyclerCleanItem, $TRAY_UNCHECKED)
				_Recycle()
			Case $g_idTrayAboutItem
				TrayItemSetState($g_idTrayAboutItem, $TRAY_UNCHECKED)
				MsgBox(8256, "Tray Recycler", StringReplace("           Why go you to High School, when you can go High to School _ _ _                                             Tray Recycler v1.0.0.1 _ _                     Copyrights: © ICE Technologie. All rights reserved. _                     Greetings from GERMANY (Singen am Hohentwiel)", "_", @CR))
			Case $g_idTrayExitItem
				ExitLoop
		EndSwitch
	WEnd
	#EndRegion ;************ SwitchLoop ************


	; Brush wieder entsorgen...
	DllCall("gdi32.dll", "bool", "DeleteObject", "handle", $hBrush)
EndFunc   ;==>_Main


Func _AutoStart($iStart = 0)
	Local $iCheck, $iRet


	Switch $iStart
		Case 0 ; Check
			$iCheck = (RegRead($g_sRegRunKey, $g_sRegRunValue) = '') ? $TRAY_UNCHECKED : $TRAY_CHECKED
			TrayItemSetState($g_idTrayAutoRun, $iCheck)
			Return ($iCheck = $TRAY_CHECKED) ? 1 : 0
		Case 1 ; AutoStart aktivieren
			$iRet = 1
			$iCheck = $TRAY_CHECKED
			RegWrite($g_sRegRunKey, $g_sRegRunValue, "REG_SZ", @ScriptFullPath)
		Case 2 ; AutoStart deaktivieren
			$iRet = 0
			$iCheck = $TRAY_UNCHECKED
			RegDelete($g_sRegRunKey, $g_sRegRunValue)
	EndSwitch


	TrayItemSetState($g_idTrayAutoRun, $TRAY_UNCHECKED)


	Return $iRet
EndFunc   ;==>_AutoStart


Func _RecycleCheck()
	Local Static $aFixedDriveList = DriveGetDrive("FIXED")
	; DeviceDisplayObjectProvider.exe
	; The process known as Device Display Object Function Discovery Provider belongs to Windows Operating System.
	; The original DeviceDisplayObjectProvider.exe is an important part of Windows and it is located in the C:\Windows\System32 folder.
	If ProcessExists("DeviceDisplayObjectProvider.exe") Then Return


	For $i = 1 To $aFixedDriveList[0] Step 1
		DllCall("shell32.dll", "int", "SHQueryRecycleBin", "str", $aFixedDriveList[$i] & "\", "ptr", DllStructGetPtr($tagSHQUERYRBINFO))
	Next


	TraySetIcon(@SystemDir & "\shell32.dll", (DllStructGetData($tagSHQUERYRBINFO, 3) = 0) ? 32 : 33)
EndFunc   ;==>_RecycleCheck


Func _Recycle()
	; Wenn kein Verzeichnispfad angegeben wird, werden alle Papierkörbe geleert!
	If FileRecycleEmpty() Then SoundPlay(@WindowsDir & "\media\recycle.wav")
EndFunc   ;==>_Recycle


Func _RecycleOpen()
	Run("explorer.exe ::{645FF040-5081-101B-9F08-00AA002F954E}")
EndFunc   ;==>_RecycleOpen


Func _CleanDisc()
	Local $sKey, $iNum = 0


	While 1
		$sKey = RegEnumKey("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches", $iNum)
		If @error Then ExitLoop
		RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\" & $sKey, "StateFlags1488")
		If @error Then RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\" & $sKey, "StateFlags1488", "REG_DWORD", "2")
		$iNum += 1
	WEnd


	Run(@SystemDir & "\cleanmgr.exe /sagerun:1488")
EndFunc   ;==>_CleanDisc


Func _CleanTempDirs()
	Local $aDirs = [@LocalAppDataDir & "\Temp\", @WindowsDir & "\Temp\", @TempDir & "\"], $iLoop, $sAttrib, $aFileTime, $sTimeStamp
	For $i = 0 To UBound($aDirs) - 1 Step 1
		Local $aFileList = _FileListToArrayRec($aDirs[$i], "*", $FLTAR_FILESFOLDERS, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH)
		If @error Then ContinueLoop ; Nächstes Verzeichnis durchsuchen...
		$iLoop = 0
		Do
			$iLoop += 1
			$sAttrib = FileGetAttrib($aFileList[$iLoop])
			$aFileTime = FileGetTime($aFileList[$iLoop])
			$sTimeStamp = StringFormat('%s%s%s', $aFileTime[0], $aFileTime[1], $aFileTime[2]) ; Jahr, Monat, Tag
			If $sTimeStamp = StringFormat('%s%s%s', @YEAR, @MON, @MDAY) Then ContinueLoop ; Nicht löschen, wenn es von heute ist!
			While 1
				Select
					Case StringInStr($sAttrib, 'R') ; Schreibgeschützt?
						FileSetAttrib($aFileList[$iLoop], '-R')
						$sAttrib = StringReplace($sAttrib, 'R', '')
					Case StringInStr($sAttrib, 'D') ; Verzeichnis?
						DirRemove($aFileList[$iLoop], $DIR_DEFAULT) ; (0) = (default) deletes the folder, only if it is empty
						ExitLoop ; Weiter mit der Do-Schleife...
					Case Else
						FileDelete($aFileList[$iLoop])
						ExitLoop ; Weiter mit der Do-Schleife...
				EndSelect
			WEnd
		Until $iLoop = $aFileList[0]
	Next
EndFunc   ;==>_CleanTempDirs


Func _SetMenuColor($idTrayMenu, $hBrush)
	Local $hTrayMenu = TrayItemGetHandle($idTrayMenu) ; Holt das Handle des TrayMenüs


	Local $tagMenuInfo = DllStructCreate("dword;dword;dword;uint;dword;dword;ptr")
	DllStructSetData($tagMenuInfo, 1, DllStructGetSize($tagMenuInfo))
	DllStructSetData($tagMenuInfo, 2, BitOR($MIM_APPLYTOSUBMENUS, $MIM_BACKGROUND))
	DllStructSetData($tagMenuInfo, 5, $hBrush)


	DllCall("user32.dll", "int", "SetMenuInfo", "hwnd", $hTrayMenu, "ptr", DllStructGetPtr($tagMenuInfo))
EndFunc   ;==>_SetMenuColor


Func _CreateSolidBrush($iColor)
	Local $aResult = DllCall("gdi32.dll", "handle", "CreateSolidBrush", "INT", $iColor)
	If @error Then Return SetError(@error, @extended, 0)


	Return $aResult[0]
EndFunc   ;==>_CreateSolidBrush

Alles anzeigen

ICE Tec 82

danke Bitnugger über Änderung!

Zitat von Bitnugger

Viele Dinge erledigst du wie ein "Profi" mit DllCall... obwohl du noch mit den Grundlagen zu kämpfen hast.

das stimmt, ich habe mir das programmieren selber beigebracht. bevor ich in den knast kamm habe ich Speed (Amphétamine) konsumiert. Auf Amphétamine hast du ausdauer