Guten Tag,
ich bräuchte ein Skript welches mir automatisch nach 15 sekunden eine Datei (dfq Format) in ein bestimmtes Laufwerk verschiebt wenn ich es aktiviere.
Pfad hab ich jetzt noch nicht zur Hand, würde ich dann selbst einfügen wenn möglich.
Herzlichen Dank schon mal im vorraus.
Sprich sowas wie von wegen, wenn zufällig eine datei mit der endung .dfg, in einem speziellem ordner, auftaucht dann soll sie an einen bestimmten ort mit dem selben namen verschoben werden?
Edit. oder sowas wie hey ich stecke jetzt einen usb stick ran & wenn ich dann F1 z.b. drücke dann verschiebt sich autonom ne datei auf den stick?
Das erstere^^
Also ich klicke das skript an
Nun wartest du 15 sec
jetzt ist hier eine datei drin
diese verschiebst du mir mit dem selben namen in den anderen Ordner
fertig
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;Author: Candyland 11.09.2017 15:50
Local $lini, $lFrom, $lTo, $arItems, $sTemp, $e_move
$lini = @ScriptDir & "\config.ini"
if Not FileExists($lini) Then
IniWrite($lini, "Localisation", "From", @ScriptDir & "\")
IniWrite($lini, "Localisation", "To", @ScriptDir & "\")
EndIf
$lFrom = IniRead($lini, "Localisation", "From", @ScriptDir & "\")
$lTo = IniRead($lini, "Localisation", "To", @ScriptDir & "\")
For $i = 15 To 1 Step -1
ConsoleWrite($i & ' Seconds Left' & @CR)
Sleep(1000)
Next
$arItems = _RecursiveFileListToArray($lFrom, '\.dfq\z', 1)
if $arItems[0] = 0 Then
MsgBox(0,"", "There are no *.dfq files found in: " & $lFrom)
Exit
EndIf
For $n = 1 To $arItems[0] Step 1
FileSetAttrib($arItems[$n], '-RSH')
$sTemp = $lTo & StringTrimLeft($arItems[$n], StringInStr($arItems[$n], '\', 0, -1))
ConsoleWrite('Moving ' & $arItems[$n] & @CRLF)
$e_move = FileMove($arItems[$n], $lTo, 1)
if $e_move = 0 Then ConsoleWrite('Cant Move ' & $arItems[$n] & @CRLF)
Next
;Author: Oscar (Autoit.de)
;Peace Oscar deine Func is PORN
Func _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
Local $hSearch, $sFile, $sReturn = ''
If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
$hSearch = FileFindFirstFile($sPath & '*.*')
If @error Or $hSearch = -1 Then Return SetError(1, 0, $sReturn)
While True
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
$sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
ContinueLoop
EndIf
If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
WEnd
FileClose($hSearch)
If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
Return $sReturn
EndFunc ;==>_RecursiveFileListToArrayEasy Peazy Lemon Squezzy.
EDIT: achja du kannst die pfade selbst in der config.ini eintragen
subba danke:)
Willst Du wirklich nur einmalig (nach 15 Sekunden) das Quellverzeichnis überprüfen und die evtl. enthaltene "dfq"-Datei verschieben?
Ich hatte das jetzt eher so verstanden, dass das Script gestartet wird und dann endlos läuft und darauf wartet, dass im Quellverzeichnis eine "dfq"-Datei auftaucht.
Und wenn das passiert, dann soll diese Datei ins Zielverzeichnis verschoben werden. Falls Du das so gemeint hast, dann wäre das hier eine mögliche Lösung:
#include <APIShellExConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>
Global Const $sSourceDir = @ScriptDir & '\SourceDir\'
Global Const $sDestDir = @ScriptDir & '\DestDir\'
If Not FileExists($sSourceDir) Then
If Not DirCreate($sSourceDir) Then
MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'Unable to create SourceDir.')
Exit
EndIf
EndIf
If Not FileExists($sDestDir) Then
If Not DirCreate($sDestDir) Then
MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'Unable to create DestDir')
Exit
EndIf
EndIf
OnAutoItExitRegister('OnAutoItExit')
Global $hGui = GUICreate('dfq-Move', 600, 400)
Global $idListview = GUICtrlCreateListView('Uhrzeit|Datei', 10, 10, 580, 380)
GUICtrlSetFont(-1, 12, 400, 2, 'Arial')
Global $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $iID = _WinAPI_ShellChangeNotifyRegister($hGui, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $sSourceDir, 1)
If @error Then
MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'Window does not registered.')
Exit
EndIf
GUISetState(@SW_SHOW, $hGui)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
#forceref $hWnd, $iMsg
Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
If BitAND($lParam, $SHCNE_CREATE) And StringRight($sPath, 4) = '.dfq' Then
If FileMove($sPath, $sDestDir, 1) Then
GUICtrlCreateListViewItem(StringFormat('%02d:%02d:%02d|%s', @HOUR, @MIN, @SEC, $sPath), $idListview)
_GUICtrlListView_SetColumnWidth($idListview, 0, $LVSCW_AUTOSIZE)
_GUICtrlListView_SetColumnWidth($idListview, 1, $LVSCW_AUTOSIZE)
EndIf
EndIf
EndFunc ;==>WM_SHELLCHANGENOTIFY
Func OnAutoItExit()
If $iID Then _WinAPI_ShellChangeNotifyDeregister($iID)
EndFunc ;==>OnAutoItExitOh vielen dank Oscar :), aber das Skript von Candyland funzt herrvorragend.
Tausend dank an alle