Prüfen, ob eine Datei geöffnet ist

Mikki

Hallo zusammen,

ich habe jetzt mal weiter probiert und mir ist folgendes aufgefallen. Unten steht mein Code, den ich jetzt auf das wesentliche reduziert habe.

C

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
#include <ButtonConstants.au3>



Global $Window_Main
Global $Button

Global $SECTION_1 = "1.Quelle", $SECTION_2 = "2.Ziel"
Global $KEY_1 = "Quellverzeichnis", $KEY_2 = "Zielverzeichnis"

Global $INI_READ_SECTION_1, $INI_READ_SECTION_2, $INI_READ_KEY_1, $INI_READ_KEY_2

Global $File_Check


;~  Startfenster erzeugen
    Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus
    $Window_Main = GUICreate("Movetest", 200, 60)
    GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSE_clicked_Window_Main")
    GUISetBkColor(0xffffff, $Window_Main)

    $Button = GUICtrlCreateButton("Test", 10, 20, 180, 30, $BS_DEFPUSHBUTTON)
    GUICtrlSetOnEvent($Button, "File_Move")
    GUISetState(@SW_SHOW)

    While 1
    Wend

    Func File_Move()

        $INI_READ_SECTION_1 = IniRead("C:\Users\Mikki\Desktop\move_test.ini", $SECTION_1, $KEY_1, "Error")
        MsgBox(262144, 'Debug line ~' & @ScriptLineNumber, 'Selection:' & @CRLF & '$INI_READ_SECTION_1' & @CRLF & @CRLF & 'Return:' & @CRLF & $INI_READ_SECTION_1) ;### Debug MSGBOX
        $INI_READ_SECTION_2 = IniRead("C:\Users\Mikki\Desktop\move_test.ini", $SECTION_2, $KEY_2, "Error")
        MsgBox(262144, 'Debug line ~' & @ScriptLineNumber, 'Selection:' & @CRLF & '$INI_READ_SECTION_2' & @CRLF & @CRLF & 'Return:' & @CRLF & $INI_READ_SECTION_2) ;### Debug MSGBOX


        $File_Check = _WinAPI_FileInUse($INI_READ_SECTION_1 & "\*.xlsx")
        MsgBox(262144, 'Debug line ~' & @ScriptLineNumber, 'Selection:' & @CRLF & '$File_Check' & @CRLF & @CRLF & 'Return:' & @CRLF & $File_Check) ;### Debug MSGBOX

    EndFunc

    Func CLOSE_clicked_Window_Main()
    Exit
    EndFunc

Alles anzeigen

Bei $File_Check = _WinAPI_FileInUse($INI_READ_SECTION_1 & "\*.xlsx") bekomme ich als Rückgabewert eine 0, egal ob eine Liste geöffnet ist oder nicht.

Schreibe ich allerdings den kompletten Pfad mit Endung hin: $File_Check = _WinAPI_FileInUse("C:\Users\Mikki\Documents\test.xlsx") funktioniert es wie gewollt.

Meine Frage ist nun: Ist _WinAPI_FileInUse die richtige Wahl? Denn es wäre schön, wenn das Script mit den variablen Dateien umgehen könnte.

LG Mikki

**Oscar**

Zitat von Mikki

Bei $File_Check = _WinAPI_FileInUse($INI_READ_SECTION_1 & "\*.xlsx") bekomme ich als Rückgabewert eine 0, egal ob eine Liste geöffnet ist oder nicht.

Das ist ja auch kein Wunder!

_WinAPI_FileInUse unterstützt keine Wildcards.

Poste bitte mal den Inhalt Deiner Inidatei.

Mikki

[1.Quelle]

Quellverzeichnis=C:\Users\Mikki\Documents

[2.Ziel]

Zielverzeichnis=C:\Users\Mikki\Desktop

Wenn _WinAPI_FileInUse keine Wildcards unterstützt, wie soll dann eine Dateiprüfung speziell für xlsx-Dateien funktionieren?

Gibt es nicht noch eine andere Möglichkeit?

LG Mikki

**Oscar**

Ach, in Deiner Ini stehen ja bloß die Verzeichnisse!

Dann musst Du doch mit _FileListToArray (den Parameter $bReturnPath auf TRUE setzen) erst die Dateien einlesen (dort kannst Du dann Filter setzen).

Anschließend das Array mit den Dateien durchgehen. So hast Du für _WinAPI_FileInUse den kompletten Dateinamen (mit Pfad).

**Musashi**

Hallo Mikki !

Hier mal ein kleines Testprogramm (mit Unterverzeichnis). Statt der .txt musst Du später deine xls.-Dateien verwenden

Quellcode (identisch zur zip)

AutoIt

#include <Array.au3>
#include <File.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Opt('MustDeclareVars', 1)  ; Variablen müssen vor Verwendung mit Global/Local deklariert werden

; Pfad, wo die zu verschiebenden Dateien liegen :
Global $sSourceDir = @ScriptDir & "\SourceDir"

; Pfad, in den die Dateien verschoben werden sollen :
Global $sDestinationDir = @ScriptDir & "\DestDir"

; Zähler für erfolgreich verschobene Dateien :
Global $iSuccessCounter = 0

; Ausgewählte Dateien (hier *.txt) in Array eintragen :
Global $aFileMoveList = _FileListToArray($sSourceDir, "*.txt", $FLTA_FILES, False)
Switch @error
    Case 0
        MsgBox($MB_SYSTEMMODAL, "", "Dateiliste erfolgreich angelegt")
    Case 1
        MsgBox($MB_SYSTEMMODAL, "", "Verzeichnis ungültig oder nicht gefunden")
        Exit
    Case 2
        MsgBox($MB_SYSTEMMODAL, "", "ungültig Dateifilter")
        Exit
    Case 4
        MsgBox($MB_SYSTEMMODAL, "", "Keine passenden Datei(en) gefunden")
        Exit
    Case Else
        MsgBox($MB_SYSTEMMODAL, "", "Anderer Fehler (CODE=" & @error)
        Exit
EndSwitch

_ArrayDisplay($aFileMoveList, "Dateiliste")  ; nur zur Anzeige

For $i = 1 To $aFileMoveList[0]
    ; Prüfen, ob aktuelle Datei mit einem Filelock versehen ist :
    ConsoleWrite('Datei = ' & $aFileMoveList[$i] & ' wird geprüft ' & @CRLF)
    If _WinAPI_FileInUse($sSourceDir & "\" & $aFileMoveList[$i]) Then
        ConsoleWrite('Datei = ' & $aFileMoveList[$i] & ' ist gesperrt - FileMove nicht möglich ' & @CRLF)
    Else
        If FileMove($sSourceDir & "\" & $aFileMoveList[$i], $sDestinationDir & "\" & $aFileMoveList[$i], BitOR($FC_OVERWRITE, $FC_CREATEPATH)) Then
            ConsoleWrite('Datei = ' & $aFileMoveList[$i] & ' erfolgreich verschoben ' & @CRLF)
            $iSuccessCounter += 1
        Else
            ConsoleWrite('Datei = ' & $aFileMoveList[$i] & ' Fehler bei FileMove ' & @CRLF)
        EndIf
    EndIf
Next

MsgBox($MB_SYSTEMMODAL, "Auswertung : ", $iSuccessCounter & " von " & $aFileMoveList[0] & " Dateien verschoben")

Alles anzeigen

Statt $sSourceDir und $sDestinationDir musst Du in deinem Programm später natürlich deine Pfade eintragen.

Gruß Musashi

Mikki

Genau das suche ich. Danke Musashi

Ich hätte dazu noch eine Frage:

For $i = 1 To $aFileMoveList[0]

Warum steht dort [0]?

Oscar : Ja genau. Und zwar wollte ich das so handhaben, dass man in dieser "Auftragsdatei" nur die Pfade angibt. Den Rest sollte er sich selbst suchen.

LG Mikki

**Musashi**

Hallo Mikki !

Zitat von Mikki

Genau das suche ich. Danke Musashi

Ich hätte dazu noch eine Frage:

For $i = 1 To $aFileMoveList[0]

Warum steht dort [0]?

Ich helfe Dir wirklich gerne weiter, aber Du solltest, auch in eigenem Interesse, ggf. vorher kurz in die Hilfe schauen

Immerhin bist Du ja gerade vom Status 'Anfänger' zu 'Schüler' aufgestiegen.

Tweaky freut sich sicher auch, wenn die Hilfe häufiger konsultiert würde.

Zur Frage :

_FileListToArray () gibt ein 1-D Array (also eine Liste) zurück). Im Element [0] des Arrays steht die Anzahl der Einträge.

Die Elemente 1..n enthalten die Einträge selbst.

Gruß Musashi

Mikki

Hallo Musashi

Ouh ja da steht es, sehe es gerade... Gut okay. Erst schauen, dann fragen.

Danke für eure Hilfe

Gruß Mikki