FileCopy() alle Dateien

Jasfar

Hallo zusammen,

nach langem muss ich mal wieder was in au3 schreiben, da wir auf Arbeit aber momentan viel zutun haben, benötige ich Hilfe bei einem einfachen Programm.

Es geht darum, dass wir nach einem Rechnertausch schnell die Daten per Script auf den neuen Rechner übertragen wollen. Dafür wird auf dem alten Rechner der neue als Laufwerk eingebunden. Funktioniert alles problemlos.

Nun ist es aber so, dass bei der Datenübertragung immer ein Fehler auftritt. Wahrscheinlich ist es ein Anfängerfehler, aber ich komme leider trotzdem nicht weiter.

Hier einmal das Script ab dem Zeitpunkt des Fehlers:

Code

;Daten übertragen
                                    $olddrive = "C:\Users\" & $username
                                    $newdrive = "A:\"
                                    $copy_desktop = FileCopy($olddrive & "\Desktop\*.*",$newdrive & "\Desktop\",1)
                                    If $copy_desktop = 1 Then
                                        GUICtrlSetData($progress,10)
                                    ElseIf $copy_desktop = 0 Then
                                        MsgBox(16,"Datenübertragunsfehler","Dateien vom Desktop konnten nicht kopiert werden.")
                                    EndIf
                                    $copy_bilder = FileCopy($olddrive & "\Pictures\*.*",$newdrive & "\Pictures\",1)
                                    If $copy_bilder = 1 then
                                        GUICtrlSetData($progress,20)
                                    ElseIf $copy_bilder = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Datein von "Bilder" konnten nicht kopiert werden.')
                                    EndIf
                                    $copy_dokumente = FileCopy($olddrive & "\Documents\*.*",$newdrive & "\Documents\",1)
                                    If $copy_dokumente = 1 Then
                                        GUICtrlSetData($progress,30)
                                    ElseIf $copy_dokumente = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Dokumente" konnten nicht kopiert werden.')                                
                                    EndIf
                                    $copy_download = FileCopy($olddrive & "\Downloads\*.*",$newdrive & "\Downloads\",1)
                                    If $copy_download = 1 Then
                                        GUICtrlSetData($progress,40)
                                    ElseIf $copy_download = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Downloads" konnten nicht kopiert werden.')                                
                                    EndIf
                                    $copy_fav = FileCopy($olddrive & "\Favorites\*.*",$newdrive & "\Favorites\",1)
                                    If $copy_fav = 1 Then
                                        GUICtrlSetData($progress,50)
                                    ElseIf $copy_fav = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Favorieten" konnten nicht kopiert werden.')                                
                                    EndIf
                                    $copy_contact = FileCopy($olddrive & "\Contacts\*.*",$newdrive & "\Contacts\",1)
                                    If $copy_contact = 1 Then
                                        GUICtrlSetData($progress,60)
                                    ElseIf $copy_contact = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Kontakte" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_links = FileCopy($olddrive & "\Links\*.*",$newdrive & "\Links\",1)
                                    If $copy_links = 1 Then
                                        GUICtrlSetData($progress,70)
                                    ElseIf $copy_links = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Links" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_music = FileCopy($olddrive & "\Music\*.*",$newdrive & "\Music\",1)
                                    If $copy_music = 1 Then
                                        GUICtrlSetData($progress,80)
                                    ElseIf $copy_music = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Musik" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_video = FileCopy($olddrive & "\Videos\*.*",$newdrive & "\Videos\",1)
                                    If $copy_video = 1 Then
                                        GUICtrlSetData($progress,90)
                                    ElseIf $copy_video = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Videos" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_ffbackup = FileCopy($olddrive & "\AppData\Roaming\Mozilla\Firefox\Profiles\*.*",$newdrive & "\FIREFOX BACKUP\",8)
                                    If $copy_ffbackup = 1 Then
                                        GUICtrlSetData($progress,95)
                                    ElseIf $copy_ffbackup = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Firefox Backup" konnten nicht kopiert werden.')                                
                                    EndIf

Alles anzeigen

Auf die einzelnen Ordner hat man Zugriff, auch die Pfade habe ich überprüft, allerdings scheitert das immer wieder aufs neue

Für Hilfe bin ich sehr Dankbar

**Musashi**

Versuche mal :

AutoIt

$olddrive = "C:\Users\" & $username
$newdrive = "A:\"
If DirCopy($olddrive & "\Desktop", $newdrive & "\Desktop", 1) Then
    GUICtrlSetData($progress,10)
Else
    MsgBox(16,"Datenübertragunsfehler","Dateien vom Desktop konnten nicht kopiert werden.")
EndIf

Jasfar

Danke für die Antwort!

Hat leider auch nicht funktioniert. Es kommt wieder eine Fehlermeldung.

**Musashi**

Zitat von Jasfar

Hat leider auch nicht funktioniert. Es kommt wieder eine Fehlermeldung.

Du hast kein lauffähiges Skript gepostet, sondern nur einen Ausschnitt. Teste mal Folgendes :

AutoIt

;Daten übertragen
Global $sOlddrive = "C:\Users\" & @Username
Global $sNewdrive = "D:\Copytest"

If DirCopy($sOlddrive & "\Desktop", $sNewdrive & "\Desktop", 1) Then
    ; Copy OK
Else
    MsgBox(16,"Datenübertragunsfehler","Dateien vom Desktop konnten nicht kopiert werden.")
EndIf

Voraussetzung : Du hast ein Laufwerk D - sonst nehme C:\Copytest

Ggf. liegt der Fehler im Bereich deiner GUI, also z.B. bei : GUICtrlSetData($progress,10)

EDIT :

Du könntest die ganze Struktur wesentlich vereinfachen, indem Du z.B. den variablen Teil der Pfade, also Desktop, Pictures usw. in ein Array schreibst, und dies dann in einer Schleife abarbeitest. Der Fortschrittswert für die Progressbar wäre dann auch berechenbar.

Gruß Musashi

**Musashi**

Ich mache mal einen neuen Beitrag, weil Edits älterer Beiträge gerne übersehen werden !

Zitat von Musashi

EDIT :

Du könntest die ganze Struktur wesentlich vereinfachen, indem Du z.B. den variablen Teil der Pfade, also Desktop, Pictures usw. in ein Array schreibst, und dies dann in einer Schleife abarbeitest. Der Fortschrittswert für die Progressbar wäre dann auch berechenbar.

Hier ein Beispiel :

AutoIt

Global $sOlddrive = 'C:\Users\' & @Username
Global $sNewdrive = 'C:\Copytest'

Global $iPathCount = 10  ; Anzahl der Verzeichnisse
Global $aPathList[$iPathCount]  ; Array mit der Verzeichnisliste
$aPathList[0] = '\Desktop'
$aPathList[1] = '\Pictures'
$aPathList[2] = '\Documents'
$aPathList[3] = '\Downloads'
$aPathList[4] = '\Favorites'
$aPathList[5] = '\Contacts'
$aPathList[6] = '\Links'
$aPathList[7] = '\Music'
$aPathList[8] = '\Videos'
$aPathList[9] = '\AppData\Roaming\Mozilla\Firefox\Profiles'
; bei Bedarf weitere anfügen -> $iPathCount erhöhen

For $i = 0 To ($iPathCount - 1)
    If DirCopy($sOlddrive & $aPathList[$i], $sNewdrive & $aPathList[$i], 1) Then
        ConsoleWrite('@@DirCopy OK : Pfad ' & ($i + 1) & ' = ' & $sOlddrive & $aPathList[$i] & @CRLF)
    Else
        ConsoleWrite('@@DirCopy NICHT OK :  Pfad ' & ($i + 1) & ' = ' & $sOlddrive & $aPathList[$i] & @CRLF)
    EndIf
Next

Alles anzeigen

Das geht natürlich noch eleganter, aber zur Anschauung sollte es reichen

Gruß Musashi

Jasfar

Das kopieren hat leider auch nicht funktioniert...

Ich poste einmal das komplette Script, vl. hilft das weiter

C

;*****************************************
;Datenübertragung.au3 by mschaefer
;Erstellt mit ISN AutoIt Studio v. 1.06
;*****************************************

; -- Created with ISN Form Studio 2 for ISN AutoIt Studio -- ;
#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiButton.au3>
#include <EditConstants.au3>
#include <ProgressConstants.au3>
$mypcname = @ComputerName



$gui = GUICreate("Datenübertraung",492,217,-1,-1,-1,-1)
GUICtrlCreateLabel("Alter PC:",20,30,106,15,-1,-1)
GUICtrlSetBkColor(-1,"-2")
$olddns = GUICtrlCreateLabel($mypcname,142,30,170,15,-1,-1)
GUICtrlSetBkColor(-1,"-2")
GUICtrlCreateLabel("Neuer PC:",20,69,106,15,-1,-1)
GUICtrlSetBkColor(-1,"-2")
Global $newpc = GUICtrlCreateInput("",162,64,150,20,-1,$WS_EX_CLIENTEDGE)
Global $username = GUICtrlCreateInput("",162,107,150,20,-1,$WS_EX_CLIENTEDGE)
GUICtrlCreateLabel("Benutzername:",20,112,106,15,-1,-1)
GUICtrlSetBkColor(-1,"-2")
$button = GUICtrlCreateButton("Übertragung starten",20,157,142,30,BitOr($BS_CENTER,$BS_MULTILINE),-1)
;~ $status = GUICtrlCreateLabel("",180,170,235,15,-1,-1)
GUICtrlSetBkColor(-1,"-2")
GUISetState(@SW_SHOW,$gui)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            
            $gui2 = GUICreate("REAL Administator Passwort",390,132,-1,-1,-1,-1)
            GUICtrlCreateLabel("Bitte die ADM-Zugangsdaten eingeben:",10,10,358,15,-1,-1)
            GUICtrlSetBkColor(-1,"-2")
            GUICtrlCreateLabel("Benutzername:",10,37,95,15,-1,-1)
            GUICtrlSetBkColor(-1,"-2")
            GUICtrlCreateLabel("Passwort:",10,60,95,15,-1,-1)
            GUICtrlSetBkColor(-1,"-2")
            $admuser = GUICtrlCreateInput("",131,32,150,20,-1,$WS_EX_CLIENTEDGE)
            $admpw = GUICtrlCreateInput("",131,55,150,20,$ES_PASSWORD,$WS_EX_CLIENTEDGE)
            $admbutton = GUICtrlCreateButton("OK",131,88,100,30,-1,-1)
            GUISetState(@SW_SHOW,$gui2)
            
            
            
            
            While 1
                $nMsg = GUIGetMsg()
                    Switch $nMsg
                        Case $GUI_EVENT_CLOSE
                            Exit
                        Case $admbutton
                            $read_newpc = GUICtrlRead($newpc)
                            $read_admuser = GUICtrlRead($admuser)
                            $read_admpw = GUICtrlRead($admpw)
                            $read_user = GUICtrlRead($username)
                            GUIDelete($gui)
                            $a = DriveMapAdd("A:","\\" & $read_newpc & "\C$\Users\" & $read_user,0,"real\" & $read_admuser,$read_admpw)
                            $read_admuser = "anmkrthon4q3foi aödhfnq4aficvoaöqARUITRH)NVUDFADFAOFHAJERHABFJKBABFbfajksdfhbhqiubakjbf"
                            $read_admpw = "amdsifnarignajdfghanrguvafdlkvgnafldi5tut84wih539084tifhernotuih3498thweurt3948trhwuth34trrhw348t3n"
                                If @error = 1 Then
                                    MsgBox(16,"Datenübertragungsfehler","Fehlercode: 1 " & @CRLF & "Undefinierter / anderer Fehler. " & @CRLF & "Fehlercode der Windows API:" & @CRLF & @extended,0)
                                ElseIf @error = 2 Then
                                    MsgBox(16,"Datenübertragungsfehler","Fehlercode: 2 " & @CRLF & "Der Zugriff auf die Remote-Freigabe wurde verweigert.",0)
                                ElseIf @error = 3 Then
                                    MsgBox(16,"Datenübertragungsfehler","Fehlercode: 3 " & @CRLF & "Dieses Gerät ist bereits zugewiesen.",0)
                                ElseIf @error = 4 Then
                                    MsgBox(16,"Datenübertragungsfehler","Fehlercode: 4 " & @CRLF & "Der Gerätename ist ungültig.",0)
                                ElseIf @error = 5 Then
                                    MsgBox(16,"Datenübertragungsfehler","Fehlercode: 5 " & @CRLF & "Ungültige Remote-Freigabe.",0)
                                ElseIf @error = 6 Then
                                    MsgBox(16,"Datenübertragungsfehler","Fehlercode: 6 " & @CRLF & "Ungültiger Benutzername oder Passwort.",0)
                                ElseIf @error = 0 Then
                                    GUIDelete($gui2)
                                    $gui3 = GUICreate("Datenübertragung läuft...",422,78,-1,-1,-1,-1)
                                    $progress = GUICtrlCreateProgress(10,10,403,20,$PBS_SMOOTH ,-1)
                                    $progressbutton = GUICtrlCreateButton("OK",162,40,100,30,-1,-1)
                                    GUICtrlSetState(-1,BitOr($GUI_SHOW,$GUI_DISABLE))
                                    GUISetState(@SW_SHOW,$gui3)
                                    
                                    ;Daten übertragen
                                    
                                    $olddrive = "C:\Users\" & $username
                                    $newdrive = "A:\"
                                    If DirCopy($olddrive & "\Desktop",$newdrive & "\Desktop\",1) Then
                                        GUICtrlSetData($progress,10)
                                    Else
                                        MsgBox(16,"Datenübertragunsfehler","Dateien vom Desktop konnten nicht kopiert werden.")
                                    EndIf
                                    
                                    $copy_bilder = FileCopy($olddrive & "\Pictures\*.*",$newdrive & "\Pictures\",1)
                                    If $copy_bilder = 1 then
                                        GUICtrlSetData($progress,20)
                                    ElseIf $copy_bilder = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Datein von "Bilder" konnten nicht kopiert werden.')
                                    EndIf
                                    $copy_dokumente = FileCopy($olddrive & "\Documents\*.*",$newdrive & "\Documents\",1)
                                    If $copy_dokumente = 1 Then
                                        GUICtrlSetData($progress,30)
                                    ElseIf $copy_dokumente = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Dokumente" konnten nicht kopiert werden.')                                
                                    EndIf
                                    $copy_download = FileCopy($olddrive & "\Downloads\*.*",$newdrive & "\Downloads\",1)
                                    If $copy_download = 1 Then
                                        GUICtrlSetData($progress,40)
                                    ElseIf $copy_download = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Downloads" konnten nicht kopiert werden.')                                
                                    EndIf
                                    $copy_fav = FileCopy($olddrive & "\Favorites\*.*",$newdrive & "\Favorites\",1)
                                    If $copy_fav = 1 Then
                                        GUICtrlSetData($progress,50)
                                    ElseIf $copy_fav = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Favorieten" konnten nicht kopiert werden.')                                
                                    EndIf
                                    $copy_contact = FileCopy($olddrive & "\Contacts\*.*",$newdrive & "\Contacts\",1)
                                    If $copy_contact = 1 Then
                                        GUICtrlSetData($progress,60)
                                    ElseIf $copy_contact = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Kontakte" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_links = FileCopy($olddrive & "\Links\*.*",$newdrive & "\Links\",1)
                                    If $copy_links = 1 Then
                                        GUICtrlSetData($progress,70)
                                    ElseIf $copy_links = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Links" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_music = FileCopy($olddrive & "\Music\*.*",$newdrive & "\Music\",1)
                                    If $copy_music = 1 Then
                                        GUICtrlSetData($progress,80)
                                    ElseIf $copy_music = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Musik" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_video = FileCopy($olddrive & "\Videos\*.*",$newdrive & "\Videos\",1)
                                    If $copy_video = 1 Then
                                        GUICtrlSetData($progress,90)
                                    ElseIf $copy_video = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Videos" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    $copy_ffbackup = FileCopy($olddrive & "\AppData\Roaming\Mozilla\Firefox\Profiles\*.*",$newdrive & "\FIREFOX BACKUP\",8)
                                    If $copy_ffbackup = 1 Then
                                        GUICtrlSetData($progress,95)
                                    ElseIf $copy_ffbackup = 0 Then
                                        MsgBox(16,"Datenübertragungsfehler",'Dateien von "Firefox Backup" konnten nicht kopiert werden.')                                
                                    EndIf
                                    
                                    Sleep(250)
                                    DriveMapDel("A:")
                                    GUICtrlSetData($progress,100)
                                    Sleep(100)
                                    GUICtrlSetState($progressbutton,$GUI_ENABLE)
                                    


                                    While 1
                                        
                                        $nMsg = GUIGetMsg()
                                        Switch $nMsg
                                            Case $GUI_EVENT_CLOSE
;~                                                 Exit
                                            Case $progressbutton
                                                Exit

                                        EndSwitch
                                    WEnd
                                EndIf
                            
                            
                            
                            
                            
                            
                            
                            

                    EndSwitch
            WEnd

    EndSwitch
WEnd

Alles anzeigen

Jasfar

Ah, den neuen Beitrag erst jetzt gesehen, werde das gleich einmal ausprobieren, danke dir

Jasfar

Ich danke die vielmals!!

Durch dein Script bin ich auf den Fehler bei mir gestoßen, die Variable $username war das GUI Control, ich hätte $read_username setzen müssen

Ich werde mir dein Script aber mal genauer anschauen und es dann umsetzen, vielen Dank für deine Unterstützung

**Musashi**

Hallo Jasfar !

Zitat von Jasfar

Ich werde mir dein Script aber mal genauer anschauen und es dann umsetzen, vielen Dank für deine Unterstützung

In meinem groben Beispiel ging es im Wesentlichen erst mal nur darum, dass Du nicht für jedes Verzeichnis einen separaten Kopierbereich benötigst. Mit dem Array und der Schleife geht es kompakter und ist flexibler, trotzdem natürlich nicht die Eleganteste aller Möglichkeiten .

Ich habe mir dein Skript mal angesehen. Vom Aufbau her, speziell bei der GUI-Steuerung, könnte man einiges verbessern, aber solange es läuft, OK

Bisher bin ich davon ausgegangen, dass der variable Teil des Quell- und Zielverzeichnisses identisch sind. Dies ist aber z.B. Firefox NICHT der Fall, daher wäre ein 2-D Array geeigneter.

Demo (nur Anzeige) :

AutoIt

#include <Array.au3>

Global $sOlddrive = 'C:\Users\' & @Username
Global $sNewdrive = 'C:\Copytest'

Global $iPathCount = 10  ; Anzahl der Verzeichnisse
Global $aPathList[$iPathCount][2]  ; Array mit der Verzeichnisliste [Quelle][Ziel]
$aPathList[0][0] = '\Desktop'
$aPathList[0][1] = '\Desktop'
$aPathList[1][0] = '\Pictures'
$aPathList[1][1] = '\Pictures'
$aPathList[2][0] = '\Documents'
$aPathList[2][1] = '\Documents'
$aPathList[3][0] = '\Downloads'
$aPathList[3][1] = '\Downloads'
$aPathList[4][0] = '\Favorites'
$aPathList[4][1] = '\Favorites'
$aPathList[5][0] = '\Contacts'
$aPathList[5][1] = '\Contacts'
$aPathList[6][0] = '\Links'
$aPathList[6][1] = '\Links'
$aPathList[7][0] = '\Music'
$aPathList[7][1] = '\Music'
$aPathList[8][0] = '\Videos'
$aPathList[8][1] = '\Videos'
$aPathList[9][0] = '\AppData\Roaming\Mozilla\Firefox\Profiles'
$aPathList[9][1] = '\FIREFOX BACKUP'
; bei Bedarf weitere anfügen -> $iPathCount erhöhen

_ArrayDisplay($aPathList)

Alles anzeigen

Das läßt sich alles auch kürzer schreiben, aber so ist es für dich ggf. verständlicher.

Den Fortschrittswert für die Progressbar kannst Du übrigens dynamisch anhand von $iPathCount berechnen.

Gruß Musashi