Löschen - einfach so- ja wohl schon?

**Bitnugger**

Zitat von Musashi

Was mich allerdings noch etwas irritiert :

Ops, mein Fehler... das ist noch ein ungewolltes Überbleibsel (hab's korrigiert), da ich es vorher auch mit FileOpen versucht hatte, wo du dann ja in @extended die Länge übergeben bekommst.
Da _WinAPI_CreateFileEx erfolgreich ausgeführt werden konnte, ist in @extended demnach eine 0, was für _WinAPI_LockFile dann wohl bedeutet, dass die komplette Datei damit gemeint ist.

Zitat von Musashi

Man kann die _WinAPI_... Funktionen wohl nicht mal eben so mit Funktionen wie FileOpen mischen, korrekt ?

Nein, kannst du nicht... weil AutoIt kein echtes Filehandle bei FileOpen liefert, was für die _WinAPI_... Funktionen aber zwingend erforderlich ist.

**Musashi**

Zitat von Bitnugger

Ops, mein Fehler... das ist noch ein ungewolltes Überbleibsel (hab's korrigiert), da ich es vorher auch mit FileOpen versucht hatte, wo du dann ja in @extended die Länge übergeben bekommst.
Da _WinAPI_CreateFileEx erfolgreich ausgeführt werden konnte, ist in @extended demnach eine 0, was für _WinAPI_LockFile dann wohl bedeutet, dass die komplette Datei damit gemeint ist.

Nein, kannst du nicht... weil AutoIt kein echtes Filehandle bei FileOpen liefert, was für die _WinAPI_... Funktionen aber zwingend erforderlich ist.

Hallo Bitnugger

Danke für die schnelle Antwort.

Meine Irritation bzgl. @extended war dann ja zum Glück doch nicht unbegründet. Ich dachte schon, ich bekomme heute gar nichts auf die Reihe .

Gruß Musashi

**Bitnugger**

Hier noch ein sehr schönes Beispiel...

LockFile 2.0 ;-)

AutoIt

;-- TIME_STAMP   2017-11-25 01:09:42   v 0.1

#Region    ;************ Includes ************
#Include <WinAPI.au3>
#include <WinAPIFiles.au3>
#EndRegion ;************ Includes ************

If Not HotKeySet('{ESC}', '_Exit') Then Exit 1

Global $g_bLock = False, $g_hFile, $g_iOffset = 0, $g_iLength = FileGetSize(@ScriptFullPath)
Global $g_iCreation = $OPEN_EXISTING, $g_iAccess = $GENERIC_READ, $g_iShare = BitOR($FILE_SHARE_READ, $FILE_SHARE_WRITE)
;~ _WinAPI_CreateFileEx ( $sFilePath, $iCreation [, $iAccess = 0 [, $iShare = 0 [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
$g_hFile = _WinAPI_CreateFileEx(@ScriptFullPath, $g_iCreation, $g_iAccess, $g_iShare) ; [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
If $g_hFile = -1 Then Exit -1
ConsoleWrite('$g_hFile = ' & $g_hFile & @CRLF)

If _WinAPI_LockFile($g_hFile, $g_iOffset, $g_iLength) Then
    ConsoleWrite('! File ist now locked!' & @CRLF & _
        '> Now you can even try to open, change or delete the file ... you will not succeed as long as the lock has not been released! ;-)' & @CRLF & _
        '- Press ESC for UnLock File and Exit!' & @CRLF & @CRLF)
    $g_bLock = True

    ; notepad darf die Datei öffnen... aber nichts ändern! ;-)
    Run('notepad.exe ' & @ScriptFullPath)

    ; wir selbst dürfen Daten an das Ende des Files anhängen!
    Local $hFile = FileOpen(@ScriptFullPath, $FO_APPEND)
    FileWrite($hFile, "ConsoleWrite('Test' & @CRLF)")

    ; aber nicht innerhalb des gelockten Bereichs!
    FileSetPos($hFile, $g_iLength - 100, $FILE_BEGIN)
    Local $iWrite = FileWrite($hFile, @CRLF & @CRLF & "; ########################################################################################################" & @CRLF)
    ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iWrite --> " & $iWrite & @CRLF & "!@ " & @TAB & "#Error: " & @error & @CRLF)

    ; auch erstaunlich, dass FileSetPos die Position in der geöffneten Datei richtig setzt, obwohl Daten angehangen wurden.
    FileSetPos($hFile, 1, $FILE_END)
    Local $iWrite = FileWrite($hFile, @CRLF & @CRLF & "; ********************************************************************************************************" & @CRLF)
    FileClose($hFile)

    ; und bitte darauf achten, wie SciTE reagiert, nachdem die Datei geändert wurde!!!
Else
     ConsoleWrite("File can't locked!" & @CRLF & 'Error: ' & _WinAPI_GetLastError() & @CRLF & 'ErrorMessage: ' & _WinAPI_GetLastErrorMessage() & @CRLF)
    Exit 2
EndIf

While 1
    Sleep(1000)
WEnd

Func _Exit()
    If $g_bLock = True Then _WinAPI_UnLockFile($g_hFile, $g_iOffset, $g_iLength)
    ConsoleWrite('File ist unlocked!' & @CRLF)
    _WinAPI_CloseHandle($g_hFile)

    ; notepad can open the file! ;-)
    Run('notepad.exe ' & @ScriptFullPath)
    Exit
EndFunc

Alles anzeigen

**Musashi**

Hallo Bitnugger

Ja, erneut ein schönes Beispiel !

Im Ablauf kommt es aber zu Fehlern, ich versuche das mal halbwegs zu beschreiben :

1. Skript starten (Go) :

-> Notepad wird geöffnet

-> Am Ende des Skriptes (innerhalb von Notepad) wird folgendes angezeigt :

AutoIt

...
Func _Exit()
    If $g_bLock = True Then _WinAPI_UnLockFile($g_hFile, $g_iOffset, $g_iLength)
    ConsoleWrite('File ist unlocked!' & @CRLF)
    _WinAPI_CloseHandle($g_hFile)
    ; notepad can open the file! ;-)
    Run('notepad.exe ' & @ScriptFullPath)
    Exit
EndFuncConsoleWrite('Test' & @CRLF) 

; ********************************************************************************************************

Alles anzeigen

-> Notepad schließen (X)

-> Die Skriptanzeige in Scite ist nun leer

-> ESC -> Notepad wird wieder angezeigt

-> Notepad schließen (X)

-> Die Skriptanzeige in Scite bleibt leer

2. sauberes Skript erneut starten (Go) :

-> Notepad wird geöffnet

-> Am Ende des Skriptes (innerhalb von Notepad) wird folgendes angezeigt (s.o.)

-> In Notepad ESC drücken

-> Die Skriptanzeige in Scite bleibt erhalten, ist am Ende aber wieder fehlerhaft :

AutoIt

...
Run('notepad.exe ' & @ScriptFullPath)
    Exit
EndFuncConsoleWrite('Test' & @CRLF) 

; ********************************************************************************************************

(Außerdem gibt es ganz am Ende auch noch ein Sonderzeichen)

-> Notepad schließen (X)

==> so ist der Code am Ende auch gespeichert

==> erneutes Laden und Build führt zu Fehlern

Gruß Musashi

**Bitnugger**

Zitat von Musashi

Im Ablauf kommt es aber zu Fehlern

Nein... nicht wirklich, denn das Script macht genau das, was es soll. ,-)

Zitat von Musashi

Am Ende des Skriptes (innerhalb von Notepad) wird folgendes angezeigt :

Ja, dies passiert durch Zeile 35-37 im Script... womit ich zeigen wollte, das du selbst Daten an die geöffnete Datei anhängen darfst... jedoch nicht innerhalb des gelockten Bereich schreiben kannst... was in Zeile 31-32 passiert.

Zitat von Musashi

Außerdem gibt es ganz am Ende auch noch ein Sonderzeichen

Das passiert durch Zeile 36... weil dort die Position im File 1 Byte hinter das Ende des Files gesetzt wird und das "übersprungene" Byte dann als Chr(0) gespeichert wird. Allerdings wird das FileWrite in Zeile 28 ausgeführt und noch eine Zeile an die Datei angehangen... bevor notepad die Datei öffnen kann... weshalb das Null-Byte dann hinter dieser Zeile geschrieben wird. Wenn du das Chr(0) nicht magst, setzt du als Parameter für das FileSetPos in Zeile 36 einfach anstelle einer 1 eine 0.

Zitat von Musashi

so ist der Code am Ende auch gespeichert

Tja, das liegt wohl daran, dass ich als Dateiname @ScriptFullPath verwendet habe.

Zitat von Musashi

erneutes Laden und Build führt zu Fehlern

Würde mich auch schwer wunden, wenn dem nicht so währe... sehr gewundert hat mich aber, wie SciTE darauf reagiert und was passiert, wenn du die noch geöffnete Datei in notepad änderst und dann speichern willst!

**Musashi**

Hallo Bitnugger

Zitat von Bitnugger

Würde mich auch schwer wunden, wenn dem nicht so währe... sehr gewundert hat mich aber, wie SciTE darauf reagiert und was passiert, wenn du die noch geöffnete Datei in notepad änderst und dann speichern willst!

Warum, und wo, etwas passiert, habe ich anhand des Codes schon verstanden .

Ich wollte nur, und völlig kritikfrei, darauf hinweisen, dass das Skript nach dem Test nicht mehr lauffähig ist.

Das mag den einen oder anderen Leser möglicherweise doch etwas verwirren. Der Grund ist, wie beschrieben und von Dir wohl auch beabsichtigt, dass der Test auf das laufende Skript selbst angewendet wird (-> @ScriptFullPath).

Ich habe es daher - quick and dirty - mal so modifiziert, dass eine separate Testdatei (locktest.txt) verwendet wird :

AutoIt

;-- TIME_STAMP   2017-11-25 18:00:00
; V 0.2 (Original by Bitnugger , modified by Musashi)
#Region    ;************ Includes ************
#Include <WinAPI.au3>
#include <WinAPIFiles.au3>
#EndRegion ;************ Includes ************

If Not HotKeySet('{ESC}', '_Exit') Then Exit 1

; Statt das Skript selbst zu verwenden(@ScriptFullPath), eine Testdatei anlegen :
Global $g_sTestFilename = @ScriptDir & '\locktest.txt'
Global $g_hTestFile = FileOpen($g_sTestFilename, $FO_OVERWRITE)
If $g_hTestFile = -1 Then
    ConsoleWrite('! Error creating ' & $g_sTestFilename & @CRLF)
    Exit -1
Else
    ; Testzeilen eintragen :
    FileWrite($g_hTestFile, 'Line01:AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA'& @CRLF)
    FileWrite($g_hTestFile, 'Line02:BBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBBB' & @CRLF)
    FileWrite($g_hTestFile, 'Line03:CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC' & @CRLF)
    FileWrite($g_hTestFile, 'Line04:DDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDD' & @CRLF)
    FileWrite($g_hTestFile, 'Line05:EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE')

    FileClose($g_hTestFile)
EndIf


Global $g_bLock = False, $g_hFile, $g_iOffset = 0, $g_iLength = FileGetSize($g_sTestFilename)
Global $g_iCreation = $OPEN_EXISTING, $g_iAccess = $GENERIC_READ, $g_iShare = BitOR($FILE_SHARE_READ, $FILE_SHARE_WRITE)

;~ _WinAPI_CreateFileEx ( $sFilePath, $iCreation [, $iAccess = 0 [, $iShare = 0 [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
$g_hFile = _WinAPI_CreateFileEx($g_sTestFilename, $g_iCreation, $g_iAccess, $g_iShare) ; [, $iFlagsAndAttributes = 0 [, $tSecurity = 0 [, $hTemplate = 0]]]]] )
If $g_hFile = -1 Then Exit -1
ConsoleWrite('$g_hFile = ' & $g_hFile & @CRLF)
If _WinAPI_LockFile($g_hFile, $g_iOffset, $g_iLength) Then

    ConsoleWrite('! File ist now locked!' & @CRLF & _
        '> Now you can even try to open, change or delete the file ... you will not succeed as long as the lock has not been released! ;-)' & @CRLF & _
        '- Press ESC for UnLock File and Exit!' & @CRLF & @CRLF)

    $g_bLock = True

    ; notepad darf die Datei öffnen... aber nichts ändern! ;-)
    Run('notepad.exe ' & $g_sTestFilename)

    ; wir selbst dürfen Daten an das Ende des Files anhängen!
    Local $hFile = FileOpen($g_sTestFilename, $FO_APPEND)
    FileWrite($hFile, "ConsoleWrite('Test' & @CRLF)")

    ; aber nicht innerhalb des gelockten Bereichs!
    FileSetPos($hFile, $g_iLength - 100, $FILE_BEGIN)
    Local $iWrite = FileWrite($hFile, @CRLF & @CRLF & "; ########################################################################################################" & @CRLF)
    ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iWrite --> " & $iWrite & @CRLF & "!@ " & @TAB & "#Error: " & @error & @CRLF)

    ; auch erstaunlich, dass FileSetPos die Position in der geöffneten Datei richtig setzt, obwohl Daten angehangen wurden.
    FileSetPos($hFile, 1, $FILE_END)
    Local $iWrite = FileWrite($hFile, @CRLF & @CRLF & "; ********************************************************************************************************" & @CRLF)

    FileClose($hFile)
    ; und bitte darauf achten, wie SciTE reagiert, nachdem die Datei geändert wurde!!!
Else
     ConsoleWrite("File can't locked!" & @CRLF & 'Error: ' & _WinAPI_GetLastError() & @CRLF & 'ErrorMessage: ' & _WinAPI_GetLastErrorMessage() & @CRLF)
    Exit 2
EndIf
While 1
    Sleep(1000)
WEnd
Func _Exit()
    If $g_bLock = True Then _WinAPI_UnLockFile($g_hFile, $g_iOffset, $g_iLength)
    ConsoleWrite('File ist unlocked!' & @CRLF)
    _WinAPI_CloseHandle($g_hFile)
    ; notepad can open the file! ;-)
    Run('notepad.exe ' & $g_sTestFilename)
    Exit
EndFunc

Alles anzeigen

Allgemein :

Wie SciTE bei @ScriptFullPath reagiert, und das Editieren->Speichern der Datei in Notepad, fand ich auch überraschend .

Gruß Musashi