Die erste benutzerdefinierte Resource hat den Wert 201, da bei jedem kompilieren auch vom AutoIt-Compiler Resourcenplätze benötigt werden. Wenn du deine .exe-Datei mal im Resource Hacker zum Beispiel anschaust, wird dir auffallen, dass sich auch noch weitere Icons in der .exe-Datei befinden. Wenn du die Resourcen unbedingt mit Namen ansprechen willst, könntest du sie auch binär einbinden, also als String und diesen in einer Variable zur Verwendung speichern.
Ist es möglich, die in die EXE inkludierten Ressourcen (icons) via ursprünglichem Dateinamen anzusprechen, oder geht das nur über deren Resource Table Position?
Direkt, nein. Du kannst sie aber dem Quellcode entnehmen...
Und wenn nur über die Position, dann würde mich interessieren, wieso Position 1 lt. Referenz den Wert 201 hat?
#AutoIt3Wrapper_Res_Icon_Add= ; Filename[,ResNumber[,LanguageCode]] of ICO to be added.
; Add extra ICO files to the resources
; Use full path of the ico files to be added
; ResNumber is a numeric value used to access the icon: TraySetIcon(@ScriptFullPath, ResNumber)
; If no ResNumber is specified, the added icons are numbered from 201 up
Hier mal ein kleines Demo-Script...
;-- TIME_STAMP 2018-05-27 12:49:20 v 0.1
;~ #AutoIt3Wrapper_Res_Icon_Add= ; Filename[,ResNumber[,LanguageCode]] of ICO to be added.
; Add icons to the file resource table
; As no resource names are specified, they will be set automatically to 201+
#AutoIt3Wrapper_Res_Icon_Add=C:\Program Files (x86)\AutoIt3\Icons\au3.ico
#AutoIt3Wrapper_Res_Icon_Add=C:\Program Files (x86)\AutoIt3\Icons\au3script_v10.ico
#AutoIt3Wrapper_Res_Icon_Add=C:\Program Files (x86)\AutoIt3\Icons\au3script_v9.ico
#AutoIt3Wrapper_Res_Icon_Add=C:\Program Files (x86)\AutoIt3\Icons\filetype-blank.ico
#Region ;************ Includes ************
#include <Array.au3>
#include <WinAPIRes.au3>
#include <ButtonConstants.au3>
#EndRegion ;************ Includes ************
Local $hModule = StringTrimRight(@ScriptFullPath, 4) & '.exe', $aData = _WinAPI_EnumResourceTypes($hModule), $aNames, $aShow[0][2], $aIconResNames[0]
For $i = 0 To UBound($aData) -1 Step 1
$aNames = _WinAPI_EnumResourceNames($hModule, $aData[$i])
_ArrayAdd($aShow, $aData[$i] & '|' & _ArrayToString($aNames, ', '))
If $aData[$i] = 14 Then _ArrayAdd($aIconResNames, _ArrayToString($aNames, '|')) ; Icons
Next
_ArrayDisplay($aShow, 'Resource Types and Names', '', 0, Default, 'Types|Names')
; Now run through the added icons in the resource table
Local $sScriptName = StringTrimRight(@ScriptFullPath, 4) & '.au3', $sIconName, $aIconNames = FileReadToArray($sScriptName)
If @error Then Exit MsgBox(16, @ScriptName, 'Quelltext nicht gefunden!' & @CRLF & $sScriptName, 3)
$aIconNames = StringRegExp(_ArrayToString($aIconNames, @CRLF, -1, -1, @CRLF), '#AutoIt3Wrapper_Res_Icon_Add=([^\s].+)', 3)
ReDim $aIconNames[UBound($aIconNames) -1]
_ArrayColInsert($aIconNames, 0)
For $i = 0 To UBound($aIconNames) -1 Step 1
$aIconNames[$i][0] = $i + 201
Next
_ArrayDisplay($aIconNames, '$aIconNames')
If Not @Compiled Then Exit MsgBox(16, @ScriptName, 'Du musst das Script erst kompilieren und dann die Exe ausführen, damit der Rest des Scripts funktioniert!', 3)
; Create the GUI
$hGUI = GUICreate("AutoIt3Wrapper_Res_Icon_Add", 400, 200)
$idButton = GUICtrlCreateButton("", 10, 10, 100, 100, $BS_ICON)
$idLabelID = GUICtrlCreateLabel("", 10, 125, 200, 20)
$idLabelName = GUICtrlCreateLabel("", 10, 150, 380, 20)
GUISetState(@SW_SHOW, $hGUI)
Local $id, $rc1, $rc2, $iSleep = 5
For $i = 0 To UBound($aIconResNames) -1 Step 1
; Change the tray icon
$id = $aIconResNames[$i]
$iIndex = _ArraySearch($aIconNames, $id)
$sIconName = $iIndex > -1 ? $aIconNames[$iIndex][1] : '?'
$rc1 = TraySetIcon(@ScriptFullPath, $id)
; Change the icon in the button
$rc2 = GUICtrlSetImage($idButton, @ScriptFullPath, $id)
GUICtrlSetData($idLabelID, "Icon ID: " & $id)
GUICtrlSetData($idLabelName, "Icon Name: " & $sIconName)
;~ TrayTip("Added icon: " & $x, "TraySetIcon rc: " & $rc1 & @CRLF & "GUICtrlSetImage rc: " & $rc2, 3)
TrayTip("Added icon: ", StringFormat('ID = %3i\nName = %s\nTraySetIcon = %i, GUICtrlSetImage = %i\n', $id, $sIconName, $rc1, $rc2), $iSleep)
; Allow time for icon to be seen
Sleep($iSleep * 1500)
Next
; Delete the GUI
GUIDelete($hGUI)