Tv Steuerung

Speedy86

Hallo,

Ich baue gerade ein TV Steuerung wo ich zumindest den Grundstein haben, wie ich es benötige.

Ich suche noch ein paar tipps dies einfacher zu gestalten da ich noch etwas ratlos bin wie es besser schreiben kann.

Ich habe in mein Script zb. 3 Tv mit einer aufklappfunktion, wo bestimmte Befehle hinterlegt werden können.

Nur wie mach ich das wenn ich zb. 10 Tv´s brauche, da wird die Liste ja endlos lang
Ich werden bei allen TV die gleiche Liste angezeigt das kann man sicher auch einfacher durchführen das ich nur mehr die Position des TV angeben muss.

Könnte mir jemand helfen ?

C

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

#Region all client IP´s
Global $telnet_port = "8080" ;Port
Global $TV1_ip = "192.168.0.10"
Global $TV2_ip = "192.168.0.11"
Global $TV3_ip = "192.168.0.12"
#EndRegion

$hGUI = GUICreate("Test", 1000, 750, 0, 0)

#Region TV1 Button
$TV1fb = GUICtrlCreateButton("TV 1", 100, 100, 60, 20)
$TV1ch = GUICtrlCreateButton("", 100, 118, 60, 20)
$TV1chContext = GUICtrlCreateContextMenu($TV1ch)
$TV1MenuItem1 = GUICtrlCreateMenuItem("Test 1", $TV1chContext)
$TV1MenuItem2 = GUICtrlCreateMenuItem("Test 2", $TV1chContext)
$TV1MenuItem3 = GUICtrlCreateMenuItem("Test 3", $TV1chContext)
$TV1MenuItem4 = GUICtrlCreateMenuItem("Test 4", $TV1chContext)
$TV1MenuItem5 = GUICtrlCreateMenuItem("Test 5", $TV1chContext)
$TV1MenuItem6 = GUICtrlCreateMenuItem("", $TV1chContext)
$TV1MenuRestart = GUICtrlCreateMenuItem("Restart", $TV1chContext)
GUICtrlSetFont($TV1fb, 8.5, 700, 0, "")
GUICtrlSetFont($TV1ch, 8.5, 500, 0, "")
#EndRegion TV1 Button
#Region TV2 Button
$TV2fb = GUICtrlCreateButton("TV2", 200, 100, 60, 20)
$TV2ch = GUICtrlCreateButton("", 200, 118, 60, 20)
$TV2chContext = GUICtrlCreateContextMenu($TV2ch)
$TV2MenuItem1 = GUICtrlCreateMenuItem("Test 1", $TV2chContext)
$TV2MenuItem2 = GUICtrlCreateMenuItem("Test 2", $TV2chContext)
$TV2MenuItem3 = GUICtrlCreateMenuItem("Test 3", $TV2chContext)
$TV2MenuItem4 = GUICtrlCreateMenuItem("Test 4", $TV2chContext)
$TV2MenuItem5 = GUICtrlCreateMenuItem("Test 5", $TV2chContext)
$TV2MenuItem6 = GUICtrlCreateMenuItem("", $TV2chContext)
$TV2MenuRestart = GUICtrlCreateMenuItem("Restart", $TV2chContext)
GUICtrlSetFont($TV2fb, 8.5, 700, 0, "")
GUICtrlSetFont($TV2ch, 8.5, 500, 0, "")
#EndRegion TV2 Button
#Region TV3 Button
$TV3fb = GUICtrlCreateButton("TV3", 300, 100, 60, 20)
$TV3ch = GUICtrlCreateButton("", 300, 118, 60, 20)
$TV3chContext = GUICtrlCreateContextMenu($TV3ch)
$TV3MenuItem1 = GUICtrlCreateMenuItem("Test 1", $TV3chContext)
$TV3MenuItem2 = GUICtrlCreateMenuItem("Test 2", $TV3chContext)
$TV3MenuItem3 = GUICtrlCreateMenuItem("Test 3", $TV3chContext)
$TV3MenuItem4 = GUICtrlCreateMenuItem("Test 4", $TV3chContext)
$TV3MenuItem5 = GUICtrlCreateMenuItem("Test 5", $TV3chContext)
$TV3MenuItem6 = GUICtrlCreateMenuItem("", $TV3chContext)
$TV3MenuRestart = GUICtrlCreateMenuItem("Restart", $TV3chContext)
GUICtrlSetFont($TV3fb, 8.5, 700, 0, "")
GUICtrlSetFont($TV3ch, 8.5, 500, 0, "")
#EndRegion TV3 Button

GUISetState(@SW_SHOW)

While 1
    Sleep(10)
    $nMsg = GUIGetMsg()
    Switch $nMsg
         Case $GUI_EVENT_CLOSE
            Exit

;TV1
         Case $TV1fb

         Case $TV1ch
            ShowMenu($hGUI, $nMsg, $TV1chContext)

         Case $TV1MenuItem1
            Test1()
            $telnet_host = $TV1_ip
            telnet_send ()
            GUICtrlSetData($TV1ch, "Test 1")

         Case $TV1MenuItem2
            Test2()
            $telnet_host = $TV1_ip
            telnet_send ()
            GUICtrlSetData($TV1ch, "Test 2")

         Case $TV1MenuItem3
            Test3()
            $telnet_host = $TV1_ip
            telnet_send ()
            GUICtrlSetData($TV1ch, "Test 3")

         Case $TV1MenuItem4
            Test4()
            $telnet_host = $TV1_ip
            telnet_send ()
            GUICtrlSetData($TV1ch, "Test 4")

         Case $TV1MenuItem5
            Test5()
            $telnet_host = $TV1_ip
            telnet_send ()
            GUICtrlSetData($TV1ch, "Test 5")

         Case $TV1MenuRestart
            restart()
            $telnet_host = $TV1_ip
            telnet_send ()
            GUICtrlSetData($TV1ch, "")
            Sleep (5000)
            telnet_send ()

;TV2
         Case $TV2fb

         Case $TV2ch
            ShowMenu($hGUI, $nMsg, $TV2chContext)

         Case $TV2MenuItem1
            Test1()
            $telnet_host = $TV2_ip
            telnet_send ()
            GUICtrlSetData($TV2ch, "Test 1")

         Case $TV2MenuItem2
            Test2()
            $telnet_host = $TV2_ip
            telnet_send ()
            GUICtrlSetData($TV2ch, "Test 2")

         Case $TV2MenuItem3
            Test3()
            $telnet_host = $TV2_ip
            telnet_send ()
            GUICtrlSetData($TV2ch, "Test 3")

         Case $TV2MenuItem4
            Test4()
            $telnet_host = $TV2_ip
            telnet_send ()
            GUICtrlSetData($TV2ch, "Test 4")

         Case $TV2MenuItem5
            Test5()
            $telnet_host = $TV2_ip
            telnet_send ()
            GUICtrlSetData($TV2ch, "Test 5")

         Case $TV2MenuRestart
            restart()
            $telnet_host = $TV2_ip
            telnet_send ()
            GUICtrlSetData($TV2ch, "")
            Sleep (5000)
            telnet_send ()

;TV3
         Case $TV3fb

         Case $TV3ch
            ShowMenu($hGUI, $nMsg, $TV3chContext)

         Case $TV3MenuItem1
            Test1()
            $telnet_host = $TV3_ip
            telnet_send ()
            GUICtrlSetData($TV3ch, "Test 1")

         Case $TV3MenuItem2
            Test2()
            $telnet_host = $TV3_ip
            telnet_send ()
            GUICtrlSetData($TV3ch, "Test 2")

         Case $TV3MenuItem3
            Test3()
            $telnet_host = $TV3_ip
            telnet_send ()
            GUICtrlSetData($TV3ch, "Test 3")

         Case $TV3MenuItem4
            Test4()
            $telnet_host = $TV3_ip
            telnet_send ()
            GUICtrlSetData($TV3ch, "Test 4")

         Case $TV3MenuItem5
            Test5()
            $telnet_host = $TV3_ip
            telnet_send ()
            GUICtrlSetData($TV3ch, "Test 5")

         Case $TV3MenuRestart
            restart()
            $telnet_host = $TV3_ip
            telnet_send ()
            GUICtrlSetData($TV3ch, "")
            Sleep (5000)
            telnet_send ()

    EndSwitch
WEnd


#Region Func
Func ShowMenu($hWnd, $CtrlID, $nContextID)
    Local $arPos, $x, $y
    Local $hMenu = GUICtrlGetHandle($nContextID)

    $arPos = ControlGetPos($hWnd, "", $CtrlID)

    $x = $arPos[0]
    $y = $arPos[1] + $arPos[3]

    ClientToScreen($hWnd, $x, $y)
    TrackPopupMenu($hWnd, $hMenu, $x, $y)
 EndFunc   ;ShowMenu
; Convert the client GUI coordinates to screen desktop coordinates
Func ClientToScreen($hWnd, ByRef $x, ByRef $y)
    Local $stPoint = DllStructCreate("int;int")

    DllStructSetData($stPoint, 1, $x)
    DllStructSetData($stPoint, 2, $y)

    DllCall("user32.dll", "int", "ClientToScreen", "hwnd", $hWnd, "ptr", DllStructGetPtr($stPoint))

    $x = DllStructGetData($stPoint, 1)
    $y = DllStructGetData($stPoint, 2)
    ; release Struct not really needed as it is a local
    $stPoint = 0
EndFunc   ;==>ClientToScreen
; Show at the given coordinates (x, y) the popup menu (hMenu) which belongs to a given GUI window (hWnd)
Func TrackPopupMenu($hWnd, $hMenu, $x, $y)
    DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hMenu, "int", 0, "int", $x, "int", $y, "hwnd", $hWnd, "ptr", 0)
EndFunc   ;==>TrackPopupMenu


;Channels Func
Func Test1()
   Global $telnet_command = "Telnet command 1"
EndFunc
Func Test2()
   Global $telnet_command = "Telnet command 2"
EndFunc
Func Test3()
   Global $telnet_command = "Telnet command 3"
EndFunc
Func Test4()
   Global $telnet_command = "Telnet command 4"
EndFunc
Func Test5()
   Global $telnet_command = "Telnet command 5"
EndFunc
Func restart()
   Global $telnet_command = "Telnet restart"
EndFunc


;Telnet_send
Func telnet_send ()
   TCPStartup ()
   $Conection = TCPConnect ( $telnet_host, $telnet_port )
   If @error Then MsgBox (0,"Error","connection not ok")
      TCPSend ( $Conection, $telnet_command & Chr ( 10 ) )
   If @error Then
      MsgBox (0,"Error","not possible")
   EndIf
EndFunc
; End Telnet_send
#EndRegion Func

Alles anzeigen

**Kanashius**

Hi Speedy86 .

Das was du suchst sind Arrays. Ich hab dein Script mal umgeschrieben, sodass es arrays nutzt. Du musst theoretisch nurnoch die globalen variablen anpassen und es sollte tun, was du möchtest und du kannst beliebig viele TVs und ContextMenuItems hinzufügen. Außerdem kannst du während das Tool läuft neue Tvs hinzufügen.

Alle Positionen der Controls werden dynamisch berechnet, sodass es erweiterbar ist und die größe geändert werden kann.

C

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

#Region global variables
;TV information
Global $iDefaultPort=8080
Global $arTvList=[["192.168.0.10",$iDefaultPort],["192.168.0.11",$iDefaultPort],["192.168.0.12",$iDefaultPort]] ;All client IP´s

;Gui control variables
Global $iWidth=1000,$iHeight=750
; [x position,y position]
Global $arPointTvListStart=[10,10]
Global $iTvListItemWidth=60, $iTvListButtonHeight=20, $iTvListButtonSpace=10
; [FB_Button,Ch_Button,Ch_Context,Item 1,Item 2,Item 3,Item 4,Item 5, Item 6]
Global $sRestart="Restart"
Global $arContextMenuButtons=[ _
        ["Test 1","Telnet command 1"], _
        ["Test 2","Telnet command 2"], _
        ["Test 3","Telnet command 3"], _
        ["Test 4","Telnet command 4"], _
        ["Test 5","Telnet command 5"], _
        ["",0], _
        [$sRestart,"Telnet restart"] _
    ]
Global $iStartOfContextMenuButtons=3
Global $arTvListControls[0][0][2]
#EndRegion global variables

$hGUI = GUICreate("Test",$iWidth,$iHeight)

$iButtonAddTV=GUICtrlCreateButton("Add TV",100,100)
$iButtonRemoveTV=GUICtrlCreateButton("Remove TV",100,130)

_refreshTvButtons()

GUISetState(@SW_SHOW)

While 1 ;Sleep(10) not needed, because guigetmsg sleeps
    $nMsg = GUIGetMsg()
    If $nMsg<>0 Then
        If $nMsg=$GUI_EVENT_CLOSE Then Exit
        Switch $nMsg
            case $iButtonAddTV
                _addTV("192.168.2.111")
            case $iButtonRemoveTV
                _removeTV("192.168.2.111")
        EndSwitch
        For $i=0 to UBound($arTvListControls)-1 step 1
            For $j=0 to UBound($arTvListControls,2)-1 step 1
                If $arTvListControls[$i][$j][0]=$nMsg Then
                    Switch $j
                        case 0 ; FB Button not used
                        case 1 ; CH Button
                            $arTvListControls[$i][$j][1]($hGUI,$nMsg,$arTvListControls[$i][$j+1][0])
                        case Else ;all contextmenu items
                            telnet_send($arTvList[$i][0],$arTvList[$i][1],$arTvListControls[$i][$j][1])
                            GUICtrlSetData($arTvListControls[$i][1][0],$arContextMenuButtons[$j-$iStartOfContextMenuButtons][0])
                            If $arContextMenuButtons[$j-$iStartOfContextMenuButtons][0]=$sRestart Then
                                GUICtrlSetData($arTvListControls[$i][1][0],"")
                            EndIf
                    EndSwitch
                    ExitLoop 2
                EndIf
            Next
        Next
    EndIf
WEnd

#Region Func

Func _addTV($sIp,$iPort=8080)
    _ArrayAdd($arTvList,$sIp&"|"&$iPort)
    _refreshTvButtons()
EndFunc

Func _removeTV($sIp,$iPort=8080)
    For $i=UBound($arTvList)-1 to 0 step -1
        If $arTvList[$i][0]=$sIp and $arTvList[$i][1]=$iPort Then
            _ArrayDelete($arTvList,$i)
        EndIf
    Next
    _refreshTvButtons()
EndFunc

Func _refreshTvButtons()
    ;delete all controls
    For $i=0 to UBound($arTvListControls)-1 step 1
        For $j=0 to UBound($arTvListControls,2)-1 step 1
            GUICtrlDelete($arTvListControls[$i][$j][0])
        Next
    Next
    ;resize control array
    ReDim $arTvListControls[UBound($arTvList)][$iStartOfContextMenuButtons+UBound($arContextMenuButtons)][2]
    ;create new controls
    For $i=0 to UBound($arTvList)-1 step 1
        $arTvListControls[$i][0][0]=GUICtrlCreateButton("TV "&($i+1),$arPointTvListStart[0]+($i*($iTvListItemWidth+$iTvListButtonSpace)),$arPointTvListStart[1],$iTvListItemWidth,$iTvListButtonHeight)
        GUICtrlSetFont($arTvListControls[$i][0][0], 8.5, 700, 0, "")
        $arTvListControls[$i][1][0]=GUICtrlCreateButton("",$arPointTvListStart[0]+($i*($iTvListItemWidth+$iTvListButtonSpace)),$arPointTvListStart[1]+$iTvListButtonHeight,$iTvListItemWidth,$iTvListButtonHeight)
        $arTvListControls[$i][1][1]=ShowMenu
        GUICtrlSetFont($arTvListControls[$i][1][0], 8.5, 500, 0, "")
        $arTvListControls[$i][2][0]=GUICtrlCreateContextMenu($arTvListControls[$i][1][0])
        For $j=0 to UBound($arContextMenuButtons)-1 step 1
            $arTvListControls[$i][$iStartOfContextMenuButtons+$j][0]=GUICtrlCreateMenuItem($arContextMenuButtons[$j][0],$arTvListControls[$i][2][0])
            $arTvListControls[$i][$iStartOfContextMenuButtons+$j][1]=$arContextMenuButtons[$j][1]
        Next
    Next
EndFunc

;Telnet_send
Func telnet_send($sIp,$iPort,$sCommand)
    TCPStartup ()
    $Conection=TCPConnect($sIp,$iPort)
    If @error Then
        MsgBox (0,"Error","Could not establish connection to: "&$sIp&":"&$iPort)
        return;
    EndIf
    TCPSend($Conection,$sCommand&Chr(10))
    If @error Then
        MsgBox(0,"Error","Could not send the command: "&$sCommand&" to "&$sIp&":"&$iPort)
    EndIf
EndFunc
; End Telnet_send

Func ShowMenu($hWnd, $CtrlID, $nContextID)
    Local $arPos, $x, $y
    Local $hMenu = GUICtrlGetHandle($nContextID)
    $arPos = ControlGetPos($hWnd, "", $CtrlID)
    $x = $arPos[0]
    $y = $arPos[1]+$arPos[3]
    ClientToScreen($hWnd, $x, $y)
    TrackPopupMenu($hWnd, $hMenu, $x, $y)
EndFunc   ;ShowMenu

; Convert the client GUI coordinates to screen desktop coordinates
Func ClientToScreen($hWnd, ByRef $x, ByRef $y)
    Local $stPoint = DllStructCreate("int;int")
    DllStructSetData($stPoint, 1, $x)
    DllStructSetData($stPoint, 2, $y)
    DllCall("user32.dll", "int", "ClientToScreen", "hwnd", $hWnd, "ptr", DllStructGetPtr($stPoint))
    $x = DllStructGetData($stPoint, 1)
    $y = DllStructGetData($stPoint, 2)
    ; release Struct not really needed as it is a local
    $stPoint = 0
EndFunc   ;==>ClientToScreen

; Show at the given coordinates (x, y) the popup menu (hMenu) which belongs to a given GUI window (hWnd)
Func TrackPopupMenu($hWnd, $hMenu, $x, $y)
    DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hMenu, "int", 0, "int", $x, "int", $y, "hwnd", $hWnd, "ptr", 0)
EndFunc   ;==>TrackPopupMenu

#EndRegion Func

Alles anzeigen

MfG Kanashius

Speedy86

Hallo Kanashius
Danke für das Script.

Werde mal mir das heute am Abend sehr genau anschauen. Weil so weit mit dem Lernen bin ich noch nicht.

Da sind zurzeit meine Grundkenntnisse noch zu wenig.

Was ich vieleicht noch einbauen werde das ich doch bei 2-4 TV andere command benötige.

Was ich meine zb. TV Profil mir würde jetzt gerade 3 verschiedene Profile einfallen. die ich verwenden würde.

Hoff das ich das in dein Script einbauen kann

Danke einmal.

mfg

Speedy

Speedy86

Hi Kanashius,

Leider muss ich zugeben das ich doch nicht ganz klar komme wie ich es brauche oder haben will.

Mein plan war wenn ich es jetzt noch genauer ausführe:

Ich möchte gerne mein Haus abbilden wo alle TV + Beamer + VLC am Pc´s zu steuern geht :), ich weiß etwas freaky...

Ich würde gerne jeden TV selber einen Anzeigenamen vergeben und possition auch selber varabel bzw. über die Position von jeden einzelnen verschieben können.

zb benötige ich auch bei den VLC andere Befehlen bzw. func wie bei den Telnet

so in etwa

Code

Global $TV1_ip = "192.168.0.10" 
Global $TV1_port = "8080"
Global $TV1_profile = $TV_Nec_profile
$TV1fb = GUICtrlCreateButton("TV 1", 100, 100, 60, 20)  ; Das ist zurzeit ein leerer button, woch ich noch eine Fernbedineung einbauen bzw. öffnen soll.
$TV1ch = GUICtrlCreateButton("", 100, 118, 60, 20)

Global $TV1_ip = "192.168.0.11" 
Global $TV1_port = "5050"
Global $TV1_profile = $TV_phillips_profile
$TV1fb = GUICtrlCreateButton("TV 1", 500, 100, 60, 20)  ; Das ist zurzeit ein leerer button, woch ich noch eine Fernbedineung einbauen bzw. öffnen soll.
$TV1ch = GUICtrlCreateButton("", 500, 118, 60, 20)

$TV_Nec_profile= 
Test 1
Test 2

Restart

hinter den Test 1 zb. :
;Telnet_send
Func telnet_send ()
   TCPStartup ()
   $Conection = TCPConnect ( $telnet_host, $telnet_port )
   If @error Then MsgBox (0,"Error","connection not ok")
      TCPSend ( $Conection, $telnet_command & Chr ( 10 ) )
   If @error Then
      MsgBox (0,"Error","not possible")
   EndIf
EndFunc
; End Telnet_send

$TV_phillips_profile =
Test 1
Test 2

Restart
Hier ist hinter Test zb. ein http Request func.

Alles anzeigen

Beim den Profilen würd ich gerne den context angeben können wie die funktion heist + Befehl zb. Telnet befehl oder http request befehl und dann hinter den context die func aus zb. telnet bzw für vlc http request.

Ich hoff ich hab es verständlich erklärt

mfg

Speedy

**Kanashius**

Naja, in dem Script hast du oben ja die Arrays für die TVs und das Contextmenü. Das kannst du beliebig erweitern:

C

Global $arTvList=[ _
        ["192.168.0.10",$iDefaultPort], _
        ["192.168.0.11",$iDefaultPort], _
        ["192.168.0.12",$iDefaultPort] _
    ] ;All client IP´s

Global $arContextMenuButtons=[ _
        ["Test 1","Telnet command 1"], _
        ["Test 2","Telnet command 2"], _
        ["Test 3","Telnet command 3"], _
        ["Test 4","Telnet command 4"], _
        ["Test 5","Telnet command 5"], _
        ["",0], _
        [$sRestart,"Telnet restart"] _
    ]

Alles anzeigen

würde mit dem was du dort haben möchtest zu:

C

Global $arTvList=[ _
        ["192.168.0.10",$iDefaultPort,"DisplayName1"], _
        ["192.168.0.11",$iDefaultPort,"DisplayName2"], _
        ["192.168.0.12",$iDefaultPort,"DisplayName3"] _
    ] ;All client IP´s

Auf dieselbe weise kannst du das ganze auch das Array für die ContextMenuButtons erweitern und z.B. die Info speichern, ob der Eintrag für VLC oder TelNet ist,...

Du kannst auch das Array für die ContextMenuButtons auf ein 3D array umstellen und dann in dem weiteren verfügbaren eintrag die information speichern, ob es ein vlc, telnet,... profil ist und beim tv das ebenfalls eintragen, auslesen und das passende profil nutzen um das contextmenü zu erzeugen.

Arrays sind im Prinzip Listen (1D), Tabellen (2D) oder Tabellen mit Listeneinträgen (3D):

C

#include <array.au3>


local $ar1D=["Eintrag 1","Eintrag 2","Eintrag 3"]
_arraydisplay($ar1D)


local $ar2D=[ _
        ["Row 1 Col 1","Row 1 Col 2","Row 1 Col 3"], _
        ["Row 2 Col 1","Row 2 Col 2","Row 2 Col 3"], _
        ["Row 3 Col 1","Row 3 Col 2","Row 3 Col 3"] _
_arraydisplay($ar2D)


local $ar3D=[ _
    [ _
        ["Row 1 Col 1 Depth 1","Row 1 Col 1 Depth 2","Row 1 Col 1 Depth 3"], _
        ["Row 1 Col 2 Depth 1","Row 1 Col 2 Depth 2","Row 1 Col 2 Depth 3"], _
        ["Row 1 Col 3 Depth 1","Row 1 Col 3 Depth 2","Row 1 Col 3 Depth 3"] _
    ], _
    [ _
        ["Row 2 Col 1 Depth 1","Row 2 Col 1 Depth 2","Row 2 Col 1 Depth 3"], _
        ["Row 2 Col 2 Depth 1","Row 2 Col 2 Depth 2","Row 2 Col 2 Depth 3"], _
        ["Row 2 Col 3 Depth 1","Row 2 Col 3 Depth 2","Row 2 Col 3 Depth 3"] _
    ], _
    [ _
        ["Row 3 Col 1 Depth 1","Row 3 Col 1 Depth 2","Row 3 Col 1 Depth 3"], _
        ["Row 3 Col 2 Depth 1","Row 3 Col 2 Depth 2","Row 3 Col 2 Depth 3"], _
        ["Row 3 Col 3 Depth 1","Row 3 Col 3 Depth 2","Row 3 Col 3 Depth 3"] _
    ] _
]

For $i=0 to UBound($ar3D)-1 step 1
    For $j=0 to UBound($ar3D,2)-1 step 1
        For $k=0 to UBound($ar3D,3)-1 step 1
            ConsoleWrite($i&":"&$j&":"&$k&@TAB&"  >>  "&$ar3D[$i][$j][$k]&@crlf)
        Next
    Next
Next

Alles anzeigen

Normal würde ich in anderen Programmiersprachen Objekte nutzen um diese Daten zu speichern, AutoIt bietet dies möglichkeit leider nicht (nativ ohne größere Umstände).

Deshalb würd ich dein Projekt vermutlich in z.B. Java umsetzen. Dort kann man eine gute Struktur mit Objekten und Vererbung aufbauen, sodass es übersichtlich ist, und das Fenster wäre auch etwas einfacher zu individualisieren

PS: Die ausgelesenen Infos (die du im anderen Thread erwähnst) kannst du nehmen um das Array zu erstellen.

MfG Kanashius

Speedy86

Hi,

also mit den Arrays versteh ich ein bissal sogar das mit den 2d und 3d aber an der umsetzten das zu schreiben versteh ich es gar nicht .

zb. das mit den Namen bekomme ich es auch nicht zusammen.

Hab dies mal geändert:

Code

;TV information
Global $iDefaultPort=8080
Global $iNecPort=8020
Global $arTvList=[ _
                     ["192.168.0.10",$iDefaultPort, "TV 1"], _
                     ["192.168.0.11",$iDefaultPort, "TV 2"], _
                     ["192.168.0.12",$iDefaultPort, "Beamer"], _
                     ["192.168.0.13",$iNecPort, "VW"], _
                     ["192.168.0.14",$iNecPort, "D-Box"], _
                     ["192.168.0.15",$iDefaultPort, "PC"] _
                  ] ;All client IP´s

Alles anzeigen

und logischerweise macht er ja noch immer TV 1 - TV 6

Code

    For $i=0 to UBound($arTvList)-1 step 1
        $arTvListControls[$i][0][0]=GUICtrlCreateButton("TV "&($i+1),$arPointTvListStart[0]+($i*($iTvListItemWidth+$iTvListButtonSpace)),$arPointTvListStart[1],$iTvListItemWidth,$iTvListButtonHeight)

Ich hab es schon versucht umzubauen aber dann kommt gar kein Button mehr oder Text fehlt komplett

Wegen der Position:

Kann ich hier auch noch die Position angeben wie zb.

Code

 ["192.168.0.10",$iDefaultPort, "TV 1", 400, 750], _

und dann noch etwas zb. fürs Profil:

Code

 ["192.168.0.10",$iDefaultPort, "TV 1", 400, 750, $arContextMenuButtons], _
 ["192.168.0.10",$iDefaultPort, "VW", 400, 750, $arContextMenuButtons2], _
 ["192.168.0.10",$iDefaultPort, "PC", 400, 750, $arContextMenuButtons3], _

Hoff das ich dich nicht schon Nerv, ich hab früher nur Windows Application mit Autoit durchgeführt, aber das Projekt ist doch aufwendiger mit den Arrays

Die Button Add and Remove hab ich komplett entfernt da ich das nicht benötige.

lg

Speedy

**Kanashius**

Für das Ändern des Namens musst du als ersten Parameter den Eintrag des Arrays nehmen, also so:

C

$arTvListControls[$i][0][0]=GUICtrlCreateButton($arTvList[$i][2],$arPointTvListStart[0]+($i*($iTvListItemWidth+$iTvListButtonSpace)),$arPointTvListStart[1],$iTvListItemWidth,$iTvListButtonHeight)

Die Position kannst du natürlich auch mit in das Array geben und dann beim erstellen der Buttons entsprechend nutzen.

Was das Profil angeht: Ja du kannst auch ein Array in ein anderes Speichern und somit die $arContextMenuButtons dort angeben. Meist speichert man dort aus performance gründen eher den Index und ruft dann mit dem Index die passenden Daten aus einem anderen Array, da dann weniger Daten gespeichert werden,... sollte für deinen Anwendungszweck aber nicht relevant sein, denke ich :thinking:

Speedy86

Hi,

Danke das mit den Namen hat super funktioniert, sogar das umschreiben mit den Positionen für jeden TV hab ich jetzt heraus wie es funktioniert. Ganz langsam aber doch versteh ich es immer mehr die Arrays.

das mit den 3d Arrays würde mich schon interessieren da ich vor allem gerne lerne.

hättest du in meinen fällen ein bsp. wie ich es mir vorstellen muss ?

Es werden vermutlich doch mehrere Profile da ich ja auch für den Receiver oder Receivern für die channel-liste auch ein machen muss.

lg

Speedy

und Danke jetzt schon mal für deine Bemühung, bin heil froh das es schöner geht als mein erstes scrpt

**BugFix**

Übrigens ist es gerade bei mehrdimensionalen Array eine Hilfe, wenn man die Indizes "sprechend" enumeriert, d.h. ihnen Variablennamen zuordnet, die leicht auf den Inhalt schließen lassen.

C++

; Enumerieren der Indizes in "sprechende" Variablen für die Zeilen des Arrays
Global Enum $TV1, $TV2, $Beamer, $VW, $D_Box, $PC

; Enumerieren der Spaltenindizes
Global Enum $IP, $Port, $Name

Global $iDefaultPort = 443, $iNecPort = 8080
; Dein Array
Global $aDevices[][] = _
[["192.168.0.10",$iDefaultPort, "TV 1"], _
["192.168.0.11",$iDefaultPort, "TV 2"], _
["192.168.0.12",$iDefaultPort, "Beamer"], _
["192.168.0.13",$iNecPort, "VW"], _
["192.168.0.14",$iNecPort, "D-Box"], _
["192.168.0.15",$iDefaultPort, "PC"]]

; Zugriff
ConsoleWrite('IP  (D-Box): ' & $aDevices[$D_Box][$IP] & @CRLF)
ConsoleWrite('Port (TV 1): ' & $aDevices[$TV1][$Port] & @CRLF)

Alles anzeigen

Speedy86

Hi BugFix,

was ich nicht ganz versthe ist warum greift die erste Enum auf die Global $aDevices zu

und das 2 Enum auf Ports.

Das will mir gerade nicht in mein Kopf rein.

Zu den Thema mit den Profilen komm ich leider gar nicht weiter, ich hätte keine Ansatz wie ich das umschreiben könnt

auch ist mir beim Testen aufgefallen das ich bei 2 Telnet Befehle oder bzw. sogar manchmal 4 benötige beider Videowall.

Ich tu mir leider immer noch mit den Contextmenu schwer wie es sich mit den arrays erstellt.

Aber so wie es ausschaut brauch ich ja nur ein 2d array für die Profile kein 3d das ist unnötig.

**BugFix**

Die erste Enumeration gibt den Geräten (Zeilen) des Arrays verständliche Namen.

Die zweite Enumeration macht dies für die Geräte - Eigenschaften (Spalten).

So kann mit: array[Gerät][Eigenschaft]

gut lesbar zugegriffen werden.

Speedy86

Also hab mal es so versucht.

Code

; Enumerieren der Indizes in "sprechende" Variablen für die Zeilen des Arrays
Global Enum $TV1, $TV2, $TV3, $VW, $PC, $Sky_receiver, $D_Box_receiver

; Enumerieren der Spaltenindizes
Global Enum $IP, $Port, $Name, $Y_pos, $X_pos, $Profile

Global $iDefaultPort = 443, $iNecPort = 8080, $iVLCPort = 9001
; Dein Array
Global $aDevices[][] = _
                     [["192.168.0.10",$iDefaultPort, "TV 1", 100, 100, "Default_Profile"], _
                     ["192.168.0.11",$iDefaultPort, "TV 2", 300, 100, "VLC_Profile"], _
                     ["192.168.0.12",$iDefaultPort, "TV 3", 500, 100, "Default_Profile"], _
                     ["192.168.0.13",$iNecPort, "VW", 700, 100, "NEC_Profile"], _
                     ["192.168.0.14",$iVLCPort, "PC", 900, 100, "VLC_Profile"], _
                     ["192.168.0.15",$iNecPort, "Sky Receiver", 900, 300, "Sky_Profile_receiver"], _
                     ["192.168.0.16",$iDefaultPort, "D-Box", 100, 650, "D-Box_Profile_receiver"]]

; Zugriff
ConsoleWrite('IP  (D-Box): ' & $aDevices[$D_Box_receiver][$IP][$Y_pos][$X_pos][$Profile] & @CRLF)
ConsoleWrite('Port (TV 1): ' & $aDevices[$TV1][$Port][$Profile] & @CRLF)

Alles anzeigen

Aber er schreibt mir immer ein Error, warum bin ich mir noch nicht sicher.

Ich würde dann die Profile auf $Default_Profile ect. umschreiben und hier dann die Context menü drauf legen.

Hoff das ich es implementieren kann.

lg und Gute Nacht

Speedy

Speedy86

Hi,

Hier noch ein anderen versuch der komplett in die hose geht

Code

; Script Start - Add your code below here
; Enumerieren der Indizes in "sprechende" Variablen für die Zeilen des Arrays
Global Enum $TV1, $TV2, $TV3, $VW, $PC, $Sky_receiver, $D_Box_receiver

; Enumerieren der Spaltenindizes
Global Enum $IP, $Port, $Name, $Y_pos, $X_pos, $Profile

Global $iDefaultPort = 443, $iNecPort = 8080, $iVLCPort = 9001
; Dein Array
Global $aDevices[][] = _
                     [["192.168.0.10",$iDefaultPort, "TV 1", 100, 100, $aDefault_Profile], _
                     ["192.168.0.11",$iDefaultPort, "TV 2", 300, 100, $aVLC_Profile], _
                     ["192.168.0.12",$iDefaultPort, "TV 3", 500, 100, $aDefault_Profile], _
                     ["192.168.0.13",$iNecPort, "VW", 700, 100, $aNEC_Profile], _
                     ["192.168.0.14",$iVLCPort, "PC", 900, 100, $aVLC_Profile], _
                     ["192.168.0.15",$iNecPort, "Sky Receiver", 900, 300, $aSky_Profile_receiver], _
                     ["192.168.0.16",$iDefaultPort, "D-Box", 100, 650, $aD_Box_Profile_receiver]]

; Zugriff
ConsoleWrite('IP  (D-Box): ' & $aDevices[$D_Box_receiver][$IP][$Y_pos][$X_pos][$Profile] & @CRLF)
ConsoleWrite('Port (TV 1): ' & $aDevices[$TV1][$Port][$Profile] & @CRLF)

Global Enum $DCH1, $DCH2, $DCH3, $DCH4, $DCH5, $DCH6, $DCH_Line, $DCH_restart
Global Enum $Dname, $Dtelnet1, $Dtime1, $Dtelnet2, $Dtime2, $Dtelnet3 ;Time ist die Sende verzögerung.
Global $aDefault_Profile[][] = _
        [["Test 1","Telnet command 1", "500", "Telnet command 2"], _
        ["Test 2","Telnet command 2"], _
        ["Test 3","Telnet command 3", "500", "Telnet command 2", "1000", , "Telnet command 3"], _
        ["Test 4","Telnet command 4"], _
        ["Test 5","Telnet command 5"], _
        ["Test 6","Telnet command 6"], _
        ["",0], _
        ["Restart","Telnet restart"]]

Global Enum $DCH1, $DCH2, $DCH3, $DCH4, $DCH5, $DCH6, $DCH_Line, $DCH_restart
Global Enum $Dname, $Dtelnet1, $Dtime1, $Dtelnet2, $Dtime2, $Dtelnet3 ;Time ist die Sende verzögerung.
Global $aVLC_Profile[][] = _
        [["Test 1","http command 1"], _
        ["Test 2","http command 2"], _
        ["Test 3","http command 3"], _
        ["Test 4","http command 4"], _
        ["Test 5","http command 5"], _
        ["Test 6","http command 6"], _
        ["",0], _
        ["Restart","telnet command restart"]]

Alles anzeigen

Dachte das mann die Enum vor jedem array angeben kann

**BugFix**

Zitat von Speedy86

C++

ConsoleWrite('IP  (D-Box): ' & $aDevices[$D_Box_receiver][$IP][$Y_pos][$X_pos][$Profile] & @CRLF) 
ConsoleWrite('Port (TV 1): ' & $aDevices[$TV1][$Port][$Profile] & @CRLF)

Du kannst nur immer auf EINEN Wert in einem Array zugreifen! Der definiert sich in diesem Bsp.-Array (2D-Array) über Angabe der Schnittstelle von Zeile und Spalte.

Damit du nicht das Array nach dem zu verwendenden Gerät durchsuchen musst, haben wir für jedes Gerät (das ja in einer eigenen Zeile steht mit seinen Werten) eine Variable statt der Zeilennummer, bzw. enthält diese Variable die Zeilennummer.

$TV1 ist die erste enumerierte Variable und hat somit den Wert 0. Zugriff im Array hast du damit also auf die Zeile 0 - die erste Zeile.

$Profile ist die sechste enumerierte Variable für die Spalten und hat somit den Wert 5. Zugriff im Array hast du damit auf die Spalte 5 -die letzte Spalte.

Das Profil für "TV 1" erfragst du also indem du sagst: arrayGeräte-inZeileTV1-inSpalteProfile: $aDevices[$TV1][$Profile]

Das Profil für "Sky Receiver" wäre demzufolge: $aDevices[$Sky_receiver][$Profile].

Der X-Wert für "D-Box" ist dann: $aDevices[$D_Box_receiver][$X_pos].

Fast identisch mit einer Excel-Tabelle, nur dass dort standardmäßig die Adressierung über Spalte,Zeile erfolgt. Hier ist es umgekehrt.

Ich empfehle dir zum besseren Verständnis mal mein Array-Tut durchzulesen (s. Signatur).

Speedy86

Hallo ihr Lieben,

Also erst mal danke für deine Erklärung ich hab mal gerstern und heute sehr viele Aha Effekte gehabt.

Das mit den Arrays hab ich jetzt verstanden auch wie ich es abrufe. (zumindest mal 1d und 2d Arrays, bei den 3D denk ich auch das ich in der Theorie verstehe)

hab auch noch mal ein paar anderen Sachen durchgelesen.

Hier hab ich noch ein paar Unklarheiten gefunden, was ich noch nicht genau versteht.

Hier mal der Code vom Func _refreshTvButtons()

Code

Global $iStartOfContextMenuButtons=7
Global $arTvListControls[0][0][2]

Func _refreshTvButtons()
    ;resize control array
    ReDim $arTvListControls[UBound($arTvList)][$iStartOfContextMenuButtons+UBound($arContextMenuButtons)][2]
    ;create new controls
    For $i=0 to UBound($arTvList)-1 step 1
        $arTvListControls[$i][0][0]=GUICtrlCreateButton($arTvList[$i][2],$arTvList[$i][3],$arTvList[$i][4],$iTvListItemWidth,$iTvListButtonHeight)
        GUICtrlSetFont($arTvListControls[$i][0][0], 8.5, 700, 0, "")
        $arTvListControls[$i][1][0]=GUICtrlCreateButton("",$arTvList[$i][3],$arTvList[$i][4]+$iTvListButtonSpace,$iTvListItemWidth,$iTvListButtonHeight)
        $arTvListControls[$i][1][1]=ShowMenu
        GUICtrlSetFont($arTvListControls[$i][1][0], 8.5, 500, 0, "")
        $arTvListControls[$i][2][0]=GUICtrlCreateContextMenu($arTvListControls[$i][1][0])
        For $j=0 to UBound($arContextMenuButtons)-1 step 1
            $arTvListControls[$i][$iStartOfContextMenuButtons+$j][0]=GUICtrlCreateMenuItem($arContextMenuButtons[$j][0],$arTvListControls[$i][2][0])
            $arTvListControls[$i][$iStartOfContextMenuButtons+$j][1]=$arContextMenuButtons[$j][1]
        Next
    Next
EndFunc

Alles anzeigen

Ich versteh schon wie hier es funktioniert aber warum macht man zb hier:

Code

 ReDim $arTvListControls[UBound($arTvList)][$iStartOfContextMenuButtons+UBound($arContextMenuButtons)][2]

ReDim und nach den $arTvListControls kein =

des weiteren Ubound bedeutet ja den wert leeren, so wie ich es verstanden habe.

was noch komisch ist warum Global $arTvListControls[0][0][2] ganz oben ?

Würde meine Aussage stimmen:

Ich man die Array $arTvListControls setzt mit Ubound den wert zurück, und setzt mir die $arTvList und auf alle Button Namen von Array $arContextMenuButtons [2]

aber für was brauch ich den $iStartOfContextMenuButtons , das kann ich ja vom Array auch auslesen lassen.

Und warum muss ich das so in diesen klammer setzen. Das ist mit leider auch noch ein kleines Rätzel

Das Letzte wo ich noch bedänken habe ist:

Code

   For $i=0 to UBound($arTvList)-1 step 1

ich setzt for $i die zahl 0 dann wieder das Ubound mein Array aber warum -1 step 1 ???? das will auch nicht in meinen Kopf.

Ich hoff das ich dann noch den richtigen weg finde wie ich das mit den 2 Profilen bewerkstelligen kann

Da hät ich mir was einfallen lassen mit in den Array Global $arTvList an wert 1, 2 oder 3 für die unterschiedlichen profilen und in der Func oder im Gui Case Else ein if abfrage wen 1, 2 oder 3 ist dann nimm die Func

sollte ja auch gehen.

Liebe Grüße

Speedy

**BugFix**

Eine Bitte: lies mein Array Tut. Alles was du zu ReDim und Ubound falsch verstanden hast (deine Annahmen sind falsch), wird dort erläutert.

Wenn dann noch Unklarheiten bestehen, melde dich wieder.

Speedy86

Hi,

Mach gerade mehrere Übungen mit Arrays ein kurze zwischen frage hätt ich.

Beim Stringsplit

Code

$string = "abcdef"
Global $aSplit = StringSplit($string, "") ; leerer Trennzeichenstring führt zu Trennung nach jedem Zeichen

 ConsoleWrite($aSplit[0] & @LF)

Stimmt das wenn ich das array mit

Local $aTest [5] deklariere ruf ich es mit

$aTest [0] beginned ab.

wenn ich zählen lass ist [0] immer die anzall der Elemente. und es beginnt mit [1] (1D array)

lg

Speedy

**BugFix**

Achte auf die Parameter bei StringSplit! Das Standardverhalten liefert die Anzahl der Splitelemente an $array[0]. Das kannst du aber mit dem Parameter $STR_NOCOUNT (2) deaktivieren. Was dann auch zum entsprechenden Verhalten im Fehlerfall führt:

Zitat von AutoIt-Hilfe StringSplit

If flag is not equal to $STR_NOCOUNT, $aArray[0] is set to 1 and the full string is returned in $aArray[1].

If flag is equal to $STR_NOCOUNT, the full string is returned in $aArray[0].

Speedy86

Hallo,

Hoff das ich euch nicht schon am nerv gehe.

Langsam aber doch gefällt mir die array sache immer mehr, vor allem was man alles damit machen kann.

Hier noch mal paar fragen. hoff das ich das jetzt schon halbwegs richtig beschrieben habe:

Code

#Region Func

Func _refreshTvButtons()
    ;resize control array
    ReDim $arTvListControls[UBound($arTvList)][$iStartOfContextMenuButtons+UBound($arContextMenuButtons)][2]

Es wird ein 3d Array erstellt mit einmal der arTvList wie viel Elemente als Liste enthalten sind, die zweite ist [$iStartOfContextMenuButtons+UBound ($arContextMenuButtons)] die als Spalten eingefügt werden von der Liste $arContextMenuButtons,und die dritte ist die 2 3d Dimension.

Nur was ich hier nicht verstehe ist warum ich die Telnet befehle als Spanten anhänge das ist mir zurzeit noch zu hoch.

Auch versuche ich die $iStartOfContextMenuButtons komplett zu entfernen da ich dies eh nicht benötige.
Aber das bekomm ich auch nicht hin.

Zb hab ich versucht ein 2. Telnet command hinzuzufügen was hintereinander ausgeführt werden soll.
wo kann ich den 2 befehle hinzufügen. Im Array $arContextMenuButtons als nächste spalte nur beim:

Code

telnet_send($arTvList[$i][0],$arTvList[$i][1],$arTvListControls[$i][$j][1], ???????????)

schaff ich es nicht das der 2. Command dem Telnet func mitübergeben wird.

Wie komm ich darauf das der 2. command vom $arContextMenuButtons [2] abgerufen wird.

Code

 Switch $j
                        case 0 ; FB Button not used
                        case 1 ; CH Button
                            $arTvListControls[$i][$j][1]($hGUI,$nMsg,$arTvListControls[$i][$j+1][0])
                        case Else ;all contextmenu items
                            telnet_send($arTvList[$i][0],$arTvList[$i][1],$arTvListControls[$i][$j][1])
                            GUICtrlSetData($arTvListControls[$i][1][0],$arContextMenuButtons[$j-$iStartOfContextMenuButtons][0])
                            If $arContextMenuButtons[$j-$iStartOfContextMenuButtons][0]=$sRestart Then
                                GUICtrlSetData($arTvListControls[$i][1][0],"")
                            EndIf

;Telnet_send
Func telnet_send($sIp,$iPort,$sCommand,$sCommand2)
    TCPStartup ()
    $Conection=TCPConnect($sIp,$iPort)
    If @error Then
        MsgBox (0,"Error","Could not establish connection to: "&$sIp&":"&$iPort)
        return;
    EndIf
    TCPSend($Conection,$sCommand&Chr(10))
    If @error Then
        MsgBox(0,"Error","Could not send the command: "&$sCommand&" to "&$sIp&":"&$iPort)
    EndIf
    Sleep(300)
    TCPSend($Conection,$sCommand2&Chr(10))
    If @error Then
        MsgBox(0,"Error","Could not send the command: "&$sCommand2&" to "&$sIp&":"&$iPort)
    EndIf
EndFunc
; End Telnet_send

Alles anzeigen

lg

Speedy

Speedy86

Hallo Ihr lieben,

Ich habe endlich wieder weiter gemacht mit meiner Tv Steuerung.

Ein komischer Bug hab ich bemerkt wo ich nicht so ganz weiter kommt.

Wisst Ihr eine Lösung in den Script weiter Oben.

Wenn ich in der

Code

Global $arTvList=[ _
                     ["192.168.55.225",        $i_nec_port,     "TV 1",         100, 100], _
                     ["192.168.55.225",        $i_nec_port,     "TV 7",         700, 100] _
                  ] ;All client IP´s

weniger als 3 Tv erstelle zb. nur 2 funktioniert das Contextmenü nicht mehr zum aufklappen. komisch das es mit der Linken Mausstate geht.

Wenn 3 oder mehr sind funktioniert alle ohne Probleme.

Das hab ich in der zwischen zeit geändert da ich kein:
Global $iStartOfContextMenuButtons=X

haben möchte wird ja eh von der Array Liste selbst gezählt.

Hier noch die änderung dazu:

Code

case 1 ; CH Button
   $arTvListControls[$i][$j][1]($hGUI,$nMsg,$arTvListControls[$i][$j+1][0])
case Else ;all contextmenu items
   telnet_send($arTvList[$i][0],$arTvList[$i][1],$arTvListControls[$i][$j][1],$arTvListControls[$i][$j][2])
   GUICtrlSetData($arTvListControls[$i][1][0],$arContextMenuButtons[$j-UBound($arTvList)][0])

   If $arContextMenuButtons[$j-UBound($arTvList)][0]=$sRestart Then
   GUICtrlSetData($arTvListControls[$i][1][0],"")
   EndIf



Func _refreshTvButtons()
    ;resize control array
    ReDim $arTvListControls[UBound($arTvList)][UBound($arTvList)+UBound($arContextMenuButtons)][3]
    ;create new controls
    For $i=0 to UBound($arTvList)-1 step 1
        $arTvListControls[$i][0][0]=GUICtrlCreateButton($arTvList[$i][2],$arTvList[$i][3],$arTvList[$i][4],$iTvListItemWidth,$iTvListButtonHeight)
        GUICtrlSetFont($arTvListControls[$i][0][0], 8.5, 700, 0, "")
        $arTvListControls[$i][1][0]=GUICtrlCreateButton("",$arTvList[$i][3],$arTvList[$i][4]+$iTvListButtonSpace,$iTvListItemWidth,$iTvListButtonHeight)
        $arTvListControls[$i][1][1]=ShowMenu
        GUICtrlSetFont($arTvListControls[$i][1][0], 8.5, 500, 0, "")
        $arTvListControls[$i][2][0]=GUICtrlCreateContextMenu($arTvListControls[$i][1][0])
        For $j=0 to UBound($arContextMenuButtons)-1 step 1
            $arTvListControls[$i][UBound($arTvList)+$j][0]=GUICtrlCreateMenuItem($arContextMenuButtons[$j][0],$arTvListControls[$i][2][0])
            $arTvListControls[$i][UBound($arTvList)+$j][1]=$arContextMenuButtons[$j][1]
            $arTvListControls[$i][UBound($arTvList)+$j][2]=$arContextMenuButtons[$j][2]
        Next
    Next
EndFunc

Alles anzeigen

Hat hier Irgendwer eine Idee ?

lg

Speedy

Tv Steuerung

Ähnliche Themen

PSPad4AutoIt3 (Editor IDE)

Bildschirmausschnitt als bmp zum Drücken

ControlSend an DOSBox

Sicherstellen dass Webseite vollständig geladen ist