Excel+dazugehörige Fehlermeldungen schließen

presenter-test

Hallo zusammen,

Ich habe ein Autoit-Skript was mir minütlich eine Excel-Datei mit Makros öffnen und nach ca 20 Sekunden auch wieder schließt.

Alle paar Stunden kommt es vor, dass Excel keine Sql-Verbindung aufbauen kann was zu Fehlermeldungen (Popups in Excel) führt.

Leider schafft es Autoit dann nicht mehr Excel mit deren Meldugen zu schließen.

Könnt ihr mir dazu ein skript empfehlen?

Ich komme hier leider trotz Suchanfragen nicht voran.

**Bitnugger**

Zitat von presenter-test

Leider schafft es Autoit dann nicht mehr Excel mit deren Meldugen zu schließen.

AutoIt schafft das ganz sicher... allerdings nur dann, wenn dein Script entsprechend geschrieben wurde, was aber wohl nicht der Fall ist.

Um dir ohne vorhergehende Ratespiele helfen zu können, solltest du dein bisheriges Script hier posten. Sensible Stellen kannst du darin ja ausixen...

presenter-test

Hier der Code:

C

#include <Excel.au3>
#include <MsgBoxConstants.au3>
#include <IE.AU3>

;Excel aktivieren
While True

Global $oExcel = _Excel_Open()
Global $oWorkbook = _Excel_BookOpen($oExcel, "C:\.....mein Speicherpfad........\Excel-Datei.xlsm")

WinSetState("Excel-Datei.xlsm - Excel", "", @SW_HIDE)

Sleep(35000)

_Excel_Close($oExcel)

Sleep(5000)
WEnd

Alles anzeigen

**Bitnugger**

Hm, ich erkenne den Sinn des Scripts nicht... du startest Excel, falls nicht schon passiert, öffnest eine Arbeitsmappe, wartest 35 (nicht 20) Sekunden, und beendest Excel dann wieder, ohne auch nur einmal auf die Arbeitsmappe zuzugreifen. Wofür soll das gut sein und was willst du mit dem Script bezwecken?

Zudem denke ich, sollte es reichen, wenn du Excel nicht alle 35 Sekunden beendest, sondern lediglich die Arbeitsmappe schließt und wieder öffnest.

Ansonsten setze mal bei _Excel_Close den 2. Parameter ($bForceClose) auf True...

_Excel_Close($oExcel, True, True) ; $bSaveChanges = True, $bForceClose = True

...und evtl. bei _Excel_BookOpen dén letzten Parameter ($bUpdateLinks) auf 3.

_Excel_BookOpen($oExcel, $sWorkbook, False, True, Default, Default, 3)

Oder teste mal hier das Bsp. mit AdlibRegister:

AutoIt

;-- TIME_STAMP   2020-09-10 23:14:25   v 0.1

;~ #include <MsgBoxConstants.au3>
#include <Excel.au3>
;~ #include <IE.AU3>

Opt('MustDeclareVars', 1)

Global $oExcel, $oWorkbook, $sWorkbook = 'F:\Eigene Dateien\TxT\Spalten_Sortieren.xlsm'

#cs
    _Excel_Open ( [$bVisible = True [, $bDisplayAlerts = False [, $bScreenUpdating = True [, $bInteractive = True [, $bForceNew = False]]]]] )
            $bVisible        [optional] True gibt an, dass das Programm sichtbar sein wird (Standard = True)
            $bDisplayAlerts  [optional] False unterdrückt alle Aufforderungsmeldungen und Fehlermeldungen, während ein Arbeitsbuch geöffnet wird (Standard = False)
            $bScreenUpdating [optional] False unterdrückt Bildschirmupdates um das Script zu beschleunigen (Standard = True)
            $bInteractive    [optional] Wenn False, blockiert Excel alle Tastatur- und Mauseingaben der Nutzer (ausgenommen den Input von Dialogfeldern) (Standard = True)
            $bForceNew       [optional] True erzwingt, dass eine neue Excel-Instanz erstellt wird, auch wenn es bereits eine laufende Instanz gibt (Standard = False)
    
    _Excel_BookOpen ( $oExcel, $sFilePath [, $bReadOnly = False [, $bVisible = True [, $sPassword = Default [, $sWritePassword = Default [, $bUpdateLinks = Default]]]]] )
            $oExcel          Excel Anwendungs-Objekt, mit dem das neue Arbeitsbuch geöffnet werden soll
            $sFilePath       Pfad oder Dateiname der Datei die geöffnet werden soll
            $bReadOnly       [optional] True öffnet das Arbeitsbuch als read-only (nur lesen) (Standard = False)
            $bVisible        [optional] True legt fest, ob das Arbeitsbuch-Fenster sichtbar sein wird (Standard = True)
            $sPassword       [optional] Passwort um das Arbeitsbuch zu lesen (falls es vergeben wurde) (standardmäßig keines)
            $sWritePassword  [optional] Passwort um das Arbeitsbuch zu schreiben (falls es vergeben wurde) (standardmäßig keines)
            $bUpdateLinks    [optional] Legt die Art fest, wie externe Referenzen (Links) in der Datei aktualisiert werden (Standard = Schlüsselwort Default)
                            Mögliche Werte sind:
                                Default: Excel fragt den Nutzer um zu entscheiden, wie Links aktualisiert werden sollen
                                0: Excel öffnet keine Aktualisierungs-Links
                                3: Excel aktualisiert alle Links
    
    _Excel_Close ( $oExcel [, $bSaveChanges = True [, $bForceClose = False]] )
            $oExcel          Excel application object as returned by _Excel_Open()
            $bSaveChanges    [optional] Specifies whether changed worksheets should be saved before closing (default = True)
            $bForceClose     [optional] If True the Excel application is closed even when it was not started by _Excel_Open() (default = False)
#ce

; Create application object or connect to an already running Excel instance
$oExcel = _Excel_Open(False) ; $bVisible = False
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Open", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

OnAutoItExitRegister('_Exit')

_OpenWorkbook($oWorkbook, $sWorkbook)

AdlibRegister('_Adlib_OpenWorkbook', 35000)

While True
    ; Do something...
WEnd

Func _Adlib_OpenWorkbook()
    ConsoleWrite('@@ (28) :(' & @MIN & ':' & @SEC & ') _Adlib_OpenWorkbook()' & @CR) ;### Function Trace
    If IsObj($oWorkbook) Then _CloseWorkbook($oWorkbook, $sWorkbook)
    _OpenWorkbook($oWorkbook, $sWorkbook)
EndFunc   ;==>_Adlib_OpenWorkbook

; Open an existing workbook and return its object identifier.
Func _OpenWorkbook(ByRef $oWorkbook, $sWorkbook)
    ConsoleWrite('@@ (48) :(' & @MIN & ':' & @SEC & ') _OpenWorkbook()' & @CR) ;### Function Trace
    $oWorkbook = _Excel_BookOpen($oExcel, $sWorkbook)
    _Excel_BookOpen($oExcel, $sWorkbook, False, True, Default, Default, 3)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpen", "Error opening '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
EndFunc   ;==>_OpenWorkbook

; Closes the specified workbook
Func _CloseWorkbook(ByRef $oWorkbook, $sWorkbook)
    ConsoleWrite('@@ (56) :(' & @MIN & ':' & @SEC & ') _CloseWorkbook()' & @CR) ;### Function Trace
    ; _Excel_BookClose ( $oWorkbook [, $bSave = True] )
    $oWorkbook = _Excel_BookClose($oWorkbook) ; Arbeitsmappe speichern und schließen
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookClose", "Error saving workbook '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
EndFunc   ;==>_CloseWorkbook

; Close the Excel instance opened by _Excel_Open
Func _Exit()
    ConsoleWrite('@@ (69) :(' & @MIN & ':' & @SEC & ') _Exit()' & @CR) ;### Function Trace
    If IsObj($oExcel) Then
        _Excel_Close($oExcel, True, True) ; $bSaveChanges = True, $bForceClose = True
        If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Close", "Error closing the Excel application." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    EndIf
EndFunc   ;==>_Exit

Alles anzeigen