Unter-Schleife per Knopfdruck beenden

Professor Bernd · 25. November 2020

Wie beendet man eine "Unter"-Schleife per Knopfdruck?

Im Demo läuft die Hauptschleife der GUI. Wenn man den Button "OK" klickt, wird die TestFunc1() gestartet, in der dann für 10 Sekunden die Unter-Schleife läuft. Wie kann man die Unter-Schleife vorzeitig beenden?

Ich habe es mit einer globalen Variablen "$g_bCancel" versucht, die beim Klick auf den Close-Button (das "rote" X) auf True gesetzt wird. In der Unter-Schleife wird $g_bCancel abgefragt und bei True sollte die Unter-Schleife beendet werden. Ich habe für die GUI den MessageLoop Modus und den OnEvent Modus probiert, leider kommt das "True" in der Unter-Schleife nicht an (in der Hauptschleife der GUI kommt es an).

Als Demo habe ich ein Beispiel aus der AutoIt Hilfe als Basis genommen und angepasst.

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus

Local $hMainGUI = GUICreate("Hallo Welt", 300, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEButton")
GUICtrlCreateLabel("Klicke auf OK und dann auf den Close-Button." & @CRLF _
  & "GUI wird NICHT geschlossen!", 30, 10, -1, 50)
Local $iOKButton = GUICtrlCreateButton("OK", 120, 70, 60)
GUICtrlSetOnEvent($iOKButton, "OKButton")
GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False

While 1
  Sleep(100) ; Im Leerlauf bummeln
  ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
WEnd

Func OKButton()
  ; Beachte: an diesem Punkt w&auml;re @GUI_CtrlId gleich $iOKButton,
  ; und @GUI_WinHandle w&auml;re gleich $hMainGUI
;   MsgBox($MB_OK, "GUI Event", "Du hast auf OK geklickt!")
  TestFunc1()
EndFunc   ;==>OKButton

Func CLOSEButton()
  ; Beachte: an diesem Punkt w&auml;re @GUI_CtrlId gleich $GUI_EVENT_CLOSE,
  ; und @GUI_WinHandle w&auml;re gleich $hMainGUI
;   MsgBox($MB_OK, "GUI Event", "Du hast auf CLOSE geklickt! Programm wird beendet...")
  $g_bCancel = True
  Exit
EndFunc   ;==>CLOSEButton

Func TestFunc1()
  Local $iCnt = 0
  Do
    Sleep(250)
    ConsoleWrite("$g_bCancel: " & $g_bCancel & @CRLF)
    If $g_bCancel Then Exit

    GUICtrlSetData($iOKButton, $iCnt)
    $iCnt += 1
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Alles anzeigen

Yjuq · 25. November 2020

Du solltest in Windows Events prinzipiell keine Schleifen verwenden. Das sorgt nur dafür dass sich das Programm aufhängt und Events nicht mehr richtig funktionieren.

Stattdessen kannst du eine Variable in dem Event setzen um dann deine gewünschte Funktion aufzurufen:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus

Local $hMainGUI = GUICreate("Hallo Welt", 300, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEButton")
GUICtrlCreateLabel("Klicke auf OK und dann auf den Close-Button." & @CRLF _
  & "GUI wird NICHT geschlossen!", 30, 10, -1, 50)
Local $iOKButton = GUICtrlCreateButton("OK", 120, 70, 60)
GUICtrlSetOnEvent($iOKButton, "OKButton")
GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False
Global $bOK = False

While 1
  Sleep(100) ; Im Leerlauf bummeln
  ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
  If $bOK Then
      TestFunc1()
      $bOK = False
  EndIf
WEnd

Func OKButton()
  ; Beachte: an diesem Punkt w&auml;re @GUI_CtrlId gleich $iOKButton,
  ; und @GUI_WinHandle w&auml;re gleich $hMainGUI
;   MsgBox($MB_OK, "GUI Event", "Du hast auf OK geklickt!")
    If $bOK = True Then $g_bCancel = True
  $bOK = True
EndFunc   ;==>OKButton

Func CLOSEButton()
  ; Beachte: an diesem Punkt w&auml;re @GUI_CtrlId gleich $GUI_EVENT_CLOSE,
  ; und @GUI_WinHandle w&auml;re gleich $hMainGUI
;   MsgBox($MB_OK, "GUI Event", "Du hast auf CLOSE geklickt! Programm wird beendet...")
  $g_bCancel = True
  Exit
EndFunc   ;==>CLOSEButton

Func TestFunc1()
  Local $iCnt = 0
  Do
    Sleep(250)
    ConsoleWrite("$g_bCancel: " & $g_bCancel & @CRLF)
    If $g_bCancel Then Exit

    GUICtrlSetData($iOKButton, $iCnt)
    $iCnt += 1
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Alles anzeigen

Noch schöner (und bei einer größeren GUI) ist natürlich eine Funktion die das managed.

Professor Bernd · 26. November 2020

Zitat von Yjuq

Du solltest in Windows Events prinzipiell keine Schleifen verwenden. Das sorgt nur dafür dass sich das Programm aufhängt und Events nicht mehr richtig funktionieren.

Naja, das ist "relativ". Ich denke, dass es gängiges Vorgehen ist, in einem Button-Click auch Routinen zu starten, in denen Schleifen benutzt werden. Das wird normalerweise nicht auffallen, weil es selten Schleifen sind, die man abbrechen möchte. Oft will man sogar, dass die weitere Ausführung erst erfolgt, nachdem die Schleife beendet ist. In Scripts mit MessageLoop Modus sehe ich das sehr oft.

Dennoch hast du recht, dass man das wohl prinzipiell nicht tun sollte, vorallem bei Events, die oft ausgelöst werden, wie z.B. Win-Messages. Und offensichtlich ist es auch bei einem Button-Click besser, falls man wie hier eine Schleife vorzeitig beendet können soll. (Konkret geht es um einen Download, der im Falle eines Falles abgebrochen werden soll.)

Danke für deinen Code-Snippet. Für eine bessere Übersicht habe ich für "Cancel" einen eigenen Button eingebaut und Kommentare entfernt.

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus

Local $hMainGUI = GUICreate("Hallo Welt", 300, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEButton")
GUICtrlCreateLabel("Klicke auf OK und dann auf den Close-Button." & @CRLF _
  & "GUI wird NICHT geschlossen!", 30, 10, -1, 50)
Local $iOKButton = GUICtrlCreateButton("OK", 80, 70, 60)
Local $iCancelBtn = GUICtrlCreateButton("Cancel", 160, 70, 60)
GUICtrlSetOnEvent($iOKButton, "OKButton")
GUICtrlSetOnEvent($iCancelBtn, "CancelBtn")
GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False
Global $bOK = False

While 1
  Sleep(100) ; Im Leerlauf bummeln
  ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
  If $bOK Then
    TestFunc1()
    $bOK = False
  EndIf
WEnd

Func OKButton()
  $bOK = True
EndFunc   ;==>OKButton

Func CancelBtn()
  ConsoleWrite("Setze $g_bCancel auf True" & @CRLF)
  $g_bCancel = True
EndFunc   ;==>CancelButton

Func CLOSEButton()
  Exit
EndFunc   ;==>CLOSEButton

Func TestFunc1()
  Local $iCnt = 0
  Do
    Sleep(250)
    ConsoleWrite("$g_bCancel: " & $g_bCancel & @CRLF)
    If $g_bCancel Then
      $g_bCancel = False
      ExitLoop
    EndIf

    GUICtrlSetData($iOKButton, $iCnt)
    $iCnt += 1
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Alles anzeigen

Das funktioniert Im OnEvent Modus soweit gut, die Unter-Schleife wird auf Knopfdruck beendet ($g_bCancel) und auch der Close-Button der GUI reagiert. Leider habe ich es im MessageLoop Modus nicht hinbekommen. Hast du da auch eine Idee?

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Local $hMainGUI = GUICreate("Hallo Welt", 310, 100)
GUICtrlCreateLabel("Klicke auf OK und dann auf den Close- oder Cancel-Button." & @CRLF _
  & "Schleife wird NICHT beendet, GUI wird NICHT geschlossen!", 10, 10, -1, 50)
Local $iOKButton = GUICtrlCreateButton("OK", 80, 70, 60)
Local $iCancelBtn = GUICtrlCreateButton("Cancel", 160, 70, 60)
GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False
Global $bOK = False

While 1
  ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
  If $bOK Then
    $bOK = False
    TestFunc1()
  EndIf

  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      ExitLoop

    Case $iOKButton
      $bOK = True
      ConsoleWrite("$g_bCancel (Ende): " & $g_bCancel & @CRLF)

    Case $iCancelBtn
      $g_bCancel = True

  EndSwitch
WEnd

Func TestFunc1()
  Local $iCnt = 0
  Do
    Sleep(250)
    ConsoleWrite("$g_bCancel: " & $g_bCancel & @CRLF)
    If $g_bCancel Then
      $g_bCancel = False
      ExitLoop
    EndIf

    GUICtrlSetData($iOKButton, $iCnt)
    $iCnt += 1
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Alles anzeigen

Yjuq · 26. November 2020

Naja, das ist auch ganz simpel. Im prinzip werden die neuen Events gefetcht nachdem du GuiGetMsg() aufrufst. Demnach musst du es nur aufrufen und auf Events reagieren:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Local $hMainGUI = GUICreate("Hallo Welt", 310, 100)
GUICtrlCreateLabel("Klicke auf OK und dann auf den Close- oder Cancel-Button." & @CRLF _
  & "Schleife wird NICHT beendet, GUI wird NICHT geschlossen!", 10, 10, -1, 50)
Local $iOKButton = GUICtrlCreateButton("OK", 80, 70, 60)
Local $iCancelBtn = GUICtrlCreateButton("Cancel", 160, 70, 60)
GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False
Global $bOK = False

While 1
  ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
  If $bOK Then
    $bOK = False
    TestFunc1()
  EndIf

    events()
WEnd

Func TestFunc1()
  Local $iCnt = 0
  Do
    Sleep(250)
    ConsoleWrite("$g_bCancel: " & $g_bCancel & @CRLF)
    If $g_bCancel Then
      $g_bCancel = False
      ExitLoop
    EndIf

    GUICtrlSetData($iOKButton, $iCnt)
    $iCnt += 1
    events()
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Func events()
      Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      Exit

    Case $iOKButton
      $bOK = True
      ConsoleWrite("$g_bCancel (Ende): " & $g_bCancel & @CRLF)

    Case $iCancelBtn
      $g_bCancel = True

  EndSwitch
EndFunc

Alles anzeigen

Sleep() verhindert aber das sofortige schließen. Ist genauso ein Fall den du nicht in Events setzen möchtest. Hier mal eine Variation mit einen richtigen Timer:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Local $hMainGUI = GUICreate("Hallo Welt", 310, 100)
GUICtrlCreateLabel("Klicke auf OK und dann auf den Close- oder Cancel-Button." & @CRLF _
  & "Schleife wird NICHT beendet, GUI wird NICHT geschlossen!", 10, 10, -1, 50)
Local $iOKButton = GUICtrlCreateButton("OK", 80, 70, 60)
Local $iCancelBtn = GUICtrlCreateButton("Cancel", 160, 70, 60)
GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False
Global $bOK = False

While 1
  ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
  If $bOK Then
    $bOK = False
    TestFunc1()
  EndIf

    events()
WEnd

Func TestFunc1()
    Local $iCnt = 0
    Local $timer = TimerInit()
  Do
    If TimerDiff($timer) > 250 Then
        ConsoleWrite("$g_bCancel: " & $g_bCancel & @CRLF)
        If $g_bCancel Then
        $g_bCancel = False
        ExitLoop
        EndIf

        GUICtrlSetData($iOKButton, $iCnt)
        $iCnt += 1
        $timer = TimerInit()
    EndIf
    events()
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Func events()
      Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      Exit

    Case $iOKButton
      $bOK = True
      ConsoleWrite("$g_bCancel (Ende): " & $g_bCancel & @CRLF)

    Case $iCancelBtn
      $g_bCancel = True

  EndSwitch
EndFunc

Alles anzeigen

Solche Sachen lassen sich aber mit einer "Manager" Funktion, welche AutoIt Skript von dem Windows Events trennt, ziemlich einfach lösen.

Professor Bernd · 26. November 2020

Beeindruckend!

Deine beiden Code-Snippets habe ich kurz durchgesehen. Beide werde ich später ausprobieren und gedanklich verarbeiten, damit ich auch verstehe, was da genau passiert. Das kann eine Weile dauern. Kannst du vielleicht zwischenzeitlich erklären, wie so eine Manager Funktion aussieht und was sie tut?

Zitat von Yjuq

Solche Sachen lassen sich aber mit einer "Manager" Funktion, welche AutoIt Skript von dem Windows Events trennt, ziemlich einfach lösen.

Professor Bernd · 26. November 2020

AutoIt

Func TestFunc1()
  ...
  Local $timer = TimerInit()
  Do
    If TimerDiff($timer) > 250 Then
      ...
    EndIf
    events()
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

Coole Sache! An dieser Möglichkeit hatte ich gearbeitet, aber nichts gefunden. Gewollt war ein "DoEvents" (Visual Basic), das die Schleife unterbricht um die Events auszuwerten. Dabei hatte ich versucht, mit 25x Sleep(10) eine Unterbrechung/Auswertung zu erreichen, was natürlich funktionierte. Nun weiß ich, dass es an der ständigen Abfrage von "events()" gelegen hat. - Da soll mal jemand drauf kommen. Naja, man könnte schon drauf kommen, aber ich bin nicht drauf gekommen.

Deine Code-Snippets will ich unbedingt in meine Tipps-Sammlung aufnehmen! (= große Ehre) Mir will einfach keine Bezeichnung einfallen, mit der ich das wiederfinde, wenn ich es in einem Jahr oder so wieder brauche. Vielleicht nehmen ich "Schleife beenden, Events in Schleife auswerten". Mal sehen.

Professor Bernd · 27. November 2020

Dank deiner Tipps habe ich die Zusammenhänge nun verstanden und noch eine Alternative mit GUIRegisterMsg() entwickelt. Als kleiner Vorteil kann man bei dieser Methode Sleep(250) problemlos in der Unter-Schleife benutzen, die Reaktionen vom Cancel- oder Close-Button treten trotzdem unmittelbar ein. Wichtig ist, dass die Funktion mit der Unter-Schleife (TestFunc1()) in der Hauptschleife aufgerufen wird.

AutoIt

; ------------------------------------------------------------------------------
; Unter-Schleife per Kopfdruck beenden
;
; Frage/Thread im AutoIt-Forum von: Professor Bernd, 2020-11-25.
; https://autoit.de/thread/87199-unter-schleife-per-kopfdruck-beenden/?postID=702367#post702367
;
; Lösung per GUIRegisterMsg ($WM_COMMAND und WM_NCLBUTTONDOWN)
;
; Autor: Professor Bernd, 2020-11-26.
; https://autoit.de/thread/87199-unter-schleife-per-kopfdruck-beenden/?postID=702375#post702375
; ------------------------------------------------------------------------------

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1)

Local $hMainGUI = GUICreate("Hallo Welt", 310, 100)
GUICtrlCreateLabel("Klicke auf Start und dann auf den Close- oder Cancel-Button." & @CRLF _
  & "Schleife wird beendet, GUI wird geschlossen!", 10, 10, -1, 50)
Local $idBtnStart = GUICtrlCreateButton("Start", 80, 70, 60)
Local $idBtnCancel = GUICtrlCreateButton("Cancel", 160, 70, 60)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")              ; <==
GUIRegisterMsg ($WM_NCLBUTTONDOWN, "WM_NCLBUTTONDOWN") ; <==

GUISetState(@SW_SHOW, $hMainGUI)

Global $g_bCancel = False

While 1
;   ConsoleWrite("$g_bCancel (MainLoop): " & $g_bCancel & @CRLF)
  Switch GUIGetMsg()
    Case $idBtnStart
      $g_bCancel = False
      TestFunc1()         ; <== TestFunc1() muss in der Hauptschleife gestartet werden.
  EndSwitch
WEnd

Func TestFunc1()
  Local $iCnt = 0
  Do
    Sleep(250)
    ConsoleWrite("$g_bCancel (SubLoop): " & $g_bCancel & @CRLF)
    If $g_bCancel Then
      $g_bCancel = False
      ExitLoop
    EndIf

    GUICtrlSetData($idBtnStart, $iCnt)
    $iCnt += 1
  Until $iCnt = 40 ; Läuft ca. 10 Sekunden.
EndFunc   ;==>TestFunc1

; Reagiert auf einen Buttonklick
Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
  Local $nNotifyCode = _WinAPI_HiWord($wParam)
  Local $iId = _WinAPI_LoWord($wParam)
  Local $hCtrl = $lParam
  If $iId <> 2 And $nNotifyCode = 0 Then   ; Prüft auf IDCANCEL - 2
    Switch $iId
      Case $idBtnCancel
        $g_bCancel = True
        ConsoleWrite("$g_bCancel (Ende): " & $g_bCancel & @CRLF)
        Return 0     ; Wird nur zurückgegeben, wenn Button gedrückt wurde
    EndSwitch
  EndIf
  Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

; Klick auf den Close-Button ("Rotes" X) ermitteln.
Func WM_NCLBUTTONDOWN($hWnd, $Msg, $WParam, $LParam)
  Local $nID = BitAnd($wParam, 0x0000FFFF)
  If $nID = 20 Then
    $g_bCancel = True
    ConsoleWrite("$g_bCancel (NCL): " & $g_bCancel & @CRLF)
    Exit
  EndIf
  Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NCLBUTTONDOWN

Alles anzeigen

Professor Bernd · 28. November 2020

Zitat von Yjuq

Solche Sachen lassen sich aber mit einer "Manager" Funktion, welche AutoIt Skript von dem Windows Events trennt, ziemlich einfach lösen.

Yjuq Wie sieht denn eine Manager Funktion aus und was tut sie?

Unter-Schleife per Knopfdruck beenden

Bitnugger 10. Dezember 2020

Teilen