Brauche Unterstützung bei AutoIt

shitgettinserious

Hallo zusammen !

Und zwar brauche ich Hilfe bei einem Script was ich mache.

Ich muss Anmerken, dass ich ein kompletter Anfänger bin.

Ich möchte ein DropDown Menu erstellen mit einem Button darunter.

Im DropDown Menu befinden sich Namen von spielen, wovon man eins Auswählen kann.

Nun möchte ich das sich durch einen klick auf den Button ein Fenster öffnet mit bestimmten Informationen die Dort auftauchen.

Was ich nicht verstehe wie ich den Button mit dem Menü verbinde und das sich zu jedem Spiel eine seperate Liste öffnet

So weit bin ich mittlerweile:

C

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>


;Hier wird ein Fenster erstellt
$Form1 = GUICreate("Minimal requirements", 615, 437, 192, 124)


;Hier werden DropDownMenu, sowie Inhalt des Menus erstellt
$DropDownMenu = GUICtrlCreateCombo("CSGO", 16, 16, 169, 25)
GUICtrlSetData($DropDownMenu, "Valorant|GTA V|The Forest|Apex Legends|League of Legends|Forza Horizon 4|Black Desert Online|Black Squad|Minecraft|Fortnite", "")


;Hier wird ein Button erstellt
$Button = GUICtrlCreateButton("Suchen", 40, 48, 123, 33)
;Hier wird der Button ausgewählt, damit er mit dem Drop Down interagieren kann.
GUICtrlSetState(-1, $GUI_FOCUS)










;Zeigt das Fenster bzw. G U I an
GUISetState(@SW_SHOW)






;Das ist eine Schleife, damit das Fenster geschlossen werden kann -> Oben Rechts in der Ecke das "x".
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit


EndSwitch
WEnd

Alles anzeigen

Ich hoffe das mir jemand behilflich sein kann.

Vielen Dank im voraus.

Beste Grüße

Lukas - shitgettinserious

blackcho

Schau mal ob es dir weiterhilft

C

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>


;Hier wird ein Fenster erstellt
$Form1 = GUICreate("Minimal requirements", 615, 437, 192, 124)


;Hier werden DropDownMenu, sowie Inhalt des Menus erstellt
$DropDownMenu = GUICtrlCreateCombo("CSGO", 16, 16, 169, 25)
GUICtrlSetData($DropDownMenu, "Valorant|GTA V|The Forest|Apex Legends|League of Legends|Forza Horizon 4|Black Desert Online|Black Squad|Minecraft|Fortnite", "")


;Hier wird ein Button erstellt
$Button = GUICtrlCreateButton("Suchen", 40, 48, 123, 33)
;Hier wird der Button ausgewählt, damit er mit dem Drop Down interagieren kann.
GUICtrlSetState(-1, $GUI_FOCUS)










;Zeigt das Fenster bzw. G U I an
GUISetState(@SW_SHOW)






;Das ist eine Schleife, damit das Fenster geschlossen werden kann -> Oben Rechts in der Ecke das "x".
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button
MsgBox(64, "Read Combo", "You selected: " & GUICtrlRead($DropDownMenu))


EndSwitch
WEnd

Alles anzeigen

**Musashi**

Zitat von shitgettinserious

Was ich nicht verstehe wie ich den Button mit dem Menü verbinde und das sich zu jedem Spiel eine seperate Liste öffnet

Was genau soll bzgl. der Spiele denn passieren, siehe Forenregeln ?

shitgettinserious

Dort soll nur eine Liste angezeigt werden mit den Mindestforderung wie z.B Grafikkarte, CPU etc.

Also es soll nur eine liste sein.

Man wählt über das Dropdown Menu aus und klickt auf suchen.

Und dann sollen einem die Mind. Specs angezeigt werden

shitgettinserious

Hey blackcho,

das hatte ich auch schon probier und konnt dem sehr nahe.

Nur leider müsste sich für jedes Spiel ein neues Fenster öffnen mit seperaten daten und das ist leider mein Problem,

weil ich leider nicht die Lösung finde

**Musashi**

Zitat von shitgettinserious

Dort soll nur eine Liste angezeigt werden mit den Mindestforderung wie z.B Grafikkarte, CPU etc.
Also es soll nur eine Liste sein.

Klingt plausibel .

Nebenbei : Willkommen im Forum .

shitgettinserious

Danke Musashi für den Willkommensgruß

blackcho

Schau dir das hier mal an

musst einfach zwischen GTA und CSGO wechseln

C

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
$var11 = 1
$var12 = 1

;Hier wird ein Fenster erstellt
$Form1 = GUICreate("Minimal requirements", 615, 437, 192, 124)





;Hier werden DropDownMenu, sowie Inhalt des Menus erstellt
$DropDownMenu = GUICtrlCreateCombo("CSGO", 16, 16, 169, 25)
GUICtrlSetData($DropDownMenu, "Valorant|GTA V|The Forest|Apex Legends|League of Legends|Forza Horizon 4|Black Desert Online|Black Squad|Minecraft|Fortnite", "")


;Hier wird ein Button erstellt
$Button = GUICtrlCreateButton("Suchen", 40, 48, 123, 33)
;Hier wird der Button ausgewählt, damit er mit dem Drop Down interagieren kann.
GUICtrlSetState(-1, $GUI_FOCUS)

$label1=GUICtrlCreateLabel("Du befindest dich im Bereich:"& GUICtrlRead($DropDownMenu),0,100)











;Zeigt das Fenster bzw. G U I an
GUISetState(@SW_SHOW)

$gui1 = GUICreate("GUI-1", 259, 46)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_HIDE)



$gui2 = GUICreate("GUI-2", 259, 46)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_HIDE)



$gui3 = GUICreate("GUI-3", 259, 46)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_HIDE)


Func Test1 ()
    If $var11 = 1 Then
    GUICtrlSetData($label1,"Du befindest dich im Bereich:"& GUICtrlRead($DropDownMenu))
    GUISetState(@SW_HIDE, $gui2)
    GUISetState(@SW_SHOW, $gui3)
    EndIf
    $var11 = 2
    $var12 = 1

EndFunc

Func Test2 ()

    If $var12 = 1 Then
        GUICtrlSetData($label1,"Du befindest dich im Bereich:"& GUICtrlRead($DropDownMenu))
        GUISetState(@SW_HIDE, $gui3)
        GUISetState(@SW_SHOW, $gui2)
    $var12 = 2
    $var11 = 1
    EndIf


EndFunc



;Das ist eine Schleife, damit das Fenster geschlossen werden kann -> Oben Rechts in der Ecke das "x".
While 1000
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
    Case $Button
        If GUICtrlRead($DropDownMenu) = "CSGO" Then
    Test1()
ElseIf GUICtrlRead($DropDownMenu) = "GTA V" Then
    Test2()
EndIf
;MsgBox(64, "Read Combo", "You selected: " & GUICtrlRead($DropDownMenu))
EndSwitch
WEnd

Alles anzeigen

**Musashi**

shitgettinserious :

Es wäre flexibler, die Daten in einer externen Datei zu pflegen und als 2-D Array einzulesen :

Hier mal ein (schnell erstellter) Ansatz :

AutoIt

#include <File.au3>
#include <FileConstants.au3>
#include <Array.au3>

#include <ButtonConstants.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $aGameSpecs, $sFileNameSpecs, $sComboString
$sFileNameSpecs = @ScriptDir & "\GameSpecs.csv"

; ----------------------------------------------------------------------
; nur für Test : Datafile im Skript erzeugen (später als Datei anlegen)
Global $sDatafile = "Valorant;NVidia 01;CPU 01;100 MB RAM" & @CRLF & _
        "GTA V;NVidia 02;CPU 02;200 MB RAM" & @CRLF & _
        "The Forest;NVidia 03;CPU 03;300 MB RAM" & @CRLF & _
        "Apex Legends;NVidia 04;CPU 04;400 MB RAM" & @CRLF & _
        "League of Legends;NVidia 05;CPU 05;500 MB RAM"
Global $hFileOpen = FileOpen($sFileNameSpecs, $FO_OVERWRITE)
FileWrite($hFileOpen, $sDatafile)
FileClose($hFileOpen)
; ----------------------------------------------------------------------


; Einlesen der GameSpecs aus dem Datafile :
_FileReadToArray($sFileNameSpecs, $aGameSpecs, $FRTA_NOCOUNT, ";")
If @error Then Exit MsgBox(BitOR(4096, 16), "Fehler : ", "Fehler " & @error & " ist aufgetreten")

Global $hGUI, $idComboDropDownMenu, $idBtnSearch, $iSearchIndex
$hGUI = GUICreate("Minimal requirements", 615, 437, 192, 124)
$idComboDropDownMenu = GUICtrlCreateCombo($aGameSpecs[0][0], 16, 16, 169, 25)
For $i = 1 To UBound ($aGameSpecs) - 1
    GUICtrlSetData($idComboDropDownMenu, $aGameSpecs[$i][0], "")
Next

$idBtnSearch = GUICtrlCreateButton("Suchen", 40, 48, 123, 33)
GUISetState(@SW_SHOW, $hGUI)
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $idOK
            ExitLoop
        Case $idBtnSearch
            $iSearchIndex = _GUICtrlComboBox_GetCurSel($idComboDropDownMenu)
            MsgBox (0, "Game Specs :", $aGameSpecs[$iSearchIndex][0] & @CRLF & _
                                       $aGameSpecs[$iSearchIndex][1] & @CRLF & _
                                       $aGameSpecs[$iSearchIndex][2] & @CRLF & _
                                       $aGameSpecs[$iSearchIndex][3] & @CRLF)
    EndSwitch
WEnd
GUIDelete($hGUI)

Alles anzeigen

**Kanashius**

Da sich der Code gerade dahin entwickelt, dass sehr viel Copy&Paste Code (Code duplicates) vorkommen, danchte ich, ich überarbeite den Code einmal vollständig und zeige dabei einige Konzepte, die ich empfehlen würde um den Code einfach und Wartbar zu halten.

Zum einen sollten unbedingt Arrays verwendet werden, um immer denselben code zu vermeiden (siehe z.B. Zeile 58-67 und 69-80 oben). Dort wird derselbe Code verwendet, das einzige was sich verändert sind die Daten in den Textfeldern => Die Daten in ein Array und es muss nurnoch eine Test1/Test2 Funktion erstellt werden und dementsprechend auch nur eine Funktion verändert werden.

Falls du arrays noch nicht kennst: Unbedingt anschauen, sie bilden das Grundkonzept jeglicher dynamischer Programmierung in AutoIt. (Gutes Tutorial von BugFix : http://www.bug-fix.info/array_tut.htm)

Bei meinen Modifikationen hab ich auch gleich Variablen zur Fenster-Erstellung genutzt. Dadurch kann z.B. die Fenstergröße oben in der Variable geändert werden und alle Controls,... passen immernoch zum Fenster.

Schau die das Programm am besten in Ruhe an, ich denke, du kannst dabei einiges/einige Konzepte lernen.

AutoIt

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <GuiComboBox.au3>
#include <Array.au3>

Global $iKB=1000,$iMB=$iKB*1000,$iGB=$iMB*1000,$iTByte=$iGB*1000

; Alle größen um das Fenster zu erstellen. Durch das Nutzen der Variablen kann man jede Größe ändern und alles passt sich an und es müssen nicht immer alle Positionen der anderen Controls angepasst werden.
; (Macht das Ändern des Designs leichter und kann dabei viel Arbeit sparen.)
Global $iWidthGuiMain=400,$iHeightGuiMain=200, $iControlHeight=25, $iControlSpace=5, $iControlCalcHeight=$iControlHeight+$iControlSpace
Global $iWidthGuiSpecs=$iWidthGuiMain, $iHeightGuiSpecs=$iHeightGuiMain
; Array mit Text zum erstellen des Spec Fensters, ControlID des Datenlabels, Funktion zum konvertieren der Daten
Global $arGameSpecLabels=[["Spielname: ", -1, -1],["Betriebssystem: ", -1, -1], ["Arbeitsspeicher: ", -1, "_byteToString"], ["Grafikkartenspeicher: ", -1, "_byteToString"]]
; Es könnte sinnvoll sein, die Daten in eine andere Datei (z.B. INI) auszulagern, wenn es zu viele werden
; Ansonsten: Größere Datenmengen mit dem gleichen Aufbau immer in Arrays speichern um diese automatisiert zu bearbeiten und mehrfach verwendeten, kopierten Code zu vermeiden.
Global $arGameSpecs=[ _ ; Gamename, OS, RAM, VRAM, ...
                        ["Valorant", "Windows 7/8/10 (64-bit)",4*$iGB,1*$iGB], _
                        ["GTA V", "Windows 7/8/10 (64-bit)",6*$iGB,2*$iGB], _
                        ["The Forest", "Windows 7/8/10 (64-bit)",7*$iGB,4*$iGB], _
                        ["Apex Legends", "Windows 7/8/10 (64-bit)",8*$iGB,8*$iGB], _
                        ["League of Legends", "Windows 7/8/10 (64-bit)",12*$iGB,6*$iGB] _
                    ]

;Hier wird ein Fenster erstellt
$iGui_Main=GUICreate("Gamestat info", $iWidthGuiMain, $iHeightGuiMain)

;Hier werden DropDownMenu, sowie Inhalt des Menus erstellt
$iCombo_GameSelect = GUICtrlCreateCombo("", $iControlSpace, $iControlSpace, $iWidthGuiMain-$iControlSpace*2, $iControlHeight)
GUICtrlSetData($iCombo_GameSelect, _ArrayToString($arGameSpecs, "", Default, Default, "|", 0, 0))

;Hier wird ein Button erstellt
$iButton_Search = GUICtrlCreateButton("Suchen", $iControlSpace, $iControlSpace + $iControlCalcHeight, $iWidthGuiMain-$iControlSpace*2, $iControlHeight)
;Hier wird der Button ausgewählt.
GUICtrlSetState(-1, $GUI_FOCUS)

$iLabel_ShowSection=GUICtrlCreateLabel("Du befandest dich im Bereich: - ", $iControlSpace, $iControlSpace + $iControlCalcHeight*2,$iWidthGuiMain-$iControlSpace*2, $iControlHeight)

; Erstelle das Specs Fenster
$iGui_Specs=GUICreate("Specs", $iWidthGuiSpecs, $iHeightGuiSpecs)
; Erstelle die Labels für die Informationen
For $i=0 To UBound($arGameSpecLabels)-1 Step 1
    local $iLabelWidth=($iWidthGuiSpecs-$iControlSpace*3)/2
    ; Erstelle das Label mit dem Infotext links
    GUICtrlCreateLabel($arGameSpecLabels[$i][0], $iControlSpace, $iControlSpace + $iControlCalcHeight*$i, $iLabelWidth, $iControlHeight)
    ; Erstelle das Label mit den Infos rechts
    $arGameSpecLabels[$i][1]=GUICtrlCreateLabel("", $iControlSpace*2 + $iLabelWidth, $iControlSpace + $iControlCalcHeight*$i, $iLabelWidth, $iControlHeight)
Next

;Zeigt das Main Fenster bzw. GUI an
GUISetState(@SW_SHOW, $iGui_Main)


;Das ist eine Endlos-Schleife, damit das Programm weiterläuft, bis Exit aufgerufen wird.
While true
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE ; Fenster wurde geschlossen
            Exit ; Beende das Programm
        Case $iButton_Search ; $iButton_Search wurde geklickt
            _showSpecs() ; Funktionsaufruf mit dem Default parameter => aktuell ausgewählter Index wird verwendet
    EndSwitch
WEnd

Func _showSpecs($iIndexOfGame=-1)
    ; Nehme den aktuell ausgewählten index, wenn kein anderer angegeben wurde
    If $iIndexOfGame=-1 Then
        ; Lese den aktuell ausgewählten index aus
        $iIndexOfGame=_GUICtrlComboBox_GetCurSel($iCombo_GameSelect)
    EndIf
    GUICtrlSetData($iLabel_ShowSection,"Du befandest dich im Bereich: " & $arGameSpecs[$iIndexOfGame][0])
    ; Setze den Text der Labels im Spec Fenster
    For $i=0 To UBound($arGameSpecLabels)-1 Step 1
        GUICtrlSetData($arGameSpecLabels[$i][1] ,$arGameSpecLabels[$i][2]=-1 ? $arGameSpecs[$iIndexOfGame][$i]: Call($arGameSpecLabels[$i][2], $arGameSpecs[$iIndexOfGame][$i]))
    Next
    GUISetState(@SW_HIDE, $iGui_Main)
    GUISetState(@SW_SHOW, $iGui_Specs)
    ; Endlosschleife um auf das Schließen des Specs Fensters zu warten
    While true
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE ; Fenster wurde geschlossen
                ExitLoop ; Verlasse die Endlosschleife
        EndSwitch
    WEnd
    GUISetState(@SW_HIDE, $iGui_Specs)
    GUISetState(@SW_SHOW, $iGui_Main)
EndFunc

Func _byteToString($iByteSize)
    Local $arByteShort = ['B', 'KB', 'MB', 'GB', 'TB', 'PB', 'EB', 'ZB', 'YB']
    local $iCount=0
    while $iByteSize>=1000 and $iCount<UBound($arByteShort)-1
        $iCount+=1
        $iByteSize/=1000
    WEnd
    return $iByteSize & " " &$arByteShort[$iCount]
EndFunc

Alles anzeigen

MfG,

Kanashius.

Edit: Ich hab den Fehler behoben, der Musashi aufgefallen ist, das hatte ich übersehen (war kein Versionsfehler)

Zitat von Musashi

Zumindest unter meiner AutoIt-Version (3.3.14.0) arbeitet Dein Skript aber nicht ganz korrekt.
Es wird nach [Suchen] immer nur das erste Element (hier also "Valorant") angezeigt, egal was man in der ComboBox auswählt.
Um das zu ändern, muss in der Func _showSpecs die Zeile :
$iIndexOfGame=_GUICtrlComboBoxEx_GetCurSel($iCombo_GameSelect)
ersetzt werden durch :
$iIndexOfGame=_GUICtrlComboBox_GetCurSel($iCombo_GameSelect)
(ggf. hat sich das Verhalten in der aktuellen Version von AutoIt aber geändert ).

Alles anzeigen

**Musashi**

Zitat von Kanashius

Zum einen sollten unbedingt Arrays verwendet werden, um immer denselben Code zu vermeiden
[...]
Aus dem Quellcode : "Es könnte sinnvoll sein, die Daten in eine andere Datei (z.B. INI) auszulagern, wenn es zu viele werden"

Da sind wir uns ohne Zweifel einig (möglicherweise hattest Du meinen Beitrag noch nicht gelesen, als Du Deinen abgesendet hast ).

Zumindest unter meiner AutoIt-Version (3.3.14.0) arbeitet Dein Skript aber nicht ganz korrekt.

Es wird nach [Suchen] immer nur das erste Element (hier also "Valorant") angezeigt, egal was man in der ComboBox auswählt.

Um das zu ändern, muss in der Func _showSpecs die Zeile :

$iIndexOfGame=_GUICtrlComboBoxEx_GetCurSel($iCombo_GameSelect)

ersetzt werden durch :

$iIndexOfGame=_GUICtrlComboBox_GetCurSel($iCombo_GameSelect)

(ggf. hat sich das Verhalten in der aktuellen Version von AutoIt aber geändert ).

EDIT :

Zitat von Kanashius

Edit: Ich hab den Fehler behoben, der Musashi aufgefallen ist, das hatte ich übersehen (war kein Versionsfehler)

Prima - hätte ja auch an meiner 'leicht' veralteten Version liegen können .

Gruß Musashi

Brauche Unterstützung bei AutoIt

Ähnliche Themen

Kommunikation zw AutoIt und PSPad's VBScript