WebDriver.udf Formularfeld auslesen

lunifrw

Guten Abend,

Ich bin noch recht neu in Sachen AutoIT, und bräuchte da mal ein Denkanstoß, wie ich ein Formularfeld, in dem ein Text steht, auslesen kann und in ein String speichern kann.

Hier ist der HTML-Code, der ausgelesen werden müsste:

<input type="email" class="whsOnd zHQkBf" jsname="YPqjbf" autocomplete="username" spellcheck="false" tabindex="0" aria-label="Nutzername" name="Username" autocapitalize="none" id="username" dir="ltr" data-initial-dir="ltr" data-initial-value=">>>>Diesen Inhalt möchte ich in einen String speichern<<<<" badinput="false">

gmmg

Hallo lunifrw,

hier mal ein Beispiel für einen Webseite Login.

Die Zugangsdaten würden aus einer Ini Datei kommen. Da hast du zumindest schonmal den Website Aufruf

Spoiler anzeigen

C

#include "wd_helper.au3"
#include "wd_core.au3"

$file = "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe" ;Pfad zu Google Chrome

;----prüfe Version von der Chromedriver.exe anhand der Google Chrome.exe---
If FileExists($file) Then

    $Fileversion = FileGetVersion($file)
    $gchrome_version = StringLeft($Fileversion,2)
    $webdriver = "chromedriver_" & $gchrome_version & ".exe"
Else
    MsgBox(0,"Info","Google Chrome in der richtigen Version nicht vorhanden.")
    Exit
EndIf


$ini_file = @scriptdir & "\bin\tc.ini"  ; muss ASCI sein (wenn nicht, mit Notepadd++ setzen)
$mail = IniRead($ini_file, "tc", "mail", "NotFound")
$pass = IniRead($ini_file, "tc", "pass", "NotFound")

$_WD_DEBUG = $_WD_DEBUG_None  ;set to $_WD_DEBUG_None before compiling.

;Global $_WD_DRIVER
Local $sDesiredCapabilities
Local $iIndex

$url = "https://URL der Website"

;SetupGecko()
SetupChrome()

_WD_Startup()
$sSession = _WD_CreateSession($sDesiredCapabilities)
_WD_Window($sSession, "Maximize", "{}")
_WD_Navigate($sSession, $url)

_WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@data-qe-id='email']")
ConsoleWrite("+ @error = " & @error & @CRLF)
$sElement_mail = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@data-qe-id='email']")

_WD_WaitElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@data-qe-id='password']")
ConsoleWrite("+ @error = " & @error & @CRLF)
$sElement_pass = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@data-qe-id='password']")

If @error = $_WD_ERROR_Success Then
   _WD_ElementAction($sSession, $sElement_mail, 'value',$mail)
    Sleep(500)
EndIf
If @error = $_WD_ERROR_Success Then
   _WD_ElementAction($sSession, $sElement_pass, 'value',$pass)
EndIf

Sleep(1000)
Send("{ENTER}")

_WD_Shutdown()

Func SetupChrome()

    _WD_Option('Driver', 'data\'& $webdriver)
    _WD_Option('Port', 9515)
    ;_WD_Option('DriverParams', '--log-path="' & @ScriptDir & '\chrome.log"')
    _WD_Option('DriverParams')

    $sDesiredCapabilities = '{"capabilities": {"alwaysMatch": {"unhandledPromptBehavior": "ignore", ' & _
    '"goog:chromeOptions": {"w3c": true, "excludeSwitches": ["enable-automation"], "useAutomationExtension": false, ' & _
    '"prefs": {"credentials_enable_service": false},' & _
    '"args": ["start-maximized"] }}}}'

EndFunc

Func SetupGecko()

    _WD_Option('Driver', 'geckodriver.exe')
    ;_WD_Option('DriverParams', '--log trace')
    _WD_Option('DriverParams')
    _WD_Option('Port', 4444)

    $sDesiredCapabilities = '{"desiredCapabilities":{"javascriptEnabled":true,"nativeEvents":true,"acceptInsecureCerts":true}}'

EndFunc

Alles anzeigen

Und hier noch ein kleines Beispiel zum Finden/ Setzen /Lesen eines Values von einem Input.

Code

;find Input
$sElement_user = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@name='_username']")

;set value
_WD_ElementAction($sSession, $sElement_user, 'value',$User)

;get_Value
$sValue = _WD_ElementAction($sSession, $sElement_user, 'property', 'value')
MsgBox(0,"", $sValue)

Gruß gmmg