SystemMenü ausblenden aber Icon trotzdem anzeigen, geht das überhaupt?

hipfzwirgel

Hallole Gemeinde,

ist es möglich das Systemmenü einer Gui auszublenden ohne das Icon der Gui ebenfalls auszublenden?

Hintergrund: Ein Programm soll quasi im Kioskmodus laufen, d.h. immer an. Deshalb würde ich da das Systemmenü ausblenden.
Mit der UDF _WinStyle.au3 von Bernd670 würde das Ausblenden des Menüs auch recht einfach zu realisieren sein (danke dafür ).
Wegen der Corporate-Identity-Vorgaben soll/muss aber das Icon der Firma in der Titelleiste erhalten bleiben...

TestGui:

Code

#include <_WinStyle.au3>

Const $SC_CLOSE = 0xF060
Const $MF_BYCOMMAND = 0x0
;~ Const $MF_GRAYED = 0x1
;~ Const $WM_SYSCOMMAND = 0x0112



$gui = GuiCreate("Catch the X Click", 300, 100)
GUISetIcon("C:\Windows\System32\user32.dll", -2)
GUISetState()

$wh = WinGetHandle("Catch the X Click") ; <- Hier den Titel des Windowsfenster eintragen
$WinStyle = _WinGetStyle($wh)
_WinSetStyle($wh, "", BitAND($WinStyle[0], BitNOT($WS_SYSMENU)))

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

Alles anzeigen

Ahnungslos

Wenn du den Schließen-Button nicht entfernst, sondern deaktivierst, dann bleibt auch das Icon erhalten:

C

#include <GUIConstants.au3>
#include <WinAPISysWin.au3>

GuiCreate("Catch the X Click", 300, 100)
GUISetIcon("C:\Windows\System32\user32.dll", -2)
GUISetState()

$hHandle = WinGetHandle("Catch the X Click") ; <- Hier den Titel des Windowsfenster eintragen
RemoveButtons($hHandle)
DisableCloseButton($hHandle)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

Func DisableCloseButton($hWindow)
    Local $aSysMenu = DllCall("User32.dll", "hwnd", "GetSystemMenu", "hwnd", $hWindow, "int", 0)
    DllCall("User32.dll", "int", "RemoveMenu", "hwnd", $aSysMenu[0], "int", 0xF060 , "int", 0)
    DllCall("User32.dll", "int", "DrawMenuBar", "hwnd", $hWindow)
EndFunc

Func RemoveButtons($hWindow)
    Local $iStyle = _WinAPI_GetWindowLong($hWindow, $GWL_STYLE)
    _WinAPI_SetWindowLong($hWindow, $GWL_STYLE, BitAND($iStyle, BitNOT($WS_MINIMIZEBOX), BitNOT($WS_MAXIMIZEBOX)))
EndFunc

Alles anzeigen

Velted

Moin!

C

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    $hGUI = GuiCreate("Test GUI", 300, 230, -1, -1, $WS_CAPTION + $WS_POPUP + $WS_SYSMENU)
    GUISetIcon("C:\Windows\System32\user32.dll", -2)
    GUICtrlCreateEdit("", 10, 10, 280, 180)
    $idBtn = GUICtrlCreateButton("Beenden", 10, 200, 280, 20)
    GUISetState()
    EmptySysMenu($hGUI)
    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idBtn
                ExitLoop
        EndSwitch
    WEnd
 EndFunc   ;==>Example

 Func EmptySysMenu($hWnd)
    Local $iSM, $hSM
    $hSM = _GUICtrlMenu_GetSystemMenu($hWnd)
    $iSM = _GUICtrlMenu_GetItemCount($hSM)
    For $i = 1 To $iSM
        _GUICtrlMenu_RemoveMenu($hSM, 0)
    Next
    Return _GUICtrlMenu_DrawMenuBar($hWnd)
EndFunc

Alles anzeigen

Allen ein schönes Wochenende!