Mit Autoit ein privates Fenster des Firefox öffnen

Rigibid

Hallo Zusammen,

Ich habe hier im Forum eine kleine Anwendung dafür gefunden und diese etwas umgearbeitet.

ich mache mir eine kleine Webseiten-Zusammenstellung mit dieseer Anwendung.

Allerdings müssen einige Seiten in einem privatem Fester geöffnet werden.

Leider weiß ich nicht wie man das hinbekommt.

So sieht das bis jetzt aus:

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=\\int\dfs\DE\PUBLIC\*****.ico
#AutoIt3Wrapper_Compression=3
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=l:********\Webseiten\website-gui.kxf
Global $Form1_1 = GUICreate("Elkamet-Links", 330, 450, 800, 300)
$Pic1 = GUICtrlCreatePic("\\int\dfs\DE\PUBLIC\*****.gif", 64, 0, 217, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###



Global $sLink1 = 'https://intranet.*****.com/'
Global $sLink2 = 'https://unterweisung.*****.com:444'
Global $sLink3 = 'https://zeiterfassung.*****.com/(S(uf3fpljnpwj3zrubyeq1jx2l))/login.aspx'
Global $sLink4 = 'https://faq.*****.com/'
Global $sLink5 = 'https://intranet.*****/it-ticket-eroeffnen'
Global $sLink6 = 'https://idee.*****.de/welcomepage'
Global $sLink7 = 'https://outlook.office365.com/'
Global $sLink8 = 'https://plan.*****.com/BZ/BZ.htm'


Global $idIcon1 = GUICtrlCreateIcon('shell32.dll', -14, 20, 46, 32, 32)
Global $idLabel1 = GUICtrlCreateLabel('Intranet', 60, 50, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink1)


Global $idIcon2 = GUICtrlCreateIcon('shell32.dll', -14, 20, 86, 32, 32)
Global $idLabel2 = GUICtrlCreateLabel('Schulungen', 60, 90, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink2)

Global $idIcon3 = GUICtrlCreateIcon('shell32.dll', -14, 20, 126, 32, 32)
Global $idLabel3 = GUICtrlCreateLabel('Zeus', 60, 130, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink3)

Global $idIcon4 = GUICtrlCreateIcon('shell32.dll', -14, 20, 166, 32, 32)
Global $idLabel4 = GUICtrlCreateLabel('FAQ', 60, 170, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink4)

Global $idIcon5 = GUICtrlCreateIcon('shell32.dll', -14, 20, 206, 32, 32)
Global $idLabel5 = GUICtrlCreateLabel('IT-Ticket erstellen', 60, 210, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink5)

Global $idIcon6 = GUICtrlCreateIcon('shell32.dll', -14, 20, 246, 32, 32)
Global $idLabel6 = GUICtrlCreateLabel('Idee einreichen', 60, 250, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink6)

Global $idIcon7 = GUICtrlCreateIcon('shell32.dll', -14, 20, 286, 32, 32)
Global $idLabel7 = GUICtrlCreateLabel('Outlook', 60, 290, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink7)

Global $idIcon8 = GUICtrlCreateIcon('shell32.dll', -14, 20, 326, 32, 32)
Global $idLabel8 = GUICtrlCreateLabel("Übersicht der BZ's", 60, 330, 170, 22)
GUICtrlSetFont(-1, 14, 400, 4, 'Arial', 5)
GUICtrlSetColor(-1, 0x0000CC)
GUICtrlSetCursor(-1, 0)
GUICtrlSetTip(-1, $sLink8)

; ShellExecute($Pfad & "\MeineExcelDatei.xlsx")

GUISetState()


Global $aCursorInfo
While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE ; Gui schließen
Exit
Case $idLabel1 ; Link1 angeklickt
ShellExecute($sLink1) ; Link1 aufrufen
Case $idLabel2 ; Link2 angeklickt
ShellExecute($sLink2) ; Link2 aufrufen
Case $idLabel3 ; Link3 angeklickt
ShellExecute($sLink3) ; Link3 aufrufen
Case $idLabel4 ; Link4 angeklickt
ShellExecute($sLink4) ; Link4 aufrufen
Case $idLabel5 ; Link5 angeklickt
ShellExecute($sLink5) ; Link5 aufrufen
Case $idLabel6 ; Link6 angeklickt
ShellExecute($sLink6) ; Link6 aufrufen
Case $idLabel7 ; Link7 angeklickt
ShellExecute($sLink7) ; Link7 aufrufen
Case $idLabel8
ShellExecute($sLink8)
Case $GUI_EVENT_MOUSEMOVE ; bei einer Mausbewegung
$aCursorInfo = GUIGetCursorInfo($Form1_1) ; CursorInfo holen
If Not @error Then
Switch $aCursorInfo[4] ; Die ID über dessen Control-Element sich die Maus befindet
Case $idLabel1, $idIcon1
GUICtrlSetImage($idIcon1, 'shell32.dll', -15)
Case $idLabel2, $idIcon2
GUICtrlSetImage($idIcon2, 'shell32.dll', -15)
Case $idLabel3, $idIcon3
GUICtrlSetImage($idIcon3, 'shell32.dll', -15)
Case $idLabel4, $idIcon4
GUICtrlSetImage($idIcon4, 'shell32.dll', -15)
Case $idLabel5, $idIcon5
GUICtrlSetImage($idIcon5, 'shell32.dll', -15)
Case $idLabel6, $idIcon6
GUICtrlSetImage($idIcon6, 'shell32.dll', -15)
Case $idLabel7, $idIcon7
GUICtrlSetImage($idIcon7, '\\int\dfs\DE\PUBLIC\*****\Web-Outlook.ico')
Case $idLabel8, $idIcon8
GUICtrlSetImage($idIcon8, 'shell32.dll', -15)
Case Else
GUICtrlSetImage($idIcon1, 'shell32.dll', -14)
GUICtrlSetImage($idIcon2, 'shell32.dll', -14)
GUICtrlSetImage($idIcon3, 'shell32.dll', -14)
GUICtrlSetImage($idIcon4, 'shell32.dll', -14)
GUICtrlSetImage($idIcon5, 'shell32.dll', -14)
GUICtrlSetImage($idIcon6, 'shell32.dll', -14)
GUICtrlSetImage($idIcon7, '\\int\dfs\DE\PUBLIC\*****\Web-Outlook.ico')
GUICtrlSetImage($idIcon8, 'shell32.dll', -14)
EndSwitch
EndIf
EndSwitch
WEnd

Alles anzeigen

Das funktioniert alles wunderbar.

Nur weiß ich jetzt nicht wie ich das erweitern kann um private Fenster zu öffnen.

Vielleicht hat ja jemand einen Tipp für mich.

**Moombas**

Das geht mit Start-Parametern. Schau dazu z.B. mal hier (2 Sekunden Google Suche):

Firefox/CommandLineOptions - MozillaWiki

**Kanashius**

Ich konnte mir die ganzen sich wiederholenden Zeilen nicht mit anschauen, also hab ich es mal passend mit nem Array erstellt.

Arrays werden immer genutzt, wenn man das gleiche mehrmals machen würde und sich nur wenig ändert und vermeiden eine Menge Code, der eigentlich nur Copy-Pasted wird.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $iCurrentHoveredCtrl = 0, $iSC = 7 ; start of CtrlLabel in the array
Global $arLinks = [ _ ; Name, Link, NormalIconFile, NormalIconId, HoverIconFile, HoverIconId, CtrlLabel, CtrlIcon
                   ["Test", "https://www.autoit.de", "shell32.dll", -12, "shell32.dll", -10, "_openInBrowser", 0, 0], _ ; This line can be removed
                   ["Test Private", "https://www.autoit.de", "shell32.dll", -14, "shell32.dll", -15, "_openInPrivateBrowser", 0, 0], _ ; This line can be removed
                   ["Intranet", "https://intranet.*****.com/", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0], _
                   ["Schulungen", "https://unterweisung.*****.com:444", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0], _
                   ["Zeus", "https://zeiterfassung.*****.com/(S(uf3fpljnpwj3zrubyeq1jx2l))/login.aspx", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0], _
                   ["FAQ", "https://faq.*****.com/", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0], _
                   ["IT-Ticket erstellen", "https://intranet.*****/it-ticket-eroeffnen", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0], _
                   ["Idee einreichen", "https://idee.*****.de/welcomepage", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0], _
                   ["Outlook", "https://outlook.office365.com/", "\\int\dfs\DE\PUBLIC\*****\Web-Outlook.ico", -1, "\\int\dfs\DE\PUBLIC\*****\Web-Outlook.ico", -1, "_openInBrowser", 0, 0], _
                   ["Übersicht der BZ's", "https://plan.*****.com/BZ/BZ.htm", "shell32.dll", -14, "shell32.dll", -15, "_openInBrowser", 0, 0] _
                  ]

Global $iWidth = 330, $iHeight = 60+UBound($arLinks)*40, $iSpace = 20
$hGui = GUICreate("Elkamet-Links", $iWidth, $iHeight, 800, 300)
$Pic1 = GUICtrlCreatePic("\\int\dfs\DE\PUBLIC\*****.gif", 64, 0, 217, 33)

; Create the Icons and Labels for all links
For $i = 0 To UBound($arLinks)-1 Step 1
    $arLinks[$i][$iSC+1] = GUICtrlCreateIcon($arLinks[$i][2], $arLinks[$i][3], $iSpace, 46+$i*40, 32, 32)
    $arLinks[$i][$iSC] = GUICtrlCreateLabel($arLinks[$i][0], $iSpace*3, 50+$i*40, $iWidth-4*$iSpace, 22)
    GUICtrlSetFont($arLinks[$i][$iSC], 14, 400, 4, 'Arial', 5)
    GUICtrlSetColor($arLinks[$i][$iSC], 0x0000CC)
    GUICtrlSetCursor($arLinks[$i][$iSC], 0)
    GUICtrlSetTip($arLinks[$i][$iSC], $arLinks[$i][1])
Next

GUISetState(@SW_SHOW, $hGui)

While 1
    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_MOUSEMOVE
            $iId = GUIGetCursorInfo($hGui)[4]
            If $iId <> $iCurrentHoveredCtrl Then
                ; Change the icon back to normal
                If $iCurrentHoveredCtrl>0 Then
                    For $i = 0 To UBound($arLinks)-1 Step 1
                        If $iCurrentHoveredCtrl = $arLinks[$i][$iSC] Then GUICtrlSetImage($arLinks[$i][$iSC+1], $arLinks[$i][2], $arLinks[$i][3])
                    Next
                EndIf
                ; Set the hover icon
                $iCurrentHoveredCtrl = $iId
                For $i = 0 To UBound($arLinks)-1 Step 1
                    If $iId = $arLinks[$i][$iSC] Then GUICtrlSetImage($arLinks[$i][$iSC+1], $arLinks[$i][4], $arLinks[$i][5])
                Next
            EndIf
    EndSwitch
    ; Check if a Label/Link was pressed
    For $i = 0 To UBound($arLinks)-1 Step 1
        If $iMsg = $arLinks[$i][$iSC] Then Call($arLinks[$i][6], $i)
    Next
WEnd

Func _openInBrowser($iIndex)
    ShellExecute("firefox", "-new-window "&$arLinks[$iIndex][1]) ;requires firefox to be installed Other possible options: -new-tab
EndFunc

Func _openInPrivateBrowser($iIndex)
    ShellExecute("firefox", "-private-window "&$arLinks[$iIndex][1]) ;requires firefox to be installed
EndFunc

Alles anzeigen

Wenn du links hinzufügen, Icons (und Hover-Icons) ändern willst und die Aktion beim klicken ändern willst (z.B. Excel statt firefox) musst du mit dieser Variante nur das Array verändern und ggf. eine neue Funktion unten hinzufügen.

Auf diese Weise ist alles dynamisch generiert und die Höhe des Fensters passt sich z.B. an die Anzahl der Links automatisch an.

Bei fragen meld dich gern wieder

MfG Kanashius.

Rigibid

Hallo Kanashius,

vielen Dank für das Überarbeiten des Codes.

Ich hatte den Code hier aus dem Forum und dann einfach nur angepasst.

Ich habe leider nicht so viel Ahnung von AutoIt, aber wenn ich was vorgefertigt finde und ich kann es dann etwas anpassen reicht mir das.

Eine Bitte hätte ich aber noch:
Was muss ich denn einstellen, dass beim anklicken eines Links nicht ein neuer Firefox geöffnet wird sondern ein neuer Tab?

**Kanashius**

Zitat von Kanashius

-new-tab

Statt -new-window. Steht im Kommentar daneben

Bzw. bei private sollte es vmtl. reichen, das -window wegzunehmen.

Moombas hat auch den Link gepostet, wo du die Infos findest.

Rigibid

Entschuldigung, habe ich übersehen.

Danke!

**Moombas**

Ich kann damit leben, wenn man meine Posts überliest. Selber Schuld

Rigibid

Danke an alle.

Erledigt!