Microsoft Word: Suche und ersetze Text in den Inhalten der VBA-Progammierung (gelöst)

MiX-MoX

Hallo Water,

vielen Dank für Deine kritische Betrachtung.

Tatsächlich kann ich auf FileOpen verzichten, da ich die Files nur auslese, aber nicht manipuliere.

$col wird mit Funktionsaufruf von _read_file definiert.

Beim ersten Funktionsaufruf von _read_file ist das Array von $aTags noch 1D,

Beim zweiten Funktionsaufruf von _rad_file ist es 2D.

$file_s und $file_r müssen so belegt sein, dass die Zeilen entsprechend korrespondieren.

In jeder Zeile von $aTags steht dann in der ersten Spalte der Such-String und in der zweiten Spalte der entsprechende Ersetzen-String.
Sonst würde der Aufruf von $aTags in Word_DocFindReplace auch nicht funktionieren.

Buchstabe "W" hatte ich eigentlich schon herauseditiert - keine Ahnung, weshalb Du den noch sehen konntest.

Der Code ist nur um sehr spezifische Datails gekürzt, dennoch voll funktionsfähig, so wie er da steht.

**Moombas**

Ganz nebenbei:

Dein Return in _read_file brauchst du nicht, da du die Funktion nicht mit Zuweisung aufrufst.

Außerdem verhindert dies die Ausführung des File close.

Zudem definierst du zwei Variablen LOCAL werden aber GLOBAL sein, da sie im globalen Kontext stehen

Hier mal dein Skript abgeändert (Zeile 31 auskommentiert, da aktuell nicht verwendet in dem geposteten Code).

Du müsstest es halt nochmal testen, da ich div. kleine Änderungen vorgenommen habe. Unteranderem:

- Variablen in den richtigen Kontext verschoben (wenn sie Global gesetzt waren aber nur Lokal verwendet wurden)

- Variablen deklaration an den Anfang der Funktion(en) gesetzt, anstatt mitten im Code

- Variablen um Const ergänzt wenn diese nicht verändert werden (dürfen)

- einzelne Variablennamen geändert um sie eindeutiger zu machen was sie beinhalten (z.B. $i in $iRow)

- Das Array $aTags ByRef übergeben anstatt direkt auf die Globale Variable zuzugreifen.

- Return aus der Funktion _read_file entfernt

- Prüfung am Anfang des Skriptes ob Parameter übergeben wurden, sonst direkter Programmabbruch um Fehlermeldungen zu vermeiden

- Bei den msgboxen den Wert 16 durch die Konstante ersetzt

- Korrektur der Funktion _read_file auf die von water (s.u.)

AutoIt

#include <File.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <Word.au3>
#include <WordConstants.au3>
 ; https://autoit.de/thread/87817-microsoft-word-suche-und-ersetze-text-in-den-inhalten-der-vba-progammierung-gel%C3%B6/?postID=708429#post708429
;~ #DIESE ROUTINE WIRD ÜBER PARAMETER AUFGERUFEN

Opt("MustDeclareVars", 1)
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

If not $CmdLine[0] = 2 then
    MsgBox($MB_ICONERROR, 'Parameter', 'No or wrong amount of parameters provided.')
    Exit
EndIf
Global Const $sSearch_1  = $CmdLine[1]
Global Const $sSearch_2  = $CmdLine[2]
Global Const $file_s     = "f_search.txt"      ;~ File mit den Suchkriterien
Global Const $file_r     = $sSearch_2 & ".txt" ;~ File mit den Replace-Strings
Global Const $sExtension = ".docx" ; Verarbeite nur MS-Word Dokument ohne Macros.
Global Const $sTemplates = _FileListToArrayRec(@ScriptDir, $sSearch_1 & $sExtension, $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH) ; Auflistung der rekursiv zu verarbeitenden MS-Word Dateien
;~ Global $iTotalProjectCount = 0, $iTotalComponentCount = 0, $iTotalReplacementCount = 0
Global $aTags[1]

_read_file($file_s, 1, $aTags)
_read_file($file_r, 2, $aTags)

For $iFiles = 1 To $sTemplates[0] ; rekursives Ermitteln der zu verarbeitenden Dateien
    _Main($sTemplates[$iFiles])
Next

For $iFiles = 1 To $sTemplates[0] ; rekursives Ermitteln der zu verarbeitenden Dateien
    _Main($sTemplates[$iFiles])
Next

;Funktion zum Einlesen der Textfiles in Arrays
Func _read_file($file_x, $col, ByRef $aArray)
Local $iRow = 1
Local $hFileHandle = FileOpen($file_x, $FO_READ)
    ReDim $aArray[_FileCountLines($hFileHandle) + 1][$col]
    While 1
        $aArray[$iRow][$col-1] = FileReadLine($hFileHandle, $iRow)
        If @error Then ExitLoop
        $iRow += 1
    WEnd
    FileClose($hFileHandle)
EndFunc

Func _Main($sTemplate)
Local $oWordDoc, $sFileName
Local $oWord = _Word_Create()
    If @error Then Return SetError(1, 0, MsgBox($MB_ICONERROR, '_Word_Open', '@error: ' & @error) * 0)
    If Not IsObj($oWord) Then Return SetError(1, 1, MsgBox($MB_ICONERROR, '_Word_DocOpen', '$oWord is not an Obj') * 0)

    $oWordDoc = _Word_DocOpen($oWord, $sTemplate)
    If @error Then Return SetError(2, 0, MsgBox($MB_ICONERROR, '_Word_DocOpen', '@error: ' & @error) * 0)
    If Not IsObj($oWordDoc) Then Return SetError(2, 0, MsgBox($MB_ICONERROR, '_Word_DocOpen', '$oWordDoc is not an Obj') * 0)

    For $j = 0 To UBound($aTags, 1) - 1
        _Word_DocFindReplace($oWordDoc, $aTags[$j][0], $aTags[$j][1], Default, -1)
    Next

;~     consolewrite(@ScriptDir & @CRLF)
    $sFileName = @ScriptDir & "\" & $sSearch_1 & "-" & $sSearch_2 & ".pdf"
    _Word_DocExport($oWordDoc, $sFileName, Default, $wdExportCurrentPage)

    _Word_DocClose($oWordDoc, false) ; speichern nicht vergessen
    If @error Then Return SetError(3, 0, MsgBox($MB_ICONERROR, '_Word_DocClose', '@error: ' & @error) * 0)

    _Word_Quit($oWord)
    If @error Then Return SetError(4, 0, MsgBox($MB_ICONERROR, '_Word_Quit', '@error: ' & @error) * 0)

    Return SetError(0, 0, 1)
EndFunc   ;==>_Main

Alles anzeigen

**water**

Zitat von MiX-MoX

Tatsächlich kann ich auf FileOpen verzichten, da ich die Files nur auslese, aber nicht manipuliere.

Das hat in Deinem Fall mit der Art der Manipulation nichts zu tun.

Nehmen wir an, Du hast 1000 Datensätze in einer Datei, dann führt FileReadLine dazu, dass die folgende Schleife 1000 mal durchgeführt wird:

Datei öffnen
angegebene Zeile suchen
Zeile lesen
Datei schließen

Mit FileOpen/FileClose/FileRead sieht das so aus:

Datei öffnen
1000x Zeile lesen (ohne Angabe der Zeilennummer läuft ein Positionspointer mit der immer auf die nächste zu lesende Zeile zeigt)
Datei schließen

Da Datei öffen, Datei schließen sowie die Suche zur nächsten zu lesenden Zeile sehr zeitaufwändig sind (bei Zeile suchen nimmt der Aufwand mit der Anzahl der Zeilen zu) ist das hier ein reines Performance-Problem.

N.B. In Deinem Code rufst Du _FileCountLines 2x auf. Sinnvoller wäre, das Ergebnis von _FileCountLines in einer Variablen zu speichern und dann in der Schleife zu verwenden. Oder nach FileReadLine den Fehlercode abzuprüfen. Der sagt Dir dann, dass das Ende der Datei erreicht wurde.

N.B. Magic Numbers (0 bei FileOpen etc.) sollten vermieden und durch die entspr. Konstanten ersetzt werden (siehe Code unten). Konstanten sind selbsterklärend und bei Kombinationen mehrerer Werte einfacher zu lesen.

Lösch also FileOpen/FileClose komplett raus (langsame Variante) oder ersetze den bisherigen Code durch:

Code

#include <FileConstants.au3>

;Funktion zum Einlesen der Textfiles in Arrays
Func _read_file($file_x, $col, ByRef $aArray)
    $Local $iRow = 0
    Local $hFileHandle = FileOpen($file_x, $FO_READ)
    ReDim $aArray[_FileCountLines($hFileHandle) + 1][$col]
    While 1
        $aArray [$iRow][$col-1] = FileReadLine($hFileHandle)
        If @error Then ExitLoop
        $iRow = $iRow + 1
    Next
    FileClose($hFileHandle)
EndFunc

Alles anzeigen

Der Code könnte noch optimiert werden, wenn _FileCountLines durch $iRow ersetzt würde. Zu zählst zuerst alle Zeilen, nach der Befüllung des Arrays hast Du aber als Nebeneffekt (und ohne Performance-Verschlechterung) in $iRow die Anzahl der Zeilen stehen.

Die Befüllung des Arrays ließe sich auch noch optimieren.

**Moombas**

Ich habe das von water mal in meins mit rein genommen, da diese Korrektur absolut sinnig ist und ich dies selber garnicht weiter betrachtet hatte beim durchschauen.

MiX-MoX

Moin!

vielen Dank für die Erläuterungen und Codeanpassungen.

Ihr habt den Code aber nicht getestet, oder? - da stecken noch drei kleine Fehler drin:

in Zeile 24 muss die Variable $aTags als Array definiert sein, also Global $aTags [1]

in Zeile 46 muss Next durch WEnd ersetzt werden.

Außerdem habe ich festgestellt, dass das Array $aTags leer bleibt - muss noch prüfen, woran das liegt.

**Moombas**

Japp, habs korrigiert und noch eine andere Stelle (du erwartest ja ein 1-basiertes Array und kein 0-basiertes).

Ein wirkliches Testen ohne samplefiles ist halt schwer.

Teste bitte nochmal das komplette Skript von oben.

MiX-MoX

Hab mal Testdateien hochgeladen

f_search.txt enthält die Such-Matrix

12345678.txt enthält die Daten die in das Word-Dokument rein sollen

Das Word-Dokument steht für ein Datenblatt, in dem die zu ersetzenden Strings stehen.

**Moombas**

Hier mal die etwas korrigierte Version (mit deinen Test Dateien; ich habe die Anzeige des Word Dokuments mal auf False gesetzt (Zeile 50)):

Ich gehe davon aus das der Dateiname (du suchst ja nach einem fixen Dateinamen) nur einmal zu finden ist (du speicherst mit einem festen Namen, der sich nicht auf Grund der gefundenen templates ändert), dann brauchst du die Schleife zum durchgehen der templates nicht, sondern kannst gleich auf den ersten Eintrag gehen.

Zeile 13-18 musst du noch anpassen, ich habe es nur mal drinne gelassen (17&18) um zu Zeigen, was ich verwendet habe.

AutoIt

#include <File.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <Word.au3>
#include <WordConstants.au3>
 ; https://autoit.de/thread/87817-microsoft-word-suche-und-ersetze-text-in-den-inhalten-der-vba-progammierung-gel%C3%B6/?postID=708429#post708429
;~ #DIESE ROUTINE WIRD ÜBER PARAMETER AUFGERUFEN

Opt("MustDeclareVars", 1)
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

;~ If not $CmdLine[0] = 2 then
;~     MsgBox($MB_ICONERROR, 'Parameter', 'No or wrong amount of parameters provided.')
;~     Exit
;~ EndIf
Global Const $sSearch_1  = 'SD - AAAA - DE - Händler' ;$CmdLine[1]
Global Const $sSearch_2  = '12345678' ;$CmdLine[2]
Global Const $file_s     = "f_search.txt"      ;~ File mit den Suchkriterien
Global Const $file_r     = $sSearch_2 & ".txt" ;~ File mit den Replace-Strings
Global Const $sExtension = ".docx" ; Verarbeite nur MS-Word Dokument ohne Macros.
Global Const $sTemplates = _FileListToArrayRec(@ScriptDir, $sSearch_1 & $sExtension, $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH) ; Auflistung der rekursiv zu verarbeitenden MS-Word Dateien
;~ Global $iTotalProjectCount = 0, $iTotalComponentCount = 0, $iTotalReplacementCount = 0
Global $aTags[1]

If not IsArray($sTemplates) Then
    MsgBox($MB_ICONERROR, 'Error', 'Die Datei ' & $sSearch_1 & $sExtension & ' wurde nicht gefunden.')
    Exit
EndIf

_FileReadToArray($file_s, $aTags)
_read_file($file_r, 1, $aTags)
_Main($sTemplates[1], $aTags)

;Funktion zum Einlesen der Textfiles in Arrays
Func _read_file($file_x, $col, ByRef $aArray)
Local $aFile
    _ArrayColInsert($aTags, $col)
    _FileReadToArray($file_x, $aFile)
    For $iRow = 1 to $aFile[0]
        $aArray[$iRow][$col] = $aFile[$iRow]
    Next
EndFunc

Func _Main($sTemplate, $aArray)
Local $oWordDoc, $sFileName
Local $oWord = _Word_Create(False)
    If @error Then Return SetError(1, 0, MsgBox($MB_ICONERROR, '_Word_Open', '@error: ' & @error) * 0)
    If Not IsObj($oWord) Then Return SetError(1, 1, MsgBox($MB_ICONERROR, '_Word_DocOpen', '$oWord is not an Obj') * 0)

    $oWordDoc = _Word_DocOpen($oWord, $sTemplate)
    If @error Then Return SetError(2, 0, MsgBox($MB_ICONERROR, '_Word_DocOpen', '@error: ' & @error) * 0)
    If Not IsObj($oWordDoc) Then Return SetError(2, 0, MsgBox($MB_ICONERROR, '_Word_DocOpen', '$oWordDoc is not an Obj') * 0)

    For $j = 1 To $aArray[0][0]
        _Word_DocFindReplace($oWordDoc, $aArray[$j][0], $aArray[$j][1], Default, -1)
    Next

    $sFileName = @ScriptDir & "\" & $sSearch_1 & "-" & $sSearch_2 & ".pdf"
    _Word_DocExport($oWordDoc, $sFileName, Default, $wdExportCurrentPage)

    _Word_DocClose($oWordDoc, false) ; speichern nicht vergessen
    If @error Then Return SetError(3, 0, MsgBox($MB_ICONERROR, '_Word_DocClose', '@error: ' & @error) * 0)

    _Word_Quit($oWord)
    If @error Then Return SetError(4, 0, MsgBox($MB_ICONERROR, '_Word_Quit', '@error: ' & @error) * 0)

    Return SetError(0, 0, 1)
EndFunc   ;==>_Main

Alles anzeigen

Andernsfalls müsstest du so vorgehen (dann gehe ich davon aus das der Dateiname mehrfach in versch. Unterordnern existiert):

AutoIt

#include <File.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <Word.au3>
#include <WordConstants.au3>
 ; https://autoit.de/thread/87817-microsoft-word-suche-und-ersetze-text-in-den-inhalten-der-vba-progammierung-gel%C3%B6/?postID=708429#post708429
;~ #DIESE ROUTINE WIRD ÜBER PARAMETER AUFGERUFEN

Opt("MustDeclareVars", 1)
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

;~ If not $CmdLine[0] = 2 then
;~     MsgBox($MB_ICONERROR, 'Parameter', 'No or wrong amount of parameters provided.')
;~     Exit
;~ EndIf
Global Const $sSearch_1  = 'SD - AAAA - DE - Händler' ;$CmdLine[1]
Global Const $sSearch_2  = '12345678' ;$CmdLine[2]
Global Const $file_s     = "f_search.txt"      ;~ File mit den Suchkriterien
Global Const $file_r     = $sSearch_2 & ".txt" ;~ File mit den Replace-Strings
Global Const $sExtension = ".docx" ; Verarbeite nur MS-Word Dokument ohne Macros.
Global Const $sTemplates = _FileListToArrayRec(@ScriptDir, $sSearch_1 & $sExtension, $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH) ; Auflistung der rekursiv zu verarbeitenden MS-Word Dateien
;~ Global $iTotalProjectCount = 0, $iTotalComponentCount = 0, $iTotalReplacementCount = 0
Global $aTags[1]

If not IsArray($sTemplates) Then
    MsgBox($MB_ICONERROR, 'Error', 'Es wurde keine Datei mit dem Namen ' & $sSearch_1 & $sExtension & ' gefunden.')
    Exit
EndIf

_FileReadToArray($file_s, $aTags)
_read_file($file_r, 1, $aTags)

For $iFiles = 1 To $sTemplates[0] ; rekursives Ermitteln der zu verarbeitenden Dateien
    _Main($sTemplates[$iFiles], $aTags)
Next

;Funktion zum Einlesen der Textfiles in Arrays
Func _read_file($file_x, $col, ByRef $aArray)
Local $aFile
    _ArrayColInsert($aTags, $col)
    _FileReadToArray($file_x, $aFile)
    For $iRow = 1 to $aFile[0]
        $aArray[$iRow][$col] = $aFile[$iRow]
    Next
EndFunc

Func _Main($sTemplate, $aArray)
Local $oWordDoc, $sFileName
Local $Folders = StringSplit($sTemplate, '\')
Local $oWord = _Word_Create(False)
    If @error Then Return SetError(1, 0, MsgBox($MB_ICONERROR, '_Word_Open', '@error: ' & @error) * 0)
    If Not IsObj($oWord) Then Return SetError(1, 1, MsgBox($MB_ICONERROR, '_Word_DocOpen', '$oWord is not an Obj') * 0)

    $oWordDoc = _Word_DocOpen($oWord, $sTemplate)
    If @error Then Return SetError(2, 0, MsgBox($MB_ICONERROR, '_Word_DocOpen', '@error: ' & @error) * 0)
    If Not IsObj($oWordDoc) Then Return SetError(2, 0, MsgBox($MB_ICONERROR, '_Word_DocOpen', '$oWordDoc is not an Obj') * 0)

    For $j = 1 To $aArray[0][0]
        _Word_DocFindReplace($oWordDoc, $aArray[$j][0], $aArray[$j][1], Default, -1)
    Next

    $sFileName = @ScriptDir & "\" & $sSearch_1 & "-" & $sSearch_2 & '-' & $Folders[$Folders[0] - 1] & ".pdf"
    _Word_DocExport($oWordDoc, $sFileName, Default, $wdExportCurrentPage)

    _Word_DocClose($oWordDoc, false) ; speichern nicht vergessen
    If @error Then Return SetError(3, 0, MsgBox($MB_ICONERROR, '_Word_DocClose', '@error: ' & @error) * 0)

    _Word_Quit($oWord)
    If @error Then Return SetError(4, 0, MsgBox($MB_ICONERROR, '_Word_Quit', '@error: ' & @error) * 0)

    Return SetError(0, 0, 1)
EndFunc   ;==>_Main

Alles anzeigen

**Moombas**

MiX-MoX : Wie sieht es aus, welche Variante ist das was du gesucht hast und funktioniert es so wie erwartet?

**Moombas**

MiX-MoX Ich sag es dir ganz ehrlich: Du schaust hier regelmäßig rein und mein "Fix" scheint ja zu funktionieren, denn sonst wärst du sicherlich mit einer negativen Meldung um die Ecke gekommen aber dann nicht mal ein "Danke" und/oder Feedback da zu lassen finde ich nicht gut und wird dafür sorgen, das (zumindest mich betreffend) es sein kann, das dir nicht mehr geholfen wird.

MiX-MoX

Moombas

sorry für mein langes schweigen. Hab Sommergrippe und warte noch auf Genesung bzw. einen klaren Kopf...

Soweit ich das beim Überfliegen erkennen kann passt das soweit - zum Testen bin ich noch nicht gekommen.