Inputfeld: Hintergrund bedingt einfärben

**Alina**

Moin zusammen

Ich würde gerne, wenn in Input1 ein Minuszeichen vorhanden ist, das dann in Input 2 die Hintergrundfarbe "rot" ist.

Spoiler anzeigen

C

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 380, 75, 300, 600)
$Input1 = GUICtrlCreateInput("Input1", 5, 5, 370, 30)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 2)
$Input2 = GUICtrlCreateInput("Input2", 5, 40, 370, 30)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 4)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Input2
    EndSwitch
WEnd

Alles anzeigen

LG Lina.

**Oscar**

Zitat von Alina

Ich würde gerne, wenn in Input1 ein Minuszeichen vorhanden ist, das dann in Input 2 die Hintergrundfarbe "rot" ist.

So:

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 380, 75, 300, 600)
$Input1 = GUICtrlCreateInput("Input1", 5, 5, 370, 30)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 2)
$Input2 = GUICtrlCreateInput("Input2", 5, 40, 370, 30)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 4)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Input2
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case GUICtrlGetHandle($Input1)
            Switch $iCode
                Case $EN_CHANGE
                    GUICtrlSetBkColor($Input2, StringInStr(GUICtrlRead($Input1), '-') ? 0xFFAAAA : 0xFFFFFF)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**Alina**

Moin Oscar.

Separat läuft das Script. Danke !

Aber ich habe bereits diese WM_COMMAND Function.

Code

Func WM_COMMAND($hGui, $iMsg, $wParam, $lParam)
    Local $Char
    If ($lParam = GUICtrlGetHandle($Separa)) And (BitAND(BitShift($wParam, 16), 0xFFFF) = $EN_CHANGE) Then
        $Char = GUICtrlRead($Separa)
        If ($Char <> '') And Not StringRegExp($Char, '^[^\d-]$') Then
            GUICtrlSetState($Separa, $GUI_FOCUS)
            _GUICtrlEdit_ShowBalloonTip($lParam, "Unzulässiges!", "Unzulässiges Trennzeichen!", 6)
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Alles anzeigen

Wie mache ich zwei dieser FWM_COMMAND Functionen? Das ist bei mir das erste mal der Fall. Einmal die bestehende und dann die von Dir dazu.

**Oscar**

Zitat von Alina

Wie mache ich zwei dieser FWM_COMMAND Functionen?

Einfach zusammenfassen:

AutoIt

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $iCode = BitShift($wParam, 16)
    Local $hWndFrom = $lParam
    Switch $hWndFrom
        Case GUICtrlGetHandle($Separa)
            Switch $iCode
                Case $EN_CHANGE
                    Local $Char = GUICtrlRead($Separa)
                    If ($Char <> '') And Not StringRegExp($Char, '^[^\d-]$') Then
                        GUICtrlSetState($Separa, $GUI_FOCUS)
                        _GUICtrlEdit_ShowBalloonTip($lParam, "Unzulässiges!", "Unzulässiges Trennzeichen!", 6)
                    EndIf
            EndSwitch
        Case GUICtrlGetHandle($Input1)
            Switch $iCode
                Case $EN_CHANGE
                    GUICtrlSetBkColor($Input2, StringInStr(GUICtrlRead($Input1), '-') ? 0xFFAAAA : 0xFFFFFF)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**Oscar**

Zitat von Alina

Ich muss nur einmal klären, wieso ich dafür einmal im Input1 klicken muss und dort etwas ändere. Erst danach wird es wie gewünscht rot.

Ja und so ist es auch korrekt! $EN_CHANGE wird ja erst bei einer Eingabe aufgerufen.

Wenn Du das Feld (auch) anderweitig füllst, musst Du das als Funktion an dieser Stelle aufrufen.

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 380, 75, 300, 600)
$Input1 = GUICtrlCreateInput("-", 5, 5, 370, 30)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 2)
$Input2 = GUICtrlCreateInput("Input2", 5, 40, 370, 30)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 4)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

_CheckInput() ; hier einmalig aufrufen (und an jeder Stelle, an der der Inhalt von $Input1 geaendert wird)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Input2
    EndSwitch
WEnd

Func _CheckInput()
    GUICtrlSetBkColor($Input2, StringInStr(GUICtrlRead($Input1), '-') ? 0xFFAAAA : 0xFFFFFF)
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $iCode = BitShift($wParam, 16)
    Local $hWndFrom = $lParam
    Switch $hWndFrom
;~         Case GUICtrlGetHandle($Separa)
;~             Switch $iCode
;~                 Case $EN_CHANGE
;~                     Local $Char = GUICtrlRead($Separa)
;~                     If ($Char <> '') And Not StringRegExp($Char, '^[^\d-]$') Then
;~                         GUICtrlSetState($Separa, $GUI_FOCUS)
;~                         _GUICtrlEdit_ShowBalloonTip($lParam, "Unzulässiges!", "Unzulässiges Trennzeichen!", 6)
;~                     EndIf
;~             EndSwitch
        Case GUICtrlGetHandle($Input1)
            Switch $iCode
                Case $EN_CHANGE
                    _CheckInput()
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**Alina**

Danke !

Läuft alles !