subst auch in autoit?

Zitat von Peter S. Taler

gerüchteweise hast Du mal eine UDF zu dem Thema geschrieben?

Was sind denn das für Gerüchte?

Also ich möchte es nicht ausschließen, kann es aber nicht mit Sicherheit bejahen. Mal gucken, ob ich da noch was finde.

Zitat von BugFix

Was sind denn das für Gerüchte?

Also ich möchte es nicht ausschließen, kann es aber nicht mit Sicherheit bejahen. Mal gucken, ob ich da noch was finde.

Im EN-Forum gibt es einen Beitrag von @progandy :

Dort wird eine UDF von Dir erwähnt, leider nur der Header. Der Link selbst ist mal wieder Opfer eines Forumsupdates geworden. Ggf. hilft Dir die Info aber beim Suchen .

Zitat

The SUBST-command can be simulated with these funcs: http://www.autoit.de/index.php?page=Thread...69362#post69362 This is the translated UDF-info:

Code

;==================================================================================================
; Function Name:   _PartialDrive($sDeviceName=-1, $sTargetPath=-1, $iDelete=0)
; Description:: Creates or removes a Virtual Drive. The Drive will
;                 be romved automatically on shutdown.
; Parameter(s): $sDeviceName        Driveletter of the Drive to create / delete
;                                  -1   first free Driveletter (default)
;                 $sTargetPath      Path to link the driveletter to,                                                      -1= Create: link to @MyDocumentsDir (default)
;                                                       Delete: the path connected with the driveletter will be found automatically.
;    optional:  $iDelete            0=Creation (default); 1=Deletion of the Drive
; Return Value(s): Success          Driveletter of the created/deleted virtual Drive
;                  Fehler           0   @error=1 given driveletter already existing (only when creating)
;                                      @error=2 no free driveletter available (only when creating)
;                                      @error=3 no valid path to link to
;                                      @error=4 Action failed
;                                      @error=5 no valid drive to delete
; Author(s):       BugFix (bugfix@autoit.de)
; Modified:     Prog@ndy (translated info)
;==================================================

Alles anzeigen

Zitat von Musashi

Dort wird eine UDF von Dir erwähnt,

Na mit dem Funktionsnamen lässt sich was anfangen.

Func _PartialDrive($sDeviceName=-1, $sTargetPath=-1, $iDelete=0)
    If $sDeviceName = -1 And $iDelete = 0 Then
        Local $aDrives = DriveGetDrive("ALL")
        Local $oDrives = ObjCreate("System.Collections.ArrayList")
        For $i = 1 To UBound($aDrives) -1
            $oDrives.Add(Asc(StringLeft($aDrives[$i],1)))
        Next
        Local $j = 100
        While $oDrives.Contains($j)
            $j += 1
            If $j > 122 Then Return SetError(2,0,0)
        WEnd
        $sDeviceName = Chr($j) & ':'
    ElseIf ($sDeviceName = -1 Or Not FileExists($sDeviceName)) And $iDelete = 1 Then
        Return SetError(5,0,0)
    ElseIf $sTargetPath = -1 And $iDelete = 1 Then
        Local $ret = DllCall("kernel32.dll", "long", "QueryDosDeviceA", "str", $sDeviceName, "str", "", "long", 260)
        If $ret[0] = 0 Then
            Return SetError(4,0,0)
        Else
            $sTargetPath = StringRegExpReplace($ret[2], '(\W*)([a-zA-Z].*)', '$2')
        EndIf
    EndIf
    $sDeviceName = StringRegExpReplace(StringLower($sDeviceName), '(.*)([a-z]{1}:)(.*)', '$2')
    If $iDelete = 0 And FileExists($sDeviceName) Then Return SetError(1,0,0)
    If $sTargetPath = -1 Then $sTargetPath = @MyDocumentsDir
    If Not FileExists($sTargetPath) Then Return SetError(3,0,0)
    Local $iFlag = 0x0
    If $iDelete <> 0 Then $iFlag = 0x2
    Local $ret = DllCall('kernel32.dll', 'long', 'DefineDosDeviceA', _
        'long', $iFlag, 'str', $sDeviceName, 'str', $sTargetPath)
    If $ret[0] = 0 Then
        Return SetError(4,0,0)
    Else
        Return $sDeviceName
    EndIf
EndFunc ;==>PartialDrive

Ich hoffe, das hilft weiter.

Zitat von Peter S. Taler

Nun muss ich Deine Funktion nur noch verstehen

Habe jetzt den zugehörigen Thread ausgegraben, das erleichtert vllt. das Verstehen.

Beitrag

Virtuelles (partielles) Laufwerk Erstellen/Löschen

Hi,
hiermit lassen sich Ordner-Pfade zu Virtuellen Laufwerken verknüpfen. Die so erstellten Laufwerke werden nicht in der Registry verewigt und sind nur für die Dauer der Sitzung gültig. Nach einem Neustart ist wieder alles 'normal'.

Edit 27.12.08:
Hab das noch etwas erweitert:
- Standardmäßig wird jetzt der erste freie Laufwerksbuchstabe verwendet
- der Verknüpfungspfad ist jetzt vorbelegt mit '@MyDocumentsDir' ( aber nur, weil ich die Parameterreihenfolge nicht ändern wollte )
- bei Erfolg wird…

BugFix

26. Dezember 2008

Zitat von Peter S. Taler

Du bearbeitest den DLL Kernel? Wenn ja, woher weiß man was warum usw?

Ich bin auf diesem Gebiet kein Fachmann

Beispiel :

Local $ret = DllCall('kernel32.dll', 'long', 'DefineDosDeviceA', _ 'long', $iFlag, 'str', $sDeviceName, 'str', $sTargetPath)

Schau Dir mal definedosdevicea an.

Zitat von Peter S. Taler

Du bearbeitest den DLL Kernel? Wenn ja woher weiss man was warum usw?

Nein, ich rufe per DllCall eine Funktion aus der Bibliothek "kernel32.dll" auf. Die Details zum Call findest du in der AutoIt Hilfe.