TCP - Send

MojoeB

Hay zusammen, ich habe ein Programm das ich mit einer Alarmzentrale verbinden über TCP-IP.

connecten kann ich, wird in der Alarmzentrale auch angezeigt, allerdings kann ich einige Meldungen nicht so absetzen wie ich möchte.

Zum Beispiel, soll diese Meldung über TCP-IP geschickt werden.

AutoIt

local $sString1 = '<?xml version="1.0" encoding="utf-8"?>' & @CRLF & _
    '<LISA>' & @CRLF & _
    @TAB & '<VERSION>5.8</VERSION>' & @CRLF & _
    @TAB & '<MEDIUM>12</MEDIUM>' & @CRLF & _
    @TAB & '<KANAL>610</KANAL>' & @CRLF & _
    @TAB & '<SENDER>' & @IPAddress1 & '</SENDER>' & @CRLF & _
    @TAB & '<ENTSTEHUNG>' & _NowDate() & ' ' & _NowTime(3) & 'Uhr</ENTSTEHUNG>' & @CRLF & _
    @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
    @TAB & @TAB & '<Identnummer>'&$id&'</Identnummer>'& @CRLF & _
    @TAB & @TAB & '<Ereignis>Connect</Ereignis>'& @CRLF & _
    @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
    @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
    @TAB & @TAB & '<Identnummer>'&$id&'</Identnummer>'& @CRLF & _
    @TAB & @TAB & '<Ereignis>ROUTINE</Ereignis>'& @CRLF & _
    @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
    '</LISA>

Alles anzeigen

Was er aber nach Programm Start nicht tut.

Und es gibt auch keine Fehlerinterpretation.
Wenn ich nun allerdings den selben String per Button los schicke funktioniert auch nur 1x, kommt dieser in der Alarmzentrale an,

Allerdings so :

XML

<?xml VERSION="1.0" ENCODING="UTF-8"?>
<LISA>
    <VERSION>5.8</VERSION>
    <MEDIUM>12</MEDIUM>
    <KANAL>610</KANAL>
    <SENDER>***.**.**.**</SENDER>
    <ENTSTEHUNG>04.04.2023 14:02:53UHR</ENTSTEHUNG>
    <VERBINDUNGSMELDUNG>
        <IDENTNUMMER>1111</IDENTNUMMER>
        <EREIGNIS>CONNECT</EREIGNIS>
    </VERBINDUNGSMELDUNG>
    <VERBINDUNGSMELDUNG>
        <IDENTNUMMER>1111</IDENTNUMMER>
        <EREIGNIS>ROUTINE</EREIGNIS>
    </VERBINDUNGSMELDUNG>
</LISA><?xml VERSION="1.0" ENCODING="UTF-8"?>

Alles anzeigen

statt so :

XML

<?xml VERSION="1.0" ENCODING="UTF-8"?>
<LISA>
    <VERSION>5.8</VERSION>
    <MEDIUM>12</MEDIUM>
    <KANAL>610</KANAL>
    <SENDER>***.**.**.**</SENDER>
    <ENTSTEHUNG>04.04.2023 14:02:53UHR</ENTSTEHUNG>
    <VERBINDUNGSMELDUNG>
        <IDENTNUMMER>1111</IDENTNUMMER>
        <EREIGNIS>CONNECT</EREIGNIS>
    </VERBINDUNGSMELDUNG>
    <VERBINDUNGSMELDUNG>
        <IDENTNUMMER>1111</IDENTNUMMER>
        <EREIGNIS>ROUTINE</EREIGNIS>
    </VERBINDUNGSMELDUNG>
</LISA>

Alles anzeigen

Ist es möglich das ich mein gesendeten String irgendwie mit einer TCP-Funktion abschließen muss?
Ohne die Verbindung zum Server zu kappen.
Habe das Gefühl das er mit jedem String den alten String erweitert, da bin ich mir aber nicht sicher.

mein bisheriger Code :

AutoIt

Global $LisaIP, $LisaPORT, $socket

TCP_connect($socket, '1111') ;steht am Anfang des Scripts
testmeldung_xml() ; wird durch einen  Button aktiviert.
TCP_Disconnect($id = '1111') ; soll nur aktiviert werden wenn  Verbindungschließen oder beenden gedrückt wird.

Func TCP_connect(ByRef $socket, $id = '')
    TCPStartup()
    $socket = TCPConnect($LisaIP, $LisaPORT)
    If $socket = -1 Then
        MsgBox(0, "Error", "Unable to connect to server.")
        Return
    Else
        Sleep(3000)
        Local $sString = '<?xml version="1.0" encoding="utf-8"?>' & @CRLF & _
                '<LISA>' & @CRLF & _
                @TAB & '<VERSION>5.8</VERSION>' & @CRLF & _
                @TAB & '<MEDIUM>12</MEDIUM>' & @CRLF & _
                @TAB & '<KANAL>610</KANAL>' & @CRLF & _
                @TAB & '<SENDER>' & @IPAddress1 & '</SENDER>' & @CRLF & _
                @TAB & '<ENTSTEHUNG>' & _NowDate() & ' ' & _NowTime(3) & 'Uhr</ENTSTEHUNG>' & @CRLF & _
                @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
                @TAB & @TAB & '<Identnummer>' & $id & '</Identnummer>' & @CRLF & _
                @TAB & @TAB & '<Ereignis>Connect</Ereignis>' & @CRLF & _
                @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
                @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
                @TAB & @TAB & '<Identnummer>' & $id & '</Identnummer>' & @CRLF & _
                @TAB & @TAB & '<Ereignis>ROUTINE</Ereignis>' & @CRLF & _
                @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
                '</LISA>'


        TCPsend_($sString)
        ConsoleWrite(sString & @CRLF)
    EndIf
EndFunc   ;==>TCP_connect

Func testmeldung_xml()
    Local $idroutine = InputBox('Routine Test', 'Trage die ID mit der dem Endgerät IP-XML ein.')
    Local $sString = '<?xml version="1.0" encoding="utf-8"?>' & @CRLF & _
            '<LISA>' & @CRLF & _
            @TAB & '<VERSION>5.8</VERSION>' & @CRLF & _
            @TAB & '<MEDIUM>12</MEDIUM>' & @CRLF & _
            @TAB & '<KANAL>610</KANAL>' & @CRLF & _
            @TAB & '<SENDER>' & @IPAddress1 & '</SENDER>' & @CRLF & _
            @TAB & '<ENTSTEHUNG>' & _NowDate() & ' ' & _NowTime(3) & 'Uhr</ENTSTEHUNG>' & @CRLF & _
            @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
            @TAB & @TAB & '<Identnummer>' & $idroutine & '</Identnummer>' & @CRLF & _
            @TAB & @TAB & '<Ereignis>Connect</Ereignis>' & @CRLF & _
            @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
            @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
            @TAB & @TAB & '<Identnummer>' & $idroutine & '</Identnummer>' & @CRLF & _
            @TAB & @TAB & '<Ereignis>ROUTINE</Ereignis>' & @CRLF & _
            @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
            '</LISA>'

    Local $aXMLTESTDATA[1] = [$sString]
    For $i = 0 To UBound($aXMLTESTDATA) - 1 Step 1
        Sleep(250)
        If $aXMLTESTDATA[$i] = '' Then ContinueLoop
        TCPsend_($aXMLTESTDATA[$i])
    Next
EndFunc   ;==>testmeldung_xml

Func TCPsend_($sString)
    TCPSend($socket, $sString)
    ConsoleWrite($sString & @CRLF)
EndFunc   ;==>TCPsend_

Func TCP_Disconnect($id = '') ; soll nur bei Exitbtn greifen.
    Local $sString = '<?xml version="1.0" encoding="utf-8"?>' & @CRLF & _
            '<LISA>' & @CRLF & _
            @TAB & '<VERSION>5.8</VERSION>' & @CRLF & _
            @TAB & '<MEDIUM>12</MEDIUM>' & @CRLF & _
            @TAB & '<KANAL>610</KANAL>' & @CRLF & _
            @TAB & '<SENDER>' & @IPAddress1 & '</SENDER>' & @CRLF & _
            @TAB & '<ENTSTEHUNG>' & _NowDate() & ' ' & _NowTime(3) & 'Uhr</ENTSTEHUNG>' & @CRLF & _
            @TAB & '<VERBINDUNGSMELDUNG>' & @CRLF & _
            @TAB & @TAB & '<Identnummer>' & $id & '</Identnummer>' & @CRLF & _
            @TAB & @TAB & '<Ereignis>Disconnect</Ereignis>' & @CRLF & _
            @TAB & '</VERBINDUNGSMELDUNG>' & @CRLF & _
            '</LISA>'

    TCPsend_($sString)

    TCPCloseSocket($socket)
    TCPShutdown()

EndFunc   ;==>TCP_Disconnect

Alles anzeigen

Ich habe die GUI im Code weggelassen, mich interessiert nur ob der Aufbau richtig wäre oder ob ich grundlegend etwas falsches mit TCP mache, da ich davor noch nie mit gearbeitet habe.

Sobald mein Programm/Script geöffnet wurde zeigt es in der Leitstelle an das mein Programm per IP verbunden ist sobald ich es schließe wird gezeigt das mein Programm ausgefallen ist.
Also habe ich ja eine Verbindung wärend mein Programm läuft aber warum kann ich dann nicht mehrere Meldungen hinter einander absetzten erst nach Neustart des Scripts/programmes funktioniert es wieder.

Deswegen glaube ich das TCPSend bei einer bestehenden Verbindung einfach den letzten geschickten String erweitert, ich kann mir auch nicht erklären warum er die Meldung dann so beendet: </LISA><?xml VERSION="1.0" ENCODING="UTF-8"?>
hoffe ihr seit schlauer als ich und könnt mir dabei helfen.

Gruß Mojoe

**eukalyptus**

Hallo!

Ich bin mit XMLDOM immer besser gefahren, als mit selber erstellten XML-Strings.

Und auch mit WinHTTP hatte ich immer weniger Probleme, als TCP-Send

Probiers mal auf diese Weise:

AutoIt

#include <Date.au3>


Global $oERR = ObjEvent("AutoIt.Error", "_ErrFunc")
Func _ErrFunc($oERR)
    ConsoleWrite("! We intercepted a COM Error !" & @CRLF & _
            "Number: 0x" & Hex($oERR.number, 8) & @CRLF & _
            "Description: " & $oERR.description & _
            "At line: " & $oERR.scriptline & @CRLF)
    SetError(1)
EndFunc   ;==>_ErrFunc



Global $oWHttp = ObjCreate("Winhttp.winhttprequest.5.1")


Global $oXML = _CreateMSG()
_SendMSG($oXML)



Func _SendMSG($oXML)
    If Not IsObj($oXML) Then Return
    $oWHttp.Open("POST", "http://" & $LisaIP & ":" & $LisaPORT, 0)

    $oWHttp.setRequestHeader("Content-Type", "text/xml")
    $oWHttp.setRequestHeader("Connection", "Keep-Alive")

    $oWHttp.Send($oXML.xml)
    If @error Then Return SetError(1, 1, False)

    Switch $oWHttp.WaitForResponse(2)
        Case True
            Switch $oWHttp.Status()
                Case 200 ;OK
                    ConsoleWrite("+ $oWHttp.Status OK " & @CRLF)
                    Return $oWHttp.Responsetext()

                Case Else
                    ConsoleWrite("! HTTP Status: " & $oWHttp.Status() & @CRLF)

            EndSwitch

        Case Else
            ConsoleWrite("! $oWHttp.TimeOut " & @CRLF)

    EndSwitch
EndFunc   ;==>_SendMSG







Func _CreateMSG()
    Local $oXML = ObjCreate("Microsoft.XMLDOM")
    If Not IsObj($oXML) Then Return SetError(1, 1, False)

    Local $oPI = $oXML.createProcessingInstruction("xml", "version=""1.0""")
    $oXML.appendChild($oPI)



    Local $oLISA = $oXML.createElement("LISA")
    $oXML.documentElement = $oLISA

    Local $oChild = $oXML.createElement("VERSION")
    $oChild.Text = "5.8"
    $oLISA.appendChild($oChild)

    $oChild = $oXML.createElement("MEDIUM")
    $oChild.Text = "12"
    $oLISA.appendChild($oChild)

    $oChild = $oXML.createElement("KANAL")
    $oChild.Text = "610"
    $oLISA.appendChild($oChild)

    $oChild = $oXML.createElement("SENDER")
    $oChild.Text = "192.168.1.73"
    $oLISA.appendChild($oChild)

    $oChild = $oXML.createElement("ENTSTEHUNG")
    $oChild.Text = _NowDate() & " " & _NowTime(3) & "Uhr"
    $oLISA.appendChild($oChild)



    Local $oVERBINDUNGSMELDUNG = $oXML.createElement("VERBINDUNGSMELDUNG")
    $oLISA.appendChild($oVERBINDUNGSMELDUNG)

    $oChild = $oXML.createElement("Identnummer")
    $oChild.Text = "1111"
    $oVERBINDUNGSMELDUNG.appendChild($oChild)

    $oChild = $oXML.createElement("Ereignis")
    $oChild.Text = "ROUTINE"
    $oVERBINDUNGSMELDUNG.appendChild($oChild)



    $oVERBINDUNGSMELDUNG = $oXML.createElement("VERBINDUNGSMELDUNG")
    $oLISA.appendChild($oVERBINDUNGSMELDUNG)

    $oChild = $oXML.createElement("Identnummer")
    $oChild.Text = "1111"
    $oVERBINDUNGSMELDUNG.appendChild($oChild)

    $oChild = $oXML.createElement("Ereignis")
    $oChild.Text = "ROUTINE"
    $oVERBINDUNGSMELDUNG.appendChild($oChild)


    ;$oXML.save(@ScriptDir & "\test.xml")

    Return $oXML
EndFunc   ;==>_CreateMSG

Alles anzeigen

Etwas übersichtlicher wirds natürlich, wenn du dir eine Helperfunktion bastelst, welche die XML-Elemente in einer Zeile erstellt...

EDIT: Zum betrachten $oXML-save und mit einem XML-Editor (Internet Explorer reicht ;)) öffnen (XML-String ist SingleLine)

lgE

MojoeB

eukalyptus

Danke für deinen Rat, Ich habe es grad über winhttp probiert, damit geht es leider gar nicht.

Aber der _CreateMSG teil ist toll weil genau das habe ich erst heute fast genauso versucht, habe aber Fehler erhalten. Dann habe ich den String erstmal zum testen einfach runtergeschrieben.

Ich bin ein doofi, ich hab grad gemerkt wo mein Fehler ist, beim Testen ist mir grad aufgefallen das

Code

davor :
Func TCPsend_($sString)
    TCPSend($socket, $sString)
    ConsoleWrite($sString & @CRLF)
EndFunc   ;==>TCPsend_

danach :

Func TCPsend_($sString)
    TCPSend($socket, $sString&@CRLF)
    ConsoleWrite($sString & @CRLF)
EndFunc   ;==>TCPsend_

Alles anzeigen

@CRLF hat gefehlt deshalb hat er wahrscheinlich auch den teil angehangen.

Ich habe es in der GUI nun mit dieser 1 Meldung getestet, also :
Programm gestartet. -> XML Meldung ist angekommen.Testbutten 1x -> XML Meldung ist angekommen.

2x wiederholt -> alle Meldungen in der Zentrale angekommen.

Ich denke das war der Fehler, ich werde morgen weiter programmieren und testen und falls sich wieder das selbe Bild zeigt wie heute dann melde ich mich wieder.^^

**Kanashius**

Hi, freut mich, dass du den Fehler gefunden hast.

Ich hätte sonst noch den Vorschlag gehabt, den XML-Teil als Template zu haben. Ist etwas lesbarer und solange die Menge überschaubar ist ggf. auch sinnvoll.

Ich hab dabei das ganze Script etwas umgebaut um zu zeigen, wie ich das umgesetzt hätte. Ist meiner Meinung nach etwas übersichtlicher, vereinfacht die Fehlersuche und ist generell mehr auf Wiederverwendbarkeit ausgelegt.

AutoIt

Global $sMainTemplate = '<?xml VERSION="1.0" ENCODING="UTF-8"?>'&@CRLF& _
                        '<LISA>'&@CRLF& _
                        '    <VERSION>%s</VERSION>'&@CRLF& _ ; Version
                        '    <MEDIUM>%u</MEDIUM>'&@CRLF& _ ; Medium
                        '    <KANAL>%u</KANAL>'&@CRLF& _ ; Kanal
                        '    <SENDER>%s</SENDER>'&@CRLF& _ ; IP sender
                        '    <ENTSTEHUNG>%sUHR</ENTSTEHUNG>'&@CRLF& _ ; date time 'dd.mm.yyyy hh:mm:ss'
                        '%s'& _ ; Template VERBINDUNGSMELDUNG *times
                        '</LISA>'
Global $sSubTemplate =    '    <VERBINDUNGSMELDUNG>'&@CRLF& _
                        '        <IDENTNUMMER>%s</IDENTNUMMER>'&@CRLF& _ ; Ident number
                        '        <EREIGNIS>%s</EREIGNIS>'&@CRLF& _ ; message
                        '    </VERBINDUNGSMELDUNG>'&@CRLF

Global $bDebug = True


Global $mConn = _connect("127.0.0.1", 1337, "1111")
If @error Then
    _showError("Error connecting to the Server", @error, @extended, $mConn)
    Exit
EndIf

_send($mConn, "SOMETHING")
If @error Then _showError("Error sending to the Server: 1", @error, @extended)

Local $arMultiple = ["SOME", "MORE"]
_send($mConn, $arMultiple)
If @error Then _showError("Error sending to the Server: 2", @error, @extended)

_disconnect($mConn)
If @error Then _showError("Error disconnecting from the Server", @error, @extended)



Func _connect($sServerIP, $iPort, $sID)
    TCPStartup()
    Local $mConn[]
    $mConn.id = $sID
    $mConn.socket = TCPConnect($sServerIP, $iPort)
    If @error Then Return SetError(1, @error, -1)
    Local $arMsg = ["CONNECT", "ROUTINE"]
    _send($mConn, $arMsg)
    If @error Then Return SetError(2, @error, -1)
    Return $mConn
EndFunc

Func _send(ByRef $mConn, $connMsg)
    Local $sSubMsg = ""
    If IsString($connMsg) Then
        $sSubMsg = StringFormat($sSubTemplate, $mConn.id, $connMsg)
    ElseIf IsArray($connMsg) Then
        For $i=0 To UBound($connMsg)-1 Step 1
            $sSubMsg &= StringFormat($sSubTemplate, $mConn.id, $connMsg[$i])
        Next
    Else
        Return SetError(1, 0, -1)
    EndIf
    Local $sMsg = StringFormat($sMainTemplate, 5.8, 12, 610, @IPAddress1, @MDAY&"."&@MON&"."&@YEAR&" "&@HOUR&":"&@MIN&":"&@SEC, $sSubMsg)
    TCPSend($mConn.socket, $sMsg)
    If @error Then Return SetError(2, @error, -1)
    If $bDebug Then ConsoleWrite($sMsg&@CRLF)
    Return 1
EndFunc

Func _disconnect(ByRef $mConn)
    _send($mConn, "DISCONNECT")
    If @error Then Return SetError(1, @error, -1)
    TCPCloseSocket($mConn.socket)
    If @error Then Return SetError(2, @error, -1)
    TCPShutdown()
    If @error Then Return SetError(3, @error, -1)
EndFunc

Func _showError($sMsg, $iError, $sExtended, $sReturn = Default)
    MsgBox(16, "Error", $sMsg&@crlf&"Details: "&$iError&":"&$sExtended)
    If $bDebug Then ConsoleWrite($sMsg&@crlf&"Details: "&$iError&":"&$sExtended&" Return: "&@crlf&$sReturn&@crlf)
EndFunc

Alles anzeigen

Dazu hab ich mir zum testen auch einen Server geschrieben. Der könnte für dich auch hilfreich sein um solche Fehler zu finden, wie den von dir genannten:

AutoIt

TCPStartup()
$iMainSocket = TCPListen("127.0.0.1", 1337)
While True
    Local $iSocket = -1
    ConsoleWrite("LISTEN FOR CLIENT"&@CRLF)
    While True
        $iSocket = TCPAccept($iMainSocket)
        If $iSocket<>-1 Then ExitLoop
    WEnd
    ConsoleWrite("CLIENT CONNECTED"&@CRLF)
    While True
        $sMsg = TCPRecv($iSocket, 8000)
        If @error Or @extended = 1 Or BinaryLen($sMsg) = 0 Then
            TCPCloseSocket($iSocket)
            ExitLoop
        EndIf
        If $sMsg<>"" Then
            ConsoleWrite("RECEIVED: "&@CRLF&$sMsg&@CRLF)
        EndIf
    WEnd
    ConsoleWrite("CLIENT DISCONNECTED"&@CRLF)
WEnd

Alles anzeigen

MfG, Kanashius

Velted

Moin, kann es vielleicht daran liegen?

Zitat von TCPSend()

Falls Unicode-Strings übertragen werden sollen, so müssen diese mit StringToBinary() bzw. BinaryToString() verschlüsselt bzw. entschlüsselt werden.

MojoeB

Velted

Ehm nein daran lag es nicht, den es wird momentan noch alles unverschlüsselt übertragen.

Aber das wird als nächstes getestet wenn ich dazu komme und lust habe^^.

Ich denke wenn ich soweit bin muss ich dieses Zitat beachten^^

eukalyptus

Das mit dem XMLDOM funktioniert gut, allerdings habe ich damit noch ein kleines Problem.

$oXML sollte doch der ganze gebaute String sein oder nicht ?
Aber irgendwie gibt er mir diesen nicht zurück, bin nun einen Umweg gegangen, ich speichere es erst als Datei und dann lese ich die Datei nochmal aus.

Kanashius

danke für deine Mühe, das muss ich mir mal genauer ansehen die Tage. mein Problem dabei ist das ich StringFormat noch nicht wirklich verstanden habe.

**Kanashius**

Zitat von MojoeB

$oXML sollte doch der ganze gebaute String sein oder nicht ?
Aber irgendwie gibt er mir diesen nicht zurück, bin nun einen Umweg gegangen, ich speichere es erst als Datei und dann lese ich die Datei nochmal aus.

Du kannst mit $oXML.xml darauf zugreifen. (Alle verfügbaren Attribute findest du hier: https://learn.microsoft.com/en-us/previous…s763798(v=vs.85) )
$oXML ist ein Objekt mit verschiedenen Daten (Fields/Properties) und Methoden. Es ist kein String! Deshalb kannst du z.B. mit $oXML.createElement("Ereignis") ein Element hinzufügen. Es wird eine Methode an dem Objekt aufgerufen.

Bei deinem Beispiel würde ich persönlich eher den String mit StringFormat verwenden, statt das XML-Objekt. Es ist einfach übersichtlicher, da du nur ein kleines Template hast. Wenn du aber XML lesen/ändern willst oder das ganze noch komplizierter/verschachtelter wird würde ich das XML-Objekt nutzen. Musst du wissen, was in diesem Fall mehr Sinn macht/was du mit dem Tool noch vorhast.

Zitat von MojoeB

danke für deine Mühe, das muss ich mir mal genauer ansehen die Tage. mein Problem dabei ist das ich StringFormat noch nicht wirklich verstanden habe.

Bei StringFormat übergibst du einen String (hier das XML). In dem String schreibst du z.B. %s, %u,... (Schau in der Hilfe, was es noch alles gibt). Das sind Platzhalter für Daten, die später mit StringFormat eingefügt werden.

%s steht dabei für einen String, %u für eine positive, ganze Zahl. Und die werden nacheinander mit den Parametern von StringFormat ersetzt. Das erste %_ mit dem ersten Parameter von StringFormat, usw.

Statt z.B. also $sText = "Ich bin die " & $sType & " Zahl: " & $iZahl kann man schreiben: $sText = StringFormat("Ich bin die %s Zahl: %u", $sType, $iZahl) Dabei kann man bei Dezimal Zahlen auch angeben, wie viele Nachkommastellen angezeigt werden sollen,... Und in diesem Fall macht es das ganze übersichtlicher, weil du den String nur einmal speichern musst und ihn immer wieder mit anderen Variablen füllen kannst, ohne dass jedesmal die ganze Zuweisung mit dem ganzen Text dort stehen muss.

AutoIt

; statt
$iZahl = 5
$sType = "positive"
$sText = "Ich bin die " & $sType & " Zahl: " & $iZahl ; Text wird 2x definiert => muss hier und weiter unten geändert werden

$iZahl = -5
$sType = "negative"
$sText = "Ich bin die " & $sType & " Zahl: " & $iZahl ; Text wird 2x definiert => muss hier und weiter oben geändert werden


; hast du also
$sTemplateNumber = "Ich bin die %s Zahl: %u" ; wird hier nur einmal definiert, und wenn du was ändern musst, musst du es nur einmal hier ändern und es passt überall
$iZahl = 5
$sType = "positive"
$sText = StringFormat($sTemplateNumber, $sType, $iZahl)

$iZahl = -5
$sType = "negative"
$sText = StringFormat($sTemplateNumber, $sType, $iZahl)

Alles anzeigen

Auf diese Weise sind Änderungen/Fehler leichter zu beheben, gerade wenn es öfter verwendet wird als hier im Beispiel und es spart Code-Zeilen (=>übersichtlicher), wenn du so wie bei dir mehrere Zeilen an Text hast, die recht lang werden.

**AspirinJunkie**

Nur zur Ergänzung (ohne eine Bewertung abzugeben): Es gibt noch eine andere Möglichkeit sich seine Strings mit variablen Inhalten zusammenzubauen: Opt("ExpandVarStrings", 1).
Wenn man diese Option setzt, werden Variablen und Makros innerhalb von Stringdefinitionen ausgewertet.
Auf die Art kann man evtl. seinen String etwas übersichtlicher zusammenbauen - Beispiel:

AutoIt

; Aktiviert die Variablenauswertung in Stringdefinitionen
$iOldOpt = Opt("ExpandVarStrings", 1)

$sVersion = "1.2.3.4"
$sMedium = "Wireless"
$sKanal = "1234"

$sText = '<?xml VERSION="1.0" ENCODING="UTF-8"?>@CRLF@' & _
         '<LISA>@CRLF@' & _
         '@TAB@<VERSION>$sVersion$</VERSION>@CRLF@' & _
         '@TAB@<MEDIUM>$sMedium$</MEDIUM>@CRLF@' & _
         '@TAB@<KANAL>$sKanal$</KANAL>@CRLF@' & _
         '@TAB@<SENDER>@IPAddress1@</SENDER>@CRLF@' & _
         '@TAB@<ENTSTEHUNG>@MDAY@.@MON@.@YEAR@ @HOUR@:@MIN@:@SEC@ Uhr</ENTSTEHUNG>@CRLF@' & _
         '</LISA>'

; Option wieder auf den vorherigen Wert setzen (falls nötig)
Opt("ExpandVarStrings", $iOldOpt)

ConsoleWrite($sText & @CRLF)

Alles anzeigen

TCP - Send

Ähnliche Themen

Probleme beim Empfangen von Modbus-Daten