grundsätzliche Fragen zu Browser

Raleigh

Hallo zusammen,

da ich mich noch nie mit AutoIT beschäftigt habe, wollte ich mal fragen, welche Herangehensweise ihr in meinem Fall wählen würdet.

Ich möchte zu bestimmten Zeiten die aktuelle Uhrzeit angesagt bekommen. Mit den internen Sprachmodulen von Windows 10 erhalte ich keine zufriedenstellende Ergebnisse. Sie klingen mir einfach zu roboterhaft. Also habe ich nach der Suche im Internet hier eine html

Datei gefunden, die mir nach Anklicken des Links die aktuelle Uhrzeit mitteilt. Wenn ich im Browser das automatische Abspielen von Audiodateien aktiviere, kommt die Ansage schon beim Öffnen der html-Seite.

Ich habe versucht, über Batch, Powersell und VBS ein Skript zum Starten des Browsers zu erstellen. Dann über den Taskplaner die definierten Zeiten um das Script zu starten. Das geht 3, 4 mal gut, aber dann wird der Browser nicht sauber beendet(....unerwartet beendet).

Wenn ich jetzt mit AutoIT ein ganz einfaches Script teste,

Code

ShellExecute("C:\Uhrzeit\Waterfox\Waterfox.exe", "file:///C:/Uhr/talk.html")
Sleep (6000)
ProcessClose ("waterfox.exe")

bekomme ich das gleiche Ergebnis. Es funktioniert eine Zeit lang und dann kommt eine Fehlermeldung. Als Browser habe ich Waterfox Portable gewählt, um von meinem Standardbrowser (Firefox) getrennt zu sein. Da ich dort viele Addons und viele Tabs parallel geöffnet habe. Oder gar nicht benutze. Ich habe auch schon versucht den Browser über IDs zu beenden. Die scheinen sich nach jeden Neustart ständig zu ändern. Ich bin für jede Hilfe dankbar.

Viele Grüße

Raleigh

**Kanashius**

Hi,

die "Webseite", verwendet gespeicherte Audiodateien, die einfach nur abgespielt werden. Die sind als Base64 in js-Dateien gespeichert.

Ich würde also ein Script schreiben, dass das ganze extrahiert und wieder als Audiodateien speichert, mit https://www.autoitscript.com/forum/topic/19…ode-extra-fast/

Danach kannst du selbst den Code schreiben, der die passenden Dateien zur aktuellen Uhrzeit raussucht und mit SoundPlay den Sound abspielen.

Dann brauchst du keine Browser.

MojoeB

falls du noch einer Lösung suchts dann teste mal das :

Also entpacke einfach den gesagtem Inhalt in den Skript Verzeichnis so das talk.html im selben Verzeichnis liegt dort wo dein Skript liegt, dann schreibe diesen Code in dein Script es öffnet den MS Edge Browser kannst auch auf Firefox umschreiben mit dem

Code

('args', 'guest')

wird kein User geladen also auch keine Addos und es ist auch unabhängig von deinen anderen offnen Browser Instanzen, da es über den Webdriver läuft. Wird der Webdriver ordnungsgemäß beendet wird dann wird auch die browsersession geschlossen.

C

#include <wd_helper.au3>
#include <wd_capabilities.au3>

Global $oSession = ''
Global $capsi

HotKeySet("!t", "HotKeySayTime") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"
HotKeySet("{ESC}", "HotKeybeenden") ; Definiere den Hotkey "ESC" und verknüpfe ihn mit der Funktion "HotKeybeenden"

start() ; Starte die Funktion "start"

While 1
    Sleep(100)
WEnd

Func start()
    $capsi = SetupEdge() ; Führe die Funktion "SetupEdge" aus und speichere das Ergebnis in der Variable "$capsi"
    $oSession = _WD_CreateSession($capsi) ; Erstelle eine Sitzung mit den übergebenen Capabilities

    Local $sLocalFilePath = @ScriptDir & '\talk.html' ; Pfade anpassen entsprechend der lokalen Dateistruktur
    Local $sLocalFileURL = "file:///" & StringReplace($sLocalFilePath, "\", "/")

    _WD_Navigate($oSession, $sLocalFileURL) ; Navigiere zur lokalen HTML-Datei "talk.html" mit dem WebDriver
EndFunc   ;==>start

Func Uhr_ansagen()
    Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
    _WD_ElementAction($oSession, $element, 'Click')
    ; Hier könntest du weitere Aktionen nach dem Klick auf das Element "clockID" ausführen
EndFunc   ;==>Uhr_ansagen

Func HotKeySayTime()
    Uhr_ansagen() ; Rufe die Funktion "Uhr_ansagen" auf, um die Uhrzeit anzusagen
EndFunc   ;==>HotKeySayTime

Func HotKeybeenden()
    _WD_Shutdown() ; Beende den WebDriver
    Exit ; Beende das Skript
EndFunc   ;==>HotKeybeenden

Func SetupEdge()
    _WD_UpdateDriver("msedge", @ScriptDir) ; Aktualisiere den Edge-Driver im lokalen Verzeichnis

    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe') ; Setze den Pfad zum Edge-Driver
    _WD_Option('Port', 9515) ; Setze den Port für die WebDriver-Kommunikation

    _WD_Startup() ; Starte den WebDriver

    _WD_CapabilitiesStartup() ; Starte die Sammlung der Startparameter (Capabilities)
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge') ; Füge die Capability "alwaysMatch" mit dem Wert "msedge" hinzu
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation') ; Füge die Capability "excludeSwitches" mit dem Wert "enable-automation" hinzu
    _WD_CapabilitiesAdd('args', 'guest') ; Füge die Capability "args" mit dem Wert "guest" hinzu
    _WD_CapabilitiesDump(@ScriptLineNumber) ; Gib die Capabilities aus

    _WD_CapabilitiesAdd('args', '--headless') ; Füge die Capability "args" mit dem Wert "--headless" hinzu, um den Browser im Headless-Modus zu starten

    Local $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10) ; Warte auf das Konsolenfenster
    WinSetState($hWnd, "", @SW_HIDE) ; Verstecke das Konsolenfenster

    Local $sCapabilities = _WD_CapabilitiesGet() ; Speichere die Capabilities in einer Variable
    Return $sCapabilities ; Gib die Capabilities zurück
EndFunc   ;==>SetupEdge

Alles anzeigen

'Ich möchte zu bestimmten Zeiten die aktuelle Uhrzeit angesagt bekommen.'

das könntest du auf mehrere arten lösen, reicht dort eine zeit nach dem Start also ein intervall dann kannst du statt wie in meinem beispiel mit hotkey durch

die Function AdlibRegister ersetzen.

oder ist hier eine ganz genaue zeit gemeint ?

edit^^:

entschuldige die *au3 Dateien findest du hier : Release 1.0.3 · Danp2/au3WebDriver · GitHub

Raleigh

Vielen Dank, euch beiden. Ich schau mir beides mal genauer an.

Mein erster Ansatz als Unwissender ist dieser:

C

#include <Constants.au3>
#include <WinAPI.au3>

Global $sURL = "file:///C:/Ansage/clock/talk.html" ; Die URL der Webseite, die geöffnet werden soll
Global $iWaitTime = 6000 ; Wartezeit in Millisekunden (hier: 6 Sekunden)

Opt("WinTitleMatchMode", 2) ; Fenstertitel werden nach Teilen abgeglichen

; Öffne den Edge-Browser und lade die angegebene URL
Global $iPID = ShellExecute("C:\Ansage\msedge.exe.lnk", $sURL, "", "", @SW_MINIMIZE)

If @error Then
    MsgBox($MB_ICONERROR, "Fehler", "Der Browser konnte nicht gestartet werden.")
    Exit
EndIf

; Warte, bis die Seite geladen ist
Sleep($iWaitTime)

; Beende den Browser
_TerminateEdgeProcess()

Func _TerminateEdgeProcess()
    Local $sProcessName = "msedge.exe"
    Local $aProcesses = ProcessList($sProcessName)

    For $i = 1 To $aProcesses[0][0]
        If $aProcesses[$i][0] <> "" Then
            Local $iProcessPID = $aProcesses[$i][1]
            ProcessClose($iProcessPID)
            ExitLoop
        EndIf
    Next
EndFunc


;Global $iPID = ShellExecute("C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe", $sURL, "", "", @SW_MINIMIZE)

;Global $iPID = ShellExecute("C:\Uhr\msedge.exe.lnk", $sURL, "", "", @SW_SHOWNORMAL

Alles anzeigen

Da die "@SW_MINIMIZE" Funktion nicht zuverlässig funktionierte, habe den Edge Browser über eine Verknüpfung, die ich dann minimiert eingestellt hatte, im Script eingetragen. Dann die Aufgabenplanung für die Startzeiten eingerichtet.

Die bestimmten Ansagezeiten lauten beispielsweise 12:28, 12:58, dann weiter jede 30 Minuten. Zusätzlich noch die Uhrzeit 15:43 Uhr.

Viele Grüße

Raleigh

MojoeB

Zitat von Raleigh

Die bestimmten Ansagezeiten lauten beispielsweise 12:28, 12:58, dann weiter jede 30 Minuten. Zusätzlich noch die Uhrzeit 15:43 Uhr.

also nach start alle 30 min bis 15:43? oder wie?

hier habe mein Beispiel nochmal geändert, da siehst du wie man ohne den Start Parameter das Fenster kontrollieren kannst.

Das hier ausklammern :

_WD_CapabilitiesAdd('args', '--headless') ; Füge die Capability "args" mit dem Wert "--headless" hinzu, um den Browser im Headless-Modus zu starten

ansonsten habe dir zum testen hotkeys eingebaut da kannste sehen das show, hide, max, min kein Problem sind.

C

#include <wd_helper.au3>
#include <wd_capabilities.au3>
#include <Date.au3>

Global $oSession = ''
Global $capsi
Global $hWndBrowser
Global $endtime = '15:43:00'





HotKeySet("!t", "HotKeySayTime") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"
HotKeySet("{ESC}", "HotKeybeenden") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"

;beispiel wie du hide show min max richtig einsetzt.
HotKeySet("!h", "hide") ; Definiere den Hotkey "Alt + h" und verknüpfe ihn mit der Funktion "hide"
HotKeySet("!s", "show") ; Definiere den Hotkey "Alt + s" und verknüpfe ihn mit der Funktion "show"
HotKeySet("!m", "_MAXIMIZE") ; Definiere den Hotkey "Alt + m" und verknüpfe ihn mit der Funktion "_MAXIMIZE"
HotKeySet("!n", "_MINIMIZE") ; Definiere den Hotkey "Alt + n" und verknüpfe ihn mit der Funktion "_MINIMIZE"


AdlibRegister('Uhr_ansagen', 1800000);alle 30min wiederholen


start()


While 1
    Sleep(100)
    IF  _NowTime() = $endtime Then ; ist now = endtime dann:
        Uhr_ansagen();endzeit erreicht führe Uhr_ansagen aus 
        HotKeybeenden();beende den webdriver + beendet das script.
    EndIf
Wend


Func start()
    $capsi = SetupEdge()
    $oSession = _WD_CreateSession($capsi)
    
    Local $sLocalFilePath = @ScriptDir & '\talk.html'
    Local $sLocalFileURL = "file:///" & StringReplace($sLocalFilePath, "\", "/")

    _WD_Navigate($oSession, $sLocalFileURL)
     Local $sBrowserTitle = '' ; Titel des Browserfensters 
    $sBrowserTitle     = _WD_Action($oSession, 'TITLE', Default); $var füllen mit dem Browserfensters (für hide/show/max/min)
    $hWndBrowser = WinGetHandle($sBrowserTitle); Browserfensters gethandle, speichert das $hWndBrowser in einer globalen variable (für hide/show/max/min)
EndFunc   ;==>start



;beispiel wie du hide show min max richtig einsetzt.
func hide()    
    WinSetState($hWndBrowser, '', @SW_HIDE) 
EndFunc

func show()
    WinSetState($hWndBrowser, '', @SW_SHOW) 
EndFunc

func _MAXIMIZE()
    WinSetState($hWndBrowser, '', @SW_MAXIMIZE) 
EndFunc

func _MINIMIZE()
    WinSetState($hWndBrowser, '', @SW_MINIMIZE) 
EndFunc



Func Uhr_ansagen()
    Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
        _WD_ElementAction($oSession, $element, 'Click')
EndFunc   ;==>Uhr_ansagen

Func HotKeySayTime()
    Uhr_ansagen()
EndFunc   ;==>HotKeySayTime

Func HotKeybeenden()
_WD_DeleteSession($oSession)
    _WD_Shutdown()
    Exit 
EndFunc   ;==>HotKeybeenden

Func SetupEdge()
    _WD_UpdateDriver("msedge", @ScriptDir)

    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()

    ; Startparameter sammeln
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('args', 'guest')
    _WD_CapabilitiesDump(@ScriptLineNumber)
;~     _WD_CapabilitiesAdd('args', '--headless')
    Local $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10)
    WinSetState($hWnd, "", @SW_HIDE)
    Local $sCapabilities = _WD_CapabilitiesGet()
    Return $sCapabilities
EndFunc   ;==>SetupEdge

Alles anzeigen

Edit habe grad gesehen das ich vergessen habe die session zu löschen '_WD_DeleteSession($oSession)'

gehört noch rein

Raleigh

Zitat von MojoeB

also nach start alle 30 min bis 15:43? oder wie?

Wenn ich den PC einschalte, egal zu welcher Uhrzeit, möchte ich alle 30 Minuten die Zeit angesagt bekommen. Aber festgelegt auf ..:28 Uhr, ..:58 Uhr, .:28 Uhr ...........

Zusätzlich als eigene Ansage noch die Uhrzeit 15:43 Uhr. Das die Ansage im Hintergrund stattfindet wäre auch schön, weil das beim konzentrierten Schauen auf den Monitor nur stören würde.

Ich habe die 6 Dateien(usertesting.au3, wd_capabilities.au3, wd_cdp.au3, wd_core.au3, wd_demo.au3, wd_helper.au3) aus der au3WebDriver-1.0.3 in den Include Ordner(C:\Program Files (x86)\AutoIt3\Include) kopiert. Wenn ich dann beide Scripte teste kommt die Fehlermeldung:

Wie du oben schon geschrieben hast, liegen die Scripte zusammen mit der talk.html und die dazu gehörenden Dateien in einem Ordner.

Viele Grüße

Raleigh

**Moombas**

Prüfe bitte ob die angegebene JSON.au3 ebenfalls in dem entsprechenden Ordner liegt.

Diese wird von der wd_core.au3 benötigt., es könnten danach noch weitere folgen.

MojoeB

Raleigh

oh das hab ich bei mir nicht gemerkt da ich die json schon auf dem pc hatte hier findest du die json.au3 : A Non-Strict JSON UDF (JSMN) - AutoIt Example Scripts - AutoIt Forums (autoitscript.com)

Info für dich wenn du startetes mit : _WD_CapabilitiesAdd('args', '--headless')

dann sagt er sofort beim Start die Uhrzeit an, dann funktionieren aber die hide/show/max/mini Funktionen nicht mehr.

Wenn du ohne : _WD_CapabilitiesAdd('args', '--headless')

startest dann sagt er es nicht an. dann müsstest du am start noch mal die funktion uhrzeit_ansagen aufrufen.

Raleigh

Zitat von von Moombas

Prüfe bitte ob die angegebene JSON.au3 ebenfalls in dem entsprechenden Ordner liegt. Diese wird von der wd_core.au3 benötigt., es könnten danach noch weitere folgen.

Die wd_core.au3, WinHttpConstants.au3 und die WinHttp.au3 fehlten bei mir noch. Danke für die Info.

@MojoeB

Ich danke Dir nochmals für Deine große Mühe. Irgendetwas stimmt bei mir immer noch nicht. Ich bekomme eine neue Fehlermeldung. Über Suchmaschine bin ich leider nicht schlauer geworden.

Viele Grüße

Raleigh

MojoeB

hm... von wo hast du deine WinHttp.au3 ?

eigentlich ist das nur eine Funktion der die Version Nummer von winhttp.au3 zurückgibt.

(in winhttp.au3)

zeile *2401

Code

Func __WinHttpVer()

Return "1.6.4.1"

EndFunc

lad dir am besten die 1.6.4.1 runter und füge Sie deinem Includes Ordner hinzu.

Dann sollte es hoffentlich gehen.

eben mal geschaut : Releases · dragana-r/autoit-winhttp (github.com)

Raleigh

Jetzt nachdem ich die WinHttp.au3 getauscht habe läuft das Script einwandfrei. Nochmals vielen Dank. Selber hätte ich das so nie hinbekommen.

Ich trau mich gar nicht zu fragen. Ist der Aufwand sehr groß das Script noch so anzupassen, dass egal wann ich das Script starte, immer die Uhrzeitangabe ..:28 Uhr bzw. ..:58(alle 30Minuten) stattfindet? Jetzt ist es ja so das nach starten des Sriptes dann alle 30 Minuten die Ansage stattfindet. Ich weiß ich hab deine Geduld arg strapaziert. Ansonsten achte ich dann beim starten des Scriptes selber drauf. Ich bin ja froh überhaupt so weit mit deiner Hilfe gekommen zu sein.

Viele Grüße

Raleigh

MojoeB

alles gut^^ da finden wir bestimmt noch einen weg bin aber für heute erstmal raus

**Moombas**

Foilgendes ist ungeprüft:

Variante 1 (einfügen vor dem Adlibregister und start() danach entfernen):

AutoIt

start()
While 1
    sleep(1000); prüfen 1mal je Sekunde sollte reichen, sonst reduzieren
    If (StringSplit(_NowTime(), ':')[2] = '28') or _ ; prüfen ob 28 oder 58 min. erreicht wurden (einmalig)
       (StringSplit(_NowTime(), ':')[2] = '58') Then ;danach wäre Adlibregister mit alle 30minuten autom. immer auf 28/58 min.
        Uhr_ansagen();führe Uhr_ansagen aus 
        ExitLoop
    EndIf    
WEnd

Variante 2 (anstatt Adlib register und nach start() einfügen):

AutoIt

start()
While 1
    sleep(1000); prüfen 1mal je Sekunde sollte reichen, sonst reduzieren
    If (StringSplit(_NowTime(), ':')[2] = '28') or _ ; prüfen ob 28 oder 58 min. erreicht wurden
       (StringSplit(_NowTime(), ':')[2] = '58') Then
        Uhr_ansagen()                                ;führe Uhr_ansagen aus 
        sleep(60000)                                 ;warte 1 Minute, damit es nicht versehentlich mehrfach ausgeführt wird
    ElseIf _NowTime() = $endtime Then ; ist now = endtime dann:
        Uhr_ansagen()                                ;endzeit erreicht führe Uhr_ansagen aus 
        HotKeybeenden()                              ;beende den webdriver + beendet das script.
    EndIf   
WEnd

Alles anzeigen

Raleigh

Für meinen Einsatzzweck habe ich mich ja für die Variante mit -Headless entschieden. Leider musste ich doch feststellen das, wenn die Global $endtime = '14:30:00' Abfrage stattfindet, sich das Script beendet. Also, wenn ich das Script starte kommt die erste Zeitansage. Wenn dann die erste festgelegte Uhrzeit eintritt findet die nächste Ansage statt. Auch die 30 Minuten später wird angesagt.

Wenn aber zwischen diesen Ansagen die Global $endtime = '14:30:00' Abfrage stattfindet, beendet sich das Script. Also immer wenn die Global $endtime = '14:30:00' abgefragt wird. Wäre es vielleicht auch sinnvoll die Hotkey Funktionen rauszunehmen?

Da ich die Funktion nicht brauche kann man so das Script klein halten.

Moombas

Deswegen wundert es mich nicht, das wenn ich Variante 1 starte sich das Script nach der ersten festgelegten Ansage beendet.

Bei Variante 2 bekomme ich gar keine Ansage. Ich setze mal die bearbeiteten Scripte nochmal hier rein. Da habe ich bestimmt auch was falsch verstanden.

C: Variante 1

#include <wd_helper.au3>
#include <wd_capabilities.au3>
#include <Date.au3>

Global $oSession = ''
Global $capsi
Global $hWndBrowser
Global $endtime = '15:43:00'





HotKeySet("!t", "HotKeySayTime") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"
HotKeySet("{ESC}", "HotKeybeenden") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"

;beispiel wie du hide show min max richtig einsetzt.
HotKeySet("!h", "hide") ; Definiere den Hotkey "Alt + h" und verknüpfe ihn mit der Funktion "hide"
HotKeySet("!s", "show") ; Definiere den Hotkey "Alt + s" und verknüpfe ihn mit der Funktion "show"
HotKeySet("!m", "_MAXIMIZE") ; Definiere den Hotkey "Alt + m" und verknüpfe ihn mit der Funktion "_MAXIMIZE"
HotKeySet("!n", "_MINIMIZE") ; Definiere den Hotkey "Alt + n" und verknüpfe ihn mit der Funktion "_MINIMIZE"

start()
While 1
    sleep(1000); prüfen 1mal je Sekunde sollte reichen, sonst reduzieren
    If (StringSplit(_NowTime(), ':')[2] = '28') or _ ; prüfen ob 28 oder 58 min. erreicht wurden (einmalig)
       (StringSplit(_NowTime(), ':')[2] = '58') Then ;danach wäre Adlibregister mit alle 30minuten autom. immer auf 28/58 min.
        Uhr_ansagen();führe Uhr_ansagen aus 
        ExitLoop
    EndIf    
WEnd

AdlibRegister('Uhr_ansagen', 1800000);alle 30min wiederholen





Func start()
    $capsi = SetupEdge()
    $oSession = _WD_CreateSession($capsi)
    
    Local $sLocalFilePath = @ScriptDir & '\talk.html'
    Local $sLocalFileURL = "file:///" & StringReplace($sLocalFilePath, "\", "/")

    _WD_Navigate($oSession, $sLocalFileURL)
     Local $sBrowserTitle = '' ; Titel des Browserfensters 
    $sBrowserTitle     = _WD_Action($oSession, 'TITLE', Default); $var füllen mit dem Browserfensters (für hide/show/max/min)
    $hWndBrowser = WinGetHandle($sBrowserTitle); Browserfensters gethandle, speichert das $hWndBrowser in einer globalen variable (für hide/show/max/min)
EndFunc   ;==>start



;beispiel wie du hide show min max richtig einsetzt.
func hide()    
    WinSetState($hWndBrowser, '', @SW_HIDE) 
EndFunc

func show()
    WinSetState($hWndBrowser, '', @SW_SHOW) 
EndFunc

func _MAXIMIZE()
    WinSetState($hWndBrowser, '', @SW_MAXIMIZE) 
EndFunc

func _MINIMIZE()
    WinSetState($hWndBrowser, '', @SW_MINIMIZE) 
EndFunc



Func Uhr_ansagen()
    Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
        _WD_ElementAction($oSession, $element, 'Click')
EndFunc   ;==>Uhr_ansagen

Func HotKeySayTime()
    Uhr_ansagen()
EndFunc   ;==>HotKeySayTime

Func HotKeybeenden()
_WD_DeleteSession($oSession)
    _WD_Shutdown()
    Exit 
EndFunc   ;==>HotKeybeenden

Func SetupEdge()
    _WD_UpdateDriver("msedge", @ScriptDir)

    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()

    ; Startparameter sammeln
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('args', 'guest')
    _WD_CapabilitiesDump(@ScriptLineNumber)
     _WD_CapabilitiesAdd('args', '--headless')
    Local $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10)
    WinSetState($hWnd, "", @SW_HIDE)
    Local $sCapabilities = _WD_CapabilitiesGet()
    Return $sCapabilities
EndFunc   ;==>SetupEdge

Alles anzeigen

C: Variante 2

#include <wd_helper.au3>
#include <wd_capabilities.au3>
#include <Date.au3>

Global $oSession = ''
Global $capsi
Global $hWndBrowser
Global $endtime = '15:43:00'





HotKeySet("!t", "HotKeySayTime") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"
HotKeySet("{ESC}", "HotKeybeenden") ; Definiere den Hotkey "Alt + T" und verknüpfe ihn mit der Funktion "HotKeySayTime"

;beispiel wie du hide show min max richtig einsetzt.
HotKeySet("!h", "hide") ; Definiere den Hotkey "Alt + h" und verknüpfe ihn mit der Funktion "hide"
HotKeySet("!s", "show") ; Definiere den Hotkey "Alt + s" und verknüpfe ihn mit der Funktion "show"
HotKeySet("!m", "_MAXIMIZE") ; Definiere den Hotkey "Alt + m" und verknüpfe ihn mit der Funktion "_MAXIMIZE"
HotKeySet("!n", "_MINIMIZE") ; Definiere den Hotkey "Alt + n" und verknüpfe ihn mit der Funktion "_MINIMIZE"





start()


While 1
    Sleep(100)
    IF  _NowTime() = $endtime Then ; ist now = endtime dann:
        Uhr_ansagen();endzeit erreicht führe Uhr_ansagen aus 
        HotKeybeenden();beende den webdriver + beendet das script.
    EndIf
Wend

start()
While 1
    sleep(1000); prüfen 1mal je Sekunde sollte reichen, sonst reduzieren
    If (StringSplit(_NowTime(), ':')[2] = '28') or _ ; prüfen ob 28 oder 58 min. erreicht wurden
       (StringSplit(_NowTime(), ':')[2] = '58') Then
        Uhr_ansagen()                                ;führe Uhr_ansagen aus 
    ElseIf _NowTime() = $endtime Then ; ist now = endtime dann:
        Uhr_ansagen()                                ;endzeit erreicht führe Uhr_ansagen aus 
        HotKeybeenden()                              ;beende den webdriver + beendet das script.
    EndIf   
WEnd

Func start()
    $capsi = SetupEdge()
    $oSession = _WD_CreateSession($capsi)
    
    Local $sLocalFilePath = @ScriptDir & '\talk.html'
    Local $sLocalFileURL = "file:///" & StringReplace($sLocalFilePath, "\", "/")

    _WD_Navigate($oSession, $sLocalFileURL)
     Local $sBrowserTitle = '' ; Titel des Browserfensters 
    $sBrowserTitle     = _WD_Action($oSession, 'TITLE', Default); $var füllen mit dem Browserfensters (für hide/show/max/min)
    $hWndBrowser = WinGetHandle($sBrowserTitle); Browserfensters gethandle, speichert das $hWndBrowser in einer globalen variable (für hide/show/max/min)
EndFunc   ;==>start



;beispiel wie du hide show min max richtig einsetzt.
func hide()    
    WinSetState($hWndBrowser, '', @SW_HIDE) 
EndFunc

func show()
    WinSetState($hWndBrowser, '', @SW_SHOW) 
EndFunc

func _MAXIMIZE()
    WinSetState($hWndBrowser, '', @SW_MAXIMIZE) 
EndFunc

func _MINIMIZE()
    WinSetState($hWndBrowser, '', @SW_MINIMIZE) 
EndFunc



Func Uhr_ansagen()
    Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
        _WD_ElementAction($oSession, $element, 'Click')
EndFunc   ;==>Uhr_ansagen

Func HotKeySayTime()
    Uhr_ansagen()
EndFunc   ;==>HotKeySayTime

Func HotKeybeenden()
_WD_DeleteSession($oSession)
    _WD_Shutdown()
    Exit 
EndFunc   ;==>HotKeybeenden

Func SetupEdge()
    _WD_UpdateDriver("msedge", @ScriptDir)

    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()

    ; Startparameter sammeln
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('args', 'guest')
    _WD_CapabilitiesDump(@ScriptLineNumber)
     _WD_CapabilitiesAdd('args', '--headless')
    Local $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10)
    WinSetState($hWnd, "", @SW_HIDE)
    Local $sCapabilities = _WD_CapabilitiesGet()
    Return $sCapabilities
EndFunc   ;==>SetupEdge

Alles anzeigen

MojoeB

Moombas

Cool deine Variante habe ich auch noch nie so in den Code geschrieben, muss ich mir mal aneignen.

~~Ich versteh nicht warum AdlibRegister in die Mitte ?~~

WER LESEN KANN IST KLAR IM VORTEIL sry jetzt erst gecheckt.

Raleigh

Du kannst es einfacher machen ich teste es grad, natürlich mit anderen Zeiten.

So nun geändert :

AutoIt

#include <wd_helper.au3>
#include <wd_capabilities.au3>
#include <Date.au3>

Global $oSession = '', $capsi, $hWndBrowser, $iclick = 0, $end = 0
Global $endtime = '15:43:00', $itime_1 = '28', $itime_2 = '58', $itime_adl = 1800000

AdlibRegister('Adlib_ansage', $itime_adl)
start()

While 1
    Sleep(50) ;einfach um die prozessorlast unten zu halten.

    If $end = 1 Then
        beenden()
    EndIf

    If $iclick = 0 Then
        If _NowTime() = $endtime Then
            Uhr_ansagen()            
            Sleep(10000);es dauert etwas bis die Ansage anläuft deshalb hier nochmal schlafen.
            $end = 1
        ElseIf StringSplit(_NowTime(), ':')[2] = $itime_1 And StringSplit(_NowTime(), ':')[3] = '00' Then
            Uhr_ansagen()
            ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr ELSEIF ! 1!' & @CRLF)
        ElseIf StringSplit(_NowTime(), ':')[2] = $itime_2 And StringSplit(_NowTime(), ':')[3] = '00' Then
            Uhr_ansagen()
            ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr ELSEIF ! 2!' & @CRLF)
        EndIf
    ElseIf $iclick = 1 Then
        Sleep(1000) ;Schlaf ca. 1sec
        $iclick = 0
    EndIf
WEnd

Func start()
    $capsi = SetupEdge()
    $oSession = _WD_CreateSession($capsi)
    Local $sLocalFilePath = @ScriptDir & '\talk.html'
    Local $sLocalFileURL = "file:///" & StringReplace($sLocalFilePath, "\", "/")
    _WD_Navigate($oSession, $sLocalFileURL)
    Uhr_ansagen()
    ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr PER START!!!!' & @CRLF)
EndFunc   ;==>start

Func Adlib_ansage()
    Uhr_ansagen()
    ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr PER ADLIB!!!!' & @CRLF)
EndFunc   ;==>Adlib_ansage

Func Uhr_ansagen()
     
    Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
    _WD_ElementAction($oSession, $element, 'Click')
    $iclick = 1
EndFunc   ;==>Uhr_ansagen

Func beenden()
    _WD_DeleteSession($oSession)
    _WD_Shutdown()
    ConsoleWrite('Script wurde Erfolgreich beendet.' & @CRLF)
    Exit
EndFunc   ;==>beenden

Func SetupEdge()
    _WD_UpdateDriver("msedge", @ScriptDir)
    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()
    ; Startparameter sammeln
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('args', 'guest')
    _WD_CapabilitiesDump(@ScriptLineNumber)
    _WD_CapabilitiesAdd('args', '--headless')
    Local $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10)
    WinSetState($hWnd, "", @SW_HIDE)
    Local $sCapabilities = _WD_CapabilitiesGet()
    Return $sCapabilities
EndFunc   ;==>SetupEdge

Alles anzeigen

Raleigh

Ich hab eine schlechte Nachricht. Sobald die festgelegte Uhrzeit(15:43 Uhr) abgefragt wird, beendet sich das Script immer noch. Im Taskmanager sind der Webdriver und die 6 Edge Tasks dann beendet worden.

Es gibt aber auch eine positive Nachricht. Wenn ich die Zeile "$end = 1"(Zeile 22) lösche funktioniert die Abfrage für die festgelegte Zeit und auch die 30 Minutenabfrage. Nur der Webdriver und die 6 Edge Tasks laufen im Tasmanager weiter. Auch wenn ich das Script manuell schließe. Ich häng das Script so wie es bei mir läuft nochmal hier rein.

C

#include <wd_helper.au3>
#include <wd_capabilities.au3>
#include <Date.au3>

Global $oSession = '', $capsi, $hWndBrowser, $iclick = 0, $end = 0
Global $endtime = '22:08:00', $itime_1 = '06', $itime_2 = '10', $itime_adl = 1800000

AdlibRegister('Adlib_ansage', $itime_adl)
start()

While 1
    Sleep(50) ;einfach um die prozessorlast unten zu halten.

    If $end = 1 Then
        beenden()
    EndIf

    If $iclick = 0 Then
        If _NowTime() = $endtime Then
            Uhr_ansagen()            
            Sleep(10000);es dauert etwas bis die Ansage anläuft deshalb hier nochmal schlafen.
;            $end = 1 
        ElseIf StringSplit(_NowTime(), ':')[2] = $itime_1 And StringSplit(_NowTime(), ':')[3] = '00' Then
            Uhr_ansagen()
            ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr ELSEIF ! 1!' & @CRLF)
        ElseIf StringSplit(_NowTime(), ':')[2] = $itime_2 And StringSplit(_NowTime(), ':')[3] = '00' Then
            Uhr_ansagen()
            ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr ELSEIF ! 2!' & @CRLF)
        EndIf
    ElseIf $iclick = 1 Then
        Sleep(1000) ;Schlaf ca. 1sec
        $iclick = 0
    EndIf
WEnd

Func start()
    $capsi = SetupEdge()
    $oSession = _WD_CreateSession($capsi)
    Local $sLocalFilePath = @ScriptDir & '\talk.html'
    Local $sLocalFileURL = "file:///" & StringReplace($sLocalFilePath, "\", "/")
    _WD_Navigate($oSession, $sLocalFileURL)
    Uhr_ansagen()
    ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr PER START!!!!' & @CRLF)
EndFunc   ;==>start

Func Adlib_ansage()
    Uhr_ansagen()
    ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr PER ADLIB!!!!' & @CRLF)
EndFunc   ;==>Adlib_ansage

Func Uhr_ansagen()
     
    Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
    _WD_ElementAction($oSession, $element, 'Click')
    $iclick = 1
EndFunc   ;==>Uhr_ansagen

Func beenden()
    _WD_DeleteSession($oSession)
    _WD_Shutdown()
    ConsoleWrite('Script wurde Erfolgreich beendet.' & @CRLF)
    Exit
EndFunc   ;==>beenden

Func SetupEdge()
    _WD_UpdateDriver("msedge", @ScriptDir)
    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()
    ; Startparameter sammeln
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('args', 'guest')
    _WD_CapabilitiesDump(@ScriptLineNumber)
    _WD_CapabilitiesAdd('args', '--headless')
    Local $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10)
    WinSetState($hWnd, "", @SW_HIDE)
    Local $sCapabilities = _WD_CapabilitiesGet()
    Return $sCapabilities
EndFunc   ;==>SetupEdge

Alles anzeigen

MojoeB

natürlich beendet sich das Skript dann

Es funktioniert so wie ich es verstanden habe.

wie möchtest du das Skript den beenden, wenn es kein Befehl dafür geben würde?

In diesem fall bau dir ESC oder etwas anderes als HOTKEY ein damit du das Skript auch beenden kannst, das Skript braucht die anweißung Session und Webdriver zu schließen, ohne das bleibt das natürlich im Taskmgr.

so in deinem beispiel ist

$endtime = '22:08:00' = Uhrzeit ansagen + BEENDEN

was willst du den abfrage $endzeit eigentlich erreichen?

Entweder soll es weiterlaufen oder beendet werden es macht für mich kein sinn was du da angemerkt hast. Aber ist ja nicht schlimm.

Code

HotKeySet("{ESC}", "beenden");(kannst natürlich eine eigne Tastenkombi raussuchen) um das Skript händisch zu beenden.


Func beenden()
_WD_DeleteSession($oSession)
_WD_Shutdown()
ConsoleWrite('Script wurde Erfolgreich beendet.' & @CRLF)
Exit
EndFunc ;==>beenden

dann kannst Zeilen 22, 21, 16 bis 14 löschen & natürlich, Global $end = 0 kannste auch löschen.

**Moombas**

Hier mal dein Script leicht abgeänder und ich sehe das wie Mojo bzgl. beenden (Änderungen: Siehe Kommentare):

AutoIt

Opt('MustDeclareVars', 1)
#include <wd_helper.au3>
#include <wd_capabilities.au3>
#include <Date.au3>

;Hotkey eingebaut zum beenden des Programms, da aktuell keine Bedingung zum Beenden vorhanden ist.
HotKeySet("{ESC}", "beenden")

;Unbenötigte Variablen entfernt, anstatt auf 0 oder 1 zu prüfen, true und false genutzt, endtime als Name irreführend, daher umbenannt
Global $oSession, $iclick = False
Global Const $specialtime = '22:08:00', $itime_1 = '06', $itime_2 = '10', $itime_adl = 1800000

start() ;Auch wenn bei 30min warten unwahrscheinlich ist das PRobleme auftreten, sollte der WD gestartet werden bevor "Adlib_ansage" durch Adlibregister ausgfeührt werden könnte. Daher Reihenfolge getauscht
AdlibRegister('Adlib_ansage', $itime_adl)

While 1 ;die Prüfung auf $end machte keinen Sinn, die Funktion beenden() einfach dort aufrufen wo sie benötigt wird (aktuell nicht genutzt)
    Sleep(50) ;einfach um die prozessorlast unten zu halten.

    If not $iclick Then
        If _NowTime() = $specialtime Then
            Uhr_ansagen()
            Sleep(10000);es dauert etwas bis die Ansage anläuft deshalb hier nochmal schlafen.
;           Exitloop
        ElseIf StringSplit(_NowTime(), ':')[2] = $itime_1 And StringSplit(_NowTime(), ':')[3] = '00' Then
            Uhr_ansagen()
            ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr ELSEIF ! 1!' & @CRLF)
        ElseIf StringSplit(_NowTime(), ':')[2] = $itime_2 And StringSplit(_NowTime(), ':')[3] = '00' Then
            Uhr_ansagen()
            ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr ELSEIF ! 2!' & @CRLF)
        EndIf
    ElseIf $iclick Then
        Sleep(1000) ;Schlaf ca. 1sec
        $iclick = False
    EndIf
WEnd
beenden()

;Variablen umsortiert (Deklarationen mittem im Code sind unschön) und eine Lokal gesetzt da außerhalb nicht genutzt
Func start()
Local Const $sLocalFilePath = @ScriptDir & '\talk.html'
Local Const $sLocalFileURL  = "file:///" & StringReplace($sLocalFilePath, "\", "/")
Local $capsi = SetupEdge()
    $oSession = _WD_CreateSession($capsi)
    _WD_Navigate($oSession, $sLocalFileURL)
    Uhr_ansagen()
    ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr PER START!!!!' & @CRLF)
EndFunc   ;==>start

Func Adlib_ansage()
    Uhr_ansagen()
    ConsoleWrite('ANSAGE : ' & _NowTime() & 'Uhr PER ADLIB!!!!' & @CRLF)
EndFunc   ;==>Adlib_ansage

Func Uhr_ansagen()
Local $element = _WD_FindElement($oSession, 'xpath', '//*[@id="clockID"]')
    _WD_ElementAction($oSession, $element, 'Click')
    $iclick = True
EndFunc   ;==>Uhr_ansagen

Func beenden()
    _WD_DeleteSession($oSession)
    _WD_Shutdown()
    ConsoleWrite('Script wurde Erfolgreich beendet.' & @CRLF)
    Exit
EndFunc   ;==>beenden

;Variablen umsortiert (Deklarationen mittem im Code sind unschön) und eine entfernt, da direkt über Return zurück gegeben werden kann
Func SetupEdge()
Local $hWnd
    _WD_UpdateDriver("msedge", @ScriptDir)
    _WD_Option('Driver', @ScriptDir & '\msedgedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()
    ; Startparameter sammeln
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'msedge')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('args', 'guest')
    _WD_CapabilitiesDump(@ScriptLineNumber)
    _WD_CapabilitiesAdd('args', '--headless')
    $hWnd = WinWait("[CLASS:ConsoleWindowClass]", "", 10)
    WinSetState($hWnd, "", @SW_HIDE)
    Return _WD_CapabilitiesGet()
EndFunc   ;==>SetupEdge

Alles anzeigen

Velted

Moin,

hier mal meine Idee zur Kernschleife, weil das Skript nur diese eine Aufgabe hat ohne AdlibRegister(). Anstelle der Funktionen aus der Date,au3 werden die Zeit-Makros genutzt.

AutoIt

Global Const $sMin1 = "28", $sMin2 = "58", $sMin3 = "43", $sStd3 = "15"
Global $sStd, $sMin

start()
; AdlibRegister('Adlib_ansage', $itime_adl) <<<<< wird nicht gebraucht

While True
    $sMin = @MIN  ; für den sehr unwahrscheinlichen Fall, dass sich die Werte während der folgenden Abfrage ändern
    $sStd = @HOUR ; für den sehr unwahrscheinlichen Fall, dass sich die Werte während der folgenden Abfrage ändern
    If ($sMin = $sMin1) Or ($sMin = $sMin2) Or (($sStd = $sStd3) And ($sMin = $sMin3)) Then
        Uhr_ansagen()
        ConsoleWrite("ANSAGE : " & $sStd & ":" & $sMin & " Uhr!" &@CRLF) ; wenn gewollt
        While (@MIN = $sMin)
            Sleep(1000) ; bis zur nächsten Minute schlafen
        WEnd
    Else
        Sleep(1000) ; um die Prozessorlast unten zu halten
    EndIf
WEnd

Alles anzeigen

Raleigh

Dann muss ich mich wohl falsch ausgedrükt haben. Das Script soll so lange die 30 Minuten Abfrage stellen, so lang der PC auch eingeschaltet ist. Die festgelegte Uhrzeit(bsw. 15:43 Uhr) findet einmal statt und danach soll natürlich auch die 30 Minuten Abfrage weiterhin stattfinden.

Das letzte Script mit Hotkey von @Moombas erfüllt jetzt alle Vorgaben. Die festgellegte Zeit, die 30 Minuten Abfragen und die Hotkey Funktion funktionieren. Wenn ich dann der Meinung bin doch die Abfragen zu beenden, brauch ich ja nur per Hotkey das Script beenden. So erfüllt das Script alle meine Wünsche. Es gibt also keinen Grund mehr eure Geduld weiterhin zu strapazieren. Daher nochmals einen großen Dank an alle.

Viele Grüße

Raleigh