markierte Vorkommnisse von Buchstabefolge markieren

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiEdit.au3>
#include <GuiRichEdit.au3>
#include <WinAPISys.au3>

Global Const $sText = '' & _
    'Mein Text im Textfeld (Edit/Imput ist sehr sehr lang. ' & _
    'Wenn ich jetzt die Buchstabefolge "eier" mit der Mause markiere, ' & _
    'soll mir alles markeirert werden, wo "eier" in dem Textfeld steht. ' & _
    'Feierabend, Geier, Leierkasten/Laierkasten, Feierabendwein, Eiermann, ....'
Global $iStyle = BitOr($ES_MULTILINE, $ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL, $WS_BORDER)

$Gui = GUICreate("RichEdit", 800, 435, -1, 100)
$hRichEdit = _GUICtrlRichEdit_Create($Gui, "", 10, 10, 780, 380, $iStyle)
; Dem Control wird automatisch der ExStyle WS_EX_CLIENTEDGE (0x00000200) zugewiesen.
; Das ergibt einen 'klassischen' Win 3.11 Rahmen.
; Ohne ExStyle aber mit WS_BORDER sieht das Control deutlich moderner aus.
_WinAPI_SetWindowLong($hRichEdit, $GWL_EXSTYLE, 0)
_GUICtrlRichEdit_SetDefaultFont($hRichEdit, 12, "Segoe UI")
_GUICtrlRichEdit_SetText($hRichEdit, $sText)
$idMark  = GUICtrlCreateButton("Markieren", 10, 400, 200, 25)
$idReset = GUICtrlCreateButton("Zurücksetzen", 590, 400, 200, 25)
GUISetState()

;~ $iStyle = _WinAPI_GetWindowLong($hRichEdit, $GWL_STYLE)
;~ $iExStyle = _WinAPI_GetWindowLong($hRichEdit, $GWL_EXSTYLE)
;~ MsgBox(0, "Styles", Hex($iStyle) & " - " & Hex($iExStyle))

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $idMark
            _GUICtrlRichEdit_PauseRedraw($hRichEdit)
            _MarkSelected($hRichEdit)
            _GUICtrlRichEdit_ResumeRedraw($hRichEdit)
        Case $idReset
            _GUICtrlRichEdit_PauseRedraw($hRichEdit)
            _ResetMarked($hRichEdit)
            _GUICtrlRichEdit_ResumeRedraw($hRichEdit)
    EndSwitch
WEnd

Func _MarkSelected($hRE, $bMatchCase = False)
    Local $aSel = _GUICtrlRichEdit_GetSel($hRE)
    If $aSel[0] = $aSel[1] Then Return
    Local $sSel = _GUICtrlRichEdit_GetSelText($hRE)
    ; If StringLen($sSel) < 4 Then Return ; eine Mindestlänge könnte sinnvoll sein
    Local $aPos, $iStart = 0, $iEnd = -1
    While True
        $aPos = _GUICtrlRichEdit_FindTextInRange($hRE, $sSel, $iStart, $iEnd, $bMatchCase)
        If $aPos[0] = -1 And $aPos[1] = -1 Then ExitLoop
        _GUICtrlRichEdit_SetSel($hRE, $aPos[0], $aPos[1], True)
        _GUICtrlRichEdit_SetCharColor($hRE, 0xFF0000) ; !! BGR !!
        _GUICtrlRichEdit_SetCharAttributes($hRE, "+bo")
        $iStart = $aPos[1] + 1
    WEnd
    _GUICtrlRichEdit_SetSel($hRichEdit, $aSel[0], $aSel[1])
EndFunc

Func _ResetMarked($hRE)
    Local $aSel = _GUICtrlRichEdit_GetSel($hRE)
    _GUICtrlRichEdit_SetSel($hRE, 0, -1, True)
    _GUICtrlRichEdit_SetCharColor($hRE)
    _GUICtrlRichEdit_SetCharAttributes($hRE, "-bo")
    _GUICtrlRichEdit_SetSel($hRE, $aSel[0], $aSel[1])
EndFunc

; #FUNCTION# ====================================================================================================================
; Author ........: Chris Haslam (c.haslam) : _GUICtrlRichEdit_SetFont
; Modified.......: Velted (www.autoit.de)
; ===============================================================================================================================
Func _GUICtrlRichEdit_SetDefaultFont($hWnd, $iPoints = Default, $sName = Default, $iCharset = Default, $iLcid = Default)
    ; MSDN does not give a mask (CFM) for bPitchAndFamily so it appears that it cannot be set => omitted here
    Local $iDwMask = 0

    If Not _WinAPI_IsClassName($hWnd, $__g_sRTFClassName) Then Return SetError(101, 0, False)
    If Not ($iPoints = Default Or __GCR_IsNumeric($iPoints, ">0")) Then Return SetError(102, 0, False)
    If $sName <> Default Then
        Local $aS = StringSplit($sName, " ")
        For $i = 1 To UBound($aS) - 1
            If Not StringIsAlpha($aS[$i]) Then Return SetError(103, 0, False)
        Next
    EndIf
    If Not ($iCharset = Default Or __GCR_IsNumeric($iCharset)) Then Return SetError(104, 0, False)
    If Not ($iLcid = Default Or __GCR_IsNumeric($iLcid)) Then Return SetError(105, 0, False)

    Local $tCharFormat = DllStructCreate($tagCHARFORMAT2)
    DllStructSetData($tCharFormat, 1, DllStructGetSize($tCharFormat))

    If $iPoints <> Default Then
        $iDwMask = $CFM_SIZE
        DllStructSetData($tCharFormat, 4, Int($iPoints * 20))
    EndIf
    If $sName <> Default Then
        If StringLen($sName) > $LF_FACESIZE - 1 Then SetError(-1, 0, False)
        $iDwMask = BitOR($iDwMask, $CFM_FACE)
        DllStructSetData($tCharFormat, 9, $sName)
    EndIf
    If $iCharset <> Default Then
        $iDwMask = BitOR($iDwMask, $CFM_CHARSET)
        DllStructSetData($tCharFormat, 7, $iCharset)
    EndIf
    If $iLcid <> Default Then
        $iDwMask = BitOR($iDwMask, $CFM_LCID)
        DllStructSetData($tCharFormat, 13, $iLcid)
    EndIf
    DllStructSetData($tCharFormat, 2, $iDwMask)

    Local $iRet = _SendMessage($hWnd, $EM_SETCHARFORMAT, $SCF_DEFAULT, $tCharFormat, 0, "wparam", "struct*")
    If Not $iRet Then Return SetError(@error + 200, 0, False)
    Return True
EndFunc   ;==>_GUICtrlRichEdit_SetDefaultFont