Access UDF -Spaltennamen in Array

gmmg

Hallo Zusammen,

in der aktuellen Access UDF ist es nicht möglich die Spaltennamen auslesen und im Array mit den Werten Zusammen zu haben.

Es gab von mir da schon mal eine Anfrage, diese konnte damals mit der Hilfe einfach gelöst werden.

Hier mal das alte Thema dazu.

MS Access Read Field + Spaltennamen der Tabellen (Im Beispiel von Musashi ist die Access zum testen angehangen)

Wie im Beispiel werden 2 Arrays erstellt. eines mit Spaltennamen und eines mit den Werten.

Wie kann ich diese nun Zusammenbringen? Irgendwie sehe ich da gerade nicht durch

Code

#include <Array.au3>
Global $oConnection, $aRecordSet, $sQuery, $aRecordSetArr, $aColumnArr[0]
Global $sTableName    =  "tblTable1"
Global $sDatabaseName = "D:\Test-mdb\Test.mdb"
If Not FileExists($sDatabaseName) Then Exit
$oConnection   = ObjCreate("ADODB.Connection")
$oConnection.Open("Driver=Microsoft Access Driver (*.mdb); DBQ=" & $sDatabaseName)
$oRecordSet    = ObjCreate("ADODB.RecordSet")
$sQuery        = "Select * From " & $sTableName
$oRecordSet.Open($sQuery, $oConnection)
For $i = 0 to $oRecordSet.Fields.Count - 1
    _ArrayAdd($aColumnArr, $oRecordSet.Fields.Item($i).Name)
Next
$aRecordSetArr = $oRecordSet.GetRows
$oRecordSet.Close()
$oConnection.Close()
_ArrayDisplay($aColumnArr, 'Spaltennamen')
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName)

Alles anzeigen

Danke

Gruß gmmg

**Moombas**

Wenn es nur im ArrayDisplay angezeigt werden soll, ersetze Spalte 17 & 18 (ungetestet):

AutoIt

$Spalten = ''
For $Row = 0 to Ubound($aColumnArr)
	$Spalten &= $aColumnArr[$Row] & '|'
Next
$Spalten = StringTrimRight($Spalten, 1)
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName, Default, Default, Default, $Spalten)

Edit:

Willst du Die Überschriften direkt auch im Array haben:

AutoIt

$Spalten = ''
For $Row = 0 to Ubound($aColumnArr)
	$Spalten &= $aColumnArr[$Row] & '|'
Next
$Spalten = StringTrimRight($Spalten, 1)
_ArrayAdd($aRecordSetArr, $Spalten, 0)
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName)

Aber alles ungeprüft.

**Moombas**

Bzw. $Spalten kannst du in Zeile 11-13 halt wie gezeigt zusammen bauen und dann entsprehend einfügen (entweder für das Arraydisplay oder als extra Zeile im Array).

gmmg

Moombas die Spaltennamen benötige ich im Array, damit ich die Spalte dann später mit Arraysearch ausauslesen kann bzw. dessen Wert.

Da sich die Spaltennamen in der Position immer mal verschieben können.

Gruß gmmg

**Moombas**

Hab das ja oben als 2. Part hinzugefügt als weitere Möglichkeit.

Hier mal zusammengefasst (ohne Gewähr):

AutoIt

#include <Array.au3>
Global $oConnection, $aRecordSet, $sQuery, $aRecordSetArr, $Spalten
Global $sTableName    =  "tblTable1"
Global $sDatabaseName = "D:\Test-mdb\Test.mdb"
If Not FileExists($sDatabaseName) Then Exit
$oConnection   = ObjCreate("ADODB.Connection")
$oConnection.Open("Driver=Microsoft Access Driver (*.mdb); DBQ=" & $sDatabaseName)
$oRecordSet    = ObjCreate("ADODB.RecordSet")
$sQuery        = "Select * From " & $sTableName
$oRecordSet.Open($sQuery, $oConnection)
For $i = 0 to $oRecordSet.Fields.Count - 1
	$Spalten &= $oRecordSet.Fields.Item($i).Name & '|'
Next
$Spalten = StringTrimRight($Spalten, 1)
$aRecordSetArr = $oRecordSet.GetRows
_ArrayAdd($aRecordSetArr, $Spalten, 0)
$oRecordSet.Close()
$oConnection.Close()
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName)

Alles anzeigen

gmmg

Habe es noch nicht hinbekommen.

AutoIt

#include <Array.au3>
Global $oConnection, $aRecordSet, $sQuery, $aRecordSetArr, $aColumnArr[0], $Spalten
Global $sTableName    =  "tblTable1"
Global $sDatabaseName = "D:\Test-mdb\Test.mdb"
If Not FileExists($sDatabaseName) Then Exit
$oConnection   = ObjCreate("ADODB.Connection")
$oConnection.Open("Driver=Microsoft Access Driver (*.mdb); DBQ=" & $sDatabaseName)
$oRecordSet    = ObjCreate("ADODB.RecordSet")
$sQuery        = "Select * From " & $sTableName
$oRecordSet.Open($sQuery, $oConnection)

;~ For $i = 0 to $oRecordSet.Fields.Count - 1
;~     _ArrayAdd($aColumnArr, $oRecordSet.Fields.Item($i).Name)
;~ Next

For $i = 0 to $oRecordSet.Fields.Count - 1
    ;_ArrayAdd($aColumnArr, $oRecordSet.Fields.Item($i).Name)
	$Spalten &= $oRecordSet.Fields.Item($i).Name & '|'
Next

MsgBox(0,"",$Spalten)

;~ For $Row = 0 to Ubound($aColumnArr) -1
;~ 	$Spalten &= $aColumnArr[$Row] & '|'
;~ Next


$Spalten = StringTrimRight($Spalten, 1)
_ArrayAdd($aRecordSetArr, $Spalten, 0)
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName)

$aRecordSetArr = $oRecordSet.GetRows
$oRecordSet.Close()
$oConnection.Close()
_ArrayDisplay($aColumnArr, 'Spaltennamen')
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName)

Alles anzeigen

gmmg

Dein angepasstes geht soweit. muss mal schauen ob die werte damit dann beim auslesen passen.

Danke

Gruß gmmg

gmmg

Habe das jetzt mal in meine Access UDF übertragen.

Danke nochmal an Moombas für den Input

_Get_Records with Column Names

AutoIt

#Region _Get_Records with Column Names
; #FUNCTION# ====================================================================================================================
; Name ..........: _Get_Records
; Description ...: This function will collect data from an access database and give it as an array.
; Syntax ........: _Get_Records($sSQLstring)
; Parameters ....: $sSQLstring          - SQL Statement for creating table.
; Return values .: If success, then it will return the data as an array. If any errors see this list
;					Return -1 - Connection error
;					Return -2 - Recordset error
;					Return -3 - No data in that table
; Author ........: kcvinu
; Modified ......: sep 2015
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: _Get_Records("SELECT [Column1],[Column2] FROM MyTable WHERE Column3 = '2500' ;") ; See the single quote.
; ===============================================================================================================================
Func _Get_Records($sSQLstring)
    If Not IsObj($objConnection) Then Return -1
    If Not IsObj($objRecordSet) Then Return -2
    _Open_Recordset($sSQLstring)
    If Not $objRecordSet.RecordCount Or ($objRecordSet.EOF = True) Then Return -3
    Dim $arrRecords, $column_name

    If Not @error Then
		;Local $header[$objRecordSet.Fields.Count], $rows

		For $i = 0 To $objRecordSet.Fields.Count - 1
			$column_name &= $objRecordSet.Fields($i).Name & "|"
        Next

		;MsgBox(0,"", $column_name)

		$column_name = StringTrimRight($column_name, 1)
		$arrRecords = $objRecordSet.GetRows()

		_ArrayInsert($arrRecords, 0, $column_name)

	EndIf

	_Close_RecordSet()
    Return $arrRecords

EndFunc
#EndRegion

Alles anzeigen

**Moombas**

Hmm, aber eigentlich gehören die Spaltenüberschriften ja nach oben.

Das Wollte ich eigentlich mit der Angabe der 0 in ArrayInsert erreichen, sehe aber Gerade das ich lt. Doku einen Fehler gemacht habe ("$vRange can be a string containing the rows above which a row is to to be inserted. ").
Ersetze die 0 mal mit einer 1 und teste erneut.

gmmg

Hallo Moombas,

habe das jetzt wie in Post #8 im Einsatz.

Gruß gmmg

**Moombas**

Das habe ich schon verstanden aber sind die Spaltenüberschriften, nicht im Array wie im Screenshot von Post #7 gmmg ?

Das wäre ja blöd, diese immer unten zu haben, daher mein Vorschlag in Zeile 37 die 0 durch eine 1 zu ersetzen, dann müssten die Spaltenüberschriften oben stehen.

gmmg

Also mit _ArrayAdd hat es bei mir nicht funktioniert.

Hatte dann _ArrayInsert benutzt. Ergebnis siehe Bild.

AutoIt

#include <Array.au3>
Global $oConnection, $aRecordSet, $sQuery, $aRecordSetArr, $Spalten
Global $sTableName    =  "tblTable1"
Global $sDatabaseName = "D:\Test-mdb\Test.mdb"
If Not FileExists($sDatabaseName) Then Exit
$oConnection   = ObjCreate("ADODB.Connection")
$oConnection.Open("Driver=Microsoft Access Driver (*.mdb); DBQ=" & $sDatabaseName)
$oRecordSet    = ObjCreate("ADODB.RecordSet")
$sQuery        = "Select * From " & $sTableName
$oRecordSet.Open($sQuery, $oConnection)
For $i = 0 to $oRecordSet.Fields.Count - 1
	$Spalten &= $oRecordSet.Fields.Item($i).Name & '|'
Next
$Spalten = StringTrimRight($Spalten, 1)
$aRecordSetArr = $oRecordSet.GetRows
;_ArrayAdd($aRecordSetArr, $Spalten, 0)
_ArrayInsert($aRecordSetArr, 0, $Spalten)
$oRecordSet.Close()
$oConnection.Close()
_ArrayDisplay($aRecordSetArr, 'Tabelle = ' & $sTableName)

Alles anzeigen

**Moombas**

Ehm, ich glaube ich habe da was zusammengewürfelt XD du hast recht, ArrayInsert() zu nutzen^^

Ich glaube ich brauche wieder Urlaub