Transparente GUI mit Memofunktion

casi4712

Hallo allerseits,

ich bräuchte mal die freundlcihe Unterstützung unserer GUI xperten. Ich habe eine transparente Eingabe GUI erstellt, die beim Verschieben die Position speichert. Soweit so gut. Bei ersten öffnen soll die GUI aber (also wenn noch keine INI Datei existiert relativ am unteren Bildschirmrand mittig sein, irgendwi3 klappt das noch nicht. Vielleicht sieht ja jemand den Fehler.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
#include <sendmessage.au3>
#include <GuiConstants.au3>
#NoTrayIcon
HotKeySet("ESC", "_Exit")

Global $ConfigFile = StringTrimRight(@ScriptFullPath, 3) & "ini"


;Create GUI
$GUI = GUICreate("Test", 400, 40, 600, 40, $WS_POPUP, $WS_EX_LAYERED)
	 if not FileExists($ConfigFile) Then ;kein configfile
	  _StandardPos()
	 endif
 
 _GUIRestorePositions($GUI, $ConfigFile)
GUISetBkColor(0xABCDEF)

;Create Boxes
Local $cmb01 = GUICtrlCreateCombo('', 10, 10, 150, 20)
Local $cmb02 = GUICtrlCreateCombo('', 170, 10, 50, 20)
Local $cmb03 = GUICtrlCreateCombo('', 230, 10, 50, 20)
Local $cmb04 = GUICtrlCreateCombo('', 290, 10, 200, 20)

_WinAPI_SetLayeredWindowAttributes($GUI, 0xABCDEF, 250)
GUISetState()

While 1
    Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_GUISavePositions($GUI, $ConfigFile)
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($GUI, $WM_SYSCOMMAND, 0xF012, 0)
    EndSwitch
WEnd

Func _Exit()
    Exit
EndFunc


Func _GUISavePositions($hGUI, $sConfigFile, $sSectName="Window Positions")
    Local $aGUI_Pos = WinGetPos($hGUI)
    If @error Then Return 0

		IniWrite($sConfigFile, $sSectName, "Left", $aGUI_Pos[0])
		IniWrite($sConfigFile, $sSectName, "Top", $aGUI_Pos[1])
		IniWrite($sConfigFile, $sSectName, "Width", $aGUI_Pos[2])
		IniWrite($sConfigFile, $sSectName, "Height", $aGUI_Pos[3])

    Return 1
EndFunc

Func _GUIRestorePositions($hGUI, $sConfigFile, $sSectName="Window Positions", $iDefWidth=700, $iDefHeight=40)
    Local $iGUI_Left = IniRead($sConfigFile, $sSectName, "Left", -1)
    Local $iGUI_Top = IniRead($sConfigFile, $sSectName, "Top", -1)
    Local $iGUI_Width = IniRead($sConfigFile, $sSectName, "Width", $iDefWidth)
    Local $iGUI_Height = IniRead($sConfigFile, $sSectName, "Height", $iDefHeight)

    If $iGUI_Left = -1 Then $iGUI_Left = (@DesktopWidth / 2) - ($iGUI_Width / 2)
    If $iGUI_Top = -1 Then $iGUI_Top = (@DesktopHeight / 2) - ($iGUI_Height / 2)

   Return WinMove($hGUI, "", $iGUI_Left, $iGUI_Top, $iGUI_Width, $iGUI_Height)
EndFunc


Func _StandardPos()
; Get screen dimensions
Local $iScreenWidth = @DesktopWidth
Local $iScreenHeight = @DesktopHeight

;Calculate window position (centered horizontally, positioned from the bottom)
Local $iWindowWidth = 800
Local $iWindowHeight = 40
Local $iWindowX = ($iScreenWidth - $iWindowWidth) / 2
Local $iWindowY = $iScreenHeight - $iWindowHeight - 3; Adjust 50 to change the gap from the bottom
EndFunc

Alles anzeigen

Danjke schon mal

lg und ein frohes Fest

Velted

Moin,

Deine Funktion _StandardPos versorgt ausschließlich lokale Variable, die außerhalb der Funktion nicht sichtbar sind. Das macht keinen Sinn, wenn Du sie nicht innerhalb der Funktion für ein WinMove benutzt (wie bei _GUIRestorePositions).

Außerdem wird nach der Funktion unbedingt immer _GUIRestorePositions aufgerufen. Das macht auch keinen Sinn, wenn es die Datei nicht gibt und man nicht die gewünschten Defaultwerte vorgibt.

Frohes Fest!

casi4712

ok danke,

Zu Punkt 1, Du meinst wirklich ich kann dass Winmove mit meiner GUIRestore Function verbinden?

Zum zweiten Punkt, ist schon klar, da müsste ne Bedingung rein, irgendwie hatte ich da auch erst eine, das hatte ihn nicht interessiert, ist hier wohl im meinem Post wieder verschwunden.

lg und Danke

casi4712

Komisch, hab es eben noch mal bisl umgestelt, dachte so hätte ich es gestern schon gehabt, nun funktionierts. Vielleicht sollte ich damit aufhören soetwas um 2Uhr in der Nacht anzufangen lach.

AutoIt

#include <WindowsConstants.au3>
#include <sendmessage.au3>
#include <GuiConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <Excel.au3>
#include <array.au3>
#include <GuiComboBox.au3>
#include <FileConstants.au3>
#include <File.au3>
#include <WinAPI.au3>
#NoTrayIcon
HotKeySet("ESC", "_Exit")

Global $siniFile = StringTrimRight(@AppDataDir, 3) & "ini"

; Create GUI
$GUI = GUICreate("Test", 400, 40, 600, 40, $WS_POPUP, $WS_EX_LAYERED)
if not FileExists($siniFile) Then
    _StandardPos()
endif

_GUIRestorePositions($GUI, $siniFile)
GUISetBkColor(0xABCDEF)

; Create Boxes
Local $cmb01 = GUICtrlCreateCombo('', 10, 10, 150, 20)
Local $cmb02 = GUICtrlCreateCombo('', 170, 10, 50, 20)
Local $cmb03 = GUICtrlCreateCombo('', 230, 10, 50, 20)
Local $cmb04 = GUICtrlCreateCombo('', 290, 10, 200, 20)

_WinAPI_SetLayeredWindowAttributes($GUI, 0xABCDEF, 250)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _GUISavePositions($GUI, $siniFile)
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($GUI, $WM_SYSCOMMAND, 0xF012, 0)
    EndSwitch
WEnd

Func _Exit()
    Exit
EndFunc

Func _GUISavePositions($hGUI, $sConfigFile, $sSectName = "Window Positions")
    Local $aGUI_Pos = WinGetPos($hGUI)
    If @error Then Return 0

    IniWrite($sConfigFile, $sSectName, "Left", $aGUI_Pos[0])
    IniWrite($sConfigFile, $sSectName, "Top", $aGUI_Pos[1])
    IniWrite($sConfigFile, $sSectName, "Width", $aGUI_Pos[2])
    IniWrite($sConfigFile, $sSectName, "Height", $aGUI_Pos[3])

    Return 1
EndFunc

Func _GUIRestorePositions($hGUI, $sConfigFile, $sSectName = "Window Positions", $iDefWidth = 700, $iDefHeight = 40)
    Local $iGUI_Left = IniRead($sConfigFile, $sSectName, "Left", -1)
    Local $iGUI_Top = IniRead($sConfigFile, $sSectName, "Top", -1)
    Local $iGUI_Width = IniRead($sConfigFile, $sSectName, "Width", $iDefWidth)
    Local $iGUI_Height = IniRead($sConfigFile, $sSectName, "Height", $iDefHeight)

    If $iGUI_Left = -1 Then $iGUI_Left = (@DesktopWidth / 2) - ($iGUI_Width / 2)
    If $iGUI_Top = -1 Then $iGUI_Top = (@DesktopHeight / 2) - ($iGUI_Height / 2)

    Return WinMove($hGUI, "", $iGUI_Left, $iGUI_Top, $iGUI_Width, $iGUI_Height)
EndFunc

Func _StandardPos()
    ; Get screen dimensions
    Local $iScreenWidth = @DesktopWidth
    Local $iScreenHeight = @DesktopHeight

    ; Calculate window position (centered horizontally, positioned from the bottom)
    Local $iWindowWidth = 800
    Local $iWindowHeight = 40
    Local $iWindowX = ($iScreenWidth - $iWindowWidth) / 2
    Local $iWindowY = $iScreenHeight - $iWindowHeight - 3; Adjust 50 to change the gap from the bottom

    ; Set window position
    WinMove($GUI, "", $iWindowX, $iWindowY, $iWindowWidth, $iWindowHeight)
    _GUISavePositions($GUI, $siniFile)
EndFunc

Alles anzeigen

lg noch und ein gesegnetes Fest

MojoeB

ich war auch grad dabei :

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
#include <sendmessage.au3>
#include <GuiConstants.au3>
#AutoIt3Wrapper_Res_HiDpi=y
#NoTrayIcon
HotKeySet("ESC", "_Exit")

Global Const $DEFAULT_WINDOW_WIDTH = 800
Global Const $DEFAULT_WINDOW_HEIGHT = 40
Global $ConfigFile = StringTrimRight(@ScriptFullPath, 3) & "ini"
Global $map[]; Erstellen einer Map für die GUI-Elemente


Main()

Func Main()
    MakeDPIAware()
    CreateGUI($map)
EndFunc

While 1
    Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_GUISavePositions($map.GUI, $ConfigFile)
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($map.GUI, $WM_SYSCOMMAND, 0xF012, 0)
    EndSwitch
WEnd

Func CreateGUI(ByRef $m)
    $m.GUI = GUICreate("Test", $DEFAULT_WINDOW_WIDTH, $DEFAULT_WINDOW_HEIGHT, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
        
    If Not FileExists($ConfigFile) Then
        _StandardPos() 
    Else
        _GUIRestorePositions($m.GUI, $ConfigFile) 
    EndIf

    GUISetBkColor(0xABCDEF)
	
    ; Hinzufügen von Combobox-Elementen zur Map
    $m.cmb01 = GUICtrlCreateCombo('123', 10, 10, 150, 20)
    $m.cmb02 = GUICtrlCreateCombo('', 170, 10, 50, 20)
    $m.cmb03 = GUICtrlCreateCombo('', 230, 10, 50, 20)
    $m.cmb04 = GUICtrlCreateCombo('', 290, 10, 200, 20)
	
	_WinAPI_SetLayeredWindowAttributes($map.GUI, 0xABCDEF, 250)
	GUISetState()
    
	Return $m.GUI	
EndFunc

Func MakeDPIAware()
    If Not @Compiled Then DllCall("User32.dll", "bool", "SetProcessDPIAware")
EndFunc

Func _GUISavePositions($hGUI, $sConfigFile, $sSectName="Window Positions")
    Local $aGUI_Pos = WinGetPos($hGUI)
    If @error Then Return 0

		IniWrite($sConfigFile, $sSectName, "Left", $aGUI_Pos[0])
		IniWrite($sConfigFile, $sSectName, "Top", $aGUI_Pos[1])
		IniWrite($sConfigFile, $sSectName, "Width", $aGUI_Pos[2])
		IniWrite($sConfigFile, $sSectName, "Height", $aGUI_Pos[3])

    Return 1
EndFunc

Func _GUIRestorePositions($hGUI, $sConfigFile, $sSectName="Window Positions", $iDefWidth=700, $iDefHeight=40)
    Local $iGUI_Left = IniRead($sConfigFile, $sSectName, "Left", -1)
    Local $iGUI_Top = IniRead($sConfigFile, $sSectName, "Top", -1)
    Local $iGUI_Width = IniRead($sConfigFile, $sSectName, "Width", $iDefWidth)
    Local $iGUI_Height = IniRead($sConfigFile, $sSectName, "Height", $iDefHeight)

    If $iGUI_Left = -1 Then $iGUI_Left = (@DesktopWidth / 2) - ($iGUI_Width / 2)
    If $iGUI_Top = -1 Then $iGUI_Top = (@DesktopHeight / 2) - ($iGUI_Height / 2)

   Return WinMove($hGUI, "", $iGUI_Left, $iGUI_Top, $iGUI_Width, $iGUI_Height)
EndFunc


Func _StandardPos()
    Local $iScreenWidth = @DesktopWidth
    Local $iScreenHeight = @DesktopHeight

    Local $iWindowWidth = $DEFAULT_WINDOW_WIDTH
    Local $iWindowHeight = $DEFAULT_WINDOW_HEIGHT
    Local $iWindowX = ($iScreenWidth - $iWindowWidth) / 2
    Local $iWindowY = $iScreenHeight - $iWindowHeight - 3  ; 3 Pixel Abstand vom unteren Rand

    ; Setze die Position des GUI-Fensters
    WinMove($map.GUI, "", $iWindowX, $iWindowY)
EndFunc

Func _Exit()
    Exit
EndFunc

Alles anzeigen

casi4712

okidoki, vielen Dank noch mal für die Verbesserungen

klappt super

wünsche geruhsamme Feiertage

Velted

Moin,

noch ein paar Anmerkung zum Weihnachtsfest:

1. Die Funktion IniRead bietet - wie Du bereits generkt hast - die Möglichkeit, einen Defaultwert vorzugeben. Dieser Wert wird nicht nur dann genutzt, wenn der Schlüssel in der INI-Datei nicht gefunden wird, sondern auch dann, wenn die INI-Datei nicht existiert. An Stelle von -1 solltest Du deshalb den echten Standardwert eintragen.

2. Es scheint mir bei dem gegebenen Skript recht unwahrscheinlich, dass der Benutzer die Fenstergröße verändern kann. Es sollte deshalb reichen, sich die Fenterposition (X/Y) zu merken.

3. Wenn Du versuchst, die Werte schon vor dem GUICreate() zu ermitteln, kannst Du sie direkt verwenden und musst das Fenster nicht nachträglich verschieben.

Frohe Weihnachten und einen gutenRutsch!

casi4712

oki doki danke für das Weihnachts Präsent, werde ich berücksichtigen,

dir auch frohe Weihnachten