Bestimmtes PDF automatisiert in ein anderes PDF einfügen und speichern

Swiffer

Ich habe den Ordner "C:\Users\Swiffer\Desktop\Rechnungen" erstellt und

21 alt

Global $sPathDestinationPDF = "\\" & $sDestinationIP & "\NAS Zuhause synch verschlüsselt\Geschäft\Rechnungen"

durch 21 neu ersetzt
Global $sPathDestinationPDF = "C:\Users\Swiffer\Desktop\Rechnungen"

Wieder: "Die Liste mit Dateien die durchsucht werden sollte, konnte nicht erstellt werden. Der Fehlercode aus _FileListArrayRec lautet:Path not found or invalid. Die Anwendung wird beendet."

Wie könnte ich das noch eingrenzen?

**Schnuffel**

PS: die Funktion "_FileListArrayRec" verwende ich nur, weil ich nicht weiß ob sich die Dateien nur in dem Ordner oder auch in Unterordner befinden können.

Für das Script ist das existenziell wichtig.

Ansonsten wäre das alles auch einfacher zu lösen.
Je mehr feststehende Parameter es gibt, um so weniger muss man im Code darauf eingehen.

Swiffer

Ich vermute 20 muss dann auch noch weg. Und weitere auch. Edit: Ne bringt irgendwie auch nichts.

Zitat von Schnuffel

ob sich die Dateien nur in dem Ordner oder auch in Unterordner befinden können

Nice to have aber nicht zwingend. Die Ordner sind eigentlich klar definiert. Daher würde das auch reichen wenns hilft.

**Schnuffel**

du siehst, es gibt weitaus mehr Details, die vorher abgeklärt sein müssen, damit ein Programmierer sich nicht verrennt.

Außerdem geht mein Script im Moment noch davon aus, dass bei Erscheinen einer Rechnung der betreffende QR-Code.pdf bereits im Ordner "QR EZ" existiert.

Auch das sind Vorgaben, die ich kennen muß.

Swiffer

Ja das QR-Code.pdf existiert bereits im Ordner "QR EZ".

**Schnuffel**

versuch mal diese abgespeckte Version

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>

Opt("WinTitleMatchMode", 2)
Opt("MustDeclareVars", 1)

#cs
Bedingungen:
Download und Installation folgender Programme im Standardverzeichnis
pdftkfree ==> https://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/pdftk_free-2.02-win-setup.exe
Ghostscript ==> https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs10021/gs10021w32.exe
#ce

; Variablen, die angepasst werden können
Global $sTitel = "merge PDF-Tool"
Global $sPathRechnungPDF = "C:\RG ohne EZ"
Global $sPathQRPDF = "C:\QR EZ"
Global $sPathQRTxt = $sPathQRPDF & "\txt"
Global $sDestinationIP = "192.168.150.34" ; um die IP pingen zu können (Test Verfügbarkeit)
Global $sPathDestinationPDF = $sDestinationIP & "\NAS Zuhause synch verschlüsselt\Firma\Rechnungen"
Global $sPathRechnungArchiv = $sPathRechnungPDF & "\Archiv"
Global $sPathQRArchiv = $sPathQRPDF & "\Archiv"

Global $sRegExSuchString = ".*(\d{4}-\d{4}).*" ; der Suchstring extrahiert aus dem Rechungsnamen nnnn-nnnn
Global $nScanPause = 10 ; Zeit in Sekunden als Pausenangabe bis zum nächsten Scan des Source Ordners, beginnt mit Pause!
Global $bArchivieren = 1 ; wenn aktiviert dann wird jede pdf in "Archiv" kopiert vor merge

; Installationen von Ghostscript und pdftk prüfen
Global $aEnvPath = StringSplit(EnvGet("Path"), ';')
For $i = 1 To $aEnvPath[0]
	If StringInStr($aEnvPath[$i], "gs\gs") Then
		If FileExists($aEnvPath[$i] & '\gswin32c.exe') And FileExists($aEnvPath[$i] & '\gsdll32.dll') Then
			Global $sPathToMergeTool = $aEnvPath[$i] & '\gswin32c.exe'
			ExitLoop
		Else
			ShellExecute("https://ghostscript.com/releases/gsdnld.html")
			Exit MsgBox(262144 + 16, $sTitel, "Die zur Ausführung benötigte Datei: " & $aEnvPath[$i] & '\gswin32c.exe' & " konnte nicht gefunden werden." & @CRLF & @CRLF & "Installieren Sie die 32-bit Version von GhostScript und starten Sie dieses Script dann erneut.")
		EndIf
	EndIf
Next

If FileExists("C:\Program Files (x86)\PDFtk\bin\pdftk.exe") And FileExists("C:\Program Files (x86)\PDFtk\bin\libiconv2.dll") Then
	Global $sPathToMergeTool = 'C:\Program Files (x86)\PDFtk\bin\pdftk.exe'
Else
	ShellExecute("https://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/")
	Exit MsgBox(262144 + 16, $sTitel, "Die zur Ausführung benötigte Datei: C:\Program Files (x86)\PDFtk\bin\pdftk.exe  konnte nicht gefunden werden." & @CRLF & @CRLF & "Installieren Sie die 32-bit Version von GhostScript und starten Sie dieses Script dann erneut.")
EndIf

; Das Script erwartet die Dateien pdftk.exe & die libiconv2.dll im Scriptverzeichnis
Global $sPathToGSWin32cTool = @ScriptDir & '\gswin32c.exe' ; Das Script erwartet die Dateien gswin32c.exe & gsdll32.dll im Scriptverzeichnis

; interne Variablendeklaration
Global $command, $PID, $sTxt, $hQRListePDF, $sQRListePDF, $sQRFilePDF, $hQRListeTxt, $sQRListeTxt, $hRechnungPDF, $sSearchString, $sRechnungFileName, $aQRListePDF, $aQRListeTxt, $nTimer, $Error, $ErrorMsg, $bQRFound = 0, $sAkt_Searchtxt, $bfirstStart = 1

; prüfen, ob die Ordner existieren, eine Berechtigungs-Prüfung innerhalb der Ordner wird nicht durchgeführt (Schreibrechte)
If DriveGetType($sPathRechnungPDF) = "Network" Then
	If Ping($sPathRechnungPDF, 500) = 0 Then Exit MsgBox(262144 + 16, $sTitel, "Der Pfad " & $sPathRechnungPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
EndIf
If DriveGetType($sPathQRPDF) = "Network" Then
	If Ping($sPathQRPDF, 500) = 0 Then Exit MsgBox(262144 + 16, $sTitel, "Der Pfad " & $sPathQRPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
EndIf
If DriveGetType($sDestinationIP) = "Network" Then
	If Ping($sDestinationIP, 500) = 0 Then Exit MsgBox(262144 + 16, $sTitel, "Der Pfad " & $sDestinationIP & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
EndIf
If Not FileWrite($sPathRechnungPDF & "\Testdatei.tmp", "") Then Exit MsgBox(262144 + 16, $sTitel, "Der Ordner " & $sPathRechnungPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
FileDelete($sPathRechnungPDF & "\Testdatei.tmp")
If Not FileWrite($sPathQRPDF & "\Testdatei.tmp", "") Then Exit MsgBox(262144 + 16, $sTitel, "Der Ordner " & $sPathQRPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
FileDelete($sPathQRPDF & "\Testdatei.tmp")
If Not FileWrite($sPathDestinationPDF & "\Testdatei.tmp", "") Then Exit MsgBox(262144 + 16, $sTitel, "Der Ordner " & $sPathDestinationPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
FileDelete($sPathDestinationPDF & "\Testdatei.tmp")

If $bArchivieren Then
	If Not FileExists($sPathRechnungArchiv) Then DirCreate($sPathRechnungArchiv)
	If Not FileExists($sPathQRArchiv) Then DirCreate($sPathQRArchiv)
EndIf
If Not FileExists($sPathQRPDF & "\txt") Then DirCreate($sPathQRPDF & "\txt") ; Unterordner für die zu durchsuchenden txt-Dateien erstellen

; HotKey, der die Anwendung beendet (funktioniert bei au3 wie auch bei exe)
HotKeySet("!x", "_Exit")

$nTimer = TimerInit() ; aktuelle Systemzeit holen und die Pausezeit addieren, damit wird sofort die Schleife durchlaufen und erst nach 1 Durchlauf pausiert

While Sleep(10) ; 10ms schlafen um Prozessor zu entlasten
	If $bfirstStart = 1 Or TimerDiff($nTimer) > $nScanPause * 1000 Then  ; solange gegen die Pausezeit prüfen, bis überschritten, dann nach PDF-Datei suchen
		$bfirstStart = 0
		$nTimer = TimerInit() ; aktuelle Systemzeit holen, damit wieder gegen die Pausezeit verglichen werden kann
		$hRechnungPDF = FileFindFirstFile($sPathRechnungPDF & "\*.pdf") ; sucht in dem angebenen Ordner nach pdf-Datei/en
		If $hRechnungPDF = -1 Then ; keine pdf-Datei gefunden
			FileClose($hRechnungPDF) ; Such-Handle $hRechnungPDF wieder schließen
			ContinueLoop ; keine Datei gefunden, Loop von vorn beginnen und von Anfang mit Pause
		Else ; mind. 1 Datei wurde gefunden
			$bQRFound = 0
			While 1 ; Loop der alle zu durchsuchenden Dateien durchgeht und wenn alle durch, dann Schleife verlassen
				$sRechnungFileName = FileFindNextFile($hRechnungPDF) ; erste/nächste pdf-Datei  aus dem Such-Handle $hRechnungPDF der Variable zuweisen
				If @error Then ExitLoop ; keine Datei mehr vorhanden, Loop Abbruch
				ConsoleWrite("pdf-Datei wird verarbeitet: " & $sRechnungFileName & @CRLF)
				$sSearchString = StringRegExpReplace($sRechnungFileName, $sRegExSuchString, "$1") ; Suchstring auf den RegEx im Dateinamen reduzieren

				; Fileliste aller QR pdf-Dateien inkl. Unterordner erstellen, in denen gesucht werden soll, Ordner Archiv und txt sind excluded
				; Prüfung bei jedem Durchlauf, damit die txt bei Rechnungsstellung auch vorhanden ist
				$hQRListePDF = FileFindFirstFile($sPathQRPDF & "\*.pdf")
				If @error > 0 Then
					ConsoleWrite('keine pdf-Datei in "QR EZ" gefunden' & @CRLF)
					ContinueLoop ; wenn keine pdf-Datei gefunden wurde, dann den Loop neu starten da keine Datei zum anhängen vorhanden ist
				EndIf
				While 1
					$sQRFilePDF = FileFindNextFile($hQRListePDF)
					If @error Then
						ConsoleWrite('keine pdf-Datei mit passendem Inhalt für die Datei: ' & $sRechnungFileName & ' in "QR EZ" gefunden' & @CRLF)
						ExitLoop ; keine Datei mehr vorhanden, Loop Abbruch
					EndIf
					$sQRListeTxt = StringRegExpReplace($sQRFilePDF, "(.pdf)", ".txt")
					If Not FileExists($sPathQRPDF & "\txt\" & StringRegExpReplace($sQRFilePDF, "(.pdf)", ".txt")) Then
						; mit Ghostscript die Datei in eine txt-Datei konvertieren und im Unterordner txt abspeichern
						RunWait('"' & $sPathToGSWin32cTool & '" -sDEVICE=txtwrite -sOutputFile="' & $sPathQRTxt & "\" & $sQRListeTxt & '" -dBATCH  -dNOPAUSE "' & $sPathQRPDF & "\" & $sQRFilePDF & '"', "", @SW_HIDE)
					EndIf
					$sTxt = FileRead($sPathQRTxt & "\" & $sQRListeTxt)
					If StringInStr($sTxt, $sSearchString) > 0 Then     ; Suchstring in einer txt-Datei gefunden
						$bQRFound = 1
						; $sRechnungFileName = aktueller Dateiname der RechnungsPDF
						; $aQRListeTxt[$i] = aktueller Dateiname der txt-Datei die durchsucht wird
						; $sQRFilePDF = aktuelle QR pdf-Datei die zur gefundenen txt-Datei gehört
						$sQRFilePDF = StringRegExpReplace($sQRListeTxt, "(.txt)", ".pdf")
						; mit gefundener Datei mergen und Output nach Destination
						$command = '"' & $sPathToMergeTool & '" "' & $sPathRechnungPDF & '\' & $sRechnungFileName & '" "' & $sPathQRPDF & '\' & $sQRFilePDF & '" cat output "' & $sPathDestinationPDF & '\' & StringReplace($sRechnungFileName, '.pdf', '+.pdf') & '"'
						;ConsoleWrite($command & @CRLF)
						$PID = Run($command, "", @SW_SHOW, 2)
						Sleep(5000)
						If FileExists($sPathDestinationPDF & '\' & StringReplace($sRechnungFileName, '.pdf', '+.pdf')) = 1 Then
							ConsoleWrite($sPathDestinationPDF & '\' & StringReplace($sRechnungFileName, '.pdf', '+.pdf') & " gemerged und abgelegt" & @CRLF & @CRLF)
							If $bArchivieren Then
								; Rechnung in Archiv kopieren wenn Archiv aktiviert
								FileCopy($sPathRechnungPDF & "\" & $sRechnungFileName, $sPathRechnungArchiv)
								; gefundene pdf-Datei in Archiv kopieren, da die Fund-Datei nach merge gelöscht wird, wenn Archiv aktiviert
								FileCopy($sPathQRPDF & "\" & $sAkt_Searchtxt, $sPathQRArchiv)
							EndIf
							FileDelete($sPathRechnungPDF & "\" & $sRechnungFileName)
							FileDelete($sPathQRTxt & "\" & $sQRListeTxt)
							FileDelete($sPathQRPDF & "\" & $sQRFilePDF)
							ExitLoop
						Else     ; merge-PDF nicht vorhanden, etwas ist beim zusammenführen schief gelaufen, Prüfung auf Return Code der Konsolenausgabe ist aufwendiger
							ConsoleWrite($sPathDestinationPDF & '\' & $sSearchString & "+.pdf nicht gefunden" & @CRLF)
							MsgBox(262144 + 16, $sTitel, "Die Datei " & $sPathRechnungPDF & "\" & $sSearchString & ".pdf konnte nicht mit " & $sPathQRPDF & '\' & StringReplace($sAkt_Searchtxt, ".txt", ".pdf") & " zusammengeführt werden" & @CRLF & "Das Skript wartet, bis das Fenster geschlossen wird.")
						EndIf
					EndIf
				WEnd
			WEnd
		EndIf
		FileClose($hRechnungPDF)
	EndIf
WEnd

Func _Exit()
	FileDelete($sPathQRTxt & "\*.txt")
	Exit
EndFunc   ;==>_Exit

Alles anzeigen

Swiffer

Musste "Global $sPathDestinationPDF = "\\" & $sDestinationIP & "\NAS Zuhause synch verschlüsselt\Firma\Rechnungen"" machen sonst wurde der Ordner nicht gefunden.

Jetzt kommt:

"pdf-Datei wird verarbeitet: Rechnung 2024-9055.pdf
keine pdf-Datei mit passendem Inhalt für die Datei: Rechnung 2024-9055.pdf in "QR EZ" gefunden
pdf-Datei wird verarbeitet: Rechnung 2024-9056.pdf
keine pdf-Datei mit passendem Inhalt für die Datei: Rechnung 2024-9056.pdf in "QR EZ" gefunden"

Wenn ich im Ordner "C:\QR EZ" per Explorer-Suchfunktion "2024-9055" oder "2024-9056" suche wird dazu jeweils ein PDF mit "gleichem" Inhalt gefunden.

**Schnuffel**

ich fürchte jetzt bin ich an dem Punkt, dass ich so nicht weiterhelfen kann.

Entweder sehe ich dein Zielsystem und kann dort alle Umstände gegenprüfen,

oder ich müsste endlos Fehlerhandling einbauen.

Swiffer

Hm ach mist Also sowas wie Remote? Ich überlegs mir mal. Ansonsten werden wir uns bei Deinem bisher geleisteten Aufwand schon irgendwie einig. Evtl. bringt ja auch drüber schlafen eine neue Idee.

**Schnuffel**

bei mir funktioniert es ja. Daher verstehe ich den Unterschied nicht.....

**Schnuffel**

letzter Versuch für heute:

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>

Opt("WinTitleMatchMode", 2)
Opt("MustDeclareVars", 1)

#cs
Bedingungen:
Download und Installation folgender Programme im Standardverzeichnis
pdftkfree ==> https://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/pdftk_free-2.02-win-setup.exe
Ghostscript ==> https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs10021/gs10021w32.exe
#ce

; Variablen, die angepasst werden können
Global $sTitel = "merge PDF-Tool"
Global $sPathRechnungPDF = "C:\RG ohne EZ"
Global $sPathQRPDF = "C:\QR EZ"
Global $sPathQRTxt = $sPathQRPDF & "\txt"
Global $sDestinationIP = "192.168.150.34" ; um die IP pingen zu können (Test Verfügbarkeit)
Global $sPathDestinationPDF = "\\" & $sDestinationIP & "\NAS Zuhause synch verschlüsselt\Firma\Rechnungen"
Global $sPathRechnungArchiv = $sPathRechnungPDF & "\Archiv"
Global $sPathQRArchiv = $sPathQRPDF & "\Archiv"

Global $sRegExSuchString = ".*(\d{4}-\d{4}).*" ; der Suchstring extrahiert aus dem Rechungsnamen nnnn-nnnn
Global $nScanPause = 10 ; Zeit in Sekunden als Pausenangabe bis zum nächsten Scan des Source Ordners, beginnt mit Pause!
Global $bArchivieren = 1 ; wenn aktiviert dann wird jede pdf in "Archiv" kopiert vor merge

; Installationen von Ghostscript und pdftk prüfen
Global $aEnvPath = StringSplit(EnvGet("Path"), ';')
For $i = 1 To $aEnvPath[0]
	If StringInStr($aEnvPath[$i], "gs\gs") Then
		If FileExists($aEnvPath[$i] & '\gswin32c.exe') And FileExists($aEnvPath[$i] & '\gsdll32.dll') Then
			Global $sPathToMergeTool = $aEnvPath[$i] & '\gswin32c.exe'
			ExitLoop
		Else
			ShellExecute("https://ghostscript.com/releases/gsdnld.html")
			Exit MsgBox(262144 + 16, $sTitel, "Die zur Ausführung benötigte Datei: " & $aEnvPath[$i] & '\gswin32c.exe' & " konnte nicht gefunden werden." & @CRLF & @CRLF & "Installieren Sie die 32-bit Version von GhostScript und starten Sie dieses Script dann erneut.")
		EndIf
	EndIf
Next

If FileExists("C:\Program Files (x86)\PDFtk\bin\pdftk.exe") And FileExists("C:\Program Files (x86)\PDFtk\bin\libiconv2.dll") Then
	Global $sPathToMergeTool = 'C:\Program Files (x86)\PDFtk\bin\pdftk.exe'
Else
	ShellExecute("https://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/")
	Exit MsgBox(262144 + 16, $sTitel, "Die zur Ausführung benötigte Datei: C:\Program Files (x86)\PDFtk\bin\pdftk.exe  konnte nicht gefunden werden." & @CRLF & @CRLF & "Installieren Sie die 32-bit Version von GhostScript und starten Sie dieses Script dann erneut.")
EndIf

; Das Script erwartet die Dateien pdftk.exe & die libiconv2.dll im Scriptverzeichnis
Global $sPathToGSWin32cTool = @ScriptDir & '\gswin32c.exe' ; Das Script erwartet die Dateien gswin32c.exe & gsdll32.dll im Scriptverzeichnis

; interne Variablendeklaration
Global $command, $PID, $sTxt, $hQRListePDF, $sQRListePDF, $sQRFilePDF, $hQRListeTxt, $sQRListeTxt, $hRechnungPDF, $sSearchString, $sRechnungFileName, $aQRListePDF, $aQRListeTxt, $nTimer, $Error, $ErrorMsg, $bQRFound = 0, $sAkt_Searchtxt, $bfirstStart = 1

; prüfen, ob die Ordner existieren, eine Berechtigungs-Prüfung innerhalb der Ordner wird nicht durchgeführt (Schreibrechte)
If DriveGetType($sPathRechnungPDF) = "Network" Then
	If Ping($sPathRechnungPDF, 500) = 0 Then Exit MsgBox(262144 + 16, $sTitel, "Der Pfad " & $sPathRechnungPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
EndIf
If DriveGetType($sPathQRPDF) = "Network" Then
	If Ping($sPathQRPDF, 500) = 0 Then Exit MsgBox(262144 + 16, $sTitel, "Der Pfad " & $sPathQRPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
EndIf
If DriveGetType($sDestinationIP) = "Network" Then
	If Ping($sDestinationIP, 500) = 0 Then Exit MsgBox(262144 + 16, $sTitel, "Der Pfad " & $sDestinationIP & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
EndIf
If Not FileWrite($sPathRechnungPDF & "\Testdatei.tmp", "") Then Exit MsgBox(262144 + 16, $sTitel, "Der Ordner " & $sPathRechnungPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
FileDelete($sPathRechnungPDF & "\Testdatei.tmp")
If Not FileWrite($sPathQRPDF & "\Testdatei.tmp", "") Then Exit MsgBox(262144 + 16, $sTitel, "Der Ordner " & $sPathQRPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
FileDelete($sPathQRPDF & "\Testdatei.tmp")
If Not FileWrite($sPathDestinationPDF & "\Testdatei.tmp", "") Then Exit MsgBox(262144 + 16, $sTitel, "Der Ordner " & $sPathDestinationPDF & " konnte nicht erreicht werden!" & @CRLF & "Die Anwendung wird beendet.")
FileDelete($sPathDestinationPDF & "\Testdatei.tmp")

If $bArchivieren Then
	If Not FileExists($sPathRechnungArchiv) Then DirCreate($sPathRechnungArchiv)
	If Not FileExists($sPathQRArchiv) Then DirCreate($sPathQRArchiv)
EndIf
If Not FileExists($sPathQRPDF & "\txt") Then DirCreate($sPathQRPDF & "\txt") ; Unterordner für die zu durchsuchenden txt-Dateien erstellen

; HotKey, der die Anwendung beendet (funktioniert bei au3 wie auch bei exe)
HotKeySet("!x", "_Exit")

$nTimer = TimerInit() ; aktuelle Systemzeit holen und die Pausezeit addieren, damit wird sofort die Schleife durchlaufen und erst nach 1 Durchlauf pausiert

While Sleep(10) ; 10ms schlafen um Prozessor zu entlasten
	If $bfirstStart = 1 Or TimerDiff($nTimer) > $nScanPause * 1000 Then  ; solange gegen die Pausezeit prüfen, bis überschritten, dann nach PDF-Datei suchen
		$bfirstStart = 0
		$nTimer = TimerInit() ; aktuelle Systemzeit holen, damit wieder gegen die Pausezeit verglichen werden kann
		$hRechnungPDF = FileFindFirstFile($sPathRechnungPDF & "\*.pdf") ; sucht in dem angebenen Ordner nach pdf-Datei/en
		If $hRechnungPDF = -1 Then ; keine pdf-Datei gefunden
			FileClose($hRechnungPDF) ; Such-Handle $hRechnungPDF wieder schließen
			ContinueLoop ; keine Datei gefunden, Loop von vorn beginnen und von Anfang mit Pause
		Else ; mind. 1 Datei wurde gefunden
			$bQRFound = 0
			While 1 ; Loop der alle zu durchsuchenden Dateien durchgeht und wenn alle durch, dann Schleife verlassen
				$sRechnungFileName = FileFindNextFile($hRechnungPDF) ; erste/nächste pdf-Datei  aus dem Such-Handle $hRechnungPDF der Variable zuweisen
				If @error Then ExitLoop ; keine Datei mehr vorhanden, Loop Abbruch
				ConsoleWrite("Rechnung gefunden: " & $sRechnungFileName & @CRLF)
				$sSearchString = StringRegExpReplace($sRechnungFileName, $sRegExSuchString, "$1") ; Suchstring auf den RegEx im Dateinamen reduzieren
				; Fileliste aller QR pdf-Dateien inkl. Unterordner erstellen, in denen gesucht werden soll, Ordner Archiv und txt sind excluded
				; Prüfung bei jedem Durchlauf, damit die txt bei Rechnungsstellung auch vorhanden ist
				$hQRListePDF = FileFindFirstFile($sPathQRPDF & "\*.pdf")
				If $hQRListePDF = -1 Then
					ConsoleWrite('keine pdf-Datei in "QR EZ" gefunden' & @CRLF)
					ContinueLoop ; wenn keine pdf-Datei gefunden wurde, dann den Loop neu starten da keine Datei zum anhängen vorhanden ist
				EndIf
				While 1
					$sQRFilePDF = FileFindNextFile($hQRListePDF)
					If @error Then
						ExitLoop ; keine Datei mehr vorhanden, Loop Abbruch
					EndIf
					$sQRListeTxt = StringRegExpReplace($sQRFilePDF, "(.pdf)", ".txt")
					If Not FileExists($sPathQRPDF & "\txt\" & StringRegExpReplace($sQRFilePDF, "(.pdf)", ".txt")) Then
						; mit Ghostscript die Datei in eine txt-Datei konvertieren und im Unterordner txt abspeichern
						RunWait('"' & $sPathToGSWin32cTool & '" -sDEVICE=txtwrite -sOutputFile="' & $sPathQRTxt & "\" & $sQRListeTxt & '" -dBATCH  -dNOPAUSE "' & $sPathQRPDF & "\" & $sQRFilePDF & '"', "", @SW_HIDE)
					EndIf
					$sTxt = FileRead($sPathQRTxt & "\" & $sQRListeTxt)
					If StringInStr($sTxt, $sSearchString) > 0 Then     ; Suchstring in einer txt-Datei gefunden
						$bQRFound = 1
						; $sRechnungFileName = aktueller Dateiname der RechnungsPDF
						; $aQRListeTxt[$i] = aktueller Dateiname der txt-Datei die durchsucht wird
						; $sQRFilePDF = aktuelle QR pdf-Datei die zur gefundenen txt-Datei gehört
						$sQRFilePDF = StringRegExpReplace($sQRListeTxt, "(.txt)", ".pdf")
						; mit gefundener Datei mergen und Output nach Destination
						$command = '"' & $sPathToMergeTool & '" "' & $sPathRechnungPDF & '\' & $sRechnungFileName & '" "' & $sPathQRPDF & '\' & $sQRFilePDF & '" cat output "' & $sPathDestinationPDF & '\' & StringReplace($sRechnungFileName, '.pdf', '+.pdf') & '"'
						;ConsoleWrite($command & @CRLF)
						$PID = Run($command, "", @SW_SHOW, 2)
						Sleep(5000)
						If FileExists($sPathDestinationPDF & '\' & StringReplace($sRechnungFileName, '.pdf', '+.pdf')) = 1 Then
							ConsoleWrite($sPathDestinationPDF & '\' & StringReplace($sRechnungFileName, '.pdf', '+.pdf') & " gemerged und abgelegt" & @CRLF & @CRLF)
							If $bArchivieren Then
								; Rechnung in Archiv kopieren wenn Archiv aktiviert
								FileCopy($sPathRechnungPDF & "\" & $sRechnungFileName, $sPathRechnungArchiv)
								; gefundene pdf-Datei in Archiv kopieren, da die Fund-Datei nach merge gelöscht wird, wenn Archiv aktiviert
								FileCopy($sPathQRPDF & "\" & $sAkt_Searchtxt, $sPathQRArchiv)
							EndIf
							FileDelete($sPathRechnungPDF & "\" & $sRechnungFileName)
							FileDelete($sPathQRTxt & "\" & $sQRListeTxt)
							FileDelete($sPathQRPDF & "\" & $sQRFilePDF)
							ExitLoop
						Else     ; merge-PDF nicht vorhanden, etwas ist beim zusammenführen schief gelaufen, Prüfung auf Return Code der Konsolenausgabe ist aufwendiger
							ConsoleWrite($sPathDestinationPDF & '\' & $sSearchString & "+.pdf nicht gefunden" & @CRLF)
							MsgBox(262144 + 16, $sTitel, "Die Datei " & $sPathRechnungPDF & "\" & $sSearchString & ".pdf konnte nicht mit " & $sPathQRPDF & '\' & StringReplace($sAkt_Searchtxt, ".txt", ".pdf") & " zusammengeführt werden" & @CRLF & "Das Skript wartet, bis das Fenster geschlossen wird.")
						EndIf
					EndIf
				WEnd
			WEnd
		EndIf
		FileClose($hRechnungPDF)
	EndIf
WEnd

Func _Exit()
	FileDelete($sPathQRTxt & "\*.txt")
	Exit
EndFunc   ;==>_Exit

Alles anzeigen

**Schnuffel**

ansonsten brauche ich mindestens die genutzten pdf-Dateien, den Inhalt der Ordner (während der Laufzeit des Scriptes) in
- C:\RG ohne EZ
- C:\QR EZ
- C:\QR EZ\txt

Swiffer

Vielen Dank für Deine Bemühungen. Es kommt jetzt keine Fehlermeldung mehr aber der Zielordner sowie die Archivordner und der txt Ordner bleiben leer.

Scite gibt das aus:

Rechnung gefunden: Rechnung 2024-9055.pdf
Rechnung gefunden: Rechnung 2024-9056.pdf
Rechnung gefunden: Rechnung 2024-9055.pdf
Rechnung gefunden: Rechnung 2024-9056.pdf

Endlosschleife.

Ich werde Dir eine Testumgebung aufbauen auf die Du per TW oder AD raufkannst wenn das für Dich in Ordnung ist. Denke aber das reicht mir heute zeitlich nicht mehr.

**Schnuffel**

das Problem ist der leere txt-Ordner. Solange da keine Dateien drin sind, die durchsucht werden können, passiert halt nix

Swiffer

Gute Arbeit Schnuffel ! Ich bin sehr zufrieden.

Code

 ; Das Script erwartet die Dateien pdftk.exe & die libiconv2.dll im Scriptverzeichnis
Global $sPathToGSWin32cTool = @ScriptDir & '\gswin32c.exe' ; Das Script erwartet die Dateien gswin32c.exe & gsdll32.dll im Scriptverzeichnis

Leider hatte es die Datei gswin32c.exe irgendwie nicht ins @ScriptDir geschaft... *hust*! Jetzt funktioniert es wunderbar.