Anzahl Minuten in Stunden und Minuten umrechnen

hipfzwirgel

Hallo Leute,

ich möchte bis zu vier Zeiträume wie z.B. 7 Std 35 min, 8 Std 35 Min(im Input steht dann 07:35 bzw. 08:35), etc. addieren.
D. h. die Anzahl der Stunden addieren und die Anzahl der Minuten
wiederum in Stunden und Minuten umrechnen und entsprechend addieren.

Code

Local $sErgebnisStd = $sStd1 + $sStd2 + $sStd3 +$sStd4 ; hier addiere ich die Anzahl der Stunden
Local $sErgebnisMin = $sMin1 + $sMin2 + $sMin3+ $sMin4 : hier die Minuten

If $sErgebnisMin > 60 Then	; 

	$sErgebnisMin = $sErgebnisMin/60
	$sGleit = StringisFloat($sErgebnisMin)
	If $sGleit > 0 Then	; Prüfung ob die Zahl durch 60 teilbar ist. Wenn ja ausgabe des Ergebnisses (bei 120 minuten z.b. 2)
		
		???? ==> wie kann ich hier z.B. 70 Minuten umrechnen???
		
	Else
		$sErgebnisStd = $sErgebnisStd + $sErgebnisMin
	EndIf

	GUICtrlSetData($Edit1, $sErgebnisStd & " / " & $sErgebnisMin)

Else

	GUICtrlSetData($Edit1, $sErgebnisStd & " / " & $sErgebnisMin)	; ausgabe der Stunden und Minuten wenn Minuten kleiner 60

EndIf

EndFunc

Alles anzeigen

**AspirinJunkie**

Vielleicht ist es etwas einfacher zu rechnen, wenn du genau andersherum rangehst.
Anstatt Minuten in Stunden umzurechnen um sie dann zu addieren, sollte es einfacher sein eine Summe aller Minuten $nMinuten zu berechnen.
Das ist einfach, da man nur die Minuten addieren braucht und die Stunden sind ja nur noch mit 60 zu multiplizieren.

Dann ist die Rechnung am Ende ziemlich easy:

AutoIt

$nStunden = Floor($nMinuten / 60)
$nMinuten = Mod($nMinuten, 60)

hipfzwirgel

Hallo Aspirinjunkie,

verstehe ich richtig? du meinst alle Zeiträume in Minuten umrechnen und aus der Gesamtsumme dann Stunden und Minuten berechnen?

**AspirinJunkie**

Bingo

hipfzwirgel

Hallo Aspirinjunkie,

na das ist ja mal eine Super einfache Lösung.

hab es gleich umgesetzt funzt prima. Wenn ich jetzt meine Arbeitsstunden vom Dezember mit der Abrechung vergleiche steht 103,99 zu 104 da. Ist wohl der Rundung geschuldet.
Für mich passt das. Vielen Lieben Dank und noch ein gesundes neues Jahr für dich...

**AspirinJunkie**

Zitat von hipfzwirgel

Wenn ich jetzt meine Arbeitsstunden vom Dezember mit der Abrechung vergleiche steht 103,99 zu 104 da. Ist wohl der Rundung geschuldet.

Rundungsfehler? Hm - zeig mal dein Skript.
Im Grunde kann man das nahezu vollständig auf Integerbasis aufbauen - da sollte es nicht zu derartigen Rundungsfehlern kommen.

hipfzwirgel

Hallo Aspirinjunkie,

also für mich ist das durchaus ausreichend. Mir geht es nur darum verschiedene Zeiträume zu einer Gesamtsumme zu addieren. Diese Summe trage ich bei uns in ein
"Projektzeit"-Buchungstool ein. Dort werden die eingegebenen Zeiträume, z. B. 37,16 std ohnehin automatisch gerundet und es würde dann zu 37 Std angepasst.

Mach dir also bitte keinen Aufwand.

Auszug aus dem Script:

Code

$Time6 = GUICtrlRead($Input6) ;auslesen Input	; Die Befüllung der Variablen $Time1 - 5 sind gleich. Nur die Arrays und die Variablen sind an die jeweilige Time-Variable 
												  angepasst
	Local $iLength = StringLen($Time6)			; ab hier wird die Eingabe an die Form hh:mm angepasst: also 735 wird zu 07:35	
	If $iLength = 3 Then
		$Time6 = _StringInsert($Time6, "0", 0)
	EndIf
	Local $aArray6 = StringSplit($Time6, "")
	If $aArray6[3] == ":" Then
		$Time6 = $Time6
	Else
		For $i = -2 To 2
			$Output6 = _StringInsert($Time6, ":", $i)
		Next
		$Time6 = $Output6
		GUICtrlSetData($Input6, $Output6) ; hier schreibe ich den angepassten Eintrag, z.B. 07:35 in das Input
	EndIf

	Local $help1 = $aArray6[1]					; ab hier "teile" ich die Eingabe in Std und Minuten auf
	Local $help3 = $aArray6[3]
	If $help1 = "0" Then
		Local $sStd6 = $aArray6[2]

	Else
		Local $sStd6 = $aArray6[1] & $aArray6[2]

	EndIf

	If $help3 = "0" Then
		Local $sMin6 = $aArray6[4]

	Else
		Local $sMin6 = $aArray6[3] & $aArray6[4]

	EndIf

	$help1 = ""									;zurücksetzen der Variablen da sie für $Time1 - 6 benutzt werden
	$help3 = ""

	;######################Region Umrechnung Std / Min ################

	Local $sErgebnisStd = $sStd1 + $sStd2 + $sStd3 + $sStd4 + $sStd5 + $sStd6
	Local $sErgebnisMin = $sMin1 + $sMin2 + $sMin3 + $sMin4 + $sMin5 + $sMin6

	$nMinuten = ($sErgebnisStd * 60) + $sErgebnisMin	; Berechnung Gesamt-Minuten
	$nDezi = Round($nMinuten / 60, 2)					; Variable mit dezimaler Darstellung(z.B. 15,10) für die Eingabe ins Buchungstool 

	$nStunden = Floor($nMinuten / 60)
	$nMinuten = Mod($nMinuten, 60)


	GUICtrlSetData($Edit1, $nStunden & "h / " & $nMinuten & "min")	; Ausgabe z.B.  16h / 10 min in Edit

Alles anzeigen

**AspirinJunkie**

Dein Skript scheint ja nur ein Ausschnitt zu sein.
Wenn ich das richtig verstehe (und da kann ich natürlich meilenweit falsch liegen), dann hast du diesen Code mindestens 6x vorliegen - oder?
Also das scheint ja nur der Code für $Input6 zu sein.
Die anderen Zeiten fehlen ja noch in dem Gezeigten.

Es ist sicherlich nicht gut was ich jetzt mache aber mich hat es irgendwie gerade gejuckt zu versuchen, dass was ich vermute was dein Ziel ist mal etwas dynamischer zu implementieren.
Wenn ich das richtig verstehe, hast du mehrere Edit-Felder wo die Zeiten eingetragen werden und am Ende kommt eine Summe heraus.
Quasi eine Art Zeitenaddierer?

Falls ja, dann würde ich dir gerne zeigen, dass man die Felder für die Zeiten und das ganze drumherum dynamisch schreiben kann, so dass man deutlich weniger Code hierfür benötigt und gleichzeitig flexibler ist.
Es besteht natürlich die Gefahr, dass ich an deinem Thema vorbei schramme aber dann hab ich mir eben halt damit kurz die Zeit vertrieben:

AutoIt

#include <GUIConstantsEx.au3>

#Region GUI erstellen
; Eventmode statt Message-Loop-Modus (gefällt mir persönlich besser)
Opt("GUIOnEventMode", 1)

; Über die Größe des Arrays, kann man die Anzahl der Einträge und die GUI-Größe steuern
Global $aIdInputs[6] ; hält die Control-IDs für die Zeitinputs

; GUI erstellen
GUICreate("Zeitaddierer", 120, UBound($aIdInputs) * 25 + 70)
GUISetOnEvent($GUI_EVENT_CLOSE, "raus")

; die Inputs für die Zeitangaben erstellen
For $i = 0 To UBound($aIdInputs) - 1
	$aIdInputs[$i] = GUICtrlCreateInput("", 10, 5 + $i * 25, 100, 20)
	GUICtrlSetOnEvent(-1, "_gui_eingetragen")
Next

; Edit-Control für die Ausgabe der Summe:
Local $idSumme = GUICtrlCreateInput("", 10, UBound($aIdInputs) * 25 + 35, 100, 20) 

; GUI sichtbar schalten
GUISetState(@SW_SHOW)

; Endlosschleife für das GUI
Do
	Sleep(10)
Until 0
#EndRegion



; Funktion um über das Kreuz zu beenden
Func raus()
	Exit
EndFunc

; Funktion, welche aufgerufen wird, wenn eine Zeit eingetragen wurde
Func _gui_eingetragen()
	Local $sInputRaw = GUICtrlRead(@GUI_CtrlId)

	; wenn eingetragene Form nicht stimmt - aufhören
	If Not StringRegExp($sInputRaw, '^(\d{3,4}|\d{1,2}:\d{2})$', 0) Then Return

	; Doppelpunkt hinzufügen, falls nicht vorhanden:
	If Not StringInStr($sInputRaw, ':') Then $sInputRaw = StringTrimRight($sInputRaw, 2) & ":"  & StringRight($sInputRaw, 2)

	; führende 0 hinzufügen:
	$sInputRaw = StringRight("0" & $sInputRaw, 5)
	
	; aufgehübschte Zeit eintragen:
	GUICtrlSetData(@GUI_CtrlId, $sInputRaw)

	; Summe berechnen und ausgeben:
	_calcTimeSum($sInputRaw, @GUI_CtrlId)	
EndFunc


; berechnet die Summe aller Zeiten
Func _calcTimeSum($sWert, $sCtrlID)
	Local Static $mZeiten[] ; map, welche die eingetragenen Zeiten hält

	; Zeit in h und m zerlegen
	Local $aZeit = StringSplit($sWert, ":", 3)
	If @error Then Return
	
	; aus String Integer machen:
	$aZeit[0] = Int($aZeit[0])
	$aZeit[1] = Int($aZeit[1])
	
	; Bereichscheck:
	If $aZeit[1] < 0 Or $aZeit[1] > 59 Then Return
	
	; den Zeiten hinzufügen:
	$mZeiten[$sCtrlID] = $aZeit

	; Alle Zeiten zusammenrechnen und Summe ausgeben:
	Local $nMinuten = 0, $aZeitTmp
	For $iID In MapKeys($mZeiten)
		$aZeitTmp = $mZeiten[$iID]
		$nMinuten += $aZeitTmp[0] * 60 + $aZeitTmp[1]
	Next
	Local $nStunden = Floor($nMinuten / 60)
	$nMinuten = Mod($nMinuten, 60)

	; ausgeben
	GUICtrlSetData($idSumme, StringFormat("%02d:%02d", $nStunden, $nMinuten)) 
EndFunc

Alles anzeigen

hipfzwirgel

Hallo Aspirinjunkie,

vielen lieben Dank für deinen Einsatz.

Du hast mich ertappt: der Code liegt tatsächlich 6 mal vor. Für $Time1 bis 6 eben. Mit der stark verkürzten Version wollte ich nur verdeutlichen,
worauf es hinauslaufen sollte. Und Ja, es soll wie du auch im angehängten Screenshot siehst, ein Zeitraumaddierer sein, mit dem ich die
Zeiträume für die jeweiligen Projekte addiere. Mit der Clipboard-Funktion kann ich dann ins Buchungstool die Summe eintragen.

Ich schaue mir deinen Code morgen mal genauer an und gebe dir Feedback. Wünsche jetzt schönen Feierabend...

wuff100

Code

#include <Array.au3>

Local $aInput = ["14:00:00", "06:00:00","01:30:00"]
Local $Summe = _Timeradd($aInput)
MsgBox(1, "", $Summe)

Func _Timeradd(ByRef $aInput)
	Local $iSec
	For $i = 0 To UBound($aInput) - 1
		$iSec += _TimeToSec($aInput[$i])
	Next
	Return _SecToTime($iSec)
EndFunc   ;==>_Timeradd

Func _TimeToSec(ByRef $sTime)
	Local $aTmpN[3]
	Local $aTmp, $iSign, $iSec
	$iSign = (StringLeft($sTime, 1) == '-') ? -1 : 1
	$aTmp = StringSplit(StringRight($sTime, 8), ':', 2)
	For $o = 0 To UBound($aTmp) - 1
		$aTmpN[$o] = $aTmp[$o]
	Next
;~ 		_ArrayDisplay($aTmpN)
	$iSec = $aTmpN[0] * 3600 + $aTmpN[1] * 60 + $aTmpN[2]
	Return $iSec * $iSign
EndFunc   ;==>_TimeToSec

Func _SecToTime($iSec)
	Local $iHour, $iMin, $iSign = $iSec < 0 ? '-' : ''
	$iHour = Int($iSec / 3600)
	$iSec = Mod($iSec, 3600)
	$iMin = Int($iSec / 60)
	$iSec = Mod($iSec, 60)
	Return $iSign & StringFormat('%02i:%02i:%02i', Abs($iHour), Abs($iMin), Abs($iSec));Mit Sekunden
;~ 	Return $iSign & StringFormat('%02i:%02i', Abs($iHour), Abs($iMin));Ohne Sekunden
EndFunc   ;==>_SecToTime

Alles anzeigen