Cairo unter Autoit nutzen

**UEZ**

Cairo scheint eine schicke 2D Grafikbibliothek zu sein, die auch auf anderen Plattformen wie Linux läuft. Ich habe einige Beispiele in Freebasic gesehen und dachte mir, warum auch nicht in Autoit.

Ein Manual gibt es hier: https://www.cairographics.org/manual/

Die Cairo UDF: Cairo.au3

AutoIt: Cairo.au3

;Ported to Autoit by UEZ build 2024-03-24
#include-once

#Region enums and constants
;cairo_status as long
Global Enum $CAIRO_STATUS_SUCCESS = 0, $CAIRO_STATUS_NO_MEMORY, $CAIRO_STATUS_INVALID_RESTORE, $CAIRO_STATUS_INVALID_POP_GROUP, $CAIRO_STATUS_NO_CURRENT_POINT, $CAIRO_STATUS_INVALID_MATRIX, _
            $CAIRO_STATUS_INVALID_STATUS, $CAIRO_STATUS_NULL_POINTER, $CAIRO_STATUS_INVALID_STRING, $CAIRO_STATUS_INVALID_PATH_DATA, $CAIRO_STATUS_READ_ERROR, $CAIRO_STATUS_WRITE_ERROR, _
            $CAIRO_STATUS_SURFACE_FINISHED, $CAIRO_STATUS_SURFACE_TYPE_MISMATCH, $CAIRO_STATUS_PATTERN_TYPE_MISMATCH, $CAIRO_STATUS_INVALID_CONTENT, $CAIRO_STATUS_INVALID_FORMAT, $CAIRO_STATUS_INVALID_VISUAL, _
            $CAIRO_STATUS_FILE_NOT_FOUND, $CAIRO_STATUS_INVALID_DASH, $CAIRO_STATUS_INVALID_DSC_COMMENT, $CAIRO_STATUS_INVALID_INDEX, $CAIRO_STATUS_CLIP_NOT_REPRESENTABLE, $CAIRO_STATUS_TEMP_FILE_ERROR, _
            $CAIRO_STATUS_INVALID_STRIDE, $CAIRO_STATUS_FONT_TYPE_MISMATCH, $CAIRO_STATUS_USER_FONT_IMMUTABLE, $CAIRO_STATUS_USER_FONT_ERROR, $CAIRO_STATUS_NEGATIVE_COUNT, $CAIRO_STATUS_INVALID_CLUSTERS, _
            $CAIRO_STATUS_INVALID_SLANT, $CAIRO_STATUS_INVALID_WEIGHT, $CAIRO_STATUS_INVALID_SIZE, $CAIRO_STATUS_USER_FONT_NOT_IMPLEMENTED, $CAIRO_STATUS_DEVICE_TYPE_MISMATCH, $CAIRO_STATUS_DEVICE_ERROR, _
            $CAIRO_STATUS_INVALID_MESH_CONSTRUCTION, $CAIRO_STATUS_DEVICE_FINISHED, $CAIRO_STATUS_JBIG2_GLOBAL_MISSING, $CAIRO_STATUS_LAST_STATUS

Global Const $g_aCairoStatus[] = ["CAIRO_STATUS_SUCCESS", "CAIRO_STATUS_NO_MEMORY", "CAIRO_STATUS_INVALID_RESTORE", "CAIRO_STATUS_INVALID_POP_GROUP", "CAIRO_STATUS_NO_CURRENT_POINT", "CAIRO_STATUS_INVALID_MATRIX", _
            "CAIRO_STATUS_INVALID_STATUS", "CAIRO_STATUS_NULL_POINTER", "CAIRO_STATUS_INVALID_STRING", "CAIRO_STATUS_INVALID_PATH_DATA", "CAIRO_STATUS_READ_ERROR", "CAIRO_STATUS_WRITE_ERROR", _
            "CAIRO_STATUS_SURFACE_FINISHED", "CAIRO_STATUS_SURFACE_TYPE_MISMATCH", "CAIRO_STATUS_PATTERN_TYPE_MISMATCH", "CAIRO_STATUS_INVALID_CONTENT", "CAIRO_STATUS_INVALID_FORMAT", "CAIRO_STATUS_INVALID_VISUAL", _
            "CAIRO_STATUS_FILE_NOT_FOUND", "CAIRO_STATUS_INVALID_DASH", "CAIRO_STATUS_INVALID_DSC_COMMENT", "CAIRO_STATUS_INVALID_INDEX", "CAIRO_STATUS_CLIP_NOT_REPRESENTABLE", "CAIRO_STATUS_TEMP_FILE_ERROR", _
            "CAIRO_STATUS_INVALID_STRIDE", "CAIRO_STATUS_FONT_TYPE_MISMATCH", "CAIRO_STATUS_USER_FONT_IMMUTABLE", "CAIRO_STATUS_USER_FONT_ERROR", "CAIRO_STATUS_NEGATIVE_COUNT", "CAIRO_STATUS_INVALID_CLUSTERS", _
            "CAIRO_STATUS_INVALID_SLANT", "CAIRO_STATUS_INVALID_WEIGHT", "CAIRO_STATUS_INVALID_SIZE", "CAIRO_STATUS_USER_FONT_NOT_IMPLEMENTED", "CAIRO_STATUS_DEVICE_TYPE_MISMATCH", "CAIRO_STATUS_DEVICE_ERROR", _
            "CAIRO_STATUS_INVALID_MESH_CONSTRUCTION", "CAIRO_STATUS_DEVICE_FINISHED", "CAIRO_STATUS_JBIG2_GLOBAL_MISSING", "CAIRO_STATUS_LAST_STATUS"]

;cairo_format as long
Global Enum    $CAIRO_FORMAT_INVALID = -1, $CAIRO_FORMAT_ARGB32, $CAIRO_FORMAT_RGB24, $CAIRO_FORMAT_A8, $CAIRO_FORMAT_A1, $CAIRO_FORMAT_RGB16_565, $CAIRO_FORMAT_RGB30

;cairo_operator as long
Global Enum $CAIRO_OPERATOR_CLEAR, $CAIRO_OPERATOR_SOURCE, $CAIRO_OPERATOR_OVER, $CAIRO_OPERATOR_IN, $CAIRO_OPERATOR_OUT, $CAIRO_OPERATOR_ATOP, $CAIRO_OPERATOR_DEST, $CAIRO_OPERATOR_DEST_OVER, $CAIRO_OPERATOR_DEST_IN, _
            $CAIRO_OPERATOR_DEST_OUT, $CAIRO_OPERATOR_DEST_ATOP, $CAIRO_OPERATOR_XOR, $CAIRO_OPERATOR_ADD, $CAIRO_OPERATOR_SATURATE, $CAIRO_OPERATOR_MULTIPLY, $CAIRO_OPERATOR_SCREEN, $CAIRO_OPERATOR_OVERLAY, _
            $CAIRO_OPERATOR_DARKEN, $CAIRO_OPERATOR_LIGHTEN, $CAIRO_OPERATOR_COLOR_DODGE, $CAIRO_OPERATOR_COLOR_BURN, $CAIRO_OPERATOR_HARD_LIGHT, $CAIRO_OPERATOR_SOFT_LIGHT, $CAIRO_OPERATOR_DIFFERENCE, _
            $CAIRO_OPERATOR_EXCLUSION, $CAIRO_OPERATOR_HSL_HUE, $CAIRO_OPERATOR_HSL_SATURATION, $CAIRO_OPERATOR_HSL_COLOR, $CAIRO_OPERATOR_HSL_LUMINOSITY

;cairo_antialias as long
Global Enum $CAIRO_ANTIALIAS_DEFAULT, $CAIRO_ANTIALIAS_NONE, $CAIRO_ANTIALIAS_GRAY, $CAIRO_ANTIALIAS_SUBPIXEL, $CAIRO_ANTIALIAS_FAST, $CAIRO_ANTIALIAS_GOOD, $CAIRO_ANTIALIAS_BEST

;cairo_fill_rule as long
Global Enum $CAIRO_FILL_RULE_WINDING, $CAIRO_FILL_RULE_EVEN_ODD

;cairo_line_join as long
Global Enum $CAIRO_LINE_JOIN_MITER, $CAIRO_LINE_JOIN_ROUND, $CAIRO_LINE_JOIN_BEVEL

;cairo_line_cap as long
Global Enum $CAIRO_LINE_CAP_BUTT, $CAIRO_LINE_CAP_ROUND, $CAIRO_LINE_CAP_SQUARE

;cairo_text_cluster_flags as long
Global Const $CAIRO_TEXT_CLUSTER_FLAG_BACKWARD = 0x00000001

;cairo_font_slant as long
Global Enum    $CAIRO_FONT_SLANT_NORMAL, $CAIRO_FONT_SLANT_ITALIC, $CAIRO_FONT_SLANT_OBLIQUE

;cairo_font_weight as long
Global Enum    $CAIRO_FONT_WEIGHT_NORMAL, $CAIRO_FONT_WEIGHT_BOLD

;cairo_subpixel_order as long
Global Enum    $CAIRO_SUBPIXEL_ORDER_DEFAULT, $CAIRO_SUBPIXEL_ORDER_RGB, $CAIRO_SUBPIXEL_ORDER_BGR, $CAIRO_SUBPIXEL_ORDER_VRGB, $CAIRO_SUBPIXEL_ORDER_VBGR

;cairo_hint_style as long
Global Enum    $CAIRO_HINT_STYLE_DEFAULT, $CAIRO_HINT_STYLE_NONE, $CAIRO_HINT_STYLE_SLIGHT, $CAIRO_HINT_STYLE_MEDIUM, $CAIRO_HINT_STYLE_FULL

;cairo_hint_metrics as long
Global Enum    $CAIRO_HINT_METRICS_DEFAULT, $CAIRO_HINT_METRICS_OFF, $CAIRO_HINT_METRICS_ON

;cairo_font_type as long
Global Enum    $CAIRO_FONT_TYPE_TOY, $CAIRO_FONT_TYPE_FT, $CAIRO_FONT_TYPE_WIN32, $CAIRO_FONT_TYPE_QUARTZ, $CAIRO_FONT_TYPE_USER

;cairo_path_data_type as long
Global Enum    $CAIRO_PATH_MOVE_TO, $CAIRO_PATH_LINE_TO, $CAIRO_PATH_CURVE_TO, $CAIRO_PATH_CLOSE_PATH

;cairo_device_type as long
Global Enum    $CAIRO_DEVICE_TYPE_DRM, $CAIRO_DEVICE_TYPE_GL, $CAIRO_DEVICE_TYPE_SCRIPT, $CAIRO_DEVICE_TYPE_XCB, $CAIRO_DEVICE_TYPE_XLIB, $CAIRO_DEVICE_TYPE_XML, $CAIRO_DEVICE_TYPE_COGL, _
            $CAIRO_DEVICE_TYPE_WIN32, $CAIRO_DEVICE_TYPE_INVALID = -1

;cairo_surface_observer_mode_t as long
Global Enum $CAIRO_SURFACE_OBSERVER_NORMAL, $CAIRO_SURFACE_OBSERVER_RECORD_OPERATIONS

;cairo_surface_type as long
Global Enum $CAIRO_SURFACE_TYPE_IMAGE, $CAIRO_SURFACE_TYPE_PDF, $CAIRO_SURFACE_TYPE_PS, $CAIRO_SURFACE_TYPE_XLIB, $CAIRO_SURFACE_TYPE_XCB, $CAIRO_SURFACE_TYPE_GLITZ, $CAIRO_SURFACE_TYPE_QUARTZ,$CAIRO_SURFACE_TYPE_WIN32, _
            $CAIRO_SURFACE_TYPE_BEOS, $CAIRO_SURFACE_TYPE_DIRECTFB, $CAIRO_SURFACE_TYPE_SVG, $CAIRO_SURFACE_TYPE_OS2, $CAIRO_SURFACE_TYPE_WIN32_PRINTING, $CAIRO_SURFACE_TYPE_QUARTZ_IMAGE, $CAIRO_SURFACE_TYPE_SCRIPT, _
            $CAIRO_SURFACE_TYPE_QT, $CAIRO_SURFACE_TYPE_RECORDING, $CAIRO_SURFACE_TYPE_VG, $CAIRO_SURFACE_TYPE_GL, $CAIRO_SURFACE_TYPE_DRM, $CAIRO_SURFACE_TYPE_TEE, $CAIRO_SURFACE_TYPE_XML, $CAIRO_SURFACE_TYPE_SKIA, _
            $CAIRO_SURFACE_TYPE_SUBSURFACE, $CAIRO_SURFACE_TYPE_COGL

;cairo_pattern_type as long
Global Enum $CAIRO_PATTERN_TYPE_SOLID, $CAIRO_PATTERN_TYPE_SURFACE, $CAIRO_PATTERN_TYPE_LINEAR, $CAIRO_PATTERN_TYPE_RADIAL, $CAIRO_PATTERN_TYPE_MESH, $CAIRO_PATTERN_TYPE_RASTER_SOURCE

;cairo_extend as long
Global Enum $CAIRO_EXTEND_NONE, $CAIRO_EXTEND_REPEAT, $CAIRO_EXTEND_REFLECT, $CAIRO_EXTEND_PAD

;cairo_filter as long
Global Enum $CAIRO_FILTER_FAST, $CAIRO_FILTER_GOOD, $CAIRO_FILTER_BEST, $CAIRO_FILTER_NEAREST, $CAIRO_FILTER_BILINEAR, $CAIRO_FILTER_GAUSSIAN

;cairo_region_overlap as long
Global Enum $CAIRO_REGION_OVERLAP_IN, $CAIRO_REGION_OVERLAP_OUT, $CAIRO_REGION_OVERLAP_PART

#EndRegion

#Region tag structs
;structs
Global Const $tagCairo_rectangle_int = "long x;long y;long width;long height;"
Global Const $tagCairo_rectangle_list = "long status;ptr rectangles;long num_rectangles;"
Global Const $tagCairo_matrix = "double xx;double yx;double xy;double yy;double x0;double y0;"
Global Const $tagCairo_glyph_t = (@AutoItX64 ? "uinteger" : "ulong") & " index;double x;double y;"
Global Const $tagCairo_text_cluster_t = "long num_bytes;long num_glyphs;"
Global Const $tagCairo_text_extents_t = "double x_bearing;double y_bearing;double width;double height;double x_advance;double y_advance;"
Global Const $tagCairo_font_extents_t = "double ascent;double descent;double height;double max_x_advance;double max_y_advance;"
Global Const $tagCairo_path_data_t_header = "long type;long length;"
Global Const $tagCairo_path_data_t_point = "double x;double y;"
Global Const $tagCairo_path_data_t = "ptr path;"
Global Const $tagCairo_path = "long status;ptr data;long num_data;"
#EndRegion


Global $g_hCairoDLL = 0

Func Cairo_Init($sPath = Default)
    Local Const $sDLL = ($sPath = Default ? (@AutoItX64 ? (@ScriptDir & "\cairo64.dll") : (@ScriptDir & "\cairo.dll")) : $sPath)
    If Not FileExists($sDLL) Then Return SetError(1, 0, 0)
    $g_hCairoDLL = DllOpen($sDLL)
    If $g_hCairoDLL = -1 Or @error Then Return SetError(2, 0, 0)
    Return 1
EndFunc

Func Cairo_Close()
    If $g_hCairoDLL Then Return DllClose($g_hCairoDLL)
    Return 0
EndFunc

Func Cairo_GetStride($iW, $iFormat = $CAIRO_FORMAT_ARGB32)
    Local Const $aStride = DllCall($g_hCairoDLL, "long:cdecl", "cairo_format_stride_for_width", "long", $iFormat, "long", $iW) ;BitShift($iW * 32 + 15, 4) * 2 * $iH
    If @error Or Not IsArray($aStride) Then Return SetError(1, 0, 0)
    If Not $aStride[0] Then Return SetError(2, 0, 0)
    Return $aStride[0]
EndFunc

Func Cairo_CreateWin32Surface($hDC)
    Local Const $aSurface = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_win32_surface_create", "ptr", $hDC)
    If @error Or Not IsArray($aSurface) Then Return SetError(1, 0, 0)
    If Not $aSurface[0] Then Return SetError(2, 0, 0)
    Return $aSurface[0]
EndFunc

Func Cairo_CreateWin32SurfacePrinting($hDC)
    Local Const $aSurface = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_win32_printing_surface_create", "ptr", $hDC)
    If @error Or Not IsArray($aSurface) Then Return SetError(1, 0, 0)
    If Not $aSurface[0] Then Return SetError(2, 0, 0)
    Return $aSurface[0]
EndFunc

Func Cairo_CreateWin32SurfaceWithFormat($hDC, $iFormat = $CAIRO_FORMAT_ARGB32)
    Local Const $aSurface = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_win32_surface_create_with_format", "ptr", $hDC, "long", $iFormat)
    If @error Or Not IsArray($aSurface) Then Return SetError(1, 0, 0)
    If Not $aSurface[0] Then Return SetError(2, 0, 0)
    Return $aSurface[0]
EndFunc

Func Cairo_CreateWin32SurfaceWithDDB($hDC, $iW, $iH, $iFormat = $CAIRO_FORMAT_ARGB32)
    Local Const $aSurface = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_win32_surface_create_with_ddb", "ptr", $hDC, "long", $iFormat, "long", $iw, "long", $ih)
    If @error Or Not IsArray($aSurface) Then Return SetError(1, 0, 0)
    If Not $aSurface[0] Then Return SetError(2, 0, 0)
    Return $aSurface[0]
EndFunc

Func Cairo_CreateSurfaceImageData($pImageData, $iW, $iH, $iStride, $iFormat = $CAIRO_FORMAT_ARGB32)
    Local Const $aSurface = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_image_surface_create_for_data", "ptr", $pImageData, "long", $iFormat, "long", $iW, "long", $iH, "long", $iStride)
    If @error Or Not IsArray($aSurface) Then Return SetError(1, 0, 0)
    If Not $aSurface[0] Then Return SetError(2, 0, 0)
    Return $aSurface[0]
EndFunc

Func Cairo_CreateContext($pSurface)
    Local Const $aContext = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_create", "ptr", $pSurface)
    If @error Or Not IsArray($aContext) Then Return SetError(1, 0, 0)
    If Not $aContext[0] Then Return SetError(2, 0, 0)
    Return $aContext[0]
EndFunc

Func Cairo_DestroyContext($pContext)
    If Not $pContext Then Return SetError(1, 0, 0)
    DllCall($g_hCairoDLL, "none:cdecl", "cairo_destroy", "ptr", $pContext)
    Return 1
EndFunc

Func Cairo_DestroySurface($pSurface)
    If Not $pSurface Then Return SetError(1, 0, 0)
    DllCall($g_hCairoDLL, "none:cdecl", "cairo_surface_destroy", "ptr", $pSurface)
    Return 1
EndFunc

Func Cairo_ClearContext($pContext, $r = 0, $g = 0, $b = 0, $a = 1)
    If Not $pContext Then Return SetError(1, 0, 0)
    DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_source_rgb", "ptr", $pContext, "double", $r, "double", $g, "double", $b, "double", $a)
    DllCall($g_hCairoDLL, "none:cdecl", "cairo_paint", "ptr", $pContext)
EndFunc

Alles anzeigen

Beispiel:

C

#AutoIt3Wrapper_UseX64=n

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include "Cairo.au3"

AutoItSetOption('MustDeclareVars', 1)

Global Const $fPi = ACos(-1), $fRad = $fPi / 180, $fDeg = 180 / $fPi, $f2PI = $fPi * 2
Global Const $iW = 600, $iH = 400, $sTitle = "Cairo Test / FPS: "
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit

AutoItSetOption("GUIOnEventMode", 1)

Cairo_Test()

AutoItSetOption("GUIOnEventMode", 0)


Func Cairo_Test()
	Cairo_Init()
	Local $iStride = Cairo_GetStride($iW)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iStride = ' & $iStride & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

	$hGUI = GUICreate($sTitle & "0", $iW, $iH)
	Local Const $hDC = _WinAPI_GetDC($hGUI)
;~ 	Local $tBits = DllStructCreate("long[" & $iStride * $iH & "]")
;~ 	Local Const $hBitmapGDI = _WinAPI_CreateBitmap($iW, $iH, 1, 32, $tBits)
	Local Const $hBitmapGDI = _WinAPI_CreateCompatibleBitmap($hDC, $iW, $iH)
	Local Const $hGfxDC = _WinAPI_CreateCompatibleDC($hDC)
	Local Const $hObjOld = _WinAPI_SelectObject($hGfxDC, $hBitmapGDI)
	GUISetState(@SW_SHOW, $hGUI)


	$bExit = False
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
	AdlibRegister("CalcFPS", 1000)

	Local $pSurface = Cairo_CreateWin32Surface($hGfxDC)

	ConsoleWrite("Surface status: " & DllCall($g_hCairoDLL, "long:cdecl", "cairo_surface_status", "ptr", $pSurface)[0] & @CRLF)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $pSurface = ' & $pSurface & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

	Local $pContext = Cairo_CreateContext($pSurface)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $pContext = ' & $pContext & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console


	ConsoleWrite(DllCall($g_hCairoDLL, "str:cdecl", "cairo_status_to_string")[0] & @CRLF)

	Local $t, $tt = 1 / 60, $x, $y, $c
	Local $tPAINTSTRUCT

	Do
        _WinAPI_BeginPaint($hGUI, $tPAINTSTRUCT)

		$c = 0.5 + 0.5 * Sin($t)
		Cairo_ClearContext($pContext, $c, $c, $c)


		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_source_rgba", "ptr", $pContext, "double", 0, "double", 0, "double", 0.5 + 0.5 * Cos($t), "double", 1.0)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_line_width", "ptr", $pContext, "double", $iH / 10)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_rectangle", "ptr",  $pContext, "double", $iW / 4, "double", $iH / 4, "double", $iW / 2, "double", $iH / 2)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)



		_WinAPI_EndPaint($hGUI, $tPAINTSTRUCT)

		$t += $tt

		_WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hGfxDC, 0, 0, $SRCCOPY)

		$iFPS += 1
		If $bExit Then ExitLoop
	Until Not Sleep(10)

	Cairo_DestroyContext($pContext)
	Cairo_DestroySurface($pSurface)

	_WinAPI_SelectObject($hGfxDC, $hObjOld)
	_WinAPI_ReleaseDC($hGUI, $hDC)
	_WinAPI_DeleteDC($hGfxDC)
	_WinAPI_DeleteObject($hBitmapGDI)
	GUIDelete($hGUI)
	Cairo_Close()

EndFunc

Func _Exit()
	$bExit = True
EndFunc   ;==>_Exit_About

Func CalcFPS() ;display FPS
	$iShowFPS = $iFPS
	$iFPS = 0
	WinSetTitle($hGUI, "", $sTitle & $iShowFPS)
EndFunc   ;==>CalcFPS

Alles anzeigen

Soweit funktioniert das Beispiel, nur wenn ich die Position über eine Variable in der cairo_rectangle Funktion hinzufüge, dann passiert nichts mehr.

Ich habe nicht herausgefunden, was man tun muss, damit auch Animationen möglich sind. Somit könnte man Cairo mit GDI / GDI+ vergleichen.

Die benötigten DLLs sind im Anhang zu finden.

Hat jemand eine Idee?

**AspirinJunkie**

Zitat von UEZ

nur wenn ich die Position über eine Variable in der cairo_rectangle Funktion hinzufüge, dann passiert nichts mehr.

Ich verstehe noch nicht ganz die Problemlage.
Du verwendest doch bereits Variablen für die Positionsparameter.
Und augenscheinlich funtkionieren diese bei mir auch.

Hab es auch mal so angepasst, dass sie sich ändern und das ganze daher animiert wird:

AutoIt

Local $x = 0, $y = 0
	Do
        _WinAPI_BeginPaint($hGUI, $tPAINTSTRUCT)
		$x = Mod($x+ 1, $iW)
		$y = Mod($y + 1, $iH)

		$c = 0.5 + 0.5 * Sin($t)
		Cairo_ClearContext($pContext, $c, $c, $c)

		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_source_rgba", "ptr", $pContext, "double", 0, "double", 0, "double", 0.5 + 0.5 * Cos($t), "double", 1.0)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_line_width", "ptr", $pContext, "double", $iH / 10)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_rectangle", "ptr",  $pContext, "double", $x, "double", $y, "double", $iW / 2, "double", $iH / 2)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)

Alles anzeigen

Auch das funktioniert bei mir wunderbar.
Ich habe dein Problem also offensichtlich noch nicht ganz verstanden.

**UEZ**

Hallo AspirinJunkie,

danke für dein Feedback.

Wenn du einfach die Zeile durch diese ersetzt,

Code

DllCall($g_hCairoDLL, "none:cdecl", "cairo_rectangle", "ptr",  $pContext, "double", $t + $iW / 4, "double", $iH / 4, "double", $iW / 2, "double", $iH / 2)

dann sollte die Grafik gelöscht werden und weiter passiert nichts. Eigentlich sollte das Viereck nach rechts wandern.

Velted

Moin UEZ

ich bin nicht sicher, meinst Du so etwas?

AutoIt

#AutoIt3Wrapper_UseX64=n

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include "Cairo.au3"

AutoItSetOption('MustDeclareVars', 1)

Global Const $fPi = ACos(-1), $fRad = $fPi / 180, $fDeg = 180 / $fPi, $f2PI = $fPi * 2
Global Const $iW = 600, $iH = 400, $sTitle = "Cairo Test / FPS: "
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit

AutoItSetOption("GUIOnEventMode", 1)

Cairo_Test()

AutoItSetOption("GUIOnEventMode", 0)


Func Cairo_Test()
	Cairo_Init()
	Local $iStride = Cairo_GetStride($iW)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iStride = ' & $iStride & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

	$hGUI = GUICreate($sTitle & "0", $iW, $iH)
	Local Const $hDC = _WinAPI_GetDC($hGUI)
;~ 	Local $tBits = DllStructCreate("long[" & $iStride * $iH & "]")
;~ 	Local Const $hBitmapGDI = _WinAPI_CreateBitmap($iW, $iH, 1, 32, $tBits)
	Local Const $hBitmapGDI = _WinAPI_CreateCompatibleBitmap($hDC, $iW, $iH)
	Local Const $hGfxDC = _WinAPI_CreateCompatibleDC($hDC)
	Local Const $hObjOld = _WinAPI_SelectObject($hGfxDC, $hBitmapGDI)
	GUISetState(@SW_SHOW, $hGUI)


	$bExit = False
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
	AdlibRegister("CalcFPS", 1000)

	Local $pSurface = Cairo_CreateWin32Surface($hGfxDC)
	ConsoleWrite("Surface status: " & DllCall($g_hCairoDLL, "long:cdecl", "cairo_surface_status", "ptr", $pSurface)[0] & @CRLF)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $pSurface = ' & $pSurface & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

	Local $pContext = Cairo_CreateContext($pSurface)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $pContext = ' & $pContext & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
	ConsoleWrite(DllCall($g_hCairoDLL, "str:cdecl", "cairo_status_to_string")[0] & @CRLF)

	Local $t, $tt = 1 / 60, $x, $y, $c
	Local $tPAINTSTRUCT
	Local $iRX = 0, $iRY = 0, $iRW = 100, $iRH = 100
	Do
        _WinAPI_BeginPaint($hGUI, $tPAINTSTRUCT)
		$c = 0.5 + 0.5 * Sin($t)
		Cairo_ClearContext($pContext, $c, $c, $c)


		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_source_rgba", "ptr", $pContext, "double", 0, "double", 0, "double", 0.5 + 0.5 * Cos($t), "double", 1.0)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_line_width", "ptr", $pContext, "double", $iH / 10)
		; DllCall($g_hCairoDLL, "none:cdecl", "cairo_rectangle", "ptr",  $pContext, "double", $iW / 4, "double", $iH / 4, "double", $iW / 2, "double", $iH / 2)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_rectangle", "ptr",  $pContext, "double", $iRX, "double", $iRY, "double", $iRW, "double", $iRH)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)

		$iRX += 1
		$iRY += 1
		If ($iRX + $iRW) > $iW Then $iRX = 0
		If ($iRY + $iRH) > $iH Then $iRY = 0

		_WinAPI_EndPaint($hGUI, $tPAINTSTRUCT)

		$t += $tt


		_WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hGfxDC, 0, 0, $SRCCOPY)

		$iFPS += 1
		If $bExit Then ExitLoop
	Until Not Sleep(10)

	Cairo_DestroyContext($pContext)
	Cairo_DestroySurface($pSurface)

	_WinAPI_SelectObject($hGfxDC, $hObjOld)
	_WinAPI_ReleaseDC($hGUI, $hDC)
	_WinAPI_DeleteDC($hGfxDC)
	_WinAPI_DeleteObject($hBitmapGDI)
	GUIDelete($hGUI)
	Cairo_Close()

EndFunc

Func _Exit()
	$bExit = True
EndFunc   ;==>_Exit_About

Func CalcFPS() ;display FPS
	$iShowFPS = $iFPS
	$iFPS = 0
	WinSetTitle($hGUI, "", $sTitle & $iShowFPS)
EndFunc   ;==>CalcFPS

Alles anzeigen

**UEZ**

Velted Moin.

Genau, das meine ich, aber warum funktioniert nicht das, wenn ich dies im DllCall eintrage.

Hmmm...

**AspirinJunkie**

Wenn ich Round($t + $iW / 4) eintrage, dann geht es wieder.
Offensichtlich dürfen dort nur ganzzahlige Werte eingetragen werden.
Das widerspricht aber bisschen dem Double-Typ.
Da hätte man ja gleich einen Integer dafür nehmen können.
Vielleicht verstehen wir da was prinzipielles noch nicht.

**UEZ**

Genau das habe ich auch eben getestet - Integer funktioniert, Gleitkommazahlen nicht! Laut Definition sollte es aber Double sein!?!!??!

Code

void
cairo_rectangle (cairo_t *cr,
                 double x,
                 double y,
                 double width,
                 double height);

**AspirinJunkie**

Ja du übergibst es ja auch als Double.
Integer 5 ist anders kodiert als 5.0 Double.
Und DllCall übergibt eben als Double.
Integer zu übergeben wird daher nicht funktionieren.

Das heißt im Grunde, man kann nur ganzzahlige Werte übergeben aber dennoch als Double kodiert.
Was für ein Unsinn.

**UEZ**

Zitat von AspirinJunkie

Was für ein Unsinn.

Und DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_line_width", "ptr", $pContext, "double", $iH / 10) scheint nur mit ganzen geraden Zahlen zu funktionieren...

Wie auch immer, danke für euer Feedback. Gehe jetzt aber mal in die Mucki Bude mich abreagieren...

**UEZ**

Irgendwie schaffe ich es nicht eine Linie zu ziehen oder einen Kreis zu zeichnen, das angezeigt wird.

Hat jemand eine Idee, woran das liegen könnte?

Kreis:

Code

DllCall($g_hCairoDLL, "none:cdecl", "cairo_arc", "ptr", $pContext, "double", ($iW / 2), "double", ($iH / 2), "double", 100, "double", 0, "double", 2 * $fPi)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_fill", "ptr", $pContext)

Linie:

Code

		DllCall($g_hCairoDLL, "none:cdecl", "cairo_move_to", "ptr", $pSurface, "double", $x, "double", $y)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_line_to", "ptr", $pSurface, "double", $iW, "double", $iH)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)

Danke.

**UEZ**

Liegt an den DLLs!

Mit denen funzt's für x86. Ich habe noch keine DLLs für x64 gefunden...

Edit: für den Kreis funzt's, aber keine Linien möglich - Absturz.

Velted

Moin,

ich habe mich gestern lange und intensiv mit den Beipielen beschäftigt. Dabei hatte ich immer wieder Rückschläge, die ich mir nicht erklären konnte. Kurz vor dem endgültigem Aufgeben entstand dann aber doch noch eine (überwiegend) funktionierende Lösung. Nach verdienter Nachtruhe habe ich die noch etwas aufgebohrt und bin jetzt recht zufrieden damit.

Ich wollte von vornherein ohne Umwege über Bitmaps/BitBlts direkt mit dem DC arbeiten. Nach vielem Try&Error habe ich dann folgendes in der Cairo-Doku gelesen:

Zitat

The resulting surface will always be of format CAIRO_FORMAT_RGB24; should you need another surface format, you will need to create one through cairo_win32_surface_create_with_format() or cairo_win32_surface_create_with_dib().

Windows unterstützt seit Version 8 nur noch 32-Bit (A)RGB. Das scheint nicht so recht zu cairo_win32_surface_create () passen. Ich habe deshalb für Win 10 die Funktion Cairo_CreateWin32SurfaceWithFormat mit $CAIRO_FORMAT_ARGB32 aufgerufen, und siehe, alles lief deutlich besser. Beim Versuch, ein Control als Zeichenfläche zu nutzen, musste ich zunächst feststellen, dass Cairo den gesamten Clientbereich des Elternfensters übermalt. Die Erklärung fand sich hier:

Zitat

The DC will be queried for its initial clip extents, and this will be used as the size of the cairo surface.

Ich habe einfach mal vermutet, dass da etwas nicht passt, und eine passende Clipping-Region gesetzt. Das hatte tatsächlich den gewünschten Erfolg.

Lange Rede, kurzer Sinn, hier kommt das Ergebnis all meiner Mühe. Es läuft hier stabil mit den DLLs aus dem ersten Beitrag mit 32 und 64 Bit:

AutoIt: Cairo_Test.au3

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPISysWin.au3>
#include "Cairo.au3"

AutoItSetOption('MustDeclareVars', 1)

Global Const $fPi = ACos(-1), $fRad = $fPi / 180, $fDeg = 180 / $fPi, $f2PI = $fPi * 2
Global Const $iW = 600, $iH = 400
Global $sTitle = "Cairo Test (" & (@AutoItX64 ? "64" : "32") & " Bit) / FPS: "
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit
Global $iRX = 0, $iRY = 0, $iRW = 0, $iRH = 0
Global $iDX = 0, $iDY = 0
Global $sShape = ""

_DrawRectangle()

AutoItSetOption("GUIOnEventMode", 1)

Cairo_Test()

AutoItSetOption("GUIOnEventMode", 0)


Func Cairo_Test()
	Cairo_Init()

	$hGUI = GUICreate($sTitle & "0", $iW + 20, $iH + 55)
	GUICtrlCreateLabel('', 10, 10, $iW, $iH)
	Local $hSurface = GUICtrlGetHandle(-1)
	GUICtrlCreateButton('Rectangle', 10,  $iH + 20, 135)
	GUICtrlSetOnEvent(-1, '_DrawRectangle')
	GUICtrlCreateButton('Arc', 165, $iH + 20, 135)
	GUICtrlSetOnEvent(-1, '_DrawArc')
	GUICtrlCreateButton('Line', 320, $iH + 20, 135)
	GUICtrlSetOnEvent(-1, '_DrawLine')
	GUICtrlCreateButton('Stop', 475, $iH + 20, 135)
	GUICtrlSetOnEvent(-1, '_StopDrawing')
	Local $hClipRgn = _WinAPI_CreateRectRgn(0, 0, $iW, $iH)
	GUISetState(@SW_SHOW, $hGUI)

	$bExit = False
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
 	AdlibRegister("CalcFPS", 1000)

	Local $t, $tt = 1 / 60, $x, $y, $c
	Local $pSurface = 0, $pContext = 0, $hDC = 0

	_SetTimerResolution("Min")

	Do
		If $sShape = 'Stop' Then ContinueLoop
		$c = 0.5 + 0.5 * Sin($t)
		; Der von GetDC gelieferte DC hat keine Cipping-Region.
		; Für Controls muss deshalb eine passende erstellt werden, damit Cairo die Größe erkennt.
		; Ansonsten nimmt Cairo den gesamten Clientbereich des GUI-Fensters.
		Local $hDC = _WinAPI_GetDC($hSurface)
		_WinAPI_SelectClipRgn($hDC, $hClipRgn)
		$pSurface = Cairo_CreateWin32SurfaceWithFormat($hDC)
		$pContext = Cairo_CreateContext($pSurface)
		Cairo_ClearContext($pContext, $c, $c, $c)
		; DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_source_rgba", "ptr", $pContext, "double", 0, "double", 0, "double", 0.5 + 0.5 * Cos($t), "double", 1.0)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_source_rgb", "ptr", $pContext, "double", 0, "double", 0, "double", 0.5 + 0.5 * Cos($t))
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_line_width", "ptr", $pContext, "double", 1)
		Switch $sShape
			Case 'Rectangle'
				DllCall($g_hCairoDLL, "none:cdecl", "cairo_rectangle", "ptr", $pContext, "double", $iRX, "double", $iRY, "double", $iRW, "double", $iRH)
			Case 'Arc'
				DllCall($g_hCairoDLL, "none:cdecl", "cairo_arc", "ptr", $pContext, "double", $iRX, "double", $iRY, "double", $iRW, "double", 0.0, "double", $f2PI)
				DllCall($g_hCairoDLL, "none:cdecl", "cairo_fill", "ptr", $pContext)
			Case 'Line'
				DllCall($g_hCairoDLL, "none:cdecl", "cairo_move_to", "ptr", $pContext, "double", 0, "double", 0)
				DllCall($g_hCairoDLL, "none:cdecl", "cairo_line_to", "ptr", $pContext, "double", $iRW, "double", $iRH)
		EndSwitch
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)
		; DllCall($g_hCairoDLL, "none:cdecl", "cairo_flush", "ptr", $pSurface)
		Cairo_DestroyContext($pContext)
		Cairo_DestroySurface($pSurface)
		_WinAPI_ReleaseDC($hSurface, $hDC)

		$iRX += $iDX
		$iRY += $iDY
		Switch $sShape
			Case 'Rectangle'
				$iRX += $iDX
				$iRY += $iDY
				If ($iRX < 0) Or ($iRX + $iRW) > $iW Then $iDX *= -1
				If ($iRY < 0) Or ($iRY + $iRH) > $iH Then $iDY *= -1
			Case 'Arc'
				$iRX += $iDX
				$iRY += $iDY
				If (($iRX - $iRW) < 0) Or (($iRX + $iRW) > $iW) Then $iDX *= -1
				If (($iRY - $iRW) < 0) Or (($iRY + $iRW) > $iH) Then $iDY *= -1
			Case 'Line'
				$iRH += $iDY
				If $iRH < 0 Then $iDY *= -1
				If $iRH > $iH Then $iDY *= -1
		EndSwitch

		$t += $tt

		$iFPS += 1
		If $bExit Then ExitLoop
		_SleepXS(4)
	Until False

	_SetTimerResolution("Def")
	_WinAPI_DeleteObject($hClipRgn)
	GUIDelete($hGUI)
	Cairo_Close()
EndFunc

Func _Exit()
	$bExit = True
EndFunc   ;==>_Exit

Func CalcFPS() ;display FPS
	$iShowFPS = $iFPS
	$iFPS = 0
	WinSetTitle($hGUI, "", $sTitle & $iShowFPS)
EndFunc   ;==>CalcFPS

Func _DrawRectangle()
	$sShape = 'Rectangle'
	$iRX = 0
	$iRY = 0
	$iRW = 100
	$iRH = 100
	$iDX = 1
	$iDY = 1
EndFunc
Func _DrawArc()
	$sShape = 'Arc'
	$iRX = 100
	$iRY = 100
	$iRW = 50
	$iRH = 50
	$iDX = 1
	$iDY = 1
EndFunc

Func _DrawLine()
	$sShape = 'Line'
	$iRX = 0
	$iRY = 0
	$iRW = $iW
	$iRH = $iH
	$iDX = 1
	$iDY = 1
EndFunc

Func _StopDrawing()
	$sShape = 'Stop'
EndFunc

Func _SleepXS($iMS)
	DllCall("Kernel32.dll", "NONE", "Sleep", "UInt", $iMS)
EndFunc

Func _SetTimerResolution($vRes)
	Static  $iMax = 0, $iMin = 0, $iDef = 0
	Local $aCall = 0
	If $iDef = 0 Then
		$aCall = DllCall("Ntdll.dll", "BOOL", "NtQueryTimerResolution", "UInt*", $iMax, "UInt*", $iMin, "UInt*", $iDef)
		If $aCall[0] = 0 Then
			$iMax = $aCall[1]
			$iMin = $aCall[2]
			$iDef = $aCall[3]
		Else
			Return SetError(1, 0, 0)
		EndIf
	EndIf
	Switch $vRes
		Case "Def"
			$vRes = $iDef
		Case "Max"
			$vRes = $iMax
		Case "Min"
			$vRes = $iMin
		Case Else
			If IsNumber($vRes) Then
				$vRes *= 10000
				If $vRes < $iMin Then $vRes = $iMin
				If $vRes > $iMax Then $vRes = $iMax
			Else
				Return SetError(2, 0, 0)
			EndIf
	EndSwitch
	Return Not DllCall("Ntdll.dll", "BOOL", "NtSetTimerResolution", "UInt", $vRes, "UInt", 1, "UInt*", 0)[0]
EndFunc

Alles anzeigen

Velted

Nachschlag für UEZ

Code

        DllCall($g_hCairoDLL, "none:cdecl", "cairo_move_to", "ptr", $pSurface, "double", $x, "double", $y)
        DllCall($g_hCairoDLL, "none:cdecl", "cairo_line_to", "ptr", $pSurface, "double", $iW, "double", $iH)
        DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)

Das kann nicht funktionieren, weil Du versuchst, auf $pSurface zu zeichnen.

**UEZ**

Danke Velted fürs Nachforschen und das Erstellen des Beispiels . Die ursprünglichen zwei DLLs funktionieren, und machen keine Probleme. Das Problem war anscheinend mein Code.

Zitat von Velted

Nachschlag für UEZ

Code

        DllCall($g_hCairoDLL, "none:cdecl", "cairo_move_to", "ptr", $pSurface, "double", $x, "double", $y)
        DllCall($g_hCairoDLL, "none:cdecl", "cairo_line_to", "ptr", $pSurface, "double", $iW, "double", $iH)
        DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)

Das kann nicht funktionieren, weil Du versuchst, auf $pSurface zu zeichnen.

Ich Idiot und ich suche mir einen Wolf, warum das nicht funzt.

Hier der Code, welches auch bei mir funzt:

C

#AutoIt3Wrapper_UseX64=n

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include "Cairo.au3"

AutoItSetOption('MustDeclareVars', 1)

Global Const $fPi = ACos(-1), $fRad = $fPi / 180, $fDeg = 180 / $fPi, $f2PI = $fPi * 2
Global Const $iW = 600, $iH = 400, $sTitle = "Cairo Test / FPS: "
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit

AutoItSetOption("GUIOnEventMode", 1)

Cairo_Test()

AutoItSetOption("GUIOnEventMode", 0)


Func Cairo_Test()
	Cairo_Init()
	Local $iStride = Cairo_GetStride($iW)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $iStride = ' & $iStride & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

	$hGUI = GUICreate($sTitle & "0", $iW, $iH)
	Local Const $hDC = _WinAPI_GetDC($hGUI)
	Local Const $hGfxDC = _WinAPI_CreateCompatibleDC($hDC)
	Local $tBIV5HDR = DllStructCreate($tagBITMAPV5HEADER)
	DllStructSetData($tBIV5HDR, 'bV5Size', DllStructGetSize($tBIV5HDR))
	DllStructSetData($tBIV5HDR, 'bV5Width', $iW)
	DllStructSetData($tBIV5HDR, 'bV5Height', -$iH)
	DllStructSetData($tBIV5HDR, 'bV5Planes', 1)
	DllStructSetData($tBIV5HDR, 'bV5BitCount', 32)
	DllStructSetData($tBIV5HDR, 'biCompression', $BI_RGB)
	DllStructSetData($tBIV5HDR, 'bV5RedMask', 0x00FF0000)
	DllStructSetData($tBIV5HDR, 'bV5GreenMask', 0x0000FF00)
	DllStructSetData($tBIV5HDR, 'bV5BlueMask', 0x000000FF)
	DllStructSetData($tBIV5HDR, 'bV5AlphaMask', 0xFF000000)
	Local $pBits
	Local $hBitmapGDI = _WinAPI_CreateDIBSection($hGfxDC, $tBIV5HDR, $DIB_RGB_COLORS, $pBits)
	Local Const $hObjOld = _WinAPI_SelectObject($hGfxDC, $hBitmapGDI)

	GUISetState(@SW_SHOW, $hGUI)

	$bExit = False
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
	AdlibRegister("CalcFPS", 1000)

	Local $pSurface
	$pSurface = DllCall($g_hCairoDLL, "ptr:cdecl", "cairo_image_surface_create_for_data", "ptr", $pBits, "long", $CAIRO_FORMAT_ARGB32, "long", $iW, "long", $iH, "long", $iStride)[0]

	Local $pContext = Cairo_CreateContext($pSurface)

	Local $t, $tt = 1 / 60, $x, $y, $c, $w = $iW / 2, $h = $iH / 2
	Local $tPAINTSTRUCT

	Do
        _WinAPI_BeginPaint($hGUI, $tPAINTSTRUCT)

		$c = 0.5 + 0.5 * Sin($t)
		$x = Int($iW / 4 + Sin($t) * 20)
		$y = Int($iH / 4 + Cos($t) * 20)

		Cairo_ClearContext($pContext, $c, $c, $c)

		Cairo_SetColor($pContext, 1, 1, 0, 1)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_arc", "ptr", $pContext, "double", ($iW / 2), "double", ($iH / 2), "double", 70, "double", 0, "double", 2 * $fPi)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_fill", "ptr", $pContext)

		Cairo_SetColor($pContext, 0, 0, 0.5 + 0.5 * Cos($t))
		Cairo_SetLineWidth($pContext, 20)
		Cairo_DrawRectangle($pContext, $x, $y, $w, $h)

		Cairo_SetColor($pContext, 1, 0, 0, 1)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_set_line_width", "ptr", $pContext, "double", 20)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_move_to", "ptr", $pContext, "double", $iw / 2, "double", $iH / 2)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_line_to", "ptr", $pContext, "double", $x, "double", $y)
		DllCall($g_hCairoDLL, "none:cdecl", "cairo_stroke", "ptr", $pContext)

		_WinAPI_EndPaint($hGUI, $tPAINTSTRUCT)

		$t += $tt

		_WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hGfxDC, 0, 0, $SRCCOPY)
		$iFPS += 1
		If $bExit Then ExitLoop
	Until Not Sleep(10)

	Cairo_DestroyContext($pContext)
	Cairo_DestroySurface($pSurface)

	_WinAPI_SelectObject($hGfxDC, $hObjOld)
	_WinAPI_ReleaseDC($hGUI, $hDC)
	_WinAPI_DeleteDC($hGfxDC)
	_WinAPI_DeleteObject($hBitmapGDI)
	GUIDelete($hGUI)
	Cairo_Close()
EndFunc

Func _Exit()
	$bExit = True
EndFunc   ;==>_Exit_About

Func CalcFPS() ;display FPS
	$iShowFPS = $iFPS
	$iFPS = 0
	WinSetTitle($hGUI, "", $sTitle & $iShowFPS)
EndFunc   ;==>CalcFPS

Alles anzeigen

Ich werde weitere Möglichkeiten checken, wie man Cairo unter Windows noch initiieren kann.

**UEZ**

Ich habe weitere Funktionen portiert (siehe Anhang).

Hier ein weiteres Beispiel.

AutoIt

;Coded by UEZ build 2024-03-29 beta
#AutoIt3Wrapper_UseX64=y

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include "Cairo.au3"

AutoItSetOption('MustDeclareVars', 1)

Global Const $fPi = ACos(-1), $fRad = $fPi / 180, $fDeg = 180 / $fPi, $f2PI = $fPi * 2
Global Const $iW = 960, $iH = 540, $sTitle = "Cairo Test (" & (@AutoItX64 ? "64" : "32") & " Bit) / FPS: "
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit

AutoItSetOption("GUIOnEventMode", 1)

Cairo_Example()

AutoItSetOption("GUIOnEventMode", 0)


Func Cairo_Example()
	If Not Cairo_Init() Then
		ConsoleWrite(@error & @CRLF)
		Exit
	EndIf
	Local $iStride = Cairo_GetStride($iW)

	$hGUI = GUICreate($sTitle & "0", $iW, $iH)
	Local Const $hDC = _WinAPI_GetDC($hGUI)
	Local Const $hGfxDC = _WinAPI_CreateCompatibleDC($hDC)

	Local $tBIV5HDR = DllStructCreate($tagBITMAPV5HEADER)
	DllStructSetData($tBIV5HDR, 'bV5Size', DllStructGetSize($tBIV5HDR))
	DllStructSetData($tBIV5HDR, 'bV5Width', $iW)
	DllStructSetData($tBIV5HDR, 'bV5Height', -$iH)
	DllStructSetData($tBIV5HDR, 'bV5Planes', 1)
	DllStructSetData($tBIV5HDR, 'bV5BitCount', 32)
	DllStructSetData($tBIV5HDR, 'biCompression', $BI_RGB)

	Local $pBits
	Local $hBitmapGDI = _WinAPI_CreateDIBSection($hGfxDC, $tBIV5HDR, $DIB_RGB_COLORS, $pBits)
	Local Const $hObjOld = _WinAPI_SelectObject($hGfxDC, $hBitmapGDI)

	GUISetState(@SW_SHOW, $hGUI)
	$bExit = False
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
	AdlibRegister("CalcFPS", 1000)

	Local $pSurface = Cairo_Image_CreateForData($pBits, $iW, $iH, $iStride)
	Local $pContext = Cairo_Context_Create($pSurface)
	Local $tMatrix = DllStructCreate($tagCairo_matrix)
	$tMatrix.x0 = $iW / 2
	$tMatrix.y0 = $iH / 2
	Local $t, $tt = 1 / 15, $b, $i, $q, $t1

	Do

		For $i = 50 To 1 Step -1
			$q = $i / 3
			$b = Sin($i / 9 - $t)
			$t1 = $q * Sin($b)
			$tMatrix.xx = $q * Cos($b)
			$tMatrix.yx = $t1
			$tMatrix.xy = -$t1
			$tMatrix.yy = $tMatrix.xx
			Cairo_Context_Transform($pContext, $tMatrix)
			Cairo_SetColor($pContext, 1 - 1 / ($i / 4))
			Cairo_FillRectangle($pContext, -48, -48, 96, 96)
			Cairo_Context_ResetIdentity($pContext)
		Next
		_WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hGfxDC, 0, 0, $SRCCOPY)

		$t += $tt

		$iFPS += 1
		If $bExit Then ExitLoop
	Until Not Sleep(10)

	Cairo_Context_Destroy($pContext)
	Cairo_Surface_Destroy($pSurface)

	_WinAPI_SelectObject($hGfxDC, $hObjOld)
	_WinAPI_ReleaseDC($hGUI, $hDC)
	_WinAPI_DeleteDC($hGfxDC)
	_WinAPI_DeleteObject($hBitmapGDI)
	GUIDelete($hGUI)
	Cairo_Close()

EndFunc

Func _Exit()
	$bExit = True
EndFunc   ;==>_Exit_About

Func CalcFPS() ;display FPS
	$iShowFPS = $iFPS
	$iFPS = 0
	WinSetTitle($hGUI, "", $sTitle & $iShowFPS)
EndFunc   ;==>CalcFPS

Alles anzeigen

Ich habe massiv die UDF geändert, d.h. die UDF im 1. Post wird nicht funktionieren und die UDF im Anhang unten kann noch viele Copy/Paste oder andere Fehler beinhalten! Die DLL kann im 1. Post heruntergeladen werden.

Habt ihr Lust Beispiele zu erstellen? Dann bitte hier Posten.

Etliche Funktionen sind noch nicht portiert, aber ich arbeite daran...

Happy Ostern!