Drag & Drop auf versteckten Button

**Tweaky**

Ich habe eine GUI. Dort verstecke ich einen Button.

Wie kann man verhindern, dass man per Drag & Drop eine Datei auf den versteckten Button ziehen kann?
Klar könnte man abfragen, ob der button versteckt ist.
Dies würde allerdings nicht klappen, wenn ich 2 Button übereinander liegen habe und immer einen von beiden verstecke.

AutoIt

#Region    ;************ Includes ************
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>
#EndRegion ;************ Includes ************

Opt("GUIOnEventMode", 1)

Global $hGui = GUICreate("test", 150, 200, -1, -1, -1, $WS_EX_ACCEPTFILES)
Global $idButton_1 = GUICtrlCreateButton("Button 1", 10, 10, 60, 30)
Global $idButton_2 = GUICtrlCreateButton("Button 2", 10, 60, 60, 30)
Global $idButton_beenden = GUICtrlCreateButton("Beenden", 10, 110, 60, 30)
Global $idLabel = GUICtrlCreateLabel("", 80, 35, 50, 35)

GUISetState(@SW_SHOW)

Sleep(2000)
GUICtrlSetState($idButton_1, $GUI_HIDE + $GUI_NODROPACCEPTED)

GUIRegisterMsg($WM_DROPFILES, "On_WM_DROPFILES")

GUISetOnEvent($GUI_EVENT_CLOSE, "_beenden")
GUICtrlSetOnEvent($idButton_beenden, "_beenden")


While 1
	Sleep(10)
WEnd


Func On_WM_DROPFILES($hWnd, $msg, $wParam, $lParam)
	Local $aFileList, $nSize, $pFileName, $tPoint, $hCtrl

	$tPoint = _WinAPI_DragQueryPoint($wParam)
	If Not DllStructGetSize($tPoint) Then Return     ;window border
	$hCtrl = _WinAPI_ChildWindowFromPointEx($hWnd, $tPoint)

	If $hCtrl = ControlGetHandle($hGui, "", $idButton_1) Then
		GUICtrlSetData($idLabel, "Button 1")
	ElseIf $hCtrl = ControlGetHandle($hGui, "", $idButton_2) Then
		GUICtrlSetData($idLabel, "Button 2")
	EndIf
	_WinAPI_DragFinish($wParam)
	_WinAPI_MessageBeep(0)         ;Ton erzeugen

	Return
EndFunc   ;==>On_WM_DROPFILES

Func _beenden()
	Exit
EndFunc   ;==>_beenden

Alles anzeigen

**Kanashius**

Hi

Die _WinAPI_ChildWindowFromPointEx hat ein paar flags, um unsichtbare Fenster zu ignorieren:

AutoIt

; https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-childwindowfrompointex
; 0 = All, 1 = SkipInvisible, 2 = SkipDisabled, 4 = SkipTransparent
$hCtrl = _WinAPI_ChildWindowFromPointEx($hWnd, $tPoint, BitOR(1, 2, 4))

Danach wird der unsichtbare Button nicht mehr gefunden, und je nach flags auch wenn er nur disabled ist.

Achja, fast vergessen:
Bei der suche nach dem Fehler hab ich auch nen Weg gefunden, wie man selbst schauen kann, welche controls an der Position sind:

AutoIt

Local $arChilds, $tWindowInfo
$arChilds = _WinAPI_EnumChildWindows($hWnd)
For $i=1 to UBound($arChilds)-1 step 1
	$tWindowInfo = _WinAPI_GetWindowInfo($arChilds[$i][0])
	ConsoleWrite($arChilds[$i][0]&" >> "&$arChilds[$i][1]&@crlf)
	;ConsoleWrite('Left:   ' & DllStructGetData($tWINDOWINFO, 'rWindow', 1) & @CRLF)
	;ConsoleWrite('Top:    ' & DllStructGetData($tWINDOWINFO, 'rWindow', 2) & @CRLF)
	;ConsoleWrite('Right:  ' & DllStructGetData($tWINDOWINFO, 'rWindow', 3) & @CRLF)
	;ConsoleWrite('Bottom: ' & DllStructGetData($tWINDOWINFO, 'rWindow', 4) & @CRLF)
Next

Velted

Moin,

warum benutzt Du nicht $GUI_EVENT_DROPPED?

**Tweaky**

Kanashius

Danke nun funktioniert es.

Velted

Ich würde aber gerne Opt("GUIOnEventMode", 1) aktiviert lassen.

Velted

Zitat von Tweaky

Ich würde aber gerne Opt("GUIOnEventMode", 1) aktiviert lassen.

Und wo ist das Problem?

AutoIt

GUISetOnEvent($GUI_EVENT_DROPPED, "_dropped")

**Tweaky**

Ah ok, gar nicht gewusst, dass es das bei GUISetOnEvent gibt.

Wieder was dazugelernt