MSSQL.au3 => Frage zu _MSSQL_Con

Code4Fun

Hallo zusammen,

ich habe jetzt schon ein paar Jahre nichts mehr mit Autoit gemacht und bräuchte mal eure Hilfe. Ich habe ein altes Script, welches diverse Datenbanken der Reihe nach andockt und dort eine oder mehrere Abfragen machen. Jetzt ist es aber so, das unsere Datenbank Admins ab und zu mal die Datenbanken auf andere Systeme verlagern, sodass die IP Adresse nicht mehr passt und dadurch mein Script auf die Nase fällt.

Mit der Funktion _MSSQL_Con aus MSSQL.au3 erstelle ich ja meine Datenbankverbindung

Code

Func _MSSQL_Con($scIP, $scUser, $scPass, $scDB)
	Local $sqlCon
	$sqlCon = ObjCreate("ADODB.Connection")
	$sqlCon.Open("Provider=SQLOLEDB; Data Source=" & $scIP & "; User ID=" & $scUser & "; Password=" & $scPass & "; database=" & $scDB & ";")
	Return $sqlCon
EndFunc   ;==>_MSSQL_Con

Wie kann ich denn jetzt prüfen, ob Return $sqlCon erfolgreich war, oder nicht.

Wenn es nicht erfolgreich ist, fliegt mir aktuell mein Script weg. Ich würde das gerne aber so lösen, das ich zumindest an dieser Stelle das irgendwie abfangen kann und mir via Messagebox mitteilen lassen kann, das diese Verbindung fehlerhaft ist. Schön wäre es dann noch, wenn das Script dann trotzdem mit den restlichen Datenbanken weiterlaufen würde.

Hier noch ein Beispiel von einer meiner Datenbankverbindungen

Code

    If $SelectedDatabase = "ABC" Then
            $URL = "https://www.platzhalter.fqdn/abc/"
            $IP = $IP3
            $USER = "abcuser"
            $PASSWORD = "abcpasswort"
            $DB = "abcdb"
            $sqlCon = _MSSQL_Con($IP, $USER, $PASSWORD, $DB) ; IP, User, PW, DB
            ConsoleWrite("$sqlCon bei ABC ist: " & $sqlCon & @CRLF)
     EndIf

Leider komme ich aktuell nicht bis zum ConsoleWrite. Wenn ich das Script mit F5 laufen lasse, fliege ich aktuell so raus

Code

"C:\Program Files (x86)\AutoIt3\Include\MSSQL.au3" (434) : ==> The requested action with this object has failed.:
$sqlCon.Open("Provider=SQLOLEDB; Data Source=" & $scIP & "; User ID=" & $scUser & "; Password=" & $scPass & "; database=" & $scDB & ";")
$sqlCon^ ERROR
->10:08:36 AutoIt3.exe ended.rc:1
+>10:08:36 AutoIt3Wrapper Finished

Danke für eure Tipps

BananaJoe

Schau mal in die Hilfe zu ObjCreate() - da findes Du den Hinweis auf ObjEvent(). Damit kannst Du Dir Dein Errorhandling bauen

gmmg

Hi Code4Fun,

hier mal ein Beispiel aus meinem SQL Script.

AutoIt

#include <MSSQL.au3>
#include <Array.au3>
#include <WindowsConstants.au3>

local $oMyError

$sserver = "servername"
$susername = "user"
$spassword = "pass"
$sdatabase = "db"


$oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
$sqlCon = _MSSQL_Con($sserver, $susername, $spassword, $sdatabase)

$ergebnis = _MSSQL_Query($sqlCon, "SELECT id, name FROM teilprojekt where projektid = 110 and geloeschtam = 0;")

$array = $ergebnis.GetRows
If Not IsArray($array) Then
	MsgBox(0, 'Array', 'kein Ergebnis')
	Exit
EndIf
_ArraySort($array, 0, 0, 0, 0)
_ArrayDisplay($array)

For $i = 1 to UBound($array) -1
	;MsgBox(0,"",$array[$i][0])
	;_MSSQL_AddRecord($oConnectionObj, $sTable, $Values, $UNIQUE, $condition)
	;-'Value1', 'Value2', 'Value3', 'Value4', 'Value5', 'Value n'
	$values = "'26931'" & ",'"&$array[$i][0]&"',100"
	;MsgBox(0,"",$values)
	_MSSQL_AddRecord($sqlCon, "zustaendigkeit", $values)
Next

_MSSQL_End($sqlCon)


Func MyErrFunc()
    Local $HexNumber
    $HexNumber = Hex($oMyError.number, 8)
    MsgBox(0, "COM Error Test", "We intercepted a COM Error !" & @CRLF & @CRLF & _
            "err.description is: " & @TAB & $oMyError.description & @CRLF & _
            "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _
            "err.number is: " & @TAB & $HexNumber & @CRLF & _
            "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _
            "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _
            "err.source is: " & @TAB & $oMyError.source & @CRLF & _
            "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _
            "err.helpcontext is: " & @TAB & $oMyError.helpcontext _
            )
    SetError(1); to check for after this function returns
EndFunc   ;==>MyErrFunc

Alles anzeigen

Gruß Marcel