Guielemente im Array

casi4712

Hallo liebe Hardcorecoder, mal ne praktische Frage. Ich lege mittlereile meine Buttons mit Hilfe von Arrays an. Nun hatte ich mir überlegt auch andere GUIelemente in einem Array zu verarbeiten. Das hat soweit auch funktioniert, nur komischerweise zeigt er die Tolltips von Icons nicht an, vielleicht sieht ja einer den Fehler, eh ich grauwe Haare kriege;)

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

;Global $button1, $Icon1

Local $arElements = [ _
    ["Button1", "Button", "Save List", 10, 340, 100, 30, "Liste speichern", "", ""], _
    ["Button2", "Button", "Host1", 210, 30, 70, 30, "nd", "", ""], _
    ["Button3", "Button", "Host2", 210, 70, 70, 30, "nd", "", ""], _
    ["Button4", "Button", "Workgroup", 210, 110, 70, 30, "nd", "", ""], _
    ["Button5", "Button", "Fritz", 280, 30, 70, 30, "nd", "", ""], _
    ["Button6", "Button", "IT-Service", 280, 70, 70, 30, "nd", "", ""], _
    ["Button7", "Button", "Lesesaal", 280, 110, 70, 30, "nd", "", ""], _
    ["Button14", "Button", "Save and choose file", 190, 340, 160, 30, "sdsds", "", ""], _
    ["Checkbox1", "Checkbox", "AdminUser", 10, 390, 90, 20, "", $GUI_CHECKED, ">>>"], _
    ["Label1", "Label", "Freie Listen", 210, 10, 100, 20, "", "", "9,800,800"], _
    ["Icon1", "Icon", "shell32.dll", 168, 320, 390, 50, 50, "Öffnet die Settings", "", ""] _
]

Local $hParent = GUICreate("TESTGUI", 500, 500)
GUISetState(@SW_SHOW, $hParent)

Local $Element[UBound($arElements)]
For $i = 0 To UBound($arElements) - 1
    Switch $arElements[$i][1]
        Case "Button"
            $Element[$i] = GUICtrlCreateButton($arElements[$i][2], $arElements[$i][3], $arElements[$i][4], $arElements[$i][5], $arElements[$i][6])
            GUICtrlSetTip($Element[$i], $arElements[$i][7])
        Case "Checkbox"
            $Element[$i] = GUICtrlCreateCheckbox($arElements[$i][2], $arElements[$i][3], $arElements[$i][4], $arElements[$i][5])
            GUICtrlSetState($Element[$i], $arElements[$i][8])
        Case "Label"
            $Element[$i] = GUICtrlCreateLabel($arElements[$i][2], $arElements[$i][3], $arElements[$i][4], $arElements[$i][5])
            If $arElements[$i][9] <> "" Then
                Local $fontParams = StringSplit($arElements[$i][9], ",")
                GUICtrlSetFont($Element[$i], $fontParams[1], $fontParams[2], $fontParams[3])
            EndIf
        Case "Icon"
            $Element[$i] = GUICtrlCreateIcon($arElements[$i][2], $arElements[$i][3], $arElements[$i][4], $arElements[$i][5], $arElements[$i][6], $arElements[$i][7], $arElements[$i][8])
            GUICtrlSetTip($Element[$i], $arElements[$i][9])
    EndSwitch
    Assign($arElements[$i][0], $Element[$i]) ; Weise die ID direkt den globalen Variablen zu
Next

; Hauptschleife
While 1
    Switch GUIGetMsg() ; Ereignis abrufen
        Case $GUI_EVENT_CLOSE
            Exit ; Beenden, wenn das Fenster geschlossen wird
        Case $Button1
            MsgBox($MB_OK, "Button Clicked", "Save List") ; Meldung anzeigen, wenn Button1 geklickt wird
        Case $Button2
            MsgBox($MB_OK, "Button Clicked", "Host1") ; Meldung anzeigen, wenn Button2 geklickt wird
        Case $Button3
            MsgBox($MB_OK, "Button Clicked", "Host2") ; Meldung anzeigen, wenn Button3 geklickt wird
        Case $Button14
            MsgBox($MB_OK, "Button Clicked", "Save and choose file") ; Meldung anzeigen, wenn Button14 geklickt wird
        ; Fügen Sie hier weitere Cases für die anderen Buttons hinzu
    EndSwitch
WEnd

Alles anzeigen

lg und schöne Woche noch

**funkey**

Du hast dich da verzählt.

Hier mal so wie ich es machen würde. Hab's umgebaut auf Funktionen und Event-Mode

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Opt("GUIOnEventMode", 1)

Global $arElements = [ _
    [0, "Button1", "Button", "Save List", 10, 340, 100, 30, "Liste speichern", "", ""], _
    [0, "Button2", "Button", "Host1", 210, 30, 70, 30, "nd", "", ""], _
    [0, "Button3", "Button", "Host2", 210, 70, 70, 30, "nd", "", ""], _
    [0, "Button4", "Button", "Workgroup", 210, 110, 70, 30, "nd", "", ""], _
    [0, "Button5", "Button", "Fritz", 280, 30, 70, 30, "nd", "", ""], _
    [0, "Button6", "Button", "IT-Service", 280, 70, 70, 30, "nd", "", ""], _
    [0, "Button7", "Button", "Lesesaal", 280, 110, 70, 30, "nd", "", ""], _
    [0, "Button14", "Button", "Save and choose file", 190, 340, 160, 30, "sdsds", "", ""], _
    [0, "Checkbox1", "Checkbox", "AdminUser", 10, 390, 90, 20, "", $GUI_CHECKED, ">>>"], _
    [0, "Label1", "Label", "Freie Listen", 210, 10, 100, 20, "", "", "9,800,800"], _
    [0, "Icon1", "Icon", "shell32.dll", 168, 320, 390, 50, 50, "Öffnet die Settings", "", ""] _
]

Global $hParent = GUICreate("TESTGUI", 500, 500)
_CreateControlFromArray($arElements)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW, $hParent)


While 1
	Sleep(10)
WEnd


Func _HandleCtrlEvent()
	Local $iIndex = _ArraySearch($arElements, @GUI_CtrlId, 0, 0, 0, 0, 1, 0)

	Switch $arElements[$iIndex][1]
        Case "Button1"
            MsgBox($MB_OK, "Button Clicked", "Save List") ; Meldung anzeigen, wenn Button1 geklickt wird
        Case "Button2"
            MsgBox($MB_OK, "Button Clicked", "Host1") ; Meldung anzeigen, wenn Button2 geklickt wird
        Case "Button3"
            MsgBox($MB_OK, "Button Clicked", "Host2") ; Meldung anzeigen, wenn Button3 geklickt wird
        Case "Button14"
            MsgBox($MB_OK, "Button Clicked", "Save and choose file") ; Meldung anzeigen, wenn Button14 geklickt wirdEndFunc
	EndSwitch
EndFunc


Func _Exit()
	Exit
EndFunc


Func _CreateControlFromArray(ByRef $aCtrlInfo)
	For $i = 0 To UBound($aCtrlInfo) -1
		Switch $aCtrlInfo[$i][2]
			Case "Button"
				$aCtrlInfo[$i][0] = GUICtrlCreateButton($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
				GUICtrlSetTip(-1, $aCtrlInfo[$i][8])
			Case "Checkbox"
				$aCtrlInfo[$i][0] = GUICtrlCreateCheckbox($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
				GUICtrlSetState(-1, $aCtrlInfo[$i][9])
			Case "Label"
				$aCtrlInfo[$i][0] = GUICtrlCreateLabel($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
				If $aCtrlInfo[$i][10] <> "" Then
					Local $fontParams = StringSplit($aCtrlInfo[$i][10], ",")
					GUICtrlSetFont(-1, $fontParams[1], $fontParams[2], $fontParams[3])
				EndIf
			Case "Icon"
				$aCtrlInfo[$i][0] = GUICtrlCreateIcon($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7], $aCtrlInfo[$i][8])
				GUICtrlSetTip(-1, $aCtrlInfo[$i][9])
		EndSwitch
		GUICtrlSetOnEvent(-1, "_HandleCtrlEvent")
	Next
EndFunc

Alles anzeigen

Schöne Grüße

funkey

casi4712

hallo danke für deine Reaktion, also verzählt weiss ich nicht, da hatte ich auch dran gedacht, han von 6-10 alles probiert ging nie, aber ich schau mal was du da feines hast

lg und schönen Abend noch

casi4712

Also ehrlich gesagt seh ich jetzt nicht ganz was du jetzt funktionstechnisch anders gemachet hast, ausser die VAriablennamen umbenannt und das GuiEvent, ansonsten hatte ich auch das mit 9 probiert, als Funktion hatte ich es auch, aber GUICtrlSetTip(-1, $arElements[$i][9]) hatte einfach nicht funktioniert, will ja nur verstehen warum;).

Aber es funzt jetzt danke noch mal.

lg

**funkey**

Du hast den Text

$arElements[$i][8] --> "Öffnet die Settings" an den Style von GUICtrlCreateIcon gehängt. Deswegen funktionierte das Control nicht mehr richtig.

Außerdem dann eben $arElements[$i][9] anstelle von $arElements[$i][8] bei GUICtrlSetTip

casi4712

ok dann waren es 2 sachen, aber wie gesagt hatte erst 8 und dann andere durchprobiert, was sicher schwachsinn war, dann weiss ich Bescheid. Aber trotzdem, dass hier GUICtrlSetTip(-1, $arElements[$i][8])) ging ja auch nicht. Vielleicht sollte ich mit sowas nächste mal nicht um halb 2 Uhr nachts anfangen lach

danke noch mal

**funkey**

Nichts zu danken. Helfe gerne wenn ich Zeit haben.

casi4712

casi4712

also ich war noch mal aktiv und hab das ganze noch um ein paar GUI elemente erweitert, aber bei Radiobuttons kommt es zu einem Problem, cant initialize variable with itsself, was hab ich denn hier hier wieder übersehen;)? Habe Deinen Ansatz fortgeführt

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Global $Button1

Opt("GUIOnEventMode", 1)

Global $arElements = [ _
    [0, "Button1", "Button", "Save and choose file", 190, 340, 160, 30, "Liste speichern und File ausführen", "", ""], _
    [0, "SaveButton", "Button", "Save List", 10, 340, 100, 30, "Liste speichern", "", ""], _
    [0, "SwitchButton1", "Button", "Host1", 210, 30, 70, 30, "nd", "", ""], _
    [0, "SwitchButton2", "Button", "Host2", 210, 70, 70, 30, "nd", "", ""], _
    [0, "SwitchButton3", "Button", "Workgroup", 210, 110, 70, 30, "nd", "", ""], _
    [0, "SwitchButton4", "Button", "Fritz", 280, 30, 70, 30, "nd", "", ""], _
    [0, "SwitchButton5", "Button", "IT-Service", 280, 70, 70, 30, "nd", "", ""], _
    [0, "SwitchButton6", "Button", "Lesesaal", 280, 110, 70, 30, "nd", "", ""], _
    [0, "AllDomPCButton", "Button", "AllDomPC", 210, 170, 70, 30, "sdsds", "", ""], _
    [0, "AllDomPCsWithAButton", "Button", "Alle PC", 280, 170, 70, 30, "sdsds", "", ""], _
    [0, "AllServerButton", "Button", "All Server", 280, 200, 70, 30, "sdsds", "", ""], _
    [0, "AllLapButton", "Button", "All Laptop", 210, 200, 70, 30, "sdsds", "", ""], _
    [0, "AugiasPCButton", "Button", "All AugiasPC", 210, 230, 70, 30, "sdsds", "", ""], _
    [0, "Checkbox1", "Checkbox", "AdminUser", 10, 390, 90, 20, "", $GUI_CHECKED, ">>>"], _
    [0, "Checkbox2", "Checkbox", "Interactive", 100, 390, 90, 20, "", $GUI_UNCHECKED, ">>>"], _
    [0, "Checkbox3", "Checkbox", "CopyFile", 200, 390, 90, 20, "", $GUI_UNCHECKED, ">>>"], _
    [0, "Label1", "Label", "Freie Listen", 210, 10, 100, 20, "", "", "9,800,800"], _
    [0, "HostsLabel", "Label", "DC-Filter", 210, 150, 70, 20, "", "", "9,800,800"], _
    [0, "DCFilterLabel", "Label", "Actions", 210, 290, 70, 20, "", "", "9,800,800"], _
    [0, "OtherUserLabel", "Label", "", 10, 312, 80, 20, "", "", ""], _
    [0, "StatusLabel", "Label", "other User", 10, 312, 80, 20, "", "", ""], _
    [0, "GearIcon", "Icon", "shell32.dll", 172, 280, 385, 30, 30, "Öffnet das aktuelle Skriptverzeichnis im Explorer", "", ""], _
    [0, "PrefIcon", "Icon", "shell32.dll", 16826, 320, 390, 25, 25, "Öffnet die Settings", "", ""], _
    [0, "ActionCombo", "Combo", "InstallActaPro|DelActaPro|-----------------------|Fun2|hdl|leise|laut|play", 210, 310, 140, 25, "", "", ""], _
    [0, "Edit1", "Edit", "", 10, 30, 190, 270, "", "", ""], _
    [0, "RadioButton1", "Radio", "Option 1", 10, 310, 90, 20, "", "", "", $GUI_ENABLE + $GUI_CHECKED], _
    [0, "RadioButton2", "Radio", "Option 2", 110, 310, 90, 20, "", "", "", $GUI_ENABLE], _
    [0, "Input1", "Input", "", 10, 350, 90, 20, "", "", "", $GUI_ENABLE] _
]

Global $hParent = GUICreate("TESTGUI", 360, 420)
_CreateGuiElement($arElements)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW, $hParent)

While 1
    Sleep(10)
WEnd

Func _HandleCtrlEvent()
    Local $iIndex = _ArraySearch($arElements, @GUI_CtrlId, 0, 0, 0, 0, 1, 0)

    Switch $arElements[$iIndex][1]
        Case "SwitchButton1"
            MsgBox($MB_OK, "Button Clicked", "Host1")
        Case "SwitchButton2"
            MsgBox($MB_OK, "Button Clicked", "Host2")
    EndSwitch
EndFunc

Func _Exit()
    Exit
EndFunc

Func _CreateGuiElement(ByRef $aCtrlInfo)
    Local $hRadioGroup
    For $i = 0 To UBound($aCtrlInfo) - 1
        Switch $aCtrlInfo[$i][2]
            Case "Button"
                $aCtrlInfo[$i][0] = GUICtrlCreateButton($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][8])
            Case "Checkbox"
                $aCtrlInfo[$i][0] = GUICtrlCreateCheckbox($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
                GUICtrlSetState(-1, $aCtrlInfo[$i][9])
            Case "Label"
                $aCtrlInfo[$i][0] = GUICtrlCreateLabel($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
                If $aCtrlInfo[$i][10] <> "" Then
                    Local $fontParams = StringSplit($aCtrlInfo[$i][10], ",")
                    GUICtrlSetFont(-1, $fontParams[1], $fontParams[2], $fontParams[3])
                EndIf
            Case "Icon"
                $aCtrlInfo[$i][0] = GUICtrlCreateIcon($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7], $aCtrlInfo[$i][8])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][9])
            Case "Combo"
                $aCtrlInfo[$i][0] = GUICtrlCreateCombo("", $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetData($aCtrlInfo[$i][0], $aCtrlInfo[$i][3])
            Case "Edit"
                $aCtrlInfo[$i][0] = GUICtrlCreateEdit($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "Radio"
                If Not IsDeclared("hRadioGroup") Then
                    $hRadioGroup = GUICtrlCreateGroup("", $aCtrlInfo[$i][4] - 5, $aCtrlInfo[$i][5] - 5, 200, 50)
                EndIf
                $aCtrlInfo[$i][0] = GUICtrlCreateRadio($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetState(-1, $aCtrlInfo[$i][11])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][8])
            Case "Input"
                $aCtrlInfo[$i][0] = GUICtrlCreateInput($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
        EndSwitch
        GUICtrlSetOnEvent(-1, "_HandleCtrlEvent")
    Next
EndFunc

Alles anzeigen

lg schönen Abend

**funkey**

Bei mir kommt keine Meldung. Prinzipiell läuft das Skript.

Hab nur gesehen, dass sich manche Controls überschneiden und die Group muss AUF und ZU gemacht werden. Würde da wohl eigene Zeilen im Array anlegen, oder bei den Radios/Checkboxen eine Option mitgeben.

Edit: Das Problem ist wahrscheinlich, dass die die Variable $hRadioGroup nicht definierst/initialisierst. Die Funktion _CreateGuiElement() wird aber öfter aufgerufen und $hRadioGroup wird wieder überschrieben.

casi4712

ja aber die beiden Radios kann ich nicht wechseln, das ist das Problem;)

casi4712

ok habs jetzt raus, die entsprechende Array zeile sollte wie folgt sein:

AutoIt

    [0, "RadioButton1", "Radio", "Option 1", 10, 310, 90, 20, "", "", "", $GUI_ENABLE + $GUI_CHECKED + $GUI_DEFBUTTON + $GUI_ONTOP + $GUI_DROPACCEPTED + $GUI_UNCHECKED + $GUI_HIDE + $GUI_SHOW  ], _

aber das is wohl eher zufall, ich sehe grade ich brauch dann wohl noch ein neues element um die Gruppe zu defineiren

lg und schönen Abend

casi4712

ich bin vielleicht ein Honk, und du sagt es noch mit den Überschneidungen, dachte mir erst nix dabei, aber das war wohl das Problem. Leider hab ich es nur über eine Krücke hinbekommen mit den Zeilen groupstart und ende.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Global $Button1

Opt("GUIOnEventMode", 1)

Global $arElements = [ _
    [0, "Button1", "Button", "Save and choose file", 190, 340, 160, 30, "Liste speichern und File ausführen", "", ""], _
    [0, "SaveButton", "Button", "Save List", 10, 340, 100, 30, "Liste speichern", "", ""], _
    [0, "SwitchButton1", "Button", "Host1", 210, 30, 70, 30, "nd", "", ""], _
    [0, "SwitchButton2", "Button", "Host2", 210, 70, 70, 30, "nd", "", ""], _
    [0, "SwitchButton3", "Button", "Workgroup", 210, 110, 70, 30, "nd", "", ""], _
    [0, "SwitchButton4", "Button", "Fritz", 280, 30, 70, 30, "nd", "", ""], _
    [0, "SwitchButton5", "Button", "IT-Service", 280, 70, 70, 30, "nd", "", ""], _
    [0, "SwitchButton6", "Button", "Lesesaal", 280, 110, 70, 30, "nd", "", ""], _
    [0, "AllDomPCButton", "Button", "AllDomPC", 210, 170, 70, 30, "sdsds", "", ""], _
    [0, "AllDomPCsWithAButton", "Button", "Alle PC", 280, 170, 70, 30, "sdsds", "", ""], _
    [0, "AllServerButton", "Button", "All Server", 280, 200, 70, 30, "sdsds", "", ""], _
    [0, "AllLapButton", "Button", "All Laptop", 210, 200, 70, 30, "sdsds", "", ""], _
    [0, "AugiasPCButton", "Button", "All AugiasPC", 210, 230, 70, 30, "sdsds", "", ""], _
    [0, "Checkbox1", "Checkbox", "AdminUser", 10, 390, 90, 20, "", $GUI_CHECKED, ">>>"], _
    [0, "Checkbox2", "Checkbox", "Interactive", 100, 390, 90, 20, "", $GUI_UNCHECKED, ">>>"], _
    [0, "Checkbox3", "Checkbox", "CopyFile", 200, 390, 90, 20, "", $GUI_UNCHECKED, ">>>"], _
    [0, "Label1", "Label", "Freie Listen", 210, 10, 100, 20, "", "", "9,800,800"], _
    [0, "HostsLabel", "Label", "DC-Filter", 210, 150, 70, 20, "", "", "9,800,800"], _
    [0, "DCFilterLabel", "Label", "Actions", 210, 290, 70, 20, "", "", "9,800,800"], _
    [0, "OtherUserLabel", "Label", "", 10, 312, 80, 20, "", "", ""], _
    [0, "StatusLabel", "Label", "other User", 10, 312, 80, 20, "", "", ""], _
    [0, "GearIcon", "Icon", "shell32.dll", 172, 280, 385, 30, 30, "Öffnet das aktuelle Skriptverzeichnis im Explorer", "", ""], _
    [0, "PrefIcon", "Icon", "shell32.dll", 16826, 320, 390, 25, 25, "Öffnet die Settings", "", ""], _
    [0, "ActionCombo", "Combo", "InstallActaPro|DelActaPro|-----------------------|Fun2|hdl|leise|laut|play", 210, 310, 140, 25, "", "", ""], _
    [0, "Edit1", "Edit", "", 10, 30, 190, 270, "", "", ""], _
    [0, "RadioGroupStart", "Group", "", 10, 450, 160, 15, "", "", "", $GUI_ENABLE], _  ; Start der Radio-Button-Gruppe
    [0, "RadioButton1", "Radio", "Option 1", 10, 450, 60, 10, "", "", "", $GUI_ENABLE + $GUI_CHECKED], _
    [0, "RadioButton2", "Radio", "Option 2", 110, 450, 60, 10, "", "", "", $GUI_ENABLE], _
    [0, "RadioGroupEnd", "GroupEnd", "", 0, 0, 0, 0, "", "", ""], _  ; Ende der Radio-Button-Gruppe
    [0, "Input1", "Input", "", 10, 370, 90, 20, "", "", "", $GUI_ENABLE] _
]

Global $hParent = GUICreate("TESTGUI", 360, 520)
_CreateGuiElement($arElements)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW, $hParent)

While 1
    Sleep(10)
WEnd

Func _HandleCtrlEvent()
    Local $iIndex = _ArraySearch($arElements, @GUI_CtrlId, 0, 0, 0, 0, 1, 0)

    Switch $arElements[$iIndex][1]
        Case "SwitchButton1"
            MsgBox($MB_OK, "Button Clicked", "Host1")
        Case "SwitchButton2"
            MsgBox($MB_OK, "Button Clicked", "Host2")
    EndSwitch
EndFunc




Func _Exit()
    Exit
EndFunc

Func _CreateGuiElement(ByRef $aCtrlInfo)
    For $i = 0 To UBound($aCtrlInfo) - 1
        Switch $aCtrlInfo[$i][2]
            Case "Button"
                $aCtrlInfo[$i][0] = GUICtrlCreateButton($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][8])
            Case "Checkbox"
                $aCtrlInfo[$i][0] = GUICtrlCreateCheckbox($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
                GUICtrlSetState(-1, $aCtrlInfo[$i][9])
            Case "Label"
                $aCtrlInfo[$i][0] = GUICtrlCreateLabel($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
                If $aCtrlInfo[$i][10] <> "" Then
                    Local $fontParams = StringSplit($aCtrlInfo[$i][10], ",")
                    GUICtrlSetFont(-1, $fontParams[1], $fontParams[2], $fontParams[3])
                EndIf
            Case "Icon"
                $aCtrlInfo[$i][0] = GUICtrlCreateIcon($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7], $aCtrlInfo[$i][8])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][9])
            Case "Combo"
                $aCtrlInfo[$i][0] = GUICtrlCreateCombo("", $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetData($aCtrlInfo[$i][0], $aCtrlInfo[$i][3])
            Case "Edit"
                $aCtrlInfo[$i][0] = GUICtrlCreateEdit($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "Radio"
                $aCtrlInfo[$i][0] = GUICtrlCreateRadio($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetState($aCtrlInfo[$i][0], $aCtrlInfo[$i][11]) ; Setzt den Radiobutton in den angegebenen Zustand
            Case "Input"
                $aCtrlInfo[$i][0] = GUICtrlCreateInput($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "Group"
                $aCtrlInfo[$i][0] = GUICtrlCreateGroup("", $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "GroupEnd"
                GUICtrlCreateGroup("", -99, -99, 1, 1)  ; End Group
        EndSwitch
        GUICtrlSetOnEvent(-1, "_HandleCtrlEvent")
    Next
EndFunc

Alles anzeigen

LG

**Kanashius**

Hi

Ich hatte mir das ganze auch mal angesehen, und ich muss sagen, dass ich das mit den vielen Werten im Array nicht so schön fand, weils unübersichtlich ist. Insbesondere, weil je nach control die Reihenfolge wechselt (icon/label),... . Ein weiterer Faktor für mich war dabei, dass du dann auch zusatzfunktionen zum ändern des controls genutzt hast (z.B. GuiCtrlSetFont beim Label).

Also hab ich mir mal alle möglichen GuiCtrlCreate... Funktionen und deren Parameter angeschaut, sowie alle möglichen GuiCtrlSet... funktionen.

Das hier war mein Ergebnis:

Code

GUICtrlCreateGraphic      (                      left, top [, width [, height [, style]]] )
GUICtrlCreateProgress     (                      left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateSlider       (                      left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateTab          (                      left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateTreeView     (                      left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateButton       ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateCheckbox     ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateCombo        ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateDate         ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateEdit         ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateGroup        ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateInput        ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateLabel        ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateList         ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateListView     ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateMonthCal     ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateObj          ( ObjectVar,           left, top [, width [, height]] )
GUICtrlCreatePic          ( filename,            left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateRadio        ( "text",              left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateAvi          ( filename, subfileid, left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
GUICtrlCreateIcon         ( filename, iconName,  left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

; special stuff
GUICtrlCreateDummy        ( )
GUICtrlCreateTabItem      ( "text" )
GUICtrlCreateTreeViewItem ( "text", treeviewID )
GUICtrlCreateListViewItem ( "text", listviewID )
GUICtrlCreateContextMenu  ( [controlID] )
GUICtrlCreateMenu         ( "submenutext" [, menuID = -1 [, menuentry = -1]] )
GUICtrlCreateMenuItem     ( "text", menuID [, menuentry = -1 [, menuradioitem = 0]] )
GUICtrlCreateUpdown       ( inputcontrolID [, style = -1] )

_CTRL_callback
_CTRL_color
_CTRL_cursor
_CTRL_font
_CTRL_image
_CTRL_limit
_CTRL_onEvent
_CTRL_resizing
_CTRL_size
_CTRL_state
_CTRL_style
_CTRL_tip

Alles anzeigen

Ich hab so eigentlich alle Controls dabei (vllt. noch für das "special stuff" was ändern).

Dabei ist die Funktion _CTRL_def(ByRef $mCtrlMap, $iType, $iLeft, $iTop, $opt1 = Default, $opt2 = Default, $opt3 = Default... entstanden. Man erstellt eine Map für alle Controls und fügt mit dieser Funktion die Controls hinzu.
Alle controls brauchen den Typ ($iCTRL_...) und die Position ($iLeft/$iTop). Danach kommen die "opt" parameter. Je nach funktion sind die unterschiedlich: Controls haben 0 bis 2 parameter vor der position, die sind bei mir hier gelandet und werden als $opt1 und $opt2 angegeben.
Sie können aber auch weggelassen werden. Danach kommen nurnoch die _CTRL_... Funktionen in beliebiger Reihenfolge.

Beispiel mit allen Möglichkeiten:

AutoIt

Global $iWidth = 800, $iHeight = 600
Global $mCtrls[]
_CTRL_def($mCtrls,   $iCTRL_BUTTON, 10, 10, "Add column", _CTRL_onEvent("_buttonPressed"), _CTRL_style($BS_BOTTOM), _CTRL_tip("Some cool Tip"))
_CTRL_def($mCtrls,   $iCTRL_BUTTON, 10, 40, "Button 2", _CTRL_color(0xFFFFFF, 0x000000), _CTRL_cursor(0))
_CTRL_def($mCtrls,   $iCTRL_BUTTON, 10, 70, "Button 3", _CTRL_size(100, 50), _CTRL_font(10, 700, BitOr(2,8)), _CTRL_image("shell32.dll", 22))
_CTRL_def($mCtrls,    $iCTRL_INPUT, 10, 130, "", _CTRL_size(Default, 25), _CTRL_limit(5, 1), _CTRL_resizing(BitOR(2, 32)))
_CTRL_def($mCtrls, $iCTRL_CHECKBOX, 10, 160, "Uncheck me", _CTRL_state($GUI_CHECKED))
$ctrlListview = _CTRL_def($mCtrls, $iCTRL_LISTVIEW, 0.02, 0.79, "TextColumn", _CTRL_size(0.96, 0.2), _CTRL_callback("_fillListview"))


GUICreate("Example", $iWidth, $iHeight)
_CTRL_gen($mCtrls, $iWidth, $iHeight)
GUISetState(@SW_SHOW)

; ...

Func _fillListview($iCtrlId)
	GUICtrlCreateListViewItem("TestItem 1", $iCtrlId)
	GUICtrlCreateListViewItem("TestItem 2", $iCtrlId)
	GUICtrlCreateListViewItem("TestItem 3", $iCtrlId)
EndFunc

Alles anzeigen

Dabei hab ich auch die Möglichkeit eingebaut, die Position in Prozent anzugeben. Wenn die Position oder Size <=1 ist, wird das als Prozent der Breite/Höhe angenommen und entsprechend verarbeitet.
Deshalb hat die Methode _CTRL_gen(ByRef $mMap, $iWidth = Default, $iHeight = Default) zum generieren der Controls auch einen Width und Height Parameter, der dann angegeben werden muss.

Umd später noch bei speziellen Controls zu wissen, welches ein Event hatte, wird der Map key des Controls zurückgegeben.
Beispiel: Local $iCtrlButtonSave = _CTRL_def($mCtrlsA, $iCTRL_BUTTON, 10, 340, "Save List", _CTRL_size(100, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("Liste speichern"))
Später kann dann mit Local Local $key = _CTRL_getKey($mCtrlsA, $iCtrlId) von der Autoit-CtrlID auf den Key gemapped werden um dann mit If $key = $iCtrlButtonSave Then eigene Aktionen auszuführen.
Mit $mCtrlsA[$iCtrlButtonSave].iCtrl kann auch von dem Key auf die AutoIt-CtrlID umgewandelt werden.

Hier einmal dein Code damit umgesetzt, sowie ein weiteres Beispiel:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <ButtonConstants.au3>
#include <GuiListView.au3>

Global $iCTRL_AVI = 1, $iCTRL_BUTTON = 2, $iCTRL_CHECKBOX = 3, $iCTRL_COMBO = 4, $iCTRL_DATE = 5, $iCTRL_EDIT = 6, $iCTRL_GRAPHIC = 7, $iCTRL_GROUP = 8, $iCTRL_ICON = 9, $iCTRL_INPUT = 10
Global $iCTRL_INPUT = 11, $iCTRL_LABEL = 12, $iCTRL_LIST = 13, $iCTRL_LISTVIEW = 14, $iCTRL_MONTHCAL = 15, $iCTRL_OBJ = 16, $iCTRL_PIC = 17, $iCTRL_PROGRESS = 18, $iCTRL_RADIO = 19
Global $iCTRL_SLIDER = 20, $iCTRL_TAB = 21, $iCTRL_TREEVIEW = 22

; => Example A

Global $mCtrlsA[]
Local $iCtrlButtonSave = _CTRL_def($mCtrlsA,   $iCTRL_BUTTON,  10, 340, "Save List", _CTRL_size(100, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("Liste speichern"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 210,  30, "Host1", _CTRL_size(70, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("nd"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 210,  70, "Host2", _CTRL_size(70, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("nd"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 210, 110, "Workgroup", _CTRL_size(70, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("nd"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 280,  30, "Fritz", _CTRL_size(70, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("nd"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 280,  70, "IT-Service", _CTRL_size(70, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("nd"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 280, 110, "Lesesaal", _CTRL_size(70, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("nd"))
_CTRL_def($mCtrlsA,   $iCTRL_BUTTON, 190, 340, "Save and choose file", _CTRL_size(160, 30), _CTRL_onEvent("_buttonPressedA"), _CTRL_tip("sdsds"))
_CTRL_def($mCtrlsA, $iCTRL_CHECKBOX,  10, 390, "AdminUser", _CTRL_size(90, 20), _CTRL_state($GUI_CHECKED))
_CTRL_def($mCtrlsA,    $iCTRL_LABEL, 210,  10, "Freie Listen", _CTRL_size(100, 20), _CTRL_font(9, 800, 2))
_CTRL_def($mCtrlsA,     $iCTRL_ICON, 320, 390, "shell32.dll", 168, _CTRL_size(50, 50), _CTRL_tip("Öffnet die Settings"))

Local $hParent = GUICreate("Button Example", 500, 500)
;Opt("GUIOnEventMode", 1)
;GUISetOnEvent($GUI_EVENT_CLOSE, "_end", $hParent)
_CTRL_gen($mCtrlsA)
GUISetState(@SW_SHOW, $hParent)

Local $bRun = True
; Hauptschleife
While $bRun
	Local $iMsg = GUIGetMsg()
    Switch $iMsg ; Ereignis abrufen
        Case $GUI_EVENT_CLOSE
            _end()
    EndSwitch
	If $iMsg<>0 Then
		For $mCtrl in $mCtrlsA
			If $mCtrl.iCtrl<>0 And $iMsg = $mCtrl.iCtrl And MapExists($mCtrl, "onEvent") Then Call($mCtrl.onEvent.sFunc, $mCtrl.iCtrl)
		Next
	EndIf
WEnd

Func _buttonPressedA($iCtrl = -1)
	Local $iCtrlId = (IsDeclared("iCtrl")?$iCtrl:@GUI_CtrlId)
	Local $key = _CTRL_getKey($mCtrlsA, $iCtrlId)
	If $key = $iCtrlButtonSave Then
		MsgBox($MB_OK, "Button Clicked", "Button clicked to save something")
	Else
		MsgBox($MB_OK, "Button Clicked", GUICtrlRead($iCtrlId))
	EndIf
EndFunc

Func _end()
	$bRun = False
EndFunc


; => Example

Global $iWidth = 800, $iHeight = 600
Global $mCtrls[]
_CTRL_def($mCtrls,   $iCTRL_BUTTON, 10, 10, "Add column", _CTRL_onEvent("_buttonPressed"), _CTRL_style($BS_BOTTOM), _CTRL_tip("Some cool Tip"))
_CTRL_def($mCtrls,   $iCTRL_BUTTON, 10, 40, "Button 2", _CTRL_color(0xFFFFFF, 0x000000), _CTRL_cursor(0))
_CTRL_def($mCtrls,   $iCTRL_BUTTON, 10, 70, "Button 3", _CTRL_size(100, 50), _CTRL_font(10, 700, BitOr(2,8)), _CTRL_image("shell32.dll", 22))
_CTRL_def($mCtrls,    $iCTRL_INPUT, 10, 130, "", _CTRL_size(Default, 25), _CTRL_limit(5, 1), _CTRL_resizing(BitOR(2, 32)))
_CTRL_def($mCtrls, $iCTRL_CHECKBOX, 10, 160, "Uncheck me", _CTRL_state($GUI_CHECKED))
$ctrlListview = _CTRL_def($mCtrls, $iCTRL_LISTVIEW, 0.02, 0.79, "TextColumn", _CTRL_size(0.96, 0.2), _CTRL_callback("_fillListview"))


GUICreate("Example", $iWidth, $iHeight)
_CTRL_gen($mCtrls, $iWidth, $iHeight)
GUISetState(@SW_SHOW)

ConsoleWrite("------------RESULT------------"&@crlf)
ConsoleWrite(_toString($mCtrls)&@crlf)
ConsoleWrite("----------END RESULT----------"&@crlf)


While True
	Local $iMsg = GUIGetMsg()
	If $iMsg = -3 Then Exit
	If $iMsg<>0 Then
		For $mCtrl in $mCtrls
			If $mCtrl.iCtrl<>0 And $iMsg = $mCtrl.iCtrl And MapExists($mCtrl, "onEvent") Then Call($mCtrl.onEvent.sFunc)
		Next
	EndIf
WEnd

Func _buttonPressed()
	ConsoleWrite("Button pressed"&@crlf)
	_GUICtrlListView_AddColumn($mCtrls[$ctrlListview].iCtrl, "Added column")
EndFunc

Func _fillListview($iCtrlId)
	GUICtrlCreateListViewItem("TestItem 1", $iCtrlId)
	GUICtrlCreateListViewItem("TestItem 2", $iCtrlId)
	GUICtrlCreateListViewItem("TestItem 3", $iCtrlId)
EndFunc

Func _CTRL_getKey(ByRef $mMap, $iCtrlId)
	For $key in MapKeys($mMap)
		If $mMap[$key].iCtrl = $iCtrlId Then return $key
	Next
	return -1
EndFunc

Func _CTRL_gen(ByRef $mMap, $iWidth = Default, $iHeight = Default)
	For $key In MapKeys($mMap)
		Local $mCtrl = $mMap[$key]
		$mCtrl.iLeftCur = (($iWidth<>Default And $mCtrl.iLeft<=1)?$iWidth*$mCtrl.iLeft:$mCtrl.iLeft)
		$mCtrl.iWidthCur = (($mCtrl.iWidth<>Default)?(($iWidth<>Default And $mCtrl.iWidth<=1)?$iWidth*$mCtrl.iWidth:$mCtrl.iWidth):(Default))
		$mCtrl.iTopCur = (($iHeight<>Default And $mCtrl.iTop<=1)?$iHeight*$mCtrl.iTop:$mCtrl.iTop)
		$mCtrl.iHeightCur = (($mCtrl.iHeight<>Default)?(($iHeight<>Default And $mCtrl.iHeight<=1)?$iHeight*$mCtrl.iHeight:$mCtrl.iHeight):(Default))
		Switch $mCtrl.iType
			Case $iCTRL_AVI
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_AVI needs the $opt1 parameter (filename)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					If $mCtrl.param2=Default Then $mCtrl.param2=0
					$mCtrl.iCtrl = GUICtrlCreateAvi($mCtrl.param1, $mCtrl.param2, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateAvi ($iLeft/$iTop/$opt1 (filename)/$opt2 (subfileid)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_BUTTON
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_BUTTON needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateButton($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateButton ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_CHECKBOX
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_CHECKBOX needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateCheckbox($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateCheckbox ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_COMBO
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_COMBO needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateCombo($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateCombo ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_DATE
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_DATE needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateDate($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateDate ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_EDIT
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_EDIT needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateEdit($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateEdit ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_GRAPHIC
				$mCtrl.iCtrl = GUICtrlCreateGraphic($mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle)
				_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateGraphic ($iLeft/$iTop/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			Case $iCTRL_GROUP
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_GROUP needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateGroup($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateGroup ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_ICON
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_ICON needs the $opt1 parameter (filename)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					If $mCtrl.param2=Default Then $mCtrl.param2=-1
					$mCtrl.iCtrl = GUICtrlCreateIcon($mCtrl.param1, $mCtrl.param2, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateIcon ($iLeft/$iTop/$opt1 (filename)/$opt2 (iconName)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_INPUT
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_INPUT needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateInput($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateInput ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_LABEL
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_LABEL needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateLabel($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateLabel ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_LIST
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_LIST needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateList($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateList ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_LISTVIEW
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_LISTVIEW needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateListView($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateListView ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_MONTHCAL
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_MONTHCAL needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateMonthCal($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateMonthCal ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_OBJ
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_OBJ needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateObj($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateObj ($iLeft/$iTop/$opt1 (ObjectVar)/_CTRL_size)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_PIC
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_PIC needs the $opt1 parameter (filename)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreatePic($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreatePic ($iLeft/$iTop/$opt1 (filename)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_PROGRESS
				$mCtrl.iCtrl = GUICtrlCreateProgress($mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
				_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateProgress ($iLeft/$iTop/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			Case $iCTRL_RADIO
				If $mCtrl.param1=Default Then
					_errCheck("_CTRL_def with $iType $iCTRL_RADIO needs the $opt1 parameter (text)", False, -1, 1, 0, "_exit", $mCtrl.iLineNumber)
				Else
					$mCtrl.iCtrl = GUICtrlCreateRadio($mCtrl.param1, $mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
					_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateRadio ($iLeft/$iTop/$opt1 (text)/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				EndIf
			Case $iCTRL_SLIDER
				$mCtrl.iCtrl = GUICtrlCreateSlider($mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
				_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateSlider ($iLeft/$iTop/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			Case $iCTRL_TAB
				$mCtrl.iCtrl = GUICtrlCreateTab($mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
				_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateTab ($iLeft/$iTop/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			Case $iCTRL_TREEVIEW
				$mCtrl.iCtrl = GUICtrlCreateTreeView($mCtrl.iLeftCur, $mCtrl.iTopCur, $mCtrl.iWidthCur, $mCtrl.iHeightCur, $mCtrl.iStyle, $mCtrl.iStyleEx)
				_errCheck("Data provided by _CTRL_def caused an error calling GUICtrlCreateTreeView ($iLeft/$iTop/_CTRL_size/_CTRL_style)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
		EndSwitch
		If Not @error Then
			If MapExists($mCtrl, "callback") Then Call($mCtrl.callback.sFunc, $mCtrl.iCtrl)
			_errCheck("Data provided by _CTRL_callback for _CTRL_def caused an error calling Call. Check if the provided function exists and has exactly one parameter ($iCtrlId)", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "color") Then
				If $mCtrl.color.iTextColor<>Default Then GUICtrlSetColor($mCtrl.iCtrl, $mCtrl.color.iTextColor)
				_errCheck("Data provided by _CTRL_color for _CTRL_def caused an error calling GUICtrlSetColor", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
				If $mCtrl.color.iBGColor<>Default Then GUICtrlSetBkColor($mCtrl.iCtrl, $mCtrl.color.iBGColor)
				_errCheck("Data provided by _CTRL_color for _CTRL_def caused an error calling GUICtrlSetBkColor", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			EndIf
			If MapExists($mCtrl, "cursor") Then GUICtrlSetCursor($mCtrl.iCtrl, $mCtrl.cursor.iCursor)
			_errCheck("Data provided by _CTRL_cursor for _CTRL_def caused an error calling GuiCtrlSetCursor", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "font") Then GUICtrlSetFont($mCtrl.iCtrl, $mCtrl.font.fSize, $mCtrl.font.iWeight, $mCtrl.font.iAttribute, $mCtrl.font.sFontName, $mCtrl.font.iQuality)
			_errCheck("Data provided by _CTRL_font for _CTRL_def caused an error calling GUICtrlSetFont", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "image") Then GUICtrlSetImage($mCtrl.iCtrl, $mCtrl.image.sFilename, $mCtrl.image.sIconName, $mCtrl.image.iIconType)
			_errCheck("Data provided by _CTRL_image for _CTRL_def caused an error calling GUICtrlSetImage", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "limit") Then GUICtrlSetLimit($mCtrl.iCtrl, $mCtrl.limit.iMax, $mCtrl.limit.iMin)
			_errCheck("Data provided by _CTRL_limit for _CTRL_def caused an error calling GUICtrlSetLimit", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "onEvent") Then GUICtrlSetOnEvent($mCtrl.iCtrl, $mCtrl.onEvent.sFunc)
			_errCheck("Data provided by _CTRL_onEvent for _CTRL_def caused an error calling GUICtrlSetOnEvent", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "resizing") Then GUICtrlSetResizing($mCtrl.iCtrl, $mCtrl.resizing.iResizing)
			_errCheck("Data provided by _CTRL_resizing for _CTRL_def caused an error calling GUICtrlSetResizing", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "state") Then GUICtrlSetState($mCtrl.iCtrl, $mCtrl.state.iState)
			_errCheck("Data provided by _CTRL_state for _CTRL_def caused an error calling GUICtrlSetState", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
			If MapExists($mCtrl, "tip") Then GUICtrlSetTip($mCtrl.iCtrl, $mCtrl.tip.sText, $mCtrl.tip.sTitle, $mCtrl.tip.iIcon, $mCtrl.tip.iOptions)
			_errCheck("Data provided by _CTRL_tip for _CTRL_def caused an error calling GUICtrlSetTip", False, -1, @error, @extended, "_exit", $mCtrl.iLineNumber)
		EndIf
		$mMap[$key] = $mCtrl
	Next
EndFunc

Func _CTRL_def(ByRef $mCtrlMap, $iType, $iLeft, $iTop, $opt1 = Default, $opt2 = Default, $opt3 = Default, $opt4 = Default, $opt5 = Default, $opt6 = Default, $opt7 = Default, $opt8 = Default, _
               $opt9 = Default, $opt10 = Default, $opt11 = Default, $opt12 = Default, $opt13 = Default, $opt14 = Default, $iLineNumber = @ScriptLineNumber)
	If Not IsMap($mCtrlMap) Then return SetError(1, 0, -1)
	If Not IsInt($iType) And $iType>=$iCTRL_AVI And $iType<=$iCTRL_TREEVIEW Then return SetError(2, 0, -1)
	Local $mEntry[]
	$mEntry.iCtrl = 0
	$mEntry.iType = $iType
	$mEntry.iLeft = $iLeft
	$mEntry.iTop = $iTop
	$mEntry.param1 = Default
	$mEntry.param2 = Default
	$mEntry.iWidth = Default
	$mEntry.iHeight = Default
	$mEntry.iStyle = -1
	$mEntry.iStyleEx = -1
	$mEntry.iLineNumber = $iLineNumber
	Local $iStart = 1
	If $opt1<>Default And Not IsMap($opt1) Then
		$iStart = 2
		$mEntry.param1 = $opt1
	EndIf
	If $opt2<>Default And Not IsMap($opt2) Then
		$iStart = 3
		$mEntry.param2 = $opt2
	EndIf
	For $i=$iStart to @NumParams-4 Step 1
		Local $param = Eval("opt"&$i)
		If IsMap($param) Then
			If $param["type"]="size" Then
				$mEntry.iWidth = $param["iWidth"]
				$mEntry.iHeight = $param["iHeight"]
			ElseIf $param["type"]="style" Then
				$mEntry.iStyle = $param["iStyle"]
				$mEntry.iStyleEx = $param["iStyleEx"]
			Else
				Local $mExtra[]
				For $key In MapKeys($param)
					If $key<>"type" Then
						$mExtra[$key] = $param[$key]
					EndIf
				Next
				$mEntry[$param["type"]] = $mExtra
			EndIf
		ElseIf $param<>Default Then
			ConsoleWrite("Error ("&$iLineNumber&"): The optional parameter 'opt"&$i&"' is not a Map/Default!"&@crlf)
		EndIf
	Next
	return MapAppend($mCtrlMap, $mEntry)
EndFunc

Func _CTRL_callback($sFunc)
	Local $mMap[]
	$mMap.type = "callback"
	$mMap.sFunc = $sFunc
	return $mMap
EndFunc

Func _CTRL_color($iTextColor = Default, $iBackgroundColor = Default)
	Local $mMap[]
	$mMap.type = "color"
	$mMap.iTextColor = $iTextColor
	$mMap.iBGColor = $iBackgroundColor
	return $mMap
EndFunc

Func _CTRL_cursor($iCursorID)
	Local $mMap[]
	$mMap.type = "cursor"
	$mMap.iCursor = $iCursorID
	return $mMap
EndFunc

Func _CTRL_font($fSize = 8.5, $iWeight = 0, $iAttribute = 0, $sFontName = "", $iQuality = 0)
	Local $mMap[]
	$mMap.type = "font"
	$mMap.fSize = $fSize
	$mMap.iWeight = $iWeight
	$mMap.iAttribute = $iAttribute
	$mMap.sFontName = $sFontName
	$mMap.iQuality = $iQuality
	return $mMap
EndFunc

Func _CTRL_image($sFilename, $sIconName = -1, $iIconType = 1)
	Local $mMap[]
	$mMap.type = "image"
	$mMap.sFilename = $sFilename
	$mMap.sIconName = $sIconName
	$mMap.iIconType = $iIconType
	return $mMap
EndFunc

Func _CTRL_limit($iMax, $iMin = 0)
	Local $mMap[]
	$mMap.type = "limit"
	$mMap.iMax = $iMax
	$mMap.iMin = $iMin
	return $mMap
EndFunc

Func _CTRL_onEvent($sFunc)
	Local $mMap[]
	$mMap.type = "onEvent"
	$mMap.sFunc = $sFunc
	return $mMap
EndFunc

Func _CTRL_resizing($iResizing)
	Local $mMap[]
	$mMap.type = "resizing"
	$mMap.iResizing = $iResizing
	return $mMap
EndFunc

Func _CTRL_size($iWidth = Default, $iHeight = Default)
	Local $mMap[]
	$mMap.type = "size"
	$mMap.iWidth = $iWidth
	$mMap.iHeight = $iHeight
	return $mMap
EndFunc

Func _CTRL_state($iState)
	Local $mMap[]
	$mMap.type = "state"
	$mMap.iState = $iState
	return $mMap
EndFunc

Func _CTRL_style($iStyle = -1, $iStyleEx = -1)
	Local $mMap[]
	$mMap.type = "style"
	$mMap.iStyle = $iStyle
	$mMap.iStyleEx = $iStyleEx
	return $mMap
EndFunc

Func _CTRL_tip($sText, $sTitle = Default, $iIcon = 0, $iOptions = 0)
	Local $mMap[]
	$mMap.type = "tip"
	$mMap.sText = $sText
	$mMap.sTitle = $sTitle
	$mMap.iIcon = $iIcon
	$mMap.iOptions = $iOptions
	return $mMap
EndFunc

; #FUNCTION# =======================================================================================
; Name ..........: _toString
; Description ...: Returns the content of a variable as String
; Syntax ........: _toString($data, $bInformative = True, $sPrefixSep = @TAB, $sSpaceOuter = @crlf, $sSpaceInner = @crlf, $iDepth = 0)
; Parameters ....: $data                  - The variable to be converted.
;                  $bInformative          - The level of detail. When True, the type of all variables is returned and not only the content
;                  $sPrefixSep            - The prefix value used for indentation
;                  $sSpaceOuter           - The space between levels of dimensions (Array) or at the beginning of a Map/DllStruct
;                  $sSpaceInner           - The space between items of an Array/Map/DllStruct
;                  $iDepth                - INTERNAL: The depth level of the call. Used in recursive calls to indent items
; Return values .: String
; Author ........: Kanashius
; ==================================================================================================
Func _toString(ByRef $data, $bInformative = True, $sPrefixSep = @TAB, $sSpaceOuter = @crlf, $sSpaceInner = @crlf, $iDepth = 0)
	Local $sPrefix = ""
	For $i=0 to $iDepth-1
		$sPrefix &= $sPrefixSep
	Next
	If IsArray($data) Then
		Local $bPrefix = False
		If StringInStr($sSpaceOuter, @crlf) or StringInStr($sSpaceInner, @crlf) Then
			$bPrefix = True
		Else
			$sPrefixSep = ""
		EndIf
		Local $iDimensions = UBound($data, 0)
		Local $sDim = ""
		For $i = 1 to $iDimensions Step 1
			$sDim &= "["&UBound($data, $i)&"]"
		Next
		Local $sOut = $sPrefix & ($bInformative ? "Array"&$sDim&" [" : "[") & $sSpaceOuter
		For $i=0 To UBound($data, 1)-1 Step 1
			If $iDimensions<2 Then
				$sOut &= _toString($data[$i], $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+1) & (($i<>UBound($data, 1)-1)?"," & $sSpaceInner:$sSpaceOuter)
			Else
				$sOut &= ($bPrefix?$sPrefix & $sPrefixSep:"") & "[" & $sSpaceOuter
				For $j=0 To UBound($data, 2)-1 Step 1
					If $iDimensions<3 Then
						$sOut &= _toString($data[$i][$j], $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+2) & (($j<>UBound($data, 2)-1)?"," & $sSpaceInner:$sSpaceOuter)
					Else
						$sOut &= ($bPrefix?$sPrefix & $sPrefixSep & $sPrefixSep:"") & "[" & $sSpaceOuter
						For $k=0 To UBound($data, 3)-1 Step 1
							$sOut &= _toString($data[$i][$j][$k], $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+3) & (($k<>UBound($data, 3)-1)?"," & $sSpaceInner:$sSpaceOuter)
						Next
						$sOut &= ($bPrefix?$sPrefix & $sPrefixSep & $sPrefixSep:"") & "]" & (($j<>UBound($data, 2)-1)?"," & $sSpaceInner:"") & $sSpaceOuter
					EndIf
				Next
				$sOut &= ($bPrefix?$sPrefix & $sPrefixSep:"") & "]" & (($i<>UBound($data, 1)-1)?"," & $sSpaceInner:$sSpaceOuter)
			EndIf
		Next
		$sOut &= ($bPrefix?$sPrefix:"") & "]"
		return $sOut
	ElseIf IsBinary($data) Then
		return $sPrefix & ($bInformative ? 'binary "'&String($data)&'"' : String($data))
	ElseIf IsBool($data) Then
		return $sPrefix & ($bInformative ? 'bool "'&StringLower(String($data))&'"' : StringLower(String($data)))
	ElseIf IsDllStruct($data) Then
		Local $bPrefix = StringInStr($sSpaceInner, @crlf)
		Local $sOut = $sPrefix & ($bInformative ? "DllStruct[b"&DllStructGetSize($data)&"]{" : "{") & $sSpaceOuter
		Local $iCount = 1
		While True
			Local $oTmp = DllStructGetData($data, $iCount)
			If @error Then ExitLoop
			$sOut &= _toString($oTmp, $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+1)
			$iCount += 1
			$sOut &=  "," & $sSpaceInner
		WEnd
		$sOut &= ($bPrefix?$sPrefix:"") & "}"
		return $sOut
	ElseIf IsFunc($data) Then
		return $sPrefix & ($bInformative ? 'function "'&FuncName($data)&'"' : FuncName($data))
	ElseIf IsFloat($data) Then
		return $sPrefix &  ($bInformative ? 'float "'&String($data)&'"' : String($data))
	ElseIf IsHWnd($data) Then
		return $sPrefix & ($bInformative ? 'hwnd "'&String($data)&'"' : String($data))
	ElseIf IsInt($data) Then
		return $sPrefix &  ($bInformative ? 'int "'&String($data)&'"' : String($data))
	ElseIf IsKeyword($data) Then
		If $data=Default Then
			return $sPrefix & ($bInformative ? 'keyword "Default"' : "default")
		ElseIf $data=Null Then
			return $sPrefix & ($bInformative ? 'keyword "Null"' : "null")
		EndIf
	ElseIf IsMap($data) Then
		Local $sOut = $sPrefix & ($bInformative ? "Map["&UBound($data)&"] {" : "{") & $sSpaceOuter
		For $key in MapKeys($data)
			$sOut &= _toString($key, $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+1) & ": " & $sSpaceOuter & _toString($data[$key], $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+2)
			$sOut &=  "," & $sSpaceInner
		Next
		$sOut &= $sPrefix & "}"
		return $sOut
	ElseIf IsNumber($data) Then
		return $sPrefix &  ($bInformative ? 'number "'&String($data)&'"' : String($data))
	ElseIf IsObj($data) Then
		If ObjName($data, 1) = "Dictionary" Then
			_hasErrorOccurred(False)
			Local $oErrHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
			Local $iCount = $data.count, $arKeys = $data.keys(), $test = $data.item("")
			If Not _hasErrorOccurred() Then
				Local $sOut =  $sPrefix & ($bInformative ? 'Object "'&ObjName($data, 1)&""" Description: """&ObjName($data, 2)&'" ' : ObjName($data, 1)) & "["&$iCount&"]" & "{" &$sSpaceOuter
				For $key in $arKeys
					Local $item = $data.item($key)
					$sOut &= _toString($key, $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+1) & ": " & $sSpaceOuter & _toString($item, $bInformative, $sPrefixSep, $sSpaceOuter, $sSpaceInner, $iDepth+2)
					$sOut &=  "," & $sSpaceInner
				Next
				$sOut &= $sPrefix & "}"
				return $sOut
			EndIf
		EndIf
		return $sPrefix & ($bInformative ? 'Object "'&ObjName($data, 1)&""" Description: """&ObjName($data, 2)&'"' : ObjName($data, 1))
	ElseIf IsPtr($data) Then
		return $sPrefix & ($bInformative ? 'pointer "'&String($data)&'"' : String($data))
	ElseIf IsString($data) Then
		return $sPrefix & ($bInformative ? 'string "'&$data&'"' : '"'&$data&'"')
	Else
		return $sPrefix & ($bInformative ? 'unsupported ('&VarGetType($data)&') "'&String($data)&'"' : String($data))
	EndIf
EndFunc

Func _ErrFunc($oError)
	_hasErrorOccurred(True)
EndFunc

Func _hasErrorOccurred($bError = Default)
	Local static $bCurrentError = False
	If $bError<>Default Then
		$bCurrentError = $bError
	EndIf
	return $bCurrentError
EndFunc

; #FUNCTION# =======================================================================================
; Name ..........: _errCheck
; Description ...: Checks if the @error is set (function call before this returned an error) and writes the error to the console.
; Syntax ........: _errCheck($sMsg = Default, $bFatal = False, $return = -1, $iError = @error, $iExtended = @extended, $sExitCallback = "_exit", $iLine = @ScriptLineNumber)
; Parameters ....: $sMsg                  - The message to show in case of an error
;                  $bFatal                - If True, the $sExitCallback will be called to exit the application gracefully
;                  $return                - The value to be returned by this function
;                  $iError                - The @error code
;                  $iExtended             - The @extended code
;                  $sExitCallback         - The function to call on exit
;                  $iLine                 - The ScriptLineNumber, where the error occurred
; Return values .: The value specified as $return and it will throw the same @error and @extended codes, the function was called with.
; Author ........: Kanashius
; ==================================================================================================
Func _errCheck($sMsg = Default, $bFatal = False, $return = -1, $iError = @error, $iExtended = @extended, $sExitCallback = "_exit", $iLine = @ScriptLineNumber)
	$sMsg = $sMsg<>Default ? " >> "&$sMsg:""
	Local $sExtended = $iExtended<>0 ? ":"&$iExtended:""
	If $iError<>0 Then ConsoleWrite("Error (line "&$iLine&"): "&$iError&$sExtended&$sMsg&@crlf)
	If $bFatal Then
		Call($sExitCallback)
		If @error Then _errCheck("Error using the ""Call"" function, while handling another error: "&@crlf&@Tab&"Error (line "&$iLine&"): "&$iError&$sExtended&$sMsg&@crlf& _
								 "Check if the function """&$sExitCallback&""" (used for $bFatal errors) exists and has no parameters!"&@crlf)
	EndIf
	Return SetError(@error, @extended, $return)
EndFunc

Alles anzeigen

Mit dem Code kann auch beliebig zwischen OnEvent und GuiGetMsg Modus umgeschaltet werden.

Ich hoffe, das hilft dir weiter und gibt dir noch einen anderen (besseren) Ansatz.

MfG, Kanashius.

casi4712

Oj e, recht herzlichen Dank erstmal, aber ich denke dass ist in meinem konkreten Fall mit Kanonnen auf Spatzen geschossen. Meine Intention war ja mit der Methode eher Codezeilen einzusparen und die Übersichtlichkeit zu erhöhen, ich finde die ist doch gegeben, zumindest wenn man gleichartige Elemente im Array direkt untereinander schreibt. Gut möglich das mit meiner Methode nicht alle Spezialfällte berückstichtigt werden. Das einzige Problem was meine Methode hat dass die im Array stehenden Ids nicht als Variable initiert werden und somit nicht in weiteren Funktionen nutzbar sind:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Global $Button1, $Edit1, $ComputerList, $fileName
Global $hostFilePath

Opt("GUIOnEventMode", 1)

Global $arElements = [ _
    [0, "Button1", "Button", "Save and choose file", 190, 340, 160, 30, "Liste speichern und File ausführen", "", ""], _
    [0, "SaveButton", "Button", "Save List", 10, 340, 100, 30, "Liste speichern", "", ""], _
    [0, "SwitchButton1", "Button", "Host1", 210, 30, 70, 30, "nd", "", ""], _
    [0, "SwitchButton2", "Button", "Host2", 210, 70, 70, 30, "nd", "", ""], _
    [0, "SwitchButton3", "Button", "Workgroup", 210, 110, 70, 30, "nd", "", ""], _
    [0, "SwitchButton4", "Button", "Fritz", 280, 30, 70, 30, "nd", "", ""], _
    [0, "SwitchButton5", "Button", "IT-Service", 280, 70, 70, 30, "nd", "", ""], _
    [0, "SwitchButton6", "Button", "Lesesaal", 280, 110, 70, 30, "nd", "", ""], _
    [0, "AllDomPCButton", "Button", "AllDomPC", 210, 170, 70, 30, "sdsds", "", ""], _
    [0, "AllDomPCsWithAButton", "Button", "Alle PC", 280, 170, 70, 30, "sdsds", "", ""], _
    [0, "AllServerButton", "Button", "All Server", 280, 200, 70, 30, "sdsds", "", ""], _
    [0, "AllLapButton", "Button", "All Laptop", 210, 200, 70, 30, "sdsds", "", ""], _
    [0, "AugiasPCButton", "Button", "All AugiasPC", 210, 230, 70, 30, "sdsds", "", ""], _
    [0, "Checkbox1", "Checkbox", "AdminUser", 10, 390, 90, 20, "", $GUI_CHECKED, ">>>"], _
    [0, "Checkbox2", "Checkbox", "Interactive", 100, 390, 90, 20, "", $GUI_UNCHECKED, ">>>"], _
    [0, "Checkbox3", "Checkbox", "CopyFile", 200, 390, 90, 20, "", $GUI_UNCHECKED, ">>>"], _
    [0, "Label1", "Label", "Freie Listen", 210, 10, 100, 20, "", "", "9,800,800"], _
    [0, "HostsLabel", "Label", "DC-Filter", 210, 150, 70, 20, "", "", "9,800,800"], _
    [0, "DCFilterLabel", "Label", "Actions", 210, 290, 70, 20, "", "", "9,800,800"], _
    [0, "OtherUserLabel", "Label", "", 10, 312, 80, 20, "", "", ""], _
    [0, "StatusLabel", "Label", "other User", 10, 312, 80, 20, "", "", ""], _
    [0, "GearIcon", "Icon", "shell32.dll", 172, 280, 385, 30, 30, "Öffnet das aktuelle Skriptverzeichnis im Explorer", "", ""], _
    [0, "PrefIcon", "Icon", "shell32.dll", 16826, 320, 390, 25, 25, "Öffnet die Settings", "", ""], _
    [0, "ActionCombo", "Combo", "InstallActaPro|DelActaPro|-----------------------|Fun2|hdl|leise|laut|play", 210, 310, 140, 25, "", "", ""], _
    [0, "Edit1", "Edit", "", 10, 30, 190, 270, "", "", ""], _
    [0, "RadioGroupStart", "Group", "", 10, 450, 160, 15, "", "", "", $GUI_ENABLE], _  ; Start der Radio-Button-Gruppe
    [0, "RadioButton1", "Radio", "Option 1", 10, 450, 60, 10, "", "", "", $GUI_ENABLE + $GUI_CHECKED], _
    [0, "RadioButton2", "Radio", "Option 2", 110, 450, 60, 10, "", "", "", $GUI_ENABLE], _
    [0, "RadioGroupEnd", "GroupEnd", "", 0, 0, 0, 0, "", "", ""], _  ; Ende der Radio-Button-Gruppe
    [0, "Input1", "Input", "", 10, 370, 90, 20, "", "", "", $GUI_ENABLE] _
]

Global $hParent = GUICreate("TESTGUI", 360, 520)
_CreateGuiElement($arElements)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW, $hParent)

While 1
    Sleep(10)
WEnd

Func _HandleCtrlEvent()
    Local $iIndex = _ArraySearch($arElements, @GUI_CtrlId, 0, 0, 0, 0, 1, 0)

    Switch $arElements[$iIndex][1]
        Case "SwitchButton1"
            LoadHostFile("host1.txt")

    EndSwitch
EndFunc



Func LoadHostFile($fileName)

    $hostFilePath = @ScriptDir & "\lists\" & $fileName
    $ComputerList = FileRead($hostFilePath)
    GUICtrlSetData($Edit1, $ComputerList)

EndFunc


Func _Exit()
    Exit
EndFunc

Func _CreateGuiElement(ByRef $aCtrlInfo)
    For $i = 0 To UBound($aCtrlInfo) - 1
        Switch $aCtrlInfo[$i][2]
            Case "Button"
                $aCtrlInfo[$i][0] = GUICtrlCreateButton($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][8])
            Case "Checkbox"
                $aCtrlInfo[$i][0] = GUICtrlCreateCheckbox($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
                GUICtrlSetState(-1, $aCtrlInfo[$i][9])
            Case "Label"
                $aCtrlInfo[$i][0] = GUICtrlCreateLabel($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6])
                If $aCtrlInfo[$i][10] <> "" Then
                    Local $fontParams = StringSplit($aCtrlInfo[$i][10], ",")
                    GUICtrlSetFont(-1, $fontParams[1], $fontParams[2], $fontParams[3])
                EndIf
            Case "Icon"
                $aCtrlInfo[$i][0] = GUICtrlCreateIcon($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7], $aCtrlInfo[$i][8])
                GUICtrlSetTip(-1, $aCtrlInfo[$i][9])
            Case "Combo"
                $aCtrlInfo[$i][0] = GUICtrlCreateCombo("", $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetData($aCtrlInfo[$i][0], $aCtrlInfo[$i][3])
            Case "Edit"
                $aCtrlInfo[$i][0] = GUICtrlCreateEdit($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "Radio"
                $aCtrlInfo[$i][0] = GUICtrlCreateRadio($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
                GUICtrlSetState($aCtrlInfo[$i][0], $aCtrlInfo[$i][11]) ; Setzt den Radiobutton in den angegebenen Zustand
            Case "Input"
                $aCtrlInfo[$i][0] = GUICtrlCreateInput($aCtrlInfo[$i][3], $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "Group"
                $aCtrlInfo[$i][0] = GUICtrlCreateGroup("", $aCtrlInfo[$i][4], $aCtrlInfo[$i][5], $aCtrlInfo[$i][6], $aCtrlInfo[$i][7])
            Case "GroupEnd"
                GUICtrlCreateGroup("", -99, -99, 1, 1)  ; End Group
        EndSwitch
        GUICtrlSetOnEvent(-1, "_HandleCtrlEvent")
    Next
EndFunc

Alles anzeigen

das würde mir fürs erste reichen,

lg und schöne Reatwoche noch