daten aus einer ini datei in ein array[x][x] nach vorgaben umwandeln? möglich? wie?

bankesbusters

hallo zusammen,

ich habe eine ini datei mit folgendem inhalt erstellt:

Code

[Data]
Key01=John|January|Room103|
Key02=John|February|Room104|
Key03=John|March|Room105|
Key04=John|April|Room106|
Key05=John|May|Room107|
Key06=John|June|Room108|
Key07=John|July|Room109|
Key08=John|August|Room111|
Key09=John|September|Room112|
Key10=John|October|Room113|
Key11=John|November|Room114|
Key12=John|December|Room115|
Key13=Lucy|January|Room116|
Key14=Lucy|February|Room117|
Key15=Lucy|March|Room118|
Key16=Lucy|April|Room119|
Key17=Lucy|May|Room121|
Key18=Lucy|June|Room122|
Key19=Lucy|July|Room123|
Key20=Lucy|August|Room124|
Key21=Lucy|September|Room125|
Key22=Lucy|October|Room126|
Key23=Lucy|November|Room127|
Key24=Lucy|December|Room128

Alles anzeigen

nun möchte ich diese daten auslesen und ein array[24][3] daraus machen, aber ich scheitere irgendwie daran.

was ich bisher getan habe ist:

AutoIt

#include <MsgBoxConstants.au3>
#include <Array.au3>
$ini = 'shortlist.ini'
$sections = IniReadSectionNames($ini)
For $a = 1 To UBound($sections) - 1
    $keys = IniReadSection($ini, $sections[$a])
    For $b = 1 To UBound($keys) - 1
        $data = IniRead($ini, $sections[$a], $keys[$b][0],'')
        #comments-start
        die daten aus der shortlist.ini wurden erfolgreich eingelesen
        #comments-end
        MsgBox(0,"",$data) ;hier kann ich die einzelnen daten in einer msgbox ausgeben lassen
        ConsoleWrite($data) ;hier lasse ich die daten in der konsole ausgeben
        #comments-start
        jetzt möchte ich die daten auch umwandeln in ein array[24][3] ... die frage ist nur wie?
        #comments-end
    Next
Next
$get_data = StringSplit($data,"|") ;nur der letzte datensatz wird abgegriffen und in ein array ausgegeben ... und dann noch das falsche array[3]
_ArrayDisplay($get_data)

Alles anzeigen

ich habe viele verschiedene ansätze probiert, aber da fehlt noch das klare verständnis warum und wieso das nicht klappt. es muss aber gehen, denn die daten werden ja auch ausgelesen. dies ist wichtig, denn dieses array ist die grundlage einer 'master-tabelle' die später der dreh- und angelpunkt meiner experimente darstellen soll. ich werde aber immer nur ein thema erfragen, denn wenn ich zu viel auf einmal frage verliert man schnell die übersicht.

hilfe wäre toll. danke vorab.

gruss

**AspirinJunkie**

Die naheliegendste Abfolge ist die folgende:

Daten der Ini-Sektion roh einlesen (mit IniReadSection())
Anzahl der eingelesenen Datensätze bestimmen (mit Ubound oder direkt im Element [0][0] von IniReadSection)
Zielarray mit der gewünschten Größe deklarieren (die Anzahl aus Schritt 2 verwenden)
Die Elemente vom Returnarray von IniReadSection einzeln durchgehen (mit For-To-Schleife)
In der Schleife den Datenwert des aktuellen Elementes an den "|"-Zeichen trennen (mit StringSplit)
In der Schleife die getrennten Werte einzeln ins Zielarray schreiben

Fertig

Bei dir ist daher schon einmal das Problem, dass du nie das Zielarray deklarierst.
Auch aufpassen muss man ob die Arrays jeweils 1-basiert oder 0-basiert sind (bei IniReadSection sind die dämlicherweise 1-basiert).

Spoiler anzeigen

AutoIt

#include <Array.au3>

Global $sIniFile = @ScriptDir & "\Test.ini"

; Daten der Ini-Sektion in 2D-Array einlesen (Datenfelder noch ungetrennt)
Global $aIniDataRaw = IniReadSection($sIniFile, "Data")
If @error Then MsgBox(0, 16, "Fehler", "Fehler " & @error & " beim Einlesen der Ini-Sektion")

; Anzahl der eingelesenen Elemente ermitteln
Global $iN = $aIniDataRaw[0][0]

; Zielarray dimensionieren
Global $aData[$iN][3]

; Daten einzeln in Zielarray übertragen
Global $aSplit
For $i = 1 To $iN
	
	; Datenwert an den | trennen
	$aSplit = StringSplit($aIniDataRaw[$i][1], "|", 3)
	If UBound($aSplit) < 3 Then Exit MsgBox(0,"Fehler", "Fehler " & @error & " beim Trennen der Daten.")

	; in Zielarray übertragen
	$aData[$i - 1][0] = $aSplit[0]
	$aData[$i - 1][1] = $aSplit[1]
	$aData[$i - 1][2] = $aSplit[2]
Next

; Zielarray ausgeben
_ArrayDisplay($aData, "Ergebnis", "", 64, "|", "Name|Monat|Raum")

Alles anzeigen

**chesstiger**

Hi!

Du bist da schon auf einem guten Weg. Ein paar Gedanken dazu...

Du musst nicht unbedingt für jeden Datensatz ein extra IniRead verwenden. IniReadSection liest nicht nur die Schlüssel aus, sondern auch die gespeicherten Werte.
Du greifst in einer Schleife immer wieder schreibend auf ein und dieselbe Variable $data zu (Zeile 8). Dabei überschreibst du bei jedem Durchlauf den letzten Wert, deshalb hast du am Ende auch nur den letzten Datensatz übrig.
Wenn es deutlich mehr Datensätze als in dem Beispiel werden, ist eine Ini-Datei vermutlich nicht die richtige Wahl. Dann macht es mehr Sinn, mit Datenbanken zu arbeiten.

So könnte man das relativ elegant lösen, allerdings ohne Fehlerbehandlung (also z.B. fehlerhaft formatierte Einträge ignorieren oder so):

C

#include <MsgBoxConstants.au3>
#include <Array.au3>
$ini = 'shortlist.ini'
$sections = IniReadSectionNames($ini)
For $a = 1 To UBound($sections) - 1
	;IniReadSection gibt ein Array im Größenformat [n][2] zurück.
    $data = IniReadSection($ini, $sections[$a])
	;Wir erweitern das Array mit ReDim auf [n][4].
	ReDim $data[UBound($data, 1)][4]
	;Jetzt gehen wir durch alle Zeilen durch.
	For $b = 1 To UBound($data) - 1
		;Wir zerlegen jeden Daten-String anhand des Trennzeichens "|"
		$line = StringSplit($data[$b][1], "|")
		;Wir setzen jetzt unsere getrennten Daten in unser Haupt-Array $data ein
		$data[$b][1] = $line[1]
		$data[$b][2] = $line[2]
		$data[$b][3] = $line[3]
	Next
Next

_ArrayDisplay($data)

Alles anzeigen

Dabei kommt dann ein Array im Format [n][4] raus.

Liebe Grüße

**Kanashius**

Und zum Wiederverwenden als Funktion könnte man es so machen:

AutoIt

ConsoleWrite("-------------Array-------------"&@crlf)
Local $arData = _iniSectionToArray("shortlist.ini", "Data")
; Display data
For $i=0 To UBound($arData)-1 Step 1
	ConsoleWrite(StringFormat("%-10s %-9s %-8s\r\n", $arData[$i][0], $arData[$i][1], $arData[$i][2]))
Next

ConsoleWrite("--------------Map--------------"&@crlf)
Local $mData = _iniToMap("shortlist.ini")
; Display data
For $sKey In MapKeys($mData)
	ConsoleWrite("-----Section "&$sKey&"-----"&@crlf)
	Local $mSection = $mData[$sKey]
	For $sSecKey In MapKeys($mSection)
		ConsoleWrite($sSecKey&": "&$mSection[$sSecKey]&@crlf)
	Next
Next

ConsoleWrite("---------Map Processed---------"&@crlf)
Local $mDataProc = _iniToMap("shortlist.ini", "_processValueData")
; Display data
For $sKey In MapKeys($mDataProc)
	ConsoleWrite("-----Section "&$sKey&"-----"&@crlf)
	Local $mSection = $mDataProc[$sKey]
	For $sSecKey In MapKeys($mSection)
		Local $arValue = $mSection[$sSecKey]
		ConsoleWrite(StringFormat("%-5s: %-10s %-9s %-8s\r\n", $sSecKey, $arValue[0], $arValue[1], $arValue[2]))
	Next
Next

Func _iniSectionToArray($sFile, $sSection)
	Local $arData = IniReadSection($sFile, $sSection)
	Local $arResult[UBound($arData)-1][3]
	For $i=1 To UBound($arData)-1 Step 1
		Local $arLine = StringSplit($arData[$i][1], "|", BitOR(1, 2))
		If UBound($arLine)<3 Then Return SetError(1, 0, -1)
		$arResult[$i-1][0] = $arLine[0]
		$arResult[$i-1][1] = $arLine[1]
		$arResult[$i-1][2] = $arLine[2]
	Next
	Return $arResult
EndFunc

Func _iniToMap($sFile, $sProcessDataCallback = Default)
	Local $mResult[]
	Local $arSections = IniReadSectionNames($sFile)
	For $i=1 To UBound($arSections)-1 Step 1
		Local $mSection[]
		Local $arData = IniReadSection($sFile, $arSections[$i])
		For $j=1 To UBound($arData)-1 Step 1
			If $sProcessDataCallback<>Default Then
				$mSection[$arData[$j][0]] = Call($sProcessDataCallback, $arData[$j][1])
			Else
				$mSection[$arData[$j][0]] = $arData[$j][1]
			EndIf
		Next
		$mResult[$arSections[$i]] = $mSection
	Next
	Return $mResult
EndFunc

Func _processValueData($sValue)
	Return StringSplit($sValue, "|", BitOR(1, 2))
EndFunc

Alles anzeigen

Ich hab noch eine Funktion hinzugefügt, die alls Sections der Ini einliest und in eine Map speichert. Dabei kann auch eine Funktion angegeben werden (z.B. "_ProcessValueData") um die Value weiter zu verarbeiten (hier z.B. in ein Array umzuwandeln).
Die Ausgabe hab ich extra manuell gemacht, um ein Beispiel zu geben, wie man das benutzen kann.

**Schnuffel**

ich weiß jetzt nicht, ob du auch Sektionen in der ini deklariert hast ([Section ...])

mit einem SectionName in der ini funktioniert es mit diesem Script

AutoIt

#include <MsgBoxConstants.au3>
#include <Array.au3>
Global $ini = @ScriptDir & "\shortlist.ini"
Global $aErgebnis[1][1]
Global $sections = IniReadSectionNames($ini)
For $a = 1 To UBound($sections) - 1
    $keys = IniReadSection($ini, $sections[$a])
	Redim $aErgebnis[UBound($keys)][4]
    For $b = 1 To UBound($keys) - 1
        $data = StringSplit($keys[$b][1], '|')
		$aErgebnis[$b][0] = $keys[$b][0]
		$aErgebnis[$b][1] = $data[1]
		$aErgebnis[$b][2] = $data[2]
		$aErgebnis[$b][3] = $data[3]
    Next
Next
_ArrayDisplay($aErgebnis)

Alles anzeigen

bankesbusters

hallo zusammen.

zunächst vielen dank für die tips und lösungsvorschläge. ich ackere mich jetzt in ruhe dadurch und teste alles mal aus um zu sehen was mir für mein vorhaben am besten passt. vielen dank für die mühen, ich weiss das sehr von allen zu schätzen.

gruss