Beiträge von UEZ

;Coded by UEZ build 2022-03-05 proof-of-concept version
#include <GDIPlus.au3>
#include <Memory.au3>

Func _GDIPlus_StreamImage2BinaryString($hBitmap, $sFormat = "PNG", $iQuality = 80, $bSave = False, $sFilename = @ScriptDir & "\Converted.jpg") ;coded by UEZ 2013 build 2014-01-25 (based on the code by Andreik)
    Local $sImgCLSID, $tGUID, $tParams, $tData
    Switch $sFormat
        Case "JPG"
            $sImgCLSID = _GDIPlus_EncodersGetCLSID($sFormat)
            $tGUID = _WinAPI_GUIDFromString($sImgCLSID)
            $tData = DllStructCreate("int Quality")
            DllStructSetData($tData, "Quality", $iQuality) ;quality 0-100
            Local $pData = DllStructGetPtr($tData)
            $tParams = _GDIPlus_ParamInit(1)
            _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData)
        Case "PNG", "BMP", "GIF", "TIF"
            $sImgCLSID = _GDIPlus_EncodersGetCLSID($sFormat)
            $tGUID = _WinAPI_GUIDFromString($sImgCLSID)
        Case Else
            Return SetError(1, 0, 0)
    EndSwitch
    Local $hStream = _WinAPI_CreateStreamOnHGlobal() ;http://msdn.microsoft.com/en-us/library/ms864401.aspx
    If @error Then Return SetError(2, 0, 0)
    _GDIPlus_ImageSaveToStream($hBitmap, $hStream, DllStructGetPtr($tGUID), DllStructGetPtr($tParams))
    If @error Then Return SetError(3, 0, 0)

    Local $hMemory = _WinAPI_GetHGlobalFromStream($hStream) ;http://msdn.microsoft.com/en-us/library/aa911736.aspx
    If @error Then Return SetError(4, 0, 0)
    Local $iMemSize = _MemGlobalSize($hMemory)
    If Not $iMemSize Then Return SetError(5, 0, 0)
    Local $pMem = _MemGlobalLock($hMemory)
    $tData = DllStructCreate("byte[" & $iMemSize & "]", $pMem)
    Local $bData = DllStructGetData($tData, 1)
    _WinAPI_ReleaseStream($hStream) ;http://msdn.microsoft.com/en-us/library/windows/desktop/ms221473(v=vs.85).aspx
    _MemGlobalFree($hMemory)
    If $bSave Then
        Local $hFile = FileOpen($sFilename, 18)
        If @error Then Return SetError(6, 0, $bData)
        FileWrite($hFile, $bData)
        FileClose($hFile)
    EndIf
    Return $bData
EndFunc   ;==>_GDIPlus_StreamImage2BinaryString

Func _StringCompress($sString)
    If StringLen($sString) < 24 Then Return SetError(1, 0, 0)
    _GDIPlus_Startup()
    Local $iLen = StringLen($sString), $iMemSize = Mod($iLen, 8) ? ($iLen + 8 - Mod($iLen, 8)) * 4 : $iLen * 4, $i
    Local $tPixelData = DllStructCreate("ubyte scan0[" & $iMemSize & "];"), $iW = Mod($iLen, 4)  ? Int($iLen / 4) + 1 : $iLen / 4
    If $iW > 65535 Then Return SetError(2, 0, 0)
    Local $hImage = _GDIPlus_BitmapCreateFromScan0($iW, 1, $GDIP_PXF32ARGB, $iMemSize, $tPixelData)
    If Not $hImage Then
        _GDIPlus_Shutdown()
        Return SetError(3, 0, 0)
    EndIf
    For $i = 1 To $iLen
        $tPixelData.Scan0(($i)) = Asc(StringMid($sString, $i, 1))
    Next
    Local $binData = _GDIPlus_StreamImage2BinaryString($hImage)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_Shutdown()
    Return $binData
EndFunc

Func _StringDecompress($vCompress)
    If BinaryLen($vCompress) < 5 Then Return SetError(1, 0, 0)
    _GDIPlus_Startup()
    Local $sString, $hImage = _GDIPlus_BitmapCreateFromMemory($vCompress)
    If Not $hImage Then
        _GDIPlus_Shutdown()
        Return SetError(2, 0, 0)
    EndIf

    Local $binBMP = _GDIPlus_StreamImage2BinaryString($hImage, "BMP"), $iLen = BinaryLen($binBMP), $iSize =  _GDIPlus_ImageGetWidth($hImage) * 4 - 3
    $sString = BinaryToString(BinaryMid($binBMP, 55, $iSize))
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_Shutdown()
    $binBMP = 0
    Return $sString
EndFunc

Global $sUsername = "UEZ"

#Region Achtung! Diese Region darf nicht veraendert werden!
Global $hFile = FileOpen(@ScriptDir & '\original.txt', 128)
If $hFile = -1 Then Exit
Global $sOriginal = FileRead($hFile)
FileClose($hFile)
Global $iOriginalLen = StringLen($sOriginal)

Global $iTimer = TimerInit()
Global $vCompressed = _StringCompress($sOriginal)
Global $iTimeDiffComp = TimerDiff($iTimer)
;Global $iCompressedLen = StringLen($vCompressed)
Global $iCompressedLen = BinaryLen($vCompressed)

Global $iTimer = TimerInit()
Global $sDecompressed = _StringDecompress($vCompressed)
Global $iTimeDiffDecomp = TimerDiff($iTimer)
Global $iDecompressedLen = StringLen($sDecompressed)

ConsoleWrite('============================================================' & @CRLF)
ConsoleWrite(StringFormat('Result for "%s"\r\n', $sUsername))
ConsoleWrite('============================================================' & @CRLF)
ConsoleWrite(StringFormat('Decompressed = Original: %s\r\n', $sOriginal == $sDecompressed))
ConsoleWrite(StringFormat('Length Original: %i\r\n', $iOriginalLen))
ConsoleWrite(StringFormat('Length compressed: %i\r\n', $iCompressedLen))
ConsoleWrite(StringFormat('Length decompressed: %i\r\n', $iDecompressedLen))
ConsoleWrite(StringFormat('Compress-Ratio: %s %%\r\n', Round(100 - (100 / $iOriginalLen * $iCompressedLen), 3)))
ConsoleWrite(StringFormat('Time compressed: %i ms\r\n', $iTimeDiffComp))
ConsoleWrite(StringFormat('Time decompressed: %i ms\r\n', $iTimeDiffDecomp))
ConsoleWrite('============================================================' & @CRLF)
#EndRegion Achtung! Diese Region darf nicht veraendert werden!

;coded by UEZ
Func HN($n, $iDepth = 0)
    If $n = 0 Or $n = 2 Or $n = 4 Or $n = 20 Or $n = 42 Or $n = 145 Or $iDepth > 16 Then Return 0
    If $n = 1 Then Return 1
    Local $i, $a = StringRegExp($n, "\d", 3), $sum = 0
    For $i = 0 To UBound($a) - 1
        $sum += $a[$i] * $a[$i]
    Next
    If $sum = 1 Then Return 1
    Return HN($sum, $iDepth + 1)
EndFunc

For $i = 0 To 100
    ConsoleWrite("Zahl " & $i & " ist Happy: " & HN($i) & @CRLF)
Next