Array ByRef in SubSkript registrieren?

**BugFix**

Ich stehe gerade etwas auf der Leitung.

Ich habe ein Skript, das ich includieren möchte. Von dort aus soll auf ein sich im Hauptskript befindliches Array mit wechselnden Inhalten, intervallmäßig zugegriffen werden.

Deshalb habe ich eine Registrierfunktion, über die das Hauptskript das Array an das SubSkript meldet.

Aber es nutzt ja nichts, wenn ich einer im SubSkript definierten Variable die Arrayvariable aus dem Hauptskript zuweise, das Array wird dann ja nur einmalig mit aktuellem Inhalt kopiert.

Ich müsste ByRef zugreifen, also schick wäre ja sowas: $a_Sub = ByRef $a_Main - OK, geht nicht.

Habt ihr einen Ansatz?

**UEZ**

Kannst du vielleicht ein kleines Beispiel basteln? Denn ich bin mir nicht ganz sicher, was das Problem ist.

**BugFix**

Ich habs mal als lauffähiges Bsp. exrahiert:

AutoIt: main.au3

#include "sub.au3"

HotKeySet("^!x", '_Exit')

Global $aData[3]
_FillArray($aData)

; sub - Funktionen
_Register_Array($aData, 50)
_Run()

; es werden immer dieselben Daten verarbeitet


While True
    Sleep(50)
    _FillArray($aData)
WEnd



Func _Exit()
    Exit
EndFunc

Func _FillArray(ByRef $a)
    For $i = 0 To UBound($a) -1
        $a[$i] = Int(Random(1,50,1))
    Next
EndFunc

Alles anzeigen

AutoIt: sub.au3

Global $g_aUpdateValues = Null
Global $g_iIntervall = Null

; Datenquelle und Intervall registrieren
Func _Register_Array($_aValues, $_iIntervall)
    $g_aUpdateValues = $_aValues
    $g_iIntervall = $_iIntervall
EndFunc


; Verarbeitung in Intervallen starten
Func _Run()
    If $g_iIntervall <> Null Then
        AdlibRegister(_Calculation, $g_iIntervall)
    EndIf
EndFunc


; Verarbeitung
Func _Calculation()
    For $i = 0 To UBound($g_aUpdateValues) -1
        ConsoleWrite('Verarbeite ' & $g_aUpdateValues[$i] & @CRLF)
    Next
    ConsoleWrite('-----------------------' & @CRLF)
EndFunc

Alles anzeigen

**UEZ**

Ich vermute, dass bei dieser Aktion (AdlibRegister) der Speicher intern kopiert wird und somit die Änderungen des Arrays nicht aktualisiert werden.

Dies funzt:

AutoIt

While True
    Sleep(50)
    _FillArray($aData)
    _Register_Array($aData, 50)
    _Run()
WEnd

**BugFix**

Ja, das ist mir klar. ByRef ist nur als Funktionsparameter möglich. Adlib ist aber parameterlos und somit wird das Anfangsarray nur kopiert und in der Sub wird nur auf diese Kopie, die sich leider nicht aktualisieren lässt, zugegriffen.

Ich hoffte nur, dass jemand einen genialen Hack kennt, um das irgendwie zu realisieren.

misterspeed

Angenommen es würde funktionieren wie du es willst... ist Adlibregister dann überhaupt eine sinnvolle Wahl? Die in Adlibregister registrierte Funktion zur Verarbeitung könnte deine Funktion zum neu Befüllen deines Arrays unterbrechen. Angenommen das passiert bei 50% des Füllvorgangs, dann verarbeitest du zur Hälfte "alte" Daten und zur Hälfte "neue" Daten. Wenn das ein Problem wäre kommt das so ohnehin nicht in Frage.

**BugFix**

Zitat von misterspeed

Angenommen das passiert bei 50% des Füllvorgangs, dann verarbeitest du zur Hälfte "alte" Daten und zur Hälfte "neue" Daten. Wenn das ein Problem wäre kommt das so ohnehin nicht in Frage.

Das Array würde natürlich ein Element enthalten, dass den Status mitteilt. Eine Verarbeitung würde davon abhängig sein.

Das Hauptskript soll nur Daten von verschiedenen Quellen einsammeln und diese werden dann in einem anderen Skript verarbeitet.

Ich werde mal versuchen, mit DllCallback zu arbeiten. Da habe ich dann Pointer zur Verfügung und somit einen Zugriff ByRef. Nur bin ich dann wieder beschränkt bei der Flexibilität meiner Datentypen.

**UEZ**

Zitat von BugFix

Das Hauptskript soll nur Daten von verschiedenen Quellen einsammeln und diese werden dann in einem anderen Skript verarbeitet.

In Freebasic kann man den Pointer von einem Array übergeben und somit direkt in den Speicher schreiben. In Autoit, soweit ich weiß, geht das leider nicht. Falls die Daten immer den gleichen Typ haben, könnte man auch eine Struct anstelle eines Arrays benutzen und den Pointer zur Struct übergeben.

**BugFix**

Ich habe mich jetzt anders entschieden.

Da das Hauptprogramm sowieso irgendeine Funktion am Laufen hat, die die Daten in das Array speichert, ist es doch auch kein Problem eine Funktion aufzurufen um das fertige Array zum Subskript zu kopieren. Dort wird einfach regelmäßig abgefragt, ob was Neues da ist, wenn ja wird es verarbeitet. Anhand meines obigen Bsp. könnte man das dann so machen:

AutoIt: main.au3

#include "sub.au3"

HotKeySet("^!x", '_Exit')

Global $aData[3]
_FillArray($aData)

; aktiviere Datenaustausch
_Sub_DataExchangeOnOff()
; sende Array
_Sub_DataExchange($aData)


While True
    Sleep(50)
    _FillArray($aData)
    _Sub_DataExchange($aData)
WEnd



Func _Exit()
    _Sub_DataExchangeOnOff(False)
    Exit
EndFunc

Func _FillArray(ByRef $a)
    For $i = 0 To UBound($a) -1
        $a[$i] = Int(Random(1,50,1))
    Next
EndFunc

Alles anzeigen

AutoIt: sub.au3

Global $g_bDataExchangeMode = False      ; ist Datenaustausch aktiv
Global $g_aUpdateValues                    ; bei neuen Daten wird Array aus Hauptanwendung hierhin kopiert
Global $g_iCounterNewData = -2147483648 ; Zähler für Updateaktionen (bis 2.147.483.647)

; De-/Aktivieren des Datenaustausches
Func _Sub_DataExchangeOnOff($_bOn=True)
    $g_bDataExchangeMode = $_bOn
    If $_bOn Then
        AdlibRegister(_Calculation, 50)
    Else
        AdlibUnRegister(_Calculation)
    EndIf
EndFunc

; Nach neuer Datenzusammenstellung sendet das Main- diese an das Subskript
Func _Sub_DataExchange($_aData)
    $g_aUpdateValues = $_aData
    $g_iCounterNewData += 1
EndFunc


; Verarbeitung
Func _Calculation()
    Local Static $iUpdateCounter = -2147483648
    If $g_iCounterNewData > $iUpdateCounter Then
        $iUpdateCounter = $g_iCounterNewData
        AdlibUnRegister(_Calculation)
        For $i = 0 To UBound($g_aUpdateValues) -1
            ConsoleWrite('Verarbeite ' & $g_aUpdateValues[$i] & @CRLF)
        Next
        ConsoleWrite('-----------------------' & @CRLF)
        AdlibRegister(_Calculation, 50)
    EndIf
EndFunc

Alles anzeigen

P.S.

Das ist jetzt nur ein funktionales Bsp. Natürlich muss man berücksichtigen, dass evtl. Zeitdifferenzen auftreten in Zusammenstellung und/oder Verarbeitung. Insofern würde ich neue Daten sinnvollerweise in einem Puffer sammeln und von dort abarbeiten.

BugFix 18. August 2021 um 11:11