1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Zeitriss

Beiträge von Zeitriss

  • Kopierhilfe

    • Zeitriss
    • 9. August 2017 um 18:16

    Hi,

    Enspricht folgendes deinen Vorstellungen?

    Spoiler anzeigen
    AutoIt
    Opt("GUIOnEventMode", 1)
    #include <Array.au3>
    #include <File.au3>
    #include <GUIConstantsEx.au3>
    #include <ListViewConstants.au3>
    #include <StaticConstants.au3>
    #include <TreeViewConstants.au3>
    #include <WindowsConstants.au3>
    
    
    Global $g_sPath_Ini = @scriptdir & "\Settings.ini"
    
    
    Global $g_sPath_Source = IniRead($g_sPath_Ini, "Path", "Source", "E:\Daten")
    Global $g_sPath_Dest = IniRead($g_sPath_Ini, "Path", "Dest", "F:\Dokumente\Aussendienst")
    
    
    Global $g_aLV_Folder[0][2]
    
    
    Global $g_hGUI = GUICreate("Projekt Kopieren", 500, 500, -1, -1, $WS_SIZEBOX)
    
    
    Opt("GUIResizeMode", BitOR($GUI_DOCKTOP, $GUI_DOCKHCENTER, $GUI_DOCKSIZE))
    GUICtrlCreateLabel("Quellordner:", 0, 23, 70, 19, $SS_RIGHT)
    Global $g_idInput_Path_Source = GUICtrlCreateInput($g_sPath_Source, 80, 20, 350, 20)
    GUICtrlSetState($g_idInput_Path_Source, $GUI_DISABLE)
    Global $g_idButton_Path_Source = GUICtrlCreateButton("...", 435, 20, 30, 20)
    GUICtrlCreateLabel("Zielordner:", 0, 53, 70, 19, $SS_RIGHT)
    Global $g_idInput_Path_Dest = GUICtrlCreateInput($g_sPath_Dest, 80, 50, 350, 20)
    GUICtrlSetState($g_idInput_Path_Dest, $GUI_DISABLE)
    Global $g_idButton_Path_Dest = GUICtrlCreateButton("...", 435, 50, 30, 20)
    
    
    Opt("GUIResizeMode", $GUI_DOCKBORDERS)
    Global $g_idLV_SelectFolder = GUICtrlCreateListView("Projekt", 5, 100, 490, 340, $LVS_LIST, BitOR($LVS_EX_CHECKBOXES,$LVS_EX_FULLROWSELECT))
    
    
    Opt("GUIResizeMode", BitOR($GUI_DOCKRIGHT, $GUI_DOCKBOTTOM, $GUI_DOCKSIZE))
    Global $g_idButton_SelectInv = GUICtrlCreateButton("Auswahl umkehren", 110, 450, 110, 22)
    Global $g_idButton_Save = GUICtrlCreateButton("Pfade Speichern", 230, 450, 150, 22)
    GUICtrlSetState($g_idButton_Save, $GUI_DISABLE)
    Global $g_idButton_Start = GUICtrlCreateButton("Kopieren", 390, 450, 100, 22)
    
    
    GUICtrlSetOnEvent($g_idButton_Path_Source, "Event_Button_Source")
    GUICtrlSetOnEvent($g_idButton_Path_Dest, "Event_Button_Dest")
    GUICtrlSetOnEvent($g_idButton_SelectInv, "Event_Button_SelectInv")
    GUICtrlSetOnEvent($g_idButton_Save, "Event_Button_Save")
    GUICtrlSetOnEvent($g_idButton_Start, "Event_Button_Start")
    GUISetOnEvent($GUI_EVENT_CLOSE, "Event_Close")
    
    
    LoadFolderInListView($g_sPath_Source)
    GUISetState(1,$g_hGUI)
    
    
    While 1
       sleep(1000)
    WEnd
    
    
    Func CopyProject($aFolder, $sPathSource, $sPathTarget); Übernimmt die eigentliche Kopierarbeit
       Local $sFolderSource, $sFolderTarget, $sFilesFail = ""
       For $i = 0 to UBound($aFolder) -1
    	  $sFolderSource = $sPathSource & "\" & $aFolder[$i] & "\Dokument-Explorer\Berechnungen"
    	  $sFolderTarget = $sPathTarget & "\" & StringLeft($aFolder[$i], 4) & "\" & StringTrimLeft($aFolder[$i], 2) & "\Berechnungen"
    	  ConsoleWrite($sFolderSource & " --> COPY --> " & $sFolderTarget & @crlf)
    ;~ 	  DirCreate($sFolderTarget)
    ;~ 	  If Not DirCopy($sFolderSource,  $sFolderTarget, $FC_OVERWRITE) Then
    ;~ 		 $sFilesFail &= $sFolderSource & @crlf & @crlf
    ;~ 	  EndIf
       Next
       If $sFilesFail <> "" Then MsgBox(16, "Fehler", "Folge Dateien konnten nicht kopiert werden: " & @crlf & @crlf & $sFilesFail)
    EndFunc
    
    
    Func Event_Button_Dest(); Auswählen des Zielordners über den Benützer
       Local $sNewPath = FileSelectFolder("Bitte den Projekt-Ordner wählen", $g_sPath_Dest)
       If @error Then Return
       $g_sPath_Dest = $sNewPath
       GUICtrlSetData($g_idInput_Path_Dest, $sNewPath)
       GUICtrlSetState($g_idButton_Save, $GUI_ENABLE)
    EndFunc
    
    
    Func Event_Button_Save(); Speichert die Pfade in einer Inidatei
       Local $iWrite = 0
       $iWrite += IniWrite($g_sPath_Ini, "Path", "Source", $g_sPath_Source)
       $iWrite += IniWrite($g_sPath_Ini, "Path", "Dest", $g_sPath_Dest)
       If $iWrite < 2 Then
    	  MsgBox(16, "Error", "Speichern in Ini-Datei nicht möglich!")
    	  Return
       EndIf
       GUICtrlSetState($g_idButton_Save, $GUI_DISABLE)
    EndFunc
    
    
    Func Event_Button_SelectInv()
       Local $iState
       GUICtrlSetState($g_idLV_SelectFolder, $GUI_HIDE)
       For $i = 0 to UBound($g_aLV_Folder) -1
    	  $iState = GUICtrlRead($g_aLV_Folder[$i][1], 1)
    	  If BitAND($iState, $GUI_CHECKED) Then
    		 GUICtrlSetState($g_aLV_Folder[$i][1], $GUI_UNCHECKED)
    	  Else
    		 GUICtrlSetState($g_aLV_Folder[$i][1], $GUI_CHECKED)
    	  EndIf
       Next
       GUICtrlSetState($g_idLV_SelectFolder, $GUI_SHOW)
    EndFunc
    
    
    Func Event_Button_Start(); Listet die ausgewählten Projekte auf und ruft CopyProject() auf
       GUICtrlSetState($g_idButton_Start, $GUI_DISABLE)
       GUICtrlSetData($g_idButton_Start, "Arbeitet")
       Local $aFolderList[UBound($g_aLV_Folder)]
       Local $iCounter = 0
       For $i = 0 to UBound($g_aLV_Folder) -1
    	  If BitAND(GUICtrlRead($g_aLV_Folder[$i][1], 1), $GUI_CHECKED) Then
    	  $aFolderList[$iCounter] = $g_aLV_Folder[$i][0]
    	  $iCounter += 1
    	  EndIf
       Next
       ReDim  $aFolderList[$iCounter]
       CopyProject($aFolderList, $g_sPath_Source, $g_sPath_Dest)
          GUICtrlSetState($g_idButton_Start, $GUI_ENABLE)
       GUICtrlSetData($g_idButton_Start, "Kopieren")
    EndFunc
    
    
    Func Event_Button_Source(); Auswählen des Quellordners über den Benützer
       Local $sNewPath = FileSelectFolder("Bitte den Projekt-Ordner wählen", $g_sPath_Source)
       If @error Then Return
       $g_sPath_Source = $sNewPath
       GUICtrlSetData($g_idInput_Path_Source, $sNewPath)
       LoadFolderInListView($g_sPath_Source)
       GUICtrlSetState($g_idButton_Save, $GUI_ENABLE)
    EndFunc
    
    
    Func Event_Close()
       Exit
    EndFunc
    
    
    Func LoadFolderInListView($sPath); Listet die Projekte aus dem Quellordner auf, wenn sie dem Schema entsprechenden.
       For $i = 0 to UBound($g_aLV_Folder) -1
    	  $g_aLV_Folder[$i][0] = ""
    	  GUICtrlDelete($g_aLV_Folder[$i][1])
       Next
       Local $aFolder = _FileListToArray($sPath, "*", $FLTA_FOLDERS, False)
       If Not IsArray($aFolder) Then
    	  ReDim $g_aLV_Folder[0][2]
    	  Return
       EndIf
       Local $iCounter = 0
       ReDim $g_aLV_Folder[ $aFolder[0] ][2]
       For $i = 1 to $aFolder[0]
    	  If StringRegExp($aFolder[$i], "\d\d\d\d....") Then
    		 $g_aLV_Folder[$iCounter][0] = $aFolder[$i]
    		 $g_aLV_Folder[$iCounter][1] = GUICtrlCreateListViewItem($aFolder[$i], $g_idLV_SelectFolder)
    		 $iCounter += 1
    	  EndIf
       Next
       ReDim $g_aLV_Folder[ $iCounter ][2]
    EndFunc
    Alles anzeigen

    Ausgabe erstmal nur in der Konsole, wenn da alles Ok ist kannst du die Zeilen 58 bis 61 entkommentieren dann kopiert das Script.

    mfg
    Zeitriss

  • Prozessliste mit Namen erstellen

    • Zeitriss
    • 26. Juli 2017 um 22:46

    @AspirinJunkie

    Hi,
    hast natürlich recht wenn man eine völlig unbekannte Menge hat macht es natürlich wenig Sinn das Array in statischen Schritten zu vergrößern, da ist ein Faktor natürlich konsequenter.
    Hatte ich mir wohl falsch angewöhnt.

    @Musashi
    Ich bezog mich mehr auf das Script von svarts und den Vorschlag von olfibits, für eure Diskusion ist das natürlich völlig irrelevant ^^

    @autoiter
    Tut mir leid:

    Zitat von https://de.wiktionary.org/wiki/Mensch

    Mensch
    ...
    Bedeutungen:

    [1] ein Lebewesen; Spezies, der Klasse der Säugetiere angehörend, die sich durch folgende besondere Eigenschaften auszeichnet: aufrechter Gang, Sprache, Erfindertum, Vorausdenken und Nachahmung

    da haben wir beide wohl nur 4/5 :P

    mfg Zeitriss

  • Prozessliste mit Namen erstellen

    • Zeitriss
    • 26. Juli 2017 um 21:18

    Hi,

    Weil es bisher noch keine Erwähnung fand:

    Wenn eine maximale Menge bekannt (und realistisch) ist gibt es eigentlich wenig Grund überhaupt ein Redim oder _arrayAdd in der Schleife zu haben.
    Man erstellt das (nicht Assoziative) Array einfach mit der größten sinnvollen Anzahl an Elementen und schneidet es sich am Ende zurecht.

    AutoIt: svarts Script (Beitrag 3)
    $aWin = processlist()
    $c = 0
    Dim $aList[ $aWin[0][0] ][3]
    AutoIt: svarts Script (Beitrag 3)
    Redim $aList[$c][3]


    Sollte die maximale Menge unbekannt oder unrealistisch groß sein kann man das Array einfach in 100, 1000, 10000... Schritten vergrößern und wenn man fertig ist ggf. wieder zurechschneiden. (siehe Beitrag 17)

    AutoIt
    Global $iIndex = 0
    Global $aArray[1000]
    For $i = 0 to 100000
       $aArray[$iIndex] = "x"
       $iIndex += 1
       If Not Mod($iIndex, 1000) Then
    	  ReDim $aArray[$iIndex + 1000]
       EndIf
    Next
    ReDim $aArray[$iIndex]


    mfg
    Zeitriss

  • Fehler beim Programm-Öffnen abfangen

    • Zeitriss
    • 19. Juli 2017 um 17:10

    Hi,

    Wie alpines schon sagte du must nur einmal mit ObjEvent eine gültige Funktion registrieren.

    AutoIt
    ObjEvent("AutoIt.Error", "__Excel_COMErrFunc")


    (Edit: Return-Wert natürlich nicht is leere laufen lassen)
    Alle Request Errors danach können (Solange das Objekt welches von ObjEvent zurückgegeben wird nicht freigegeben wird), soweit ich weiß wie gewohnt mit @error (If @error Then ...) ausgewertet werden.

    Wenn du den Rückgabewert von ObjEvent auf 0/Null setzt, kannst du das Objekt wieder freigeben.

    Edit2:

    AutoIt: Beispiel
    Global $oExcel = _Excel_Open()
    
    
    Global $__g_oTemplateCOMErrorHandler = ObjEvent("AutoIt.Error", "__Excel_COMErrFunc")
    ; Ab hier werden Fehler dein Script nicht mit einem Request-Error beenden
    
    
    $oExcel.adgojk5dtrj()
    If @error Then MsgBox(16,"Fehler", "Fehler aber Script läuft weiter!")
    
    
    ; Ab hier würde sich das Script wieder bei einem Request-Error beenden
    $__g_oTemplateCOMErrorHandler = Null
    
    
    $oExcel.adgojk5dtrj()
    If @error Then MsgBox(16,"Fehler", "Diese Msgbox wird nie angezeigt werden.")
    
    
    _Excel_Close($oExcel)
    Alles anzeigen


    mfg
    Zeitriss

  • Nach dem Aufruf einer Schleife wieder zurück in die GUI

    • Zeitriss
    • 4. Juli 2017 um 11:53

    Hi,

    Du könntest Exit durch ContinueLoop ersetzen.

    Der übersichtlichkeits halber würde ich den Code allerdings in Funktionen verpacken und dann mit Return zur Hauptschleife zurückkehren (s. beispiel oben).
    Select-Case würde ich durch Switch-Case ersetzten (s. Hilfe)
    Die "Else-Abzweigung" beim "If" ist optional, wenn sie keinen Inhalt hat sollte sie weggelassen werden.

    Beispiel GUIMsg-Schleife mit Switch-Case und Funktionsaufrufen
    AutoIt
    While 1
       $msg = GUIGetMsg()
       Switch $msg
       Case $Button1
    	  _Button1()
       Case $Button2
    	  _Button2()
       Case $Button3
    	  _Button3()
       Case $GUI_EVENT_CLOSE
    	  exit
       EndSwitch
    WEnd
    
    
    ; Funktionen (s. mein Beispiel oben)
    Alles anzeigen

    mfg
    Zeitriss

  • Nach dem Aufruf einer Schleife wieder zurück in die GUI

    • Zeitriss
    • 4. Juli 2017 um 10:53

    Hi,

    Vielleicht konnen dir die Befehle Return oder Exitloop etwas helfen (s. Hilfe).
    Ansonsten wäre es hilfreich dein Script zu kennen.
    [spoiler=Beispiel Return, Exitloop]

    AutoIt: Beispiel
    #include <GUIConstantsEx.au3>
    #include<MsgBoxConstants.au3>
    Opt("GUIOnEventMode", 1)
    $hGUI_Main = GUICreate("Main GUI", 320, 30)
    $idButton_1 = GUICtrlCreateButton("Button1", 5, 4, 100, 22)
    $idButton_2 = GUICtrlCreateButton("Button2", 110, 4, 100, 22)
    $idButton_3 = GUICtrlCreateButton("Button3", 215, 4, 100, 22)
    GUICtrlSetOnEvent($idButton_1, "_Button1")
    GUICtrlSetOnEvent($idButton_2, "_Button2")
    GUICtrlSetOnEvent($idButton_3, "_Button3")
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Button3")
    GUISetState(1, $hGUI_Main)
    While sleep(1000); Tu nichts
    WEnd
    
    
    Func _Button1(); Mit Exitloop
       While 1
    	  MsgBox(BitOR($MB_OK, $MB_TOPMOST), "Würfeln","Zufällige Zahl zwischen 1-6: " & Random(1,6,1))
    	  If MsgBox(BitOR($MB_YESNO, $MB_TOPMOST), ,"","Fortfahren?") = $idNO Then exitloop
       Wend
    EndFunc
    
    
    Func _Button2(); Mit Return
       If MsgBox(BitOR($MB_YESNO, $MB_TOPMOST), "Meldung","Meldung 1 von 5" & @crlf & "Fortfahren?") = $idNO Then Return
       If MsgBox(BitOR($MB_YESNO, $MB_TOPMOST), "Meldung","Meldung 2 von 5" & @crlf & "Fortfahren?") = $idNO Then Return
       If MsgBox(BitOR($MB_YESNO, $MB_TOPMOST), "Meldung","Meldung 3 von 5" & @crlf & "Fortfahren?") = $idNO Then Return
       If MsgBox(BitOR($MB_YESNO, $MB_TOPMOST), "Meldung","Meldung 4 von 5" & @crlf & "Fortfahren?") = $idNO Then Return
       If MsgBox(BitOR($MB_YESNO, $MB_TOPMOST), "Meldung","Meldung 5 von 5" & @crlf & "Fortfahren?") = $idNO Then Return
    EndFunc
    
    
    Func _Button3()
       exit
    EndFunc
    Alles anzeigen

    [/spoiler]
    Return bricht Funktionen ab.
    Exitloop bricht Schleifen ab.

    mfg
    Zeitriss

  • Kleines Desktop-Spiel (ChipHunter)

    • Zeitriss
    • 20. Juni 2017 um 19:20

    Hi,

    Wenn das Spiel keinen kein "Audio-Grät" findet, bricht es mit der Fehlermeldung "Das Audio-Gerät konnte nicht initialisiert werden!" ab.
    Da ich nun an einem PC kein (funktionstüchiges) Wiedergabegerät habe ist es dort nicht spielbar.
    Hier würde vll eine Infobox/Warnung ohne Abbruch reichen, da der Ton ja nicht essenziell ist.

    Zudem scheinen Explosionen die Klicks abfangen.


    Ansonsten gefällt mir das Spiel recht gut. :)

    mfg
    Zeitriss

  • Variablen Deklaration Unterschiede

    • Zeitriss
    • 20. Juni 2017 um 11:40

    Hi,

    es gibt durchaus einen gewaltigen unterschied zwischen

    Local $var = ...
    und
    $var = ...

    Bei ersterem erzwingst du dass eine neue Variable erstellt wird, bei letzterem kann AutoIt auch eine gleichbennante globale Varriable überschreiben. Beide Varrianten dürfen also auf garkeinen fall beliebig vertauscht werden.

    €: Bei Korekter Kennzeichnung globaler Varriablen, sollte es allerings normalerweise zu keinem Fehler führen.

    mfg
    Zeitriss

  • Powershell If Bedingung Hilfe

    • Zeitriss
    • 4. Mai 2017 um 13:05

    Hi,

    Die Varriable $Input darfst du nicht verwenden, da diese von Powershell für andere zweck vorgesehen ist.
    Du musst sie umbennenen.
    z.B. in $objInput oder $objTextbox.

    mfg
    Zeitriss

  • Alt Gr-Tastenkombination mit HotkeySet abfangen

    • Zeitriss
    • 28. April 2017 um 15:25

    hi,

    Zitat von https://www.autoitscript.com/autoit3/docs/functions/Send.htm

    This tells AutoIt to send a CONTROL keystroke; therefore, Send("^!a") would send "CTRL+ALT+a".

    Steht doch in der von alpines verlinkten Hilfeseite.

    mfg
    Zeitriss

  • String in Buchstaben aufteilen und jeden Buchstaben einzeln ersetzen?

    • Zeitriss
    • 27. März 2017 um 21:36
    Zitat von alpines

    Du ersetzt in dem Fall aber nur ein Emoji und nicht mehrere gleichzeitig. Das richtige Pattern zu finden kann für Neulinge extrem schwierig sein.

    Ich kann dir nicht ganz folgen, folgendes ersetzt alle (ich gehe davon aus dass ß,ü,ö,ä usw. nicht erforderlich sind) Buchstaben durch sein jeweiliges Emoji-Equivalent (und zwar in unbegrenzter Anzahl):

    Zitat von Zeitriss

    $sString = StringRegExpReplace(StringLower($sString), "([a-z])", ":regional_indicator_$1: ")

    Oder habe ich die Problemstellung falsch verstanden?

    Es ist zwar richtig dass, das finden des richtigen Pattern für Neulinge schwer ist, allerdings trifft das auf so ziemlich alles zu was man neu lernen muss :P .

    mfg
    Zeitriss

  • String in Buchstaben aufteilen und jeden Buchstaben einzeln ersetzen?

    • Zeitriss
    • 27. März 2017 um 21:18
    Zitat von AspirinJunkie

    Man muss also ausschließen, dass Zeichen innerhalb von ":" (balanciert auswerten) ersetzt werden.
    Ein regulärer Ausdruck hierfür wäre eine ziemlich finstere Geschichte.

    Wenn man mit StringRegExpReplace alle Buchstaben in einem Durchgang ersetzt, kommt es nicht zu diesem Problem.
    Zumal diese Anwendung von RegExp vergleichsweise simpel ist.

    mfg
    Zeitriss

  • String in Buchstaben aufteilen und jeden Buchstaben einzeln ersetzen?

    • Zeitriss
    • 27. März 2017 um 20:38

    Hi,

    zum ersetzen der Buchstaben würde sich StringRegExpReplace anbieten, erfordert jedoch etwas Einarbeitungszeit.

    Ersetzen der Buchstaben:

    AutoIt
    $sString = StringRegExpReplace(StringLower($sString), "([a-z])", ":regional_indicator_$1: ")


    Die Hilfe zu StringregExp und StringRegExpReplace + ggf. ein Tutorial (im Forum sollte eines zu finden sein) sollte das nötige Wissen schaffen.

    Sollten noch andere Zeichen ersetzt werden lohnt sich der Einsatz von Arrays, hier ein Beispiel:

    Spoiler anzeigen
    AutoIt
    Global $sNewString = MyReplaceFunc("(test) 0+")
    ConsoleWrite($sNewString & @crlf)
    
    
    Func MyReplaceFunc($sString)
       Local $aReplace[][2] = _
       [ _
    	  ["0", ":zero:"], _
    	  ["1", ":one:"], _
    	  ["2", ":two:"], _
    	  ["3", ":three:"], _
    	  ["4", ":four:"], _
    	  ["5", ":five:"], _
    	  ["6", ":six:"], _
    	  ["7", ":seven:"], _
    	  ["8", ":eight:"], _
    	  ["9", ":nine:"], _
    	  [",", ":black_small_square:"], _
    	  [".", ":black_circle:"], _
    	  ["+", ":heavy_plus_sign:"], _
    	  ["-", ":heavy_minus_sign:"], _
    	  ["✕", ":heavy_multiplication_x:"], _
    	  ["÷", ":heavy_division_sign:"], _
    	  ["1", ":exclamation:"], _
    	  ["1", ":question:"], _
    	  ["'", ":arrow_down_small:"], _
    	  ["*", ":asterisk:"], _
    	  ["#", ":hash:"] _
       ]
    
    
       ; ersetzt alle Buchstaben (siehe StringRegExp bzw. StringRegExpReplace)
       $sString = StringRegExpReplace(StringLower($sString), "([a-z])", ":regional_indicator_$1: ")
    
    
       ; ersetzt die (oben definierten) anderen Zeichen.
       For $i = 0 to UBound($aReplace) -1
    	  $sString = StringReplace($sString, $aReplace[$i][0], $aReplace[$i][1] & " ")
       Next
       Return $sString
    EndFunc
    Alles anzeigen


    mfg
    Zeitriss

  • TCPSend($socket, $data) data von inputbox

    • Zeitriss
    • 3. März 2017 um 19:10

    Hi,

    versuch mal im Client Zeile 36 :
    "=" durch "&=" zu erstzten (ansonsten werden Daten, welche nicht $trenner enthalten, ignoriert) und "32768" durch "2048"

    und im Server die verschlüsselten Informertionen in 2048 Zeichen Paketen zu senden.

    Kann grade nicht testen ob es irgendetwas hilft.

    mfg
    Zeitriss

  • Drag & Drop in Inputfeld geht nicht mehr?

    • Zeitriss
    • 20. Februar 2017 um 20:02

    Hi,

    Hast du vielleicht $WS_EX_ACCEPTFILES vergessen?

    mfg
    Zeitriss

  • Patcher patcht nur teilweise

    • Zeitriss
    • 17. Februar 2017 um 17:38

    Nein, du musst es im Prinzip wie in der Hauptschleife machen, also den Return wert von GUIGetMsg() mit $GUI_EVENT_CLOSE vergleichen.

    Zudem macht das Else keinen Sinn wenn du eh das Programm beendest.

    Dies ist auch etwas umständlich:

    AutoIt
    GUICtrlRead($progr_dateidown) <> $FileProgress

    Das solltest du vielleicht nochmal überdenken.
    Wie sinnvoll ist es deine Daten von deiner eigenen GUI auszulesen?

    Edit: Oh viel zu langsam... ;( (6min)

    mfg
    Zeitriss

  • Patcher patcht nur teilweise

    • Zeitriss
    • 17. Februar 2017 um 17:13

    Hi,

    Die Do-Until ist schon in der Funktion _Patch() von Zeile 189 bis 196.
    Dort bleibt das Programm wärend des Downloads hängen, somit sollte eine einfache Abbruchbedingung das Problem lösen.

    Denk aber daran dass du _Crypt_Shutdown() aufrufst.
    Und beende den Download und lösche die Datei, vll macht AutoIt letzteres auch Automatisch.
    usw.

    Edit:

    Zitat von Paul01

    ^ hab ich aber auch 3 mal geschrieben?

    Die letzte Zeile in deinem Beitrag 11 ließ da etwas Spielraum für Interpretationen.

    mfg
    Zeitriss

  • Patcher patcht nur teilweise

    • Zeitriss
    • 17. Februar 2017 um 16:57

    Hi,

    solange du was Downloadest befindet er sich nicht in der Hauptschleife (151-167), daher kann er natürlich nicht auf das Close Event reagieren.

    Du könntest deine _patch() Funktion durch eine mit AdlibRegister aufgerufene Funktion erstetzen, welche dann deinen Patch in Schritten abarbeitet (welche Datei grade gedownloadet wird usw. müssten dann in Globale oder Static Varriable).

    Du könntest so eine Funktion natürlich auch über die Hauptschleife wiederholt aufrufen.

    Oder du fragst in der Do-Until Schleife nach $GUI_EVENT_CLOSE ab und beendest dein Programm dann darüber.

    Edit:

    Zitat von alpines

    Du meinst selber das beim Klick auf Patch nichts passiert

    Ich glaube er meinte das er wärend des Patch vorgangs das Programm nicht schließen kann, dass der Patch Button nicht Funktioniert kann ich eigentlich nicht rauslesen.

    mfg
    Zeitriss

  • Notepad immer über einem AutoIt-Control und Control Größe

    • Zeitriss
    • 13. Februar 2017 um 20:36

    Hi,

    Zitat von Bitnugger

    Wieso bei der einen Funktion SetPos und bei der anderen Move, wenn sie doch beide dieselbe Aufgabe haben?

    What’s the point of the MoveWindow function when we already have SetWindowPos?
    Nicht direkt auf AutoIt bezogen, vll intressiert es dich trotzdem.

    mfg
    Zeitriss

  • Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

    • Zeitriss
    • 7. Februar 2017 um 19:26

    Hi,

    AutoIt
    $aFileTime = FileGetTime($aFiles[$i], $iTimestampType)
    $sFileTime = $aFileTime[0] & "/" & $aFileTime[1] & "/" & $aFileTime[2] & " " & $aFileTime[3] & ":" & $aFileTime[4] & ":" & $aFileTime[5]

    Hier sollte besser nochmal überprüft werden ob $aFileTime überhaupt ein Array ist.
    Wenn jemand noch am PC Arbeitet, wärend das Script läuft kann es passieren, dass Dateien gelöscht werden [Edit: nur zu verständlichkeit: nicht von deiner Funktion sondern vom Nützer oder anderen Anwendungen] (z.B. wird beim schließen eines Word Dokuments eine versteckte Datei gelöscht).
    Da diese zwischenzeitlich gelöschten Dateien immernoch in dem von _FileListToArrayRec() erstellten Array enthalten sind wird trotzdem versucht sie über FileGetTime abzufragen, was dann in Zeile 106/122/141 zu einem Fehler führt.

    @Bitnugger:

    AutoIt
    $aReturnedFiles[$i][0] = DllCall($hDll, 'none', 'PathStripPathW', 'wstr', $aReturnedFiles[$i][0])[1]


    Hier würdest du mit RegExpReplace vermutlich deutlich schneller sein, statt ständig DllCall zu benützen.

    Beim gesamten Konzept frage ich mich ob eine Funktion, welche Dateien auf einem frei bestimmbaren Zeitraum überprüft nicht deutlich sinnvoller wäre.
    Also anstatt den Zeitraum über $iAge und $iAgeAndOlder festzulegen einfach $sStartDate und $sEndDate zu verwenden.
    Habe schnell mal hierzu auch mal was zusammen gebastelt, ist allerdings "quick and dirty".

    Spoiler anzeigen
    AutoIt
    Opt("MustDeclareVars", 1)
    #include<Array.au3>
    #include<Date.au3>
    #include<FileConstants.au3>
    
    
    Global $sFolder = @ScriptDir
    Global $sStartDate = "2017/01/01"; Datumformat YYYY/MM/DD[ HH:MM:SS]
    Global $sEndDate = _NowCalc(); Datumformat YYYY/MM/DD[ HH:MM:SS]
    Global $bRecursive = False
    Global $iTimeStep = $FT_MODIFIED ; s. FileGetTime
    Global $iSort = 1 ; s. _ArraySort (-1 für keine Sortierung)
    
    
    Global $aFiles = _FileListBetweenDates($sFolder, $sStartDate, $sEndDate, $bRecursive, $iTimeStep, $iSort)
    Switch @error
    Case 1
       MsgBox(16, "Fehler", "Die ausgewählte Datei ist kein Ordner oder der Pfad ist fehlerhaft.")
       Exit
    Case 2
       MsgBox(16, "Fehler", "Format des Datums fehlerhaft.")
       Exit
    Case 3
       MsgBox(16, "Fehler", "Ungültiger Timestamp")
       Exit
    EndSwitch
    _ArrayDisplay($aFiles, @extended & " Dateien gefunden")
    
    
    Func _FileListBetweenDates($sFolder, $sStartDate, $sEndDate, $bRec = True, $iTimeStep = 1, $iSort = 0)
       If Not StringInStr(FileGetAttrib($sFolder), "D") Then Return SetError(1)
       If Not StringRegExp($sStartDate, "^\d{4}/\d{2}/\d{2}( \d{2}:\d{2}:\d{2})?$") Then Return SetError(2)
       If Not StringRegExp($sEndDate, "^\d{4}/\d{2}/\d{2}( \d{2}:\d{2}:\d{2})?$") Then Return SetError(2)
       If Not (0 <= $iTimeStep and $iTimeStep <= 2) Then Return SetError(3)
       $sFolder = StringRegExpReplace($sFolder, "\\$", "")
       Local $iDiffRange = _DateDiff("s", $sStartDate, $sEndDate)
       Local $iArraySize = 100000
       Local $aFiles[$iArraySize][2], $iCount, $aSearchFile[256], $sFile, $iDepth, $sTime, $sTime2, $iDiffSec
    
    
       $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*")
       While $iDepth >= 0; In dieser Schleife werden alle Dateien/Ordner abgehandelt
    	  $sFile = FileFindNextFile($aSearchFile[$iDepth])
    	  If @extended and $bRec Then; Wenn es sich um ein Ordner handelt wird in diesem weiter gesucht
    		 $iDepth += 1
    		 $sFolder &= "\" & $sFile
    		 $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*")
    	  ElseIf @error Then; Wenn keine Dateien mehr im Ordner vorhanden sind wird das "Handle" Freigegeben
    		 FileClose($aSearchFile[$iDepth])
    		 $iDepth -= 1
    		 $sFolder = StringRegExpReplace($sFolder, "\\[^\\]*$", "")
    	  Else; Hier werden die Dateien dem $aFiles hinzugefügt, wenn sie mit den vorgaben übereinstimmen
    		 $sTime = FileGetTime($sFolder & "\" & $sFile, $iTimeStep, 1)
    		 If @error Then ContinueLoop
    		 $sTime2 = StringRegExpReplace($sTime, "(.{4})(.{2})(.{2})(.{2})(.{2})(.{2})", "$1/$2/$3 $4:$5:$6")
    		 $iDiffSec = _DateDiff("s", $sStartDate, $sTime2)
    		 If $iDiffSec >= 0 and $iDiffSec <= $iDiffRange Then
    			If $iCount >= $iArraySize Then
    			   $iArraySize += 100000
    			   ReDim $aFiles[$iArraySize][2]
    			EndIf
    			$aFiles[$iCount][0] = $sFolder & "\" & $sFile
    			$aFiles[$iCount][1] = $sTime2
    			$iCount += 1
    		 EndIf
    	  EndIf
       Wend
    
    
       ReDim $aFiles[$iCount][2]
       If $iSort = 0 or $iSort = 1 Then _ArraySort($aFiles, $iSort, Default, Default, 1)
       Return SetExtended($iCount, $aFiles)
    EndFunc
    Alles anzeigen

    mfg
    Zeitriss

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™