String in Buchstaben aufteilen und jeden Buchstaben einzeln ersetzen?

Invisible90

Einen schönen guten Abend.

Ich wollte soeben ein Script erstellen, welches jeden Buchstaben in einen String ersetzt.
Es soll für Discord eingesetzt werden, dort gibt es ja diese regional_indicator Emojis.
Allerdings kann ich nicht einfach den StringReplace anwenden und irgendwie fehlt mir der logische Ansatz dieses
Problem zu lösen. Es muss ja den String einlesen und zum Beispiel ein A mit einem :regional_indicator_a: ersetzen, allerdings ist in dem replacement ja wieder ein A vorhanden.
Es wäre schön, wenn mir jemand einen kleinen Schubs in die richtige Richtung geben könnte. Habe mich nie so wirklich mit dem Verändern von Strings befasst

olfibits

Entweder dürfte dir trotzdem StringReplace() helfen:

AutoIt

StringReplace ( "string", "searchstring/start", "replacestring" [, occurrence = 0 [, casesense = 0]] )

string: der string in dem gesucht werden soll
searchstring/start: dein Suchstring, bei dir z.B. "A"
replacestring: Ersatzstring, bei dir z.B. ":regional_indicator_a:"
occurrence: lass das mal auf 0
casesense: Groß/Kleinschreibung Relevanz, bei 0 ist die Schreibweise egal, bei 1 wird auf Groß/Kleinschreibung geachtet.

Oder: StringSplit()

AutoIt

$Array = StringSplit ( "string", "delimiters" [, flag = 0] )

$Array: in dem Array sind alle Teilstrings gespeichert
string: dein String in dem gesucht werden soll
delimiters: wo getrennt werden soll

Oder:
StringTrimLeft ( "string", count )
string: dein String in dem immer noch gesucht werden soll
und count die nummer von links wo gespaltet werden soll

StringTrimRight ( "string", count )
string: dein String in dem gesucht werden soll
und count die nummer von rechts wo gespaltet werden soll

**alpines**

Zitat von Invisible90

Es muss ja den String einlesen und zum Beispiel ein A mit einem :regional_indicator_a: ersetzen, allerdings ist in dem replacement ja wieder ein A vorhanden.

Du kannst abfragen ob das A klein ist oder innerhalb von zwei Doppelpunkten steht. Dann ignorierst du es.

Mit StringReplace kannst du die Zeichen ersetzen. Da verwendest du am besten eine For-Schleife mit einem Array was die ganzen Such-und-Ersetz-Strings beinhaltet.

Zeitriss

Hi,

zum ersetzen der Buchstaben würde sich StringRegExpReplace anbieten, erfordert jedoch etwas Einarbeitungszeit.

Ersetzen der Buchstaben:

AutoIt

$sString = StringRegExpReplace(StringLower($sString), "([a-z])", ":regional_indicator_$1: ")

Die Hilfe zu StringregExp und StringRegExpReplace + ggf. ein Tutorial (im Forum sollte eines zu finden sein) sollte das nötige Wissen schaffen.

Sollten noch andere Zeichen ersetzt werden lohnt sich der Einsatz von Arrays, hier ein Beispiel:

Spoiler anzeigen

AutoIt

Global $sNewString = MyReplaceFunc("(test) 0+")
ConsoleWrite($sNewString & @crlf)


Func MyReplaceFunc($sString)
   Local $aReplace[][2] = _
   [ _
	  ["0", ":zero:"], _
	  ["1", ":one:"], _
	  ["2", ":two:"], _
	  ["3", ":three:"], _
	  ["4", ":four:"], _
	  ["5", ":five:"], _
	  ["6", ":six:"], _
	  ["7", ":seven:"], _
	  ["8", ":eight:"], _
	  ["9", ":nine:"], _
	  [",", ":black_small_square:"], _
	  [".", ":black_circle:"], _
	  ["+", ":heavy_plus_sign:"], _
	  ["-", ":heavy_minus_sign:"], _
	  ["✕", ":heavy_multiplication_x:"], _
	  ["÷", ":heavy_division_sign:"], _
	  ["1", ":exclamation:"], _
	  ["1", ":question:"], _
	  ["'", ":arrow_down_small:"], _
	  ["*", ":asterisk:"], _
	  ["#", ":hash:"] _
   ]


   ; ersetzt alle Buchstaben (siehe StringRegExp bzw. StringRegExpReplace)
   $sString = StringRegExpReplace(StringLower($sString), "([a-z])", ":regional_indicator_$1: ")


   ; ersetzt die (oben definierten) anderen Zeichen.
   For $i = 0 to UBound($aReplace) -1
	  $sString = StringReplace($sString, $aReplace[$i][0], $aReplace[$i][1] & " ")
   Next
   Return $sString
EndFunc

Alles anzeigen

mfg
Zeitriss

**AspirinJunkie**

Ich glaube sein Problem ist (wie alpines bereits andeutete) etwas komplexer als es erst erscheint.
Wenn man die Zeichen in einem Loop hintereinander ersetzt werden auch die Zeichen innerhalb der Ersetzungsstrings ersetzt.
Mal als Beispiel:

Ausgangsstring: Das ist ein Test
Ersetzung von "a" durch ":regional_indicator_a:" : D:regional_indicator_a:s ist ein Test
Ersetzung von "e" durch ":regional_indicator_e:" : D:r:regional_indicator_e:gional_indicator_a:s ist :regional_indicator_e:in T:regional_indicator_e:st

Man muss also ausschließen, dass Zeichen innerhalb von ":" (balanciert auswerten) ersetzt werden.
Ein regulärer Ausdruck hierfür wäre eine ziemlich finstere Geschichte.

Eine Alternative wäre die Strings durch Zwischenstrings zu ersetzen welche keine Zeichen enthalten welche ersetzt werden könnten und dann abschließend diese in ihre Endform zu ersetzen.

Zeitriss

Zitat von AspirinJunkie

Man muss also ausschließen, dass Zeichen innerhalb von ":" (balanciert auswerten) ersetzt werden.
Ein regulärer Ausdruck hierfür wäre eine ziemlich finstere Geschichte.

Wenn man mit StringRegExpReplace alle Buchstaben in einem Durchgang ersetzt, kommt es nicht zu diesem Problem.
Zumal diese Anwendung von RegExp vergleichsweise simpel ist.

mfg
Zeitriss

**alpines**

Zitat von Zeitriss

Wenn man mit StringRegExpReplace alle Buchstaben in einem Durchgang ersetzt, kommt es nicht zu diesem Problem.

Du ersetzt in dem Fall aber nur ein Emoji und nicht mehrere gleichzeitig. Das richtige Pattern zu finden kann für Neulinge extrem schwierig sein.

NO1 :-)

Ich glaube du brauchst sowas:

AutoIt

Dim $Text = "Das ist ein Test", $Ausgabe = "", $actualChar = ""
$SingleChar = StringSplit($Text, "") ;Text in einzelne Buchstaben aufteilen
For $actualChar = 1 To $SingleChar[0] ;Für die Anzahl an Buchstaben das Vorkommen von a oder e testen
	If $SingleChar[$actualChar] == "a" Then ;Wenn a vorhanden, dann
		$actualCharText = ":regional_indicator_a"
		$Ausgabe &= $actualCharText ;an die Ausgabe :regional_indicator_a "hinhängen"
	ElseIf $SingleChar[$actualChar] == "e" Then ;Wenn e vorhanden, dann
		$actualCharText = ":regional_indicator_e"
		$Ausgabe &= $actualCharText ;an die Ausgabe :regional_indicator_e "hinhängen"
	Else ;Wenn ein anderer Buchstabe vorhanden, dann
		$actualCharText = $SingleChar[$actualChar]
		$Ausgabe &= $actualCharText ;nichts an diesem Buchstaben ändern und diesen an die Ausgabe "hinhängen"
	EndIf
Next
MsgBox(0, "", $Ausgabe) ;Ausgabe mit MsgBox ausgeben
Exit ;Skript beenden

Alles anzeigen

Zeitriss

Zitat von alpines

Du ersetzt in dem Fall aber nur ein Emoji und nicht mehrere gleichzeitig. Das richtige Pattern zu finden kann für Neulinge extrem schwierig sein.

Ich kann dir nicht ganz folgen, folgendes ersetzt alle (ich gehe davon aus dass ß,ü,ö,ä usw. nicht erforderlich sind) Buchstaben durch sein jeweiliges Emoji-Equivalent (und zwar in unbegrenzter Anzahl):

Zitat von Zeitriss

$sString = StringRegExpReplace(StringLower($sString), "([a-z])", ":regional_indicator_$1: ")

Oder habe ich die Problemstellung falsch verstanden?

Es ist zwar richtig dass, das finden des richtigen Pattern für Neulinge schwer ist, allerdings trifft das auf so ziemlich alles zu was man neu lernen muss .

mfg
Zeitriss

**AspirinJunkie**

Wenn die Form tatsächlich immer gleich bleibt dann würde das gehen.
Wenn es aber so ist wie in deinem zweiten Beispiel dann geht es so nicht mehr (auch wenn die Zeichen dort so gewählt wurden dass sie nicht im Ersatzstring vorkommen)

@NO1
Der Ansatz ist schonmal gut.
Somit wird eine Mehrfachbehandlung der Buchstaben vermieden.

**BugFix**

Ich würde _StringRegexReplace_Callback (von @Taz77) verwenden - ist auch die schnellste Variante:

Edit: Gloß-/Kleinschreibung hatte ich nicht beachtet - nun korrigiert.

AutoIt

Local $sText = "Das ist ein Test"


_StringRegExpReplace_Callback($sText, "([aei])", "_MyCallback('$1')")
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sText --> " & $sText & @LF)




Func _MyCallback($_s)
	If $_s == "a" Then
		Return ":regional_indicator_a:"
	ElseIf $_s == "e" Then
		Return ":regional_indicator_e:"
	ElseIf $_s == "i" Then
		Return ":regional_indicator_i:"
	Else
		Return $_s
	EndIf
EndFunc




; #FUNCTION# ====================================================================================================================
; Name ..........: _StringRegExpReplace_Callback
; Description ...: Replaces ByRef all matches in a string by manipulation of the matches in a callback function
; Parameters ....: $sString    String to manipulate
; ...............: $sPattern   RegExp pattern for the match
; ...............: $sCallback  Callback function as string, i.e. "MyCallback('$1')" -- '$1' represents the match
; .....optional..: $sBefore    String to insert before the manipulated match
; .....optional..: $sAfter     String to insert after the manipulated match
; Return values .: Success     1
; ...............: Failure     0  set error = 1
; Author ........: Taz77
; ===============================================================================================================================
Func _StringRegExpReplace_Callback(ByRef $sString, $sPattern, $sCallback, $sBefore = '', $sAfter = '')
	$sString = Execute("'" & StringRegExpReplace(StringReplace($sString, "'", Chr(26), 0, 2), $sPattern, $sBefore & "'&" & $sCallback & "&'" & $sAfter) & "'")
	If @error Then
		ConsoleWrite('_StringRegExpReplace_Callback error! Pattern: "' & $sPattern & '", Callback: "' & $sCallback & '"' & @LF)
		Return SetError(1,0,0)
	EndIf
	$sString = StringReplace($sString, Chr(26), "'", 0, 2)
	Return 1
EndFunc  ;==>_StringRegExpReplace_Callback

Alles anzeigen

NO1 :-)

Ne for Schleife ist deutlich langsamer, ja.

**alpines**

Zitat von NO1 :-)

Ne for Schleife ist deutlich langsamer, ja.

Setz es doch erstmal in Relation. Ich glaube nicht, dass du mit mehreren Megabyte an Text rumhantierst sondern wenigen Kilobytes.
Da wirst du nicht so viel Unterschied merken.

NO1 :-)

Hab ich grad erstellt, kann man für den Zweck hier glaub ich benutzen:

_String_MultiReplace UDF