1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Script eingaben Überspringen aber wie?

    • AspirinJunkie
    • 25. März 2010 um 10:45
    Zitat von Mitnick

    Error: Incorrect number of parameters in function call.


    Bedeutet: da stimmt was mit der Anzahl deiner Parameter in der WinWait-Funktion nicht.
    Kurzer Blick in den Code und auffällig wird der 2. Parameter "" - ich denke mal der ist da zu viel da der eigentlich 2. Parameter (der Window-Textabschnitt) erst an 3. Stelle erscheint.

  • Hotkey

    • AspirinJunkie
    • 24. März 2010 um 07:10

    Dein Skript beendet sich sofort nach der Ausführung von HotkeySet wieder.
    Der Hotkey ist nur gültig solange das Programm läuft - also musst du noch eine Endlosschleife oder etwas ähnliches einbauen.

  • Thundebirth ähnliches Programm mit Autoit

    • AspirinJunkie
    • 23. März 2010 um 15:17
    OffTopic

    Was hab ich mir unter einer "Donnergeburt" vorzustellen?.... ;)


    Ansonsten wie alle sagten: Sowas wie Thunderbird bekommst du nicht mal schnell in den Schulferien hin.
    Aber Mails verschicken über z.B. POP3 geht sogar recht simpel mit AutoIt - einfach mal die Suche anwerfen.
    Oder hat dein Info-Lehrer dir detaillierter geschildert was er sich genau vorstellt?

  • Stadtnamen ohne ä,ü,ö

    • AspirinJunkie
    • 22. März 2010 um 23:18

    Doch tut sie:

    [autoit]

    MsgBox(0,"", StringRegExpReplace("Förster", "ö", "oe"))

    [/autoit]
  • Problem Kein text Eintrag

    • AspirinJunkie
    • 22. März 2010 um 10:29
    Spoiler anzeigen
    [autoit]

    Do
    Sleep(10)
    Until ControlCommand("Fenstertitel", "Fenstertext", "ControlIdent", "IsVisible", "") And ControlCommand("Fenstertitel", "Fenstertext", "ControlIdent", "IsEnabled", "")

    [/autoit]
  • Problem Kein text Eintrag

    • AspirinJunkie
    • 22. März 2010 um 10:04

    Schwer zu sagen ohne weitere Informationen und ohne Vorliegen des Programmes.
    Mir fällt auf: Ich kann nicht mehrere Fenster unterscheiden anhand deines Codes - das Fenster könnte immer das selbe sein und eindeutig wird es nicht.
    Da du in einem anderen Post meintest du wölltest keinen Fenstertitel eintragen sondern die Class führt das nun dazu das du die Fenster nicht mehr voneinander unterscheiden kannst.
    Sie haben ja alle die selbe Class.
    Jetzt nimmt man zur genaueren Unterscheidung eigentlich den 2. Parameter, welcher eine beliebige Textpassage aus dem Fenster darstellt (natürlich am besten ein Textausschnitt welcher wirklich nur in diesem Fenster vorkommt).
    Aber du hast diesen ja gar nicht benutzt bzw. stattdessen den Text des Controls eingetragen.
    Da ich davon ausgehe dass in weiteren Fenstern Buttons mit dem Text >Weiter existieren ist dieser Parameter also auch nicht dienlich zur Unterscheidung der Fenster.
    Auch wenn ich jetzt absolut nichts vorliegen habe versuche ich dir mal einen kleinen Grundaufbau, auf Grundlage deines letzten Threads, vorzugeben bei dem ich hoffe das dir ein bisschen was klarer wird:

    Spoiler anzeigen
    [autoit]

    $hWinHandle = WinWait("CATIA V5R19 - Benutzerdefinierte Verknüpfungen erstellen", "irgendein Textabschnitt aus DIESEM Fenster")
    ControlClick($hWinHandle, '', "Button3")

    [/autoit] [autoit][/autoit] [autoit]

    ; Der Titel muss auch nicht unbedingt komplett ausgeschrieben werden:
    $hWinHandle = WinWait("CATIA V5R19 - Dokumentation", 'irgendein Textabschnitt aus dem Fenster "Dokumentation auswählen"')
    ControlClick($hWinHandle, '', "Button3")

    [/autoit] [autoit][/autoit] [autoit]

    $hWinHandle = WinWait("CATIA V5R19 - Kopieren der Dateien starten", 'Wie immer: Textabschnitt aus genau dem Fenster "Kopieren starten"')
    ControlClick($hWinHandle, '', "Button3")
    ControlSend($hWinHandle, "", "Edit1", "CATIA") ;weiß nicht ob das schon hier zu diesem Fenster gehört?

    [/autoit]


    Du siehst hier dass ich bei ControlClick nur die Variable $hWinHandle statt weiterer Window-Informationen eintrage.
    Ein Handle ist eine eindeutige Bezeichnung für ein Fenster so dass man keine weitere Informationen dazu braucht.
    WinWait gibt eine solch eindeutige Nummer für ein Fenster zurück (seit AutoIt v3.3.2.0) so dass man sicher sein kann dass sich das nachfolgende ControlClick auf exakt dieses Fenster bezieht.

  • ne frage zu dem CLASS

    • AspirinJunkie
    • 22. März 2010 um 08:57

    Du hast die eckige Klammer nicht geschlossen.
    Ansonsten steht alles in der Hilfe: >>Klickmich<<.
    Bei den Buttons kannst du das auch sparsamer durch einfaches hinschreiben der ClassNameNN gestalten.
    Aus "[CLASS:Button; INSTANCE:3]" wird dann einfach "Button3".

    Ach der ClassCode #32770 ist durchaus bekannt: >>Klickmich<<

    Edit: Wenn ich das so sehe was du machst dann verstehe ich es so dass diese 3 Fenster alle nacheinander, nachdem man jeweils auf das vorherige geklickt hat, erscheinen?
    Wenn ja dann mach vor jedes ControlClick ein WinWait.
    Da es eine kurze Zeit dauert bis das Fenster erscheint kann es sein das dein ControlClick ins leere läuft da das entsprechende Fenster noch nicht da ist - daher: WinWait.

  • Fehler beim auslesen von Einträgen in der Registry

    • AspirinJunkie
    • 22. März 2010 um 00:03

    32Bit Programme werden unter einem x64-System auf WOW6432Node umgelenkt.
    Also entweder als x64 kompilieren (ein Run in Scite ruft standardmäßig das Skript als x64 auf - deswegen sollte es bei dir klappen m-obi) oder den Key mal so schreiben:

    Code
    HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
  • Anwendungspfad herausfinden

    • AspirinJunkie
    • 21. März 2010 um 12:07

    Wenn du es von MUICache auslesen willst dann vielleicht so?:

    Spoiler anzeigen
    [autoit]

    Global $Dateiname = "spider.exe"
    Global $Pfad

    [/autoit] [autoit][/autoit] [autoit]

    $Pfad = CheckFileNameInMUICache($Dateiname)
    If @error Then
    MsgBox(0, "Fehler", "Nichts gefunden")
    Else
    MsgBox(0, "Pfad", $Pfad)
    EndIf

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; by AspirinJunkie
    Func CheckFileNameInMUICache($sFN, $sKey = "HKCU64\Software\Microsoft\Windows\ShellNoRoam\MUICache", $iCaseSense = 2)
    Local Const $iFNLen = StringLen($sFN)
    Local $iC = 1, $sVal
    While True
    $sVal = RegEnumVal($sKey, $iC)
    If @error Then ExitLoop
    If StringRight($sVal, $iFNLen) = $sFN Then Return $sVal
    $iC += 1
    WEnd
    Return SetError(1, 0, "")
    EndFunc

    [/autoit]


    Alternative dazu wäre die Brute-Force-Methode: Einfach mal alle Laufwerke nach der Datei absuchen...

  • Sonderzeichen

    • AspirinJunkie
    • 17. März 2010 um 16:12

    Wie bitte?
    Versteh noch nicht ganz was du meinst - sowas vielleicht?:

    Spoiler anzeigen
    [autoit]

    #include <Misc.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $Var = _Iif(Random(0,1,1) = 0, '-', '+')

    [/autoit] [autoit][/autoit] [autoit]

    MsgBox(0,"", $Var)

    [/autoit]


    Oder willst du das Vorzeichen für eine Zahl zufällig bestimmen?

    Spoiler anzeigen
    [autoit]

    #include <Misc.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $Zahl = 123

    [/autoit] [autoit][/autoit] [autoit]

    $Zahl = _Iif(Random(0,1,1) = 0, - $Zahl, $Zahl)

    [/autoit] [autoit][/autoit] [autoit]

    MsgBox(0,"", $Zahl)

    [/autoit]
  • Sonderzeichen

    • AspirinJunkie
    • 17. März 2010 um 15:42
    [autoit]

    #include <Misc.au3>

    [/autoit][autoit][/autoit][autoit]

    MsgBox(0,"", _Iif(Random(0,1,1) = 0, '-', '+'))

    [/autoit]


    Sowas?

    Edit: Nun bin ich zu spät ;)

  • Wo ist der Fehler in der Fyntax

    • AspirinJunkie
    • 17. März 2010 um 12:38

    Nutz mal als Editor >>Scite4AutoIt<<.
    Dort einfach mal Strg-F5 bzw. Strg-T drücken und du weißt sofort das ein "Then" fehlt.

  • Reg auslesen - 64bit geht nicht (Funktion von BugFix)

    • AspirinJunkie
    • 16. März 2010 um 22:13

    Nimm eine eigene Funktion welche die AutoIt-Regfunktionen nutzt.
    Dann sollte auch die Sache mit "HKLM64" funktionieren.

    Beispiel:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $reg_schluessel100 = "HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages"

    [/autoit] [autoit][/autoit] [autoit]

    $subkeys = _GetRegSubKeys($reg_schluessel100)
    _ArrayDisplay($subkeys)

    [/autoit] [autoit][/autoit] [autoit]

    ; by AspirinJunkie
    ; needs .Net
    Func _GetRegSubKeys($HKEY)
    Local $iCount = 1, $sSubKey
    Local $cRetQueue = ObjCreate("System.Collections.Queue")
    If @error Then Return SetError(1, 0, -1)

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $sSubKey = RegEnumKey($HKEY, $iCount)
    If @error <> 0 Then ExitLoop
    $iCount += 1
    $cRetQueue.Enqueue($sSubKey)
    WEnd
    Return $cRetQueue.ToArray
    EndFunc

    [/autoit]
  • Denkfehler: Zählen aber Zahlen einer Exclude Liste überspringen

    • AspirinJunkie
    • 16. März 2010 um 19:58
    Spoiler anzeigen
    [autoit]

    $start = 1
    $end = 20
    Global $exclude[6] = [5,3,6,7,12,17]

    [/autoit] [autoit][/autoit] [autoit]

    for $i = $start to $end
    $bIn = False
    for $e = 1 to $exclude[0]
    if ($i = $exclude[$e]) Then
    $bIn = True
    EndIf
    Next
    If Not $bIn Then MsgBox (0,0,$i)
    Next

    [/autoit]
  • Files fortlaufend benennen

    • AspirinJunkie
    • 16. März 2010 um 15:53

    Wo definierst du die Variable $ij ?
    Wenn du dafür $j meintest dann kommt es unweigerlich zum Überlauf da die Zeilennummer ja nicht größer werden kann als die Gesamtanzahl der Zeilen (_FileCountLines).
    Das wäre aber der Fall da du auf $i immer etwas addierst und das würde die Grenzen der Datei überschreiten.

    Edit: Ich muss mich korrigieren - wenn $file nicht der kamera_jpg.txt entspricht könnte es theoretisch klappen aber ich denk mal es ist wirklich nur der Fehler das die 100000 nicht abgezogen wurden.

  • i=zufall

    • AspirinJunkie
    • 16. März 2010 um 15:41

    SEuBo
    Eigentlich mag ich Kollektiv-Bashing nicht wirklich aber das Ding hat echt Niveau ;)

  • Files fortlaufend benennen

    • AspirinJunkie
    • 16. März 2010 um 15:38
    [autoit]

    $line = FileReadLine ($file, $i)

    [/autoit]


    Das wär dann ab Zeile 100000 im kleinsten Fall.
    Denke mal da musst du die 100000 wieder abziehen sonst kann ich mir das schwer vorstellen.

  • Bilder auf Netzlaufwerk aus mehreren Ordner zusammenziehen

    • AspirinJunkie
    • 16. März 2010 um 14:19
    Zitat von Storyteller

    Das Problem ist das es extrem viele Bilder sind [...], d.h das Array wird ziemlich gross, was mein Computer glaube ich nicht speichern kann, bzw Verarbeiten kann. Gibt es nicht ne möglichkeit die Bilder direkt zu kopieren?


    Ich glaube zwar weniger das das Array dermaßen groß wird aber natürlich gibt es eine spezielle Lösung für diesen Fall.
    Wenn es tatsächlich nur eine Verzeichnisebene gibt dann lässt sich das z.B. der Einfachheit halber folgendermaßen lösen:

    Spoiler anzeigen
    [autoit]

    MoveFilePics("E:\Temp\Test", "C:\Windows")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func MoveFilePics($sStartdir, $sTargDir)
    Local $iFFFFDirs, $iFFFFFiles, $sFFNFDirs, $sFFNFFiles, $iCounter = 1

    [/autoit] [autoit][/autoit] [autoit]

    If StringRight($sStartdir, 1) = '\' Then $sStartdir = StringTrimRight($sStartdir, 1)
    If Not FileExists($sStartdir) Then Return SetError(1, 0, 0)

    [/autoit] [autoit][/autoit] [autoit]

    $iFFFFDirs = FileFindFirstFile($sStartdir & '\*')
    If $iFFFFDirs = -1 Then Return SetError(2, 0, 0)

    [/autoit] [autoit][/autoit] [autoit]

    While True
    $sFFNFDirs = FileFindNextFile($iFFFFDirs)
    If @error Then ExitLoop
    If @extended Then
    $iFFFFFiles = FileFindFirstFile($sStartdir & '\' & $sFFNFDirs & '\E00000.jpg')
    If $iFFFFFiles <> -1 Then
    While True
    $sFFNFFiles = FileFindNextFile($iFFFFFiles)
    If @error Then ExitLoop

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite('FileMove("' & $sStartdir & '\' & $sFFNFDirs & '\E00000.jpg, "' & $sTargDir & '\' & StringFormat('%06d.jpg")', $iCounter) & @CRLF)
    $iCounter += 1
    WEnd
    EndIf
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>MoveFilePics

    [/autoit]

    Wenn es doch mehr Verzeichnisebenen sind wäre eine Möglichkeit das rekursiv zu lösen:

    Spoiler anzeigen
    [autoit]

    MoveFilePicsRek("E:\Temp\Test", "C:\Windows")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func MoveFilePicsRek($sStDir, $sTargDir, $sPat = 'E00000.jpg', $iCounter = 1)
    Local $FFFF, $FFNF

    [/autoit] [autoit][/autoit] [autoit]

    If StringRight($sStDir, 1) = '\' Then $sStDir = StringTrimRight($sStDir, 1)
    If Not FileExists($sStDir) Then Return SetError(2, 0, 0)

    [/autoit] [autoit][/autoit] [autoit]

    $FFFF = FileFindFirstFile($sStDir & '\*')
    If $FFFF <> -1 Then
    Do
    $FFNF = FileFindNextFile($FFFF)
    If @error Then ExitLoop
    If @extended Then
    $iCounter = MoveFilePicsRek($sStDir & '\' & $FFNF, $sTargDir, $sPat, $iCounter)
    Else
    If $FFNF = $sPat Then
    ConsoleWrite('FileMove("' & $sStDir & '\' & $sPat & '", "' & $sTargDir & '\' & StringFormat('%06d.jpg")', $iCounter) & @CRLF)
    $iCounter += 1
    EndIf
    EndIf
    Until 0
    EndIf
    Return $iCounter
    EndFunc ;==>MoveFilePicsRek

    [/autoit]

    und eine weitere es iterativ zu lösen (Wäre die bessere Lösung je mehr Verzeichnisebenen es gibt - ansonsten halt rekursiv):

    Spoiler anzeigen
    [autoit]

    MoveFilePicsIt("E:\Temp\Test", "C:\Windows")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func MoveFilePicsIt($sStDir, $sTargDir, $sPat = 'E00000.jpg')
    Local $cSQueue = ObjCreate("System.Collections.Queue")
    If @error Then Return SetError(1, 1, -1)
    Local $FFFF, $FFNF, $sDir, $iCounter = 1

    [/autoit] [autoit][/autoit] [autoit]

    If StringRight($sStDir, 1) = '\' Then $sStDir = StringTrimRight($sStDir, 1)
    If Not FileExists($sStDir) Then Return SetError(2, 0, "")

    [/autoit] [autoit][/autoit] [autoit]

    $cSQueue.Enqueue($sStDir)

    [/autoit] [autoit][/autoit] [autoit]

    While $cSQueue.Count > 0
    $sDir = $cSQueue.Dequeue
    $FFFF = FileFindFirstFile($sDir & '\*')
    If $FFFF <> -1 Then
    Do
    $FFNF = FileFindNextFile($FFFF)
    If @error Then ExitLoop
    If @extended Then
    $cSQueue.Enqueue($sDir & '\' & $FFNF)
    Else
    If $FFNF = $sPat Then
    ConsoleWrite('FileMove("' & $sDir & '\' & $sPat & '", "' & $sTargDir & '\' & StringFormat('%06d.jpg")', $iCounter) & @CRLF)
    $iCounter += 1
    EndIf
    EndIf
    Until 0
    EndIf
    WEnd
    EndFunc ;==>MoveFilePicsIt

    [/autoit]


    Ich hab dir statt einem FileMove mal nur ein Consolewrite eingebaut so dass du dir dein FileMove entsprechend selbst einbauen kannst.

  • ( Dubletten - Finder ) bei Übereinstim.... der Dateinamen

    • AspirinJunkie
    • 14. März 2010 um 14:16

    Meinst du bei der md5-Berechnung oder den Vergleich allgemein?
    Weil bei der reinen Namensvergleichmethode bin ich mit der Performance erstmal recht zufrieden und hab auf Anhieb jetzt auch nicht mehr so viele Ansätze das noch wesentlich zu steigern.
    Wär natürlich über Hinweise deinerseits dazu erfreut.

  • ( Dubletten - Finder ) bei Übereinstim.... der Dateinamen

    • AspirinJunkie
    • 14. März 2010 um 09:58

    Um nicht nur anhand der Dateinamen zu vergleichen bietet sich die Berechnung des Hashwertes mit der Crypt.au3 an.
    Das sollte aber ziemlich langwierig werden da für jede Datei der Hashwert berechnet werden muss.
    Wenn es, in kleinem Maße, doch mal jemand braucht hab ich mal 2 Funktionen geschrieben welche Dubletten anhand des Dateinamens bzw. anhand ihrer md5-Hash finden können:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>
    #include <Crypt.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $Array = FindeDublettesByName(@SystemDir)
    _ArrayDisplay($Array, "Dubletten anhand Name")

    [/autoit] [autoit][/autoit] [autoit]

    $Array = FindeDublettesByHash(@SystemDir)
    _ArrayDisplay($Array, "Dubletten nach Hash-Wert")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ;===============================================================================
    ;
    ; Name...........: FindeDublettesByName
    ; Description ...: Findet Dateien deren Name mehrmals vorkommt
    ; Syntax.........: FindeDublettesByName($sStDir)
    ; Parameters ....: $sStDir - Startverzeichnis
    ; Return values .: Erfolg - 2D-Array mit Dateiname und Verzeichnissen getrennt durch |
    ; Fehler - Gibt -1 zurück und setzt @error:
    ; |1 - Fehler beim erstellen der Collections
    ; |2 - Startverzeichnis existiert nicht
    ; Author ........: AspirinJunkie
    ; Modified.......:
    ; Remarks .......: Benötigt .Net für Collections
    ; Related .......:
    ; Link ..........;
    ; Example .......; No
    ;
    ; ;==========================================================================================
    Func FindeDublettesByName($sStDir)
    Local $cSQueue = ObjCreate("System.Collections.Queue")
    If @error Then Return SetError(1, 1, -1)
    Local $cRetQu = ObjCreate("System.Collections.Queue")
    If @error Then Return SetError(1, 2, -1)
    Local $cFiles = ObjCreate("Scripting.Dictionary")
    If @error Then Return SetError(1, 3, -1)
    Local $cRet = ObjCreate("Scripting.Dictionary")
    If @error Then Return SetError(1, 3, -1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $FFFF, $FFNF, $sDir, $sTemp, $iCount = 1

    [/autoit] [autoit][/autoit] [autoit]

    If StringRight($sStDir, 1) = '\' Then $sStDir = StringTrimRight($sStDir, 1)
    If Not FileExists($sStDir) Then Return SetError(2, 0, "")

    [/autoit] [autoit][/autoit] [autoit]

    $cSQueue.Enqueue($sStDir)

    [/autoit] [autoit][/autoit] [autoit]

    While $cSQueue.Count > 0
    $sDir = $cSQueue.Dequeue
    $FFFF = FileFindFirstFile($sDir & '\*')
    If $FFFF <> -1 Then
    Do
    $FFNF = FileFindNextFile($FFFF)
    If @error Then ExitLoop
    If @extended Then
    $cSQueue.Enqueue($sDir & '\' & $FFNF)
    Else
    If $cFiles.Exists($FFNF) Then
    If $cRet.Exists($FFNF) Then
    $sTemp = $cRet($FFNF)
    $cRet.Remove($FFNF)
    $cRet.Add($FFNF, $sTemp & '|' & $sDir)
    Else
    $cRet.Add($FFNF, $cFiles($FFNF) & '|' & $sDir)
    EndIf
    Else
    $cFiles.Add($FFNF, $sDir)
    EndIf
    EndIf
    Until 0
    EndIf
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Local $aRet[$cRet.Count + 1][2]
    $aRet[0][0] = $cRet.Count
    For $i In $cRet.Keys
    $aRet[$iCount][0] = $i
    $aRet[$iCount][1] = $cRet($i)
    $iCount += 1
    Next

    [/autoit] [autoit][/autoit] [autoit]

    Return $aRet
    EndFunc ;==>FindeDublettesByName

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ;===============================================================================
    ;
    ; Name...........: FindeDublettesByHash
    ; Description ...: Findet doppelte Dateien anhand ihres Hash-Wertes
    ; Syntax.........: FindeDublettesByHash($sStDir)
    ; Parameters ....: $sStDir - Startverzeichnis
    ; $iMethod - Hash-Methode (siehe _Crypt_HashFile()) - Standard: md5
    ; Return values .: Erfolg - 1D-Array mit Dateipfaden getrennt durch |
    ; Fehler - Gibt -1 zurück und setzt @error:
    ; |1 - Fehler beim erstellen der Collections
    ; |2 - Startverzeichnis existiert nicht
    ; Author ........: AspirinJunkie
    ; Modified.......:
    ; Remarks .......: Benötigt .Net für Collections
    ; Related .......: Crypt.au3
    ; Link ..........;
    ; Example .......; No
    ;
    ; ;==========================================================================================
    Func FindeDublettesByHash($sStDir, $iMethod = 0x00008003)
    Local $cSQueue = ObjCreate("System.Collections.Queue")
    If @error Then Return SetError(1, 1, -1)
    Local $cRetQu = ObjCreate("System.Collections.Queue")
    If @error Then Return SetError(1, 2, -1)
    Local $cHashes = ObjCreate("Scripting.Dictionary")
    If @error Then Return SetError(1, 3, -1)
    Local $cRet = ObjCreate("Scripting.Dictionary")
    If @error Then Return SetError(1, 3, -1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $FFFF, $FFNF, $sDir, $iTemp, $iCount = 1
    Local $sHash

    [/autoit] [autoit][/autoit] [autoit]

    If StringRight($sStDir, 1) = '\' Then $sStDir = StringTrimRight($sStDir, 1)
    If Not FileExists($sStDir) Then Return SetError(2, 0, "")

    [/autoit] [autoit][/autoit] [autoit]

    $cSQueue.Enqueue($sStDir)

    [/autoit] [autoit][/autoit] [autoit]

    While $cSQueue.Count > 0
    $sDir = $cSQueue.Dequeue
    $FFFF = FileFindFirstFile($sDir & '\*')
    If $FFFF <> -1 Then
    Do
    $FFNF = FileFindNextFile($FFFF)
    If @error Then ExitLoop
    If @extended Then
    $cSQueue.Enqueue($sDir & '\' & $FFNF)
    Else
    $sHash = String(_Crypt_HashFile($sDir & '\' & $FFNF, $iMethod))
    If $cHashes.Exists($sHash) Then
    If $cRet.Exists($sHash) Then
    $iTemp = $cRet($sHash)
    $cRet.Remove($sHash)
    $cRet.Add($sHash, $iTemp & '|' & $sDir & '\' & $FFNF)
    Else
    $cRet.Add($sHash, $cHashes($sHash) & '|' & $sDir & '\' & $FFNF)
    EndIf
    Else
    $cHashes.Add($sHash, $sDir & '\' & $FFNF)
    EndIf
    EndIf
    Until 0
    EndIf
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Local $aRet[$cRet.Count + 1]
    $aRet[0] = $cRet.Count
    For $i In $cRet.Keys
    $aRet[$iCount] = $cRet($i)
    $iCount += 1
    Next

    [/autoit] [autoit][/autoit] [autoit]

    Return $aRet
    EndFunc ;==>FindeDublettesByHash

    [/autoit]

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™