7-Zip und AutoIt

Mikki

Guten Morgen zusammen,

ich habe eine Frage zu zum oben genannten Thema mit 7Zip. Kann mir jemand eine funktionierende 7Zip UDF zeigen / zukommen lassen? Und wie installiere ich eine UDF? Oder reicht es wenn ich die per #include einbinde? Ich schätze aber mal da erscheinen dann keine Vorschläge, wenn ich einen Befehl / Funktion eingebe?

Noch eine Frage: Ist es dort dann auch möglich, einen Ordner zu verpacken, indem wiederum Ordner und Dateien existieren?

Bsp: 01 Lieferungen -> 01 Lieferungen Meier, zweiter Ordner 02 Lieferungen Müller. Und in diesen Ordnern wiederum sind Dateien enthalten.

Danke im Voraus

LG Mikki

**BugFix**

Muss es zwingend 7Zip sein? Ansonsten kannst du die in Windows integrierte ZIP-Funktion nutzen: ZIP - Packen / Entpacken mit Windows eigener Funktion

**Musashi**

Hallo Mikki !

Für 7-Zip benötigst Du im Grunde gar keine UDF. Es gibt die stand-alone Version 7za.exe, die man hervorragend über Kommandozeilenbefehle steuern kann. Eine GUI wird dabei nicht angezeigt, der Zip-Vorgang läuft im Hintergrund ab. Aufgerufen wird 7za.exe über Run oder RunWait.

Die Kommandozeilenbefehle selbst sind sehr umfangreich, damit läßt sich quasi alles machen. Ich hatte vor einiger Zeit bereits einige Beiträge dazu erstellt. Falls zwischenzeitlich keine Antwort von anderen Usern kommen sollte, werde ich Dir dazu Morgen mal ein Beispiel liefern.

Gruß Musashi

Tuxedo

Und falls es unbedingt eine UDF für 7zip sein muss, hab ich hier was für dich gefunden

https://www.autoitscript.com/forum/topic/85094-7zip/

Aber Downloads solltest du wohl erst auf den beiden letzen Seiten suchen, die älteren Links gibts nicht mehr.

Und ich hoffe du kannst weniger schlecht Englisch als ich, da gab es einige Diskussionen ich denke du solltest den

Thread durchackern um mit der UDF umgehen zu können.

Jetzt hast du schon die Wahl zwischen 7zip Commandline und einer UDF die allerdings schon etwas älter ist.

oh-ha

7zip kann man doch auch komplett über Komandozeile steuern wozu dann auch noch eine UDF ?

Zip Command Line Version

Mikki

Hallo zusammen,

danke für die schnellen Antworten. Nein es muss natürlich keine UDF sein.

Die Idee mit Komandozeilensteuerung bzw mit der Windows eigenen Zip-Funktion finde ich gut, und würde für meine Zwecke völlig ausreichen. Dazu aber noch ein paar Fragen:

BugFix : Der Code von der _BuildInZip. Was genau muss ich denn damit machen? Den Code in einer .au3-Datei speichern und einbinden?

Musashi , oh-ha : Die stand-alone muss aber dann auf jedem Rechner vorhanden sein, richtig? Und wie übergebe ich Pfade an die Kommandozeile? Hat jemand ein Beispiel indem z.B. ganze Ordner samt Inhalt gepackt werden? Habe so etwas leider noch nie gemacht.

Tuxedo : Danke Jaaa mein Englisch ist jetzt auch nicht soo das beste, zugegeben. Aber ja die Seite habe ich auch schon gefunden und ausprobiert. Bin aber leider dran gescheitert diese UDF für meine Zwecke einzusetzen.

Gruß Mikki

Tuxedo

Na ganz einfach weil es der Wunsch von Mikki war.

Und weil eine UDF verfügbar ist.

Und ausserdem wäre es möglich daß die UDF eventuell in Autoit einfacher handhabbar ist als

die Commandline Befehle.

Ich bin sicher nicht der einzige den der sinnlose Gebrauch von Anführungszeichen in den Befehlen Run

oder ShellExecute in den Wahnsinn treiben, bis es endlich richtig funktioniert.

Also spart eine UDF möglicherweise einiges an Ärger.

Ausserdem ist es einfach nur ein Auswahlmöglichkeit mehr.

Schönes Wochende Tuxedo

**BugFix**

Zitat von Mikki

Der Code von der _BuildInZip. Was genau muss ich denn damit machen? Den Code in einer .au3-Datei speichern und einbinden?

Das ist eine Funktion. In dein Skript einfügen und die Funktion aufrufen mit den Parametern. Beschreibung siehst du im Funktionskopf.

**Musashi**

Hallo Mikki !

Ich hatte vor einiger Zeit in einer 'Konversation' auf Bitte eines Users mal ein kleines Testskript für eine simple Datensicherung erstellt.

Das dürfte für Dich als Demo aber auch geeignet sein. Es enthält eine kleine GUI und eine Progressbar, aber das sollte Dich nicht stören.

Lege Dir ein Verzeichnis an, z.B. c:\Autoit\projekte\Ziptest

Falls Du bereits einen Ordner für eigene Projekte hast, kannst Du natürlich auch den nehmen.

Die angehängte Datei 'Ziptest.zip' enthält :

- mein Testskript ZiptestV1.au3

- die aktuelle 7za.exe sowie die passende Hilfedatei

- eine Teststruktur zum Packen \SourceDir

Diese Daten bitte in den Ordner ..\Ziptest kopieren. Danach sollte der Ordner wie folgt aussehen :

ZiptestV1.au3 , 7za.exe , 7-zip.chm , \SourceDir

-> ZiptestV1.au3 im Editor starten/kompilieren

-> Button [Backup] ==> erzeugt 'Backup.zip' im @ScriptDir (\SourceDir wird gesichert)

-> Button [Restore] ==> stellt \SourceDir wieder her

Hier noch mal der Code der ZiptestV1.au3 (identisch zur Version in 'Ziptest.zip') :

AutoIt

; ===============================================================================================================================
; Projekt : kleines Testprogramm für Backup und Restore mit 7-Zip :
; erstellt am 23.09.2017 von @Musashi
; ===============================================================================================================================
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=MyAutoIt3_Blue.ico
#AutoIt3Wrapper_UseX64 = N
#AutoIt3Wrapper_UseUpx = N ; interne UPX Komprimierung ausschalten
#AutoIt3Wrapper_Res_SaveSource = N
#AutoIt3Wrapper_Res_Description = Testprogramm für Backup und Restore
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GUIConstants.au3>
#include <Constants.au3>
#include <StringConstants.au3>
#include <Misc.au3>

Opt('MustDeclareVars', 1)  ; Variablen müssen vor Verwendung mit Global/Local deklariert werden

; Name der Backupdatei (voller Pfad) :
Global $sBackupFileName = @ScriptDir & "\backup.zip"

; Name der verwendeten ZIP-Software (voller Pfad) :
Global $sZipProgramm = @ScriptDir & "\7za.exe"  ; hier : 7za.exe im Skriptverzeichnis

; Hauptroutine aufrufen :
_GUI_Main()
Exit

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _GUI_Main
; -------------------------------------------------------------------------------------------------------------------------------
Func _GUI_Main()
    Local $iGuiMsg
    Local Const $iMinPosL = 30  ; Offset für linke Startposition von GUI-Elementen

    ; Controls GUI-Seite :
    Local $hGUI, $idLblInfo, $idProgressBar, $idBtnBackup, $idBtnRestore, $idBtnCancel

    $hGUI = GUICreate("Datensicherung : ", 500, 200, -1, -1)
    GUISetBkColor($COLOR_WHITE)
    GUISetFont(10, $FW_NORMAL, 1, "Arial")  ; Standardfont GUI-weit setzen

    ; Infotext :
    $idLblInfo = GUICtrlCreateLabel("", $iMinPosL, 10, 400, 25)
    GUICtrlSetFont($idLblInfo, 12)
    GUICtrlSetState($idLblInfo, $GUI_HIDE)

    ; ProgressBar initialisieren :
    Local $idProgressBar = GUICtrlCreateProgress($iMinPosL, 50, 440, 25, $PBS_MARQUEE)
    GUICtrlSetColor($idProgressBar , 0x426DA9)   ; Farbwert (bei Bedarf ändern)
    GUICtrlSetBkColor($idProgressBar, 0xF0F0F0)  ; Farbwert Hintergrund (bei Bedarf ändern)
    GUICtrlSetState($idProgressBar, $GUI_HIDE)

    $idBtnBackup  = GUICtrlCreateButton("&Backup", $iMinPosL, 150, 120, 25)
    $idBtnRestore = GUICtrlCreateButton("&Restore", $iMinPosL+140, 150, 120, 25)
    $idBtnCancel  = GUICtrlCreateButton("&Abbrechen", $iMinPosL+280, 150, 120, 25)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        $iGuiMsg = GUIGetMsg()

        Select
            Case $iGuiMsg = $GUI_EVENT_CLOSE
                ExitLoop

            Case $iGuiMsg = $idBtnBackup
                GUICtrlSetData($idLblInfo, "Datensicherung läuft ... ")
                GUICtrlSetState($idLblInfo, $GUI_SHOW)
                GUICtrlSetState($idProgressBar, $GUI_SHOW)

                _ProgressMarquee_Start($idProgressBar)
                ; Funktion für Datensicherung aufrufen :
                _Backup()
                Sleep(5000)  ; zum Test : 5 Sek. Pause, um bei geringer Datenmenge die Progressbar zu sehen
                _ProgressMarquee_Stop($idProgressBar)
                ExitLoop

            Case $iGuiMsg = $idBtnRestore
                If Not FileExists($sBackupFileName) Then
                    MsgBox(0, "Fehler :", $sBackupFileName & " nicht gefunden")
                    ExitLoop
                EndIf

                GUICtrlSetData($idLblInfo, "Datenwiederherstellung läuft ... ")
                GUICtrlSetState($idLblInfo, $GUI_SHOW)
                GUICtrlSetState($idProgressBar, $GUI_SHOW)

                _ProgressMarquee_Start($idProgressBar)
                ; Funktion für Datenwiederherstellung aufrufen :
                _Restore()
                Sleep(5000)  ; zum Test : 5 Sek. Pause, um bei geringer Datenmenge die Progressbar zu sehen
                _ProgressMarquee_Stop($idProgressBar)
                ExitLoop

            Case $iGuiMsg = $idBtnCancel
                ExitLoop

        EndSelect
    WEnd
    GUIDelete($hGUI)
EndFunc    ;==>_GUI_Main

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _Backup
; Beschreibung : ausgewählte Dateien mit 7za packen
; -------------------------------------------------------------------------------------------------------------------------------
Func _Backup()
    Local $sFileFolder  ; Datei oder Ordnername, der gepackt werden soll
    Local $sCommand     ; ZIP-Befehl (nur der Übersichtlichkeit wegen)

    ; eine Datei separat in das ZIP-Backup eintragen :
    $sFileFolder = @ScriptDir & "\SourceDir\File-SourceDir.txt"
    If FileExists($sFileFolder) Then
        $sCommand = $sZipProgramm & ' a -tzip "' & $sBackupFileName & '" "' & $sFileFolder & '"'
        RunWait ($sCommand, "", @SW_HIDE)
    Else
        MsgBox(0, "Fehler :", $sFileFolder & " nicht gefunden")
    EndIf

    ; ein ausgewähltes Unterverzeichnis in das ZIP-Backup eintragen :
    $sFileFolder = @ScriptDir & "\SourceDir\SubDir1\"
    If FileExists($sFileFolder) Then
        $sCommand = $sZipProgramm & ' a -tzip "' & $sBackupFileName & '" "' & $sFileFolder & '"'
        RunWait ($sCommand, "", @SW_HIDE)
    Else
        MsgBox(0, "Fehler :", $sFileFolder & " nicht gefunden")
    EndIf

    ; ein ausgewähltes Unterverzeichnis (mit Unterverzeichnissen) in das ZIP-Backup eintragen :
    $sFileFolder = @ScriptDir & "\SourceDir\SubDir2\"
    If FileExists($sFileFolder) Then
        $sCommand = $sZipProgramm & ' a -tzip "' & $sBackupFileName & '" "' & $sFileFolder & '"'
        RunWait ($sCommand, "", @SW_HIDE)
    Else
        MsgBox(0, "Fehler :", $sFileFolder & " nicht gefunden")
    EndIf
EndFunc   ;==>_Backup

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _Restore
; Beschreibung : Backupdatei mit 7za wieder entpacken (zurückspielen)
; -------------------------------------------------------------------------------------------------------------------------------
Func _Restore()
    Local $sSourceFolder  ; Zielordner, in den die ZIP-Struktur entpackt werden soll
    Local $sCommand       ; ZIP-Befehl (nur der Übersichtlichkeit wegen)

    $sSourceFolder = @ScriptDir & "\SourceDir"

    If FileExists($sBackupFileName) And FileGetSize($sBackupFileName) > 0 Then
        ; Info :
        ;   -aoa => bestehende Dateien überschreiben
        ;   -aos => bestehende Dateien überspringen
        $sCommand = $sZipProgramm & ' x "' & $sBackupFileName & '" -o"' & $sSourceFolder & '" -aoa -y'
        RunWait ($sCommand, "", @SW_HIDE)
    EndIf
EndFunc   ;==>_Restore

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _ProgressMarquee_Start
; Beschreibung : starten einer Progressanzeige im Marquee-Stil
; -------------------------------------------------------------------------------------------------------------------------------
Func _ProgressMarquee_Start($iControlID)
    Return GUICtrlSendMsg($iControlID, $PBM_SETMARQUEE, True, 30)  ; 30=Geschwindigkeit
EndFunc   ;==>_ProgressMarquee_Start

; -------------------------------------------------------------------------------------------------------------------------------
; Funktion     : _ProgressMarquee_Stop
; Beschreibung : stoppen der Progressanzeige
; -------------------------------------------------------------------------------------------------------------------------------
Func _ProgressMarquee_Stop($iControlID, $bReset = False)
    Local $bReturn = GUICtrlSendMsg($iControlID, $PBM_SETMARQUEE, False, 30)
    If $bReturn And $bReset Then
        GUICtrlSetStyle($iControlID, $PBS_MARQUEE)
    EndIf
    Return $bReturn
EndFunc   ;==>_ProgressMarquee_Stop

Alles anzeigen

Der relevante Teil findet in der Funktion _Backup statt.

Zu den obigen Fragen/Kommentaren :

Zitat von Mikki

Musashi , oh-ha : Die stand-alone muss aber dann auf jedem Rechner vorhanden sein, richtig? Und wie übergebe ich Pfade an die Kommandozeile? Hat jemand ein Beispiel indem z.B. ganze Ordner samt Inhalt gepackt werden? Habe so etwas leider noch nie gemacht.

Ja, die Datei 7za.exe muss vorhanden sein. Beispiel s.o. Die Hilfedatei nicht (ich werde mal nach einer deutschen 7Zip-Hilfe suchen).

Zitat von Tuxedo

Ich bin sicher nicht der einzige den der sinnlose Gebrauch von Anführungszeichen in den Befehlen Run

oder ShellExecute in den Wahnsinn treiben, bis es endlich richtig funktioniert.

Sorry Tuxedo , aber das kann man so nicht sagen !

Die Übergabeparameter werden von dem aufzurufenen Programm festgelegt, nicht von der Run-Funktion in AutoIt .

Gruß Musashi

Mikki

Hallo,

Musashi super vielen Dank hat Einwandfrei funktioniert genau das was ich brauche.

Ist auch recht einfach gehalten und hab´s verstanden

BugFix : ich werde die Funktion morgen mal in Ruhe testen, da ich heute Abend noch was vor habe werde berichten.

Gruß Mikki

**Kanashius**

Zu der Lösung von Musashi :

Als ich vor ein paar Tagen 7zip genutzt hab viel mir auf, dass die 7za.exe nicht mit rar-Dateien funktioniert. Um diese zu entpacken muss die 7z.exe genutzt werden.

Die Konsolenbefehle sind die gleichen. Um es unsichtbar zu machen, einfach ShellExecute mit @SW_HIDE zum aufrufen nutzen

**Musashi**

Hallo Kanashius !

Zitat von Kanashius

Als ich vor ein paar Tagen 7zip genutzt hab viel mir auf, dass die 7za.exe nicht mit rar-Dateien funktioniert. Um diese zu entpacken muss die 7z.exe genutzt werden.

Das ist korrekt !

7za.exe (a = alone) ist die standalone Variante von 7-Zip und unterstützt die Formate 7z, lzma, cab, zip, gzip, bzip2, Z and tar. Dafür benötigt 7za.exe aber auch keine externen Module.

7z.exe benötigt zusätzlich die 7z.dll, und hat eine offene Architektur gegenüber neueren Formaten (wobei sich 7za.exe natürlich auch weiterentwickelt).

Im Ergebnis geht es also nicht so sehr um die Frage : besser oder schlechter, sondern was man braucht.

Sofern man das Format selbst festlegen kann, ist man mit dem 'Leichtgewicht' 7za.exe, meiner Meinung nach, besser bedient. Der Aufruf über Run/RunWait mit @SW_HIDE funktioniert bei beiden Varianten.

Gruß Musashi