MYSQL - Insert Into Pfad Problem

Sonderbaar

Hallo liebe Autoitler...

folgender Code soll eine Verzeichnisübersicht geben und diese in eine MYSQL-Tabelle der Version 3.51 reinpumpen.

für den mysql-connect müsstet ihr nur die Zugangsdaten ändern und die Tabelle bei euch anlegen mit ID_NR (Autoincrement), dateipfad und groesse_in_bytes

Datentypen sind: Int, Varchar, Int

Ziel ist es den Pfad C:\ in die Spalte dateipfad zu bekommen... leider ist es so, dass beim schreiben in die DB der "\" Backslash einfach weg gelassen wird...

Auch ein StringRegExpReplace schafft dem ganzen keine Abhilfe...

Meine Frage jetzt: Geht es nur mit der MYSQL-Version nicht? Oder habe ich irgendwo einen anderen Fehler? Meines erachtens muss ich den StringRegExpReplace garnicht nutzen, da im Array der Pfad ja korrekt angezeigt wird... war aber ein Strohhalm an den ich mich geklammert hatte...

Spoiler anzeigen

C

#Include <File.au3>
#Include <Array.au3>
#include <_GetFilesFolder_Rekursiv.au3>
#include <MySQL.au3>
hotKeySet("{ESC}", "Terminate")

$pfad = "C:\"
$folder = "app"

$test = _GetFilesFolder_Rekursiv($pfad & $folder, '*', "0")
$SQL = _MySQLConnect("user","password","table_name","IP")

;~ $test2 = StringRegExpReplace("C:\todo\bla\", '\\', '\\')
;~ ConsoleWrite($test2)

For $i = 1 to $test[0]
$insert_datensatz_anlegen = "INSERT INTO fs_owner (ID_NR, dateipfad, groesse_in_bytes) VALUES ('', '" & StringRegExpReplace($test[$i], '\\', '\\') & "','" & _GetExtProperty($test[$i], 1) & "');"
_Query($SQL,$insert_datensatz_anlegen)
Next


Func Terminate()
Exit 0
EndFunc

;~ ===============================================================================
; Function Name:    GetExtProperty($sPath,$iProp)
; Description:      Returns an extended property of a given file.
; Parameter(s):     $sPath - The path to the file you are attempting to retrieve an extended property from.
;                   $iProp - The numerical value for the property you want returned. If $iProp is is set
;                              to -1 then all properties will be returned in a 1 dimensional array in their corresponding order.
;                            The properties are as follows:
;                            Name = 0
;                            Size = 1
;                            Type = 2
;                            DateModified = 3
;                            DateCreated = 4
;                            DateAccessed = 5
;                            Attributes = 6
;                            Status = 7
;                            Owner = 8
;                            Author = 9
;                            Title = 10
;                            Subject = 11
;                            Category = 12
;                            Pages = 13
;                            Comments = 14
;                            Copyright = 15
;                            Artist = 16
;                            AlbumTitle = 17
;                            Year = 18
;                            TrackNumber = 19
;                            Genre = 20
;                            Duration = 21
;                            BitRate = 22
;                            Protected = 23
;                            CameraModel = 24
;                            DatePictureTaken = 25
;                            Dimensions = 26
;                            Width = 27
;                            Height = 28
;                            Company = 30
;                            Description = 31
;                            FileVersion = 32
;                            ProductName = 33
;                            ProductVersion = 34
; Requirement(s):   File specified in $spath must exist.
; Return Value(s):  On Success - The extended file property, or if $iProp = -1 then an array with all properties
;                   On Failure - 0, @Error - 1 (If file does not exist)
; Author(s):        Simucal (Simucal@gmail.com)
; Note(s):
;
;===============================================================================

Func _GetExtProperty($sPath, $iProp)
    Local $iExist, $sFile, $sDir, $oShellApp, $oDir, $oFile, $aProperty, $sProperty
    $iExist = FileExists($sPath)
    If $iExist = 0 Then
        SetError(1)
        Return 0
    Else
        $sFile = StringTrimLeft($sPath, StringInStr($sPath, "\", 0, -1))
        $sDir = StringTrimRight($sPath, (StringLen($sPath) - StringInStr($sPath, "\", 0, -1)))
        $oShellApp = ObjCreate ("shell.application")
        $oDir = $oShellApp.NameSpace ($sDir)
        $oFile = $oDir.Parsename ($sFile)
        If $iProp = -1 Then
            Local $aProperty[35]
            For $i = 0 To 34
                $aProperty[$i] = $oDir.GetDetailsOf ($oFile, $i)
            Next
            Return $aProperty
        Else
            $sProperty = $oDir.GetDetailsOf ($oFile, $iProp)
            If $sProperty = "" Then
                Return 0
            Else
                Return $sProperty
            EndIf
        EndIf
    EndIf
EndFunc   ;==>_Get

Alles anzeigen

**autoiter**

Hallo Sonderbaar

Du musst den Backslash doppeln, damit er im String erscheint. Das ist eigentlich ein spezielles Zeichen, mit dem du Anweisungen machen kannst. (C:\\)

**AspirinJunkie**

Backslashes müssen in MySQL escaped werden.
Am einfachsten durch Dopplung: "C:\Test" -> "C:\\Test"

Etwas einfacher (und sicherer) wäre es wenn du direkt Funktionen verwendest welche den übergebenen String SQL-konform escapen.
In der Sqlite-UDF gibt es eine solche Funktion die auch weitestgehend für MySQL verwendbar sein sollte: _SQLite_Escape()

Sonderbaar

Zitat von AspirinJunkie

Backslashes müssen in MySQL escaped werden.
Am einfachsten durch Dopplung: "C:\Test" -> "C:\\Test"

ABER... ich habe doch durch den RegEx quasi "Escaped" oder nicht? (Zeile 17 in meinem Script)

Dopplung geht ja nicht, da der String ja durch die Funktion _GetFilesFolder_Rekursiv schon kommt...

Ich bin verwirrt.

**autoiter**

Nein, du hast StringRegExpReplace($test[$i], '\\', '\\') zwei Backslash durch zwei andere ersetzt

Da sollte wohl eher ein Backslash durch zwei ersetzt werden.

**AspirinJunkie**

Zitat von autoiter

Nein, du hast StringRegExpReplace($test[$i], '\\', '\\') zwei Backslash durch zwei andere ersetzt

Nicht ganz - er hat einzelne Backslashes durch einzelne Backslashes ersetzt.
Denn für StringRegExpReplace müssen Backslashes - genauso wie bei SQL - durch Dopplung escaped werden. Und zwar sowohl im Pattern als auch im Replace-String.

**autoiter**

Danke für die Korrektur, AspirinJunkie

Sonderbaar

Zitat von autoiter

Nein, du hast StringRegExpReplace($test[$i], '\\', '\\') zwei Backslash durch zwei andere ersetzt

Aber:

Code

$test2 = StringRegExpReplace("C:\todo\bla\", '\\', 'b')
ConsoleWrite($test2)

Ersetzt den Backslash doch zu einem b... also muss es korrekt heißen:

Code

$test2 = StringRegExpReplace("C:\todo\bla\", '\\', '\\\\')
ConsoleWrite($test2)

Danke für eure Geduld!!!

**alpines**

Zitat von AspirinJunkie

Nicht ganz - er hat einzelne Backslashes durch einzelne Backslashes ersetzt.

Ich wollte es auch schreiben aber dachte mir nur, mehh.

**AspirinJunkie**

alpines: Du hast es unterlassen etwas zu schreiben weil du es als nicht erheblich genug eingeschätzt hast?

Jedoch der Umstand darüber zu schreiben dass du eigentlich etwas schreiben wolltest es aber dann gelassen hast, hat hingegen für dich dann die Bedeutungsschwelle zum tatsächlichen Schreiben überschritten?

**alpines**

Zitat von AspirinJunkie

Jedoch der Umstand darüber zu schreiben dass du eigentlich etwas schreiben wolltest es aber dann gelassen hast, hat hingegen für dich dann die Bedeutungsschwelle zum tatsächlichen Schreiben überschritten?

Volltreffer.

**autoiter**

Ich finde das scheiße alpines

Sonderbaar

streitet euch nicht die Lösung kam ja, egal von wem...

Sonderbaar

Ich muss leider nochmal stören...

irgendwie habe ich noch ein Problem mit einer Schleife...

offenbar bricht das Script bei einem Dateinamen ab, der den Aufbau: Textdatei für Maschine aus Dokument 'ABCDEFG...'.txt hat

Mal davon abgesehen, dass man den Ersteller eigentlich dafür erschlagen müsste...

möchte ich gerne, dass das Script, die Datei die den Fehler generiert, in eine Textdatei schreibt und dann einfach die nächste Datei nimmt, statt sich gleich komplett zu verabschieden.

Vor lauter Verzweiflung habe ich den if @error doppelt reingemacht... die MsgBox zum Fehler die ich erhalte lautet:

AutoIt Error

Line 3126 (File C:\scripte\besitzer.exe"):

Error: The Requested action with this object has failed.

Spoiler anzeigen

AutoIt

#Include <File.au3>
#Include <Array.au3>
#include <_GetFilesFolder_Rekursiv.au3>
#include <MySQL.au3>
#include <TrayConstants.au3>
hotKeySet("{ESC}", "Terminate")

$pfad = $CmdLine[1]
$folder = $CmdLine[2]

$file = FileOpen("C:\scripte\Fehlerdatei.txt", $FO_APPEND)
TrayTip("Array einlesen", "Ich lese das Array ein", 5)
$test = _GetFilesFolder_Rekursiv($pfad & $folder, '*', "0")
$SQL = _MySQLConnect("user","password","table_name","IP")

TrayTip("Ich führe den Rest aus", "Jetzt hole ich mir den Rest", 10)
For $i = 1 to $test[0]
$insert_datensatz_anlegen = "INSERT INTO fs_owner (dateipfad, groesse, owner, modified, created, accessed) VALUES ('" & StringRegExpReplace($test[$i], '\\', '\\\\') & "','" & _GetExtProperty($test[$i], 1) & "','" & StringRegExpReplace(_GetExtProperty($test[$i], 8), '\\', '\\\\', 8) & "','" & StringRegExpReplace(_GetExtProperty($test[$i], 3), '(\d{2}).(\d{2}).(\d{4}) (\d{2}):(\d{2})', '$3-$2-$1 $4:$5') & "','" & StringRegExpReplace(_GetExtProperty($test[$i], 4), '(\d{2}).(\d{2}).(\d{4}) (\d{2}):(\d{2})', '$3-$2-$1 $4:$5') & "','" & StringRegExpReplace(_GetExtProperty($test[$i], 5), '(\d{2}).(\d{2}).(\d{4}) (\d{2}):(\d{2})', '$3-$2-$1 $4:$5') & "');"
If @error Then
FileWriteLine($file, $test[$i])
ContinueLoop
EndIf
_Query($SQL,$insert_datensatz_anlegen)
If @error Then
FileWriteLine($file, $test[$i])
ContinueLoop
EndIf
Next

FileClose($file)

Func Terminate()
Exit 0
EndFunc

;~ ===============================================================================
; Function Name:    GetExtProperty($sPath,$iProp)
; Description:      Returns an extended property of a given file.
; Parameter(s):     $sPath - The path to the file you are attempting to retrieve an extended property from.
;                   $iProp - The numerical value for the property you want returned. If $iProp is is set
;                              to -1 then all properties will be returned in a 1 dimensional array in their corresponding order.
;                            The properties are as follows:
;                            Name = 0
;                            Size = 1
;                            Type = 2
;                            DateModified = 3
;                            DateCreated = 4
;                            DateAccessed = 5
;                            Attributes = 6
;                            Status = 7
;                            Owner = 8
;                            Author = 9
;                            Title = 10
;                            Subject = 11
;                            Category = 12
;                            Pages = 13
;                            Comments = 14
;                            Copyright = 15
;                            Artist = 16
;                            AlbumTitle = 17
;                            Year = 18
;                            TrackNumber = 19
;                            Genre = 20
;                            Duration = 21
;                            BitRate = 22
;                            Protected = 23
;                            CameraModel = 24
;                            DatePictureTaken = 25
;                            Dimensions = 26
;                            Width = 27
;                            Height = 28
;                            Company = 30
;                            Description = 31
;                            FileVersion = 32
;                            ProductName = 33
;                            ProductVersion = 34
; Requirement(s):   File specified in $spath must exist.
; Return Value(s):  On Success - The extended file property, or if $iProp = -1 then an array with all properties
;                   On Failure - 0, @Error - 1 (If file does not exist)
; Author(s):        Simucal (Simucal@gmail.com)
; Note(s):
;
;===============================================================================

Func _GetExtProperty($sPath, $iProp)
    Local $iExist, $sFile, $sDir, $oShellApp, $oDir, $oFile, $aProperty, $sProperty
    $iExist = FileExists($sPath)
    If $iExist = 0 Then
        SetError(1)
        Return 0
    Else
        $sFile = StringTrimLeft($sPath, StringInStr($sPath, "\", 0, -1))
        $sDir = StringTrimRight($sPath, (StringLen($sPath) - StringInStr($sPath, "\", 0, -1)))
        $oShellApp = ObjCreate ("shell.application")
        $oDir = $oShellApp.NameSpace ($sDir)
        $oFile = $oDir.Parsename ($sFile)
        If $iProp = -1 Then
            Local $aProperty[35]
            For $i = 0 To 34
                $aProperty[$i] = $oDir.GetDetailsOf ($oFile, $i)
            Next
            Return $aProperty
        Else
            $sProperty = $oDir.GetDetailsOf ($oFile, $iProp)
            If $sProperty = "" Then
                Return 0
            Else
                Return $sProperty
            EndIf
        EndIf
    EndIf
EndFunc   ;==>_Get

Alles anzeigen

Hilfe!!!

**autoiter**

Hallo Sonderbaar

Die Fehlermeldung ist natürlich mäßig gewinnbringend:

Zitat von Sonderbaar

AutoIt Error

Line 3126 (File C:\scripte\besitzer.exe"):

Error: The Requested action with this object has failed.

Die Zeile ist in der kompilierten exe natürlich eine ganz andere. Wenn du einen reproduzierbaren Fehler behandeln willst, führe das Skript direkt aus SciTE heraus aus.

Du solltest nach der Objekterstellung immer auf IsObj() prüfen. Wenn hier ein Fehler kommt, kannst du die Funktion mit Fehler verlassen und die Datei in deine Fehlerliste eintragen.

**alpines**

Zitat von autoiter

Du solltest nach der Objekterstellung immer auf IsObj() prüfen. Wenn hier ein Fehler kommt, kannst du die Funktion mit Fehler verlassen und die Datei in deine Fehlerliste eintragen.

So ein Fehler wird nicht zwangsweise von Nicht-Objekten geworfen. Es kann auch sein, dass das Objekt gültig ist und man Methoden aufrufen kann aber einige einfach fehlschlagen.

Da ist es besser ein ObjEvent zu registrieren welche eine COM-Meldung auswirft und AutoIt nicht crasht sondern in die Fehlerfunktion springt.

Sonderbaar

Zitat von alpines

So ein Fehler wird nicht zwangsweise von Nicht-Objekten geworfen. Es kann auch sein, dass das Objekt gültig ist und man Methoden aufrufen kann aber einige einfach fehlschlagen.

Da ist es besser ein ObjEvent zu registrieren welche eine COM-Meldung auswirft und AutoIt nicht crasht sondern in die Fehlerfunktion springt.

HÄH?

**alpines**

Zitat von Sonderbaar

HÄH?

Hier ein kleines Beispiel, die Methode "blablabla..." ist in Shell.Application nicht enthalten aber bringt AutoIt nicht dazu zu crashen, da der Fehler abgefangen wird.

AutoIt

$oShell = ObjCreate("Shell.Application")
$oMyError = ObjEvent("AutoIt.Error", "_MyErrorHandler")

$oShell.blablablablabla()

Func _MyErrorHandler()
    $HexNumber = Hex($oMyError.Number, 8)
    $strMSG = "Error Number: " & $HexNumber & @CRLF
    $strMsg &= "WinDescription: " & $oMyError.WinDescription & @CRLF
    $strMsg &= "Script Line: " & $oMyError.ScriptLine & @CRLF

    MsgBox(0, "ERROR", $strMSG)
Endfunc

Alles anzeigen

Selbes kannst du mit deinem Problem machen, registriere den Fehlerhandler und prüfe nach was die letzte Datei war und schreibe sie ins Fehlerlog/überspringe sie.

Sonderbaar

Ah, ok. Danke jetzt habe ich es kapiert...