Erstellt ein Dummy-Control für die GUI.
GUICtrlCreateDummy ( )
Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
Fehler: | Gibt 0 zurück. |
Dieses Control kann Nachrichten über den Aufruf von GUICtrlSendToDummy() erhalten. Das Item wird sich normal "melden" und der Wert, der mit GUICtrlSendToDummy gesendet wurde kann mit GUICtrlRead() gelesen werden.
- - - - - - - - Erklärung der Controls - - - - - - - -
GUICtrlRead, GUICtrlSendToDummy, GUICtrlSetData, GUICtrlSetOnEvent
#include <GUIConstantsEx.au3>
Example()
Func Example()
$gui = GUICreate("GUICtrlCreateDummy", 250, 200, 100, 200)
GUISetBkColor(0x00E0FFFF) ; Ändert die Hintergrundfarbe
$idUser = GUICtrlCreateDummy()
$idButton_Event = GUICtrlCreateButton("OK", 75, 170, 70, 20)
$idButton_Cancel = GUICtrlCreateButton("Abbrechen", 150, 170, 70, 20)
GUISetState(@SW_SHOW)
Local $idMsg
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
$idMsg = GUIGetMsg()
Select
Case $idMsg = $idButton_Event
GUICtrlSendToDummy($idUser)
Case $idMsg = $idButton_Cancel
GUICtrlSendToDummy($idUser)
Case $idMsg = $idUser
; Besondere Anweisungen vor Skriptende
; ...
Exit
EndSelect
Until $idMsg = $GUI_EVENT_CLOSE
EndFunc ;==>Example
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $gui, $CheckboxesStart, $CheckboxesStop, $CheckAll, $UnCheckAll, $msg
$gui = GUICreate("Dummy-Control", 200, 850)
$CheckboxesStart = GUICtrlCreateDummy() ; ==> Merkt sich den Start
For $i = 0 To 49
GUICtrlCreateCheckbox("Checkbox " & $i + 1, 0, 0 + ($i * 17))
Next
$CheckboxesStop = GUICtrlCreateDummy() ; ==> Merkt sich den Stopp
$CheckAll = GUICtrlCreateButton("alle markieren", 100, 100)
$UnCheckAll = GUICtrlCreateButton("alle demarkieren", 100, 130)
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
Switch $msg
Case $CheckAll
For $i = $CheckboxesStart To $CheckboxesStop
GUICtrlSetState($i, $GUI_CHECKED)
Next
Case $UnCheckAll
For $i = $CheckboxesStart To $CheckboxesStop
GUICtrlSetState($i, $GUI_UNCHECKED)
Next
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
EndFunc ;==>Example