_GDIPlus_BitmapCreateApplyEffect

Beschreibung anzeigen in

Erstellt eine neue Bitmap durch anwenden eines bestimmten Effekts auf eine existierende Bitmap

#include <GDIPlus.au3>
_GDIPlus_BitmapCreateApplyEffect ( $hBitmap, $hEffect [, $tRECT = Null [, $tOutRECT = Null]] )

Parameter

$hBitmap	Handle zu der Bitmap auf die der Effekt angewendet wird.
$hEffect	Handle zu dem Effekt der angewendet wird.
$tRECT	[optional] eine $tagRECT Struktur die den Bereich der Eingabe-Bitmap angibt welche genutzt wird.
$tOutRECT	[optional] eine $tagRECT Struktur die den Bereich der Eingabe-Bitmap erhält welche genutzt wurde.

Rückgabewert

Erfolg:	Ein Handle zu einem Bitmap Objekt.
Fehler:	False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.
@error:	-1 - GDIPlus.dll unterstützt diese Funktion nicht. 10 - Falsche Parameter.

Bemerkungen

Wenn du mit dem Effekt-Objekt fertig bist, rufe _GDIPlus_EffectDispose() auf um die Ressource wieder freizugeben.

Siehe auch

Suche nach GdipBitmapCreateApplyEffect in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    If Not _GDIPlus_Startup() Or @extended < 6 Then
        MsgBox($MB_SYSTEMMODAL, "FEHLER", "GDIPlus.dll v1.1 ist nicht verfügbar")
        Return
    EndIf

    Local $sFile = FileOpenDialog("Bitte ein Bild auswählen", "", "Bilder (*.bmp;*.png;*.jpg;*.gif;*.tif)")
    If @error Or Not FileExists($sFile) Then Return

    Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)

    Local $hEffect = _GDIPlus_EffectCreateBlur()

    Local $tRECT = DllStructCreate($tagRECT)
    Local $hBitmap = _GDIPlus_BitmapCreateApplyEffect($hImage, $hEffect, Null, $tRECT)

    Local $iBmpW = $tRECT.Right - $tRECT.Left
    Local $iBmpH = $tRECT.Bottom - $tRECT.Top

    Local $iWidth = 600
    Local $iHeight = $iBmpH * 600 / $iBmpW

    Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    GUISetState(@SW_SHOW)

    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $iWidth, $iHeight)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GDIPlus_EffectDispose($hEffect)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Example