_GDIPlus_BitmapCreateApplyEffectEx
Beschreibung anzeigen in
Erstellt eine neue Bitmap durch anwenden eines angegebenen Effekts auf eine existierende Bitmap
#include <GDIPlus.au3>
_GDIPlus_BitmapCreateApplyEffectEx ( $hBitmap, $hEffect [, $iX = 0 [, $iY = 0 [, $iW = 0 [, $iH = 0]]]] )
Parameter
| $hBitmap | Handle der Bitmap auf die der Effekt angewendet wird. |
| $hEffect | Handle zu dem Effekt der angewendet wird. |
| $iX | [optional] Die X Koordinate der oberen linken Ecke des Bereichs auf die der Effekt angewendet wird |
| $iY | [optional] Die Y Koordinate der oberen linken Ecke des Bereichs auf die der Effekt angewendet wird |
| $iW | [optional] Definiert die Breite des Bereichs auf den der Effekt angewendet wird |
| $iH | [optional] Definiert die Höhe des Bereichs auf den der Effekt angewendet wird |
Rückgabewert
| Erfolg: | Ein Handle zu einem Bitmap Objekt. |
| Fehler: | False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten. |
| @error: | -1 - GDIPlus.dll unterstützt diese Funktion nicht. 10 - Falsche Parameter. |
Bemerkungen
Wenn du mit dem Effekt-Objekt fertig bist, rufe _GDIPlus_EffectDispose() auf um die Ressourcen freizugeben.
Verwandte Funktionen
_GDIPlus_BitmapCreateApplyEffect, _GDIPlus_EffectCreate
Beispiel
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
_Example()
Func _Example()
If Not _GDIPlus_Startup() Or @extended < 6 Then
MsgBox($MB_SYSTEMMODAL, "FEHLER", "GDIPlus.dll v1.1 ist nicht verfügbar")
Return
EndIf
Local $sFile = FileOpenDialog("Bitte ein Bild auswählen", "", "Bilder (*.bmp;*.png;*.jpg;*.gif;*.tif)")
If @error Or Not FileExists($sFile) Then Return
Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)
Local $iImgW = _GDIPlus_ImageGetWidth($hImage)
Local $iImgH = _GDIPlus_ImageGetHeight($hImage)
Local $iWidth = 600
Local $iHeight = $iImgH * 600 / $iImgW
Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
GUISetState(@SW_SHOW)
Local $hEffect = _GDIPlus_EffectCreate($GDIP_BlurEffectGuid)
Local $tEffectParameters = DllStructCreate($tagGDIP_EFFECTPARAMS_Blur)
Local $hBitmap
For $i = 0 To 12
DllStructSetData($tEffectParameters, "Radius", Abs($i - 6) * 12)
_GDIPlus_EffectSetParameters($hEffect, $tEffectParameters)
$hBitmap = _GDIPlus_BitmapCreateApplyEffectEx($hImage, $hEffect, $i * Ceiling($iImgW / 13), 0, Ceiling($iImgW / 13) * 2, $iImgH)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, $i * Ceiling($iWidth / 13), 0, Ceiling($iWidth / 13), $iHeight)
_GDIPlus_BitmapDispose($hBitmap)
Next
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
_GDIPlus_EffectDispose($hEffect)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
EndFunc ;==>_Example