_GUICtrlEdit_Find

Beschreibung anzeigen in

Lässt einen Suchdialog auftauchen

#include <GuiEdit.au3>
_GUICtrlEdit_Find ( $hWnd [, $bReplace = False] )

Parameter

$hWnd	Control-ID / Handle des Controls
$bReplace	[optional] Ersetzoption: True - Zeigt Optionen False - Versteckt Optionen

Rückgabewert

Keine.

Bemerkungen

Falls Text von dem Edit-Control verwendet und dieser Text ersetzt wird, so wird diese Funktion nicht mehr länger korrekt funktionieren

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <WindowsConstants.au3>

; verwendet die AutoIt-Funktion

Example_Internal()

Func Example_Internal()
    Local $s_Text = "Das ist ein Test." & @CRLF & _
            "Das ist nur ein Test." & @CRLF & _
            "Das Testen sollte bei dir genauso funktionieren wie bei mir!"
    Local $idButton1, $idButton2, $iMsg, $idEdit

    GUICreate('Beispiel: Suchen und Ersetzen mit AutoIt ' & FileGetVersion(@AutoItExe), 622, 448, 192, 125)
    $idEdit = GUICtrlCreateEdit($s_Text, 64, 24, 505, 233, _
            BitOR($ES_AUTOVSCROLL, $WS_VSCROLL, $ES_MULTILINE, $WS_HSCROLL, $ES_NOHIDESEL))
    $idButton1 = GUICtrlCreateButton("Suchen", 176, 288, 121, 33, 0)
    $idButton2 = GUICtrlCreateButton("Suchen und Ersetzen", 368, 288, 121, 33, 0)
    GUISetState(@SW_SHOW)

    While 1
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $iMsg = $idButton1
                _GUICtrlEdit_Find($idEdit)
            Case $iMsg = $idButton2
                _GUICtrlEdit_Find($idEdit, True)
            Case Else
                ;;;;;;;
        EndSelect
    WEnd
    GUIDelete()
EndFunc   ;==>Example_Internal

Beispiel 2

; mit Standard-UDF

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example_External()

Func Example_External()
    Local $s_Text = 'Beispiel für Suchen und Ersetzen mit AutoIt ' & FileGetVersion(@AutoItExe) & @CRLF & _
            "dies ist ein Test" & @CRLF & _
            "dies ist nur ein Test" & @CRLF & _
            "dieser Test sollte für Sie genauso gut funktionieren wie für mich"
    Local $hTitle, $hHandle
    Local $sTitle = "[CLASS:Notepad]"

    Run("notepad.exe", "", @SW_MAXIMIZE)
    ;Warten, bis das Fenster "Untitled" existiert
    WinWait($sTitle)

    ;Das Handle eines Notepad-Fensters abrufen
    $hTitle = WinGetHandle($sTitle)
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "Fehler", "Das richtige Fenster wurde nicht gefunden")
    Else
        $hHandle = ControlGetHandle($hTitle, "", "Edit1")
        If @error Then
            MsgBox($MB_SYSTEMMODAL, "Fehler", "Konnte das richtige Steuerelement nicht finden")
        Else
            ; Senden Sie einen Text direkt an das Bearbeitungsfeld dieses Fensters
            ControlSend($hTitle, "", "Edit1", $s_Text)
            _GUICtrlEdit_Find($hHandle, True)
        EndIf
    EndIf
EndFunc   ;==>Example_External