Funktionreferenz

_GUICtrlHeader_GetItemBitmap

Beschreibung anzeigen in

Ermittelt das Item Bitmap Handle

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemBitmap ( $hWnd, $iIndex )

Parameter

$hWnd Handle des Controls
$iIndex 0-basierender Itemindex

Rückgabewert

Erfolg: Item Bitmap Handle
Fehler: 0

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlHeader_SetItemBitmap

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGui = GUICreate("Header", 400, 300)
    Local $hHeader = _GUICtrlHeader_Create($hGui)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    GUISetState(@SW_SHOW)

    ; Erstellt eine Imagelist mit Bildern
    Local $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 0", 100, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 100, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 100, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 100)

    ; Setzt das Bitmap für Spalte 3
    _GUICtrlHeader_SetItemBitmap($hHeader, 3, _WinAPI_CreateSolidBitmap($hGui, 0xFF00FF, 11, 11))
    _GUICtrlHeader_SetItemDisplay($hHeader, 3, 1 + 8)

    ; Zeigt das Bitmap-Handle von Spalte 3
    _MemoWrite("Bitmap-Handle von Spalte 3: " & "0x" & Hex(_GUICtrlHeader_GetItemBitmap($hHeader, 3)))

    _MemoMsgBoxStatus("", -1, $hGui) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc   ;==>Example

Example 2 : Header Set ItemBitMap to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo, True)

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 0, $sFromTo)

    ; Show column 3 bitmap handle
    _MemoWrite("Column 3 bitmap handle: " & Ptr(_GUICtrlHeader_GetItemBitmap($hHeader, 3)))

    ; Set column 3 bitmap
    _GUICtrlHeader_SetItemBitmap($hHeader, 3, _WinAPI_CreateSolidBitmap($hWin, 0xFFFF00, 11, 11))
    If @error Then
        _MemoWrite("_GUICtrlHeader_SetItemBitmap()" & " @error = " & @error & @CRLF & _
            @TAB & "cannot be set by an external process")
    EndIf

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example