_GUICtrlHeader_SetItem
Beschreibung anzeigen in
Setzt Informationen über ein Item
#include <GuiHeader.au3>
_GUICtrlHeader_SetItem ( $hWnd, $iIndex, ByRef $tItem )
Parameter
| $hWnd | Handle des Controls |
| $iIndex | 0-basierender Itemindex |
| $tItem | DllStructCreate($tagHDITEM) Struktur |
Rückgabewert
| Erfolg: | True, @extended wird eventuell gesetzt (siehe Bemerkungen) |
| Fehler: | False |
Bemerkungen
Wenn sich das referenzierte Steuerelement $hWnd nicht im selben Prozess befindet und beide Prozesse in unterschiedlichen AutoIt-Modi (@AutoItVersion) ausgeführt werden,
wird @extended so eingestellt, dass $tItem für die PTR-Größenanpassung angepasst werden muss.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
$tagHDITEM, _GUICtrlHeader_GetItem
Beispiel
#include "Extras\HelpFileInternals.au3"
#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <StructureConstants.au3>
#include <WinAPIGdi.au3>
Example()
Func Example()
; Erstellt eine GUI
Local $hGUI = GUICreate("Header: Setzt und ermittelt das Item (v" & @AutoItVersion & ")", 500, 300, 100, 100)
Local $hHeader = _GUICtrlHeader_Create($hGUI)
_GUICtrlHeader_SetUnicodeFormat($hHeader, True)
_MemoCreate(2, 52, 444, 220)
GUISetState(@SW_SHOW)
; Erstellt eine Imagelist mit Bildern
Local $hImage = _GUIImageList_Create(11, 11)
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
_GUICtrlHeader_SetImageList($hHeader, $hImage)
; Fügt die Spalten hinzu
_GUICtrlHeader_AddItem($hHeader, "Spalte 0", 100, 0, 0)
_GUICtrlHeader_AddItem($hHeader, "Spalte 1", 100, 0, 1)
_GUICtrlHeader_AddItem($hHeader, "Spalte 2", 100, 0, 2)
_GUICtrlHeader_AddItem($hHeader, "Spalte 3", 100)
; Setzt den Bildindex für Spalte 2
Local $tItem = DllStructCreate($tagHDITEM)
DllStructSetData($tItem, "Mask", $HDI_IMAGE)
DllStructSetData($tItem, "Image", 0)
_GUICtrlHeader_SetItem($hHeader, 2, $tItem)
; Zeigt den Bilderindex von Spalte 2
$tItem = DllStructCreate($tagHDITEM)
DllStructSetData($tItem, "Mask", $HDI_IMAGE)
_GUICtrlHeader_GetItem($hHeader, 2, $tItem)
_MemoWrite("Bilderindex von Spalte 2: " & DllStructGetData($tItem, "Image"))
_MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc ;==>Example