Funktionreferenz


_GUICtrlListView_GetOrigin

Beschreibung anzeigen in

Ermittelt den Ursprung der aktuellen Ansicht für das Control

#include <GuiListView.au3>
_GUICtrlListView_GetOrigin ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert


Array mit dem folgenden Format:
    [0] - X-Koordinate der Ansicht
    [1] - Y-Koordinate der Ansicht

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListView_GetOriginX, _GUICtrlListView_GetOriginY

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Ermittelt den Ursprung der aktuellen Ansicht (v" & @AutoItVersion & ")", 600, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($idListview, $LVS_ICON)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Lädt die Bilder
    Local $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 0)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
    _GUICtrlListView_AddItem($idListview, "Item 2", 1)
    _GUICtrlListView_AddItem($idListview, "Item 3", 2)

    ; Ermittelt den Ursprung der aktuellen Ansicht
    Local $aOrigin = _GUICtrlListView_GetOrigin($idListview)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Erfolg: %s Ursprung: X=%d, Y=%d", @extended = 1, $aOrigin[0], $aOrigin[1]))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example