Funktionreferenz

_GUICtrlRebar_AddBand

Beschreibung anzeigen in

Fügt eine neue Gruppe in einem Rebar-Control ein

#include <GuiRebar.au3>
_GUICtrlRebar_AddBand ( $hWndRebar, $hWndChild [, $iMinWidth = 100 [, $iDefaultWidth = 100 [, $sText = "" [, $iIndex = -1 [, $iStyle = -1]]]]] )

Parameter

$hWndRebar Handle des Rebar-Controls
$hWndChild Handle des hinzuzufügenden Controls
$iMinWidth [optional] Minimale Breite für die Gruppe
$iDefaultWidth [optional] Länge der Gruppe in Pixel
$sText [optional] Anzuzeigender Text für die Gruppe
$iIndex [optional] 0-basierender Index des Ortes, wo die Gruppe eingefügt werden soll.
Falls dieser Parameter auf -1 gesetzt wird, wird das Control die Gruppe an das Ende einfügen
$iStyle [optional] Flags die den Stil des Bereiches festlegen. Dieser Wert kann eine Kombination der folgenden sein:
    $RBBS_BREAK - Die Gruppe beginnt in einer neuen Zeile.
    $RBBS_CHILDEDGE - Die Gruppe hat oben und unten des Unterfensters eine Kante.
    $RBBS_FIXEDBMP - Das Hintergrundbitmap verändert sich nicht, wenn die Gruppe in der Größe verändert wird.
    $RBBS_FIXEDSIZE - Die Gruppe kann in der Größe nicht verändert werden. Mit diesem Stil wird der Verschiebebalken nicht dargestellt.
    $RBBS_GRIPPERALWAYS - Version 4.71. Die Gruppe hat immer einen Verschiebebalken, auch wenn es nur einen Bereich in der Rebar gibt.
    $RBBS_HIDDEN - Die Gruppe wird nicht sichtbar sein.
    $RBBS_NOGRIPPER - Version 4.71. Die Gruppe wird nie einen Verschiebebalken haben, auch nicht wenn es mehr als einen Bereich in der Rebar gibt.
    $RBBS_USECHEVRON - Version 5.80. Zeigt einen "Chevron-Button" [>>] wenn die Gruppe kleiner als cxIdeal ist.
    $RBBS_VARIABLEHEIGHT - Version 4.71. Die Gruppe kann durch das Rebar-Control in der Größe verändert werden; cyIntegral und cyMaxChild sind für die Art wie die Rebar die Gruppe verändert verantwortlich.
    $RBBS_NOVERT - nicht anzeigen wenn vertikal.
    $RBBS_USECHEVRON - Zeigt Dropdown Button.
    $RBBS_HIDETITLE - Hält den Titel versteckt.
    $RBBS_TOPALIGN - Hält die Gruppe in der obersten Zeile.

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlRebar_AddToolBarBand, _GUICtrlRebar_DeleteBand

Beispiel

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <GuiReBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtnExit, $hCombo, $hReBar, $hDTP, $idInput

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Erstellt ein Rebar-Control
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Erstellt eine Combobox in der Rebar
    $hCombo = _GUICtrlComboBox_Create($hGui, "", 0, 0, 120)

    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Erstellt ein DTP in der Rebar
    $hDTP = _GUICtrlDTP_Create($hGui, 0, 0, 190)

    ; Erstellt eine Inputbox in der Rebar
    $idInput = GUICtrlCreateInput("Input-Control", 0, 0, 120, 20)

    ; Fügt eine Gruppe mit Controls ein
    _GUICtrlRebar_AddBand($hReBar, $hCombo, 120, 200, "Dir *.exe")

    ; Hinzufügen und in die zweite Zeile
    _GUICtrlRebar_AddBand($hReBar, $hDTP, 120)
    _GUICtrlRebar_SetBandStyleBreak($hReBar, 1)

    ; Am Anfang der Rebar hinzufügen
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:", 0)

    $idBtnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idBtnExit
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example