Funktionreferenz


_GUICtrlRebar_AddToolBarBand

Beschreibung anzeigen in

Fügt eine neue Gruppe in einem Rebar-Control ein

#include <GuiRebar.au3>
_GUICtrlRebar_AddToolBarBand ( $hWndRebar, $hWndToolbar [, $sText = "" [, $iIndex = -1 [, $iStyle = -1]]] )

Parameter

$hWndRebar Handle des Rebar-Controls
$hwndToolbar Handle des hinzuzufügenden Controls
$sText [optional] Anzuzeigender Text für die Gruppe
$iIndex [optional] 0-basierender Index des Ortes, wo die Gruppe eingefügt werden soll.
Falls dieser Parameter auf -1 gesetzt wird, wird das Control die Gruppe an das Ende einfügen
$iStyle [optional] Flags die den Stil der Gruppe festlegen. Dieser Wert kann eine Kombination der folgenden sein:
    $RBBS_BREAK - Die Gruppe beginnt in einer neuen Zeile.
    $RBBS_CHILDEDGE - Die Gruppe hat oben und unten des Unterfensters eine Kante.
    $RBBS_FIXEDBMP - Das Hintergrundbitmap verändert sich nicht, wenn die Gruppe in der Größe verändert wird.
    $RBBS_FIXEDSIZE - Die Gruppe kann in der Größe nicht verändert werden. Mit diesem Stil wird der Verschiebebalken nicht dargestellt.
    $RBBS_GRIPPERALWAYS - Version 4.71. Die Gruppe hat immer einen Verschiebebalken, auch wenn es nur eine Gruppe in der Rebar gibt.
    $RBBS_HIDDEN - Die Gruppe wird nicht sichtbar sein.
    $RBBS_NOGRIPPER - Version 4.71. Die Gruppe wird nie einen Verschiebebalken haben. Auch nicht wenn es mehr als eine Gruppe in der Rebar gibt.
    $RBBS_USECHEVRON - Version 5.80. Zeigt einen "Chevron-Button" [>>] wenn die Gruppe kleiner als cxIdeal ist.
    $RBBS_VARIABLEHEIGHT - Version 4.71. Die Gruppe kann durch das Rebar-Control in der Größe verändert werden; cyIntegral und cyMaxChild sind für die Art wie die Rebar die Gruppe verändert verantwortlich.
    $RBBS_NOVERT - nicht anzeigen wenn vertikal.
    $RBBS_USECHEVRON - Zeigt Dropdown Button.
    $RBBS_HIDETITLE - Hält den Titel versteckt.
    $RBBS_TOPALIGN - Hält die Gruppe in der obersten Zeile.

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlRebar_AddBand, _GUICtrlRebar_DeleteBand

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtnExit, $hToolbar, $hReBar, $idInput
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Erstellt ein Rebar-Control
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Erstellt eine Toolbar in der Rebar
    $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Fügt die Standard-Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt der Toolbar die Standard-Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Erstellt eine Inputbox in der Rebar
    $idInput = GUICtrlCreateInput("Eingabebox", 0, 0, 120, 20)

    ; Fügt der Rebar eine Gruppe mit einem Control hinzu
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

    ; Fügt am Anfang der Rebar eine Gruppe mit einem Control ein
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    $idBtnExit = GUICtrlCreateButton("Beenden", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idBtnExit
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example