_GUICtrlRichEdit_GetCharPosOfNextWord
Beschreibung anzeigen in
Ermittelt die Zeichenposition vor dem nächsten Wort
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosOfNextWord ( $hWnd, $iCpStart )
Parameter
| $hWnd | Handle des Controls |
| $iCPStart | Zeichenposition, ab der gesucht werden soll |
Rückgabewert
| Erfolg: | die Zeichenposition vor dem nächsten Wort |
| Fehler: | 0 und setzt das @error Flag auf ungleich 0 |
| @error: | 101 - $hWnd ist kein Handle 102 - $iCpStart ist keine Zahl |
Bemerkungen
"Wort" ist ungenau definiert - es enthält Zeichensetzung [".,"], Klammern ["()[]{}"] und Bindestriche ['-']
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlRichEdit_GetCharPosOfPreviousWord, _GUICtrlRichEdit_GetCharWordBreakInfo
Siehe auch
Suche nach EM_FINDWORDBREAK in der MSDN Bibliothek.
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtn_Next, $idLbl_Msg, $hRichEdit, $iCp = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtn_Next = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($hRichEdit, "AutoIt v3 ist eine Freeware BASIC-Ähnliche Script Sprache, entwickelt um " _
& "die Windows-GUI zu automatisieren und um andere Scripte zu programmieren.")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtn_Next
$iCp = _GUICtrlRichEdit_GetCharPosOfNextWord($hRichEdit, $iCp)
GUICtrlSetData($idLbl_Msg, $iCp)
_GUICtrlRichEdit_GotoCharPos($hRichEdit, $iCp)
EndSelect
WEnd
EndFunc ;==>Example