Ermittelt die Rahmeneinstellungen des (ersten) ausgewählten Absatzes oder, wenn keiner ausgewählt ist, die des aktiven Absatzes
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaBorder ( $hWnd )
$hWnd | Handle des Controls |
Erfolg: | Einstellungen des ersten selektierten Absatzes - Ein String aus durch Semikola getrennten Werten (;): Wert 1 - Platzierung - Einer oder mehrere aus: l - linker Rahmen r - rechter Rahmen t - oberer Rahmen b - unterer Rahmen i - innerer Rahmen o - äußerer Rahmen oder leer - kein Rahmen Wert 2 - Linienstil - Einer von: nichts - keine Linie .75 - 3/4 Punkt 1.5 - 1 1/2 Punkte 2.25 - 2 1/4 Punkte 3 - 3 Punkte 4.5 - 4 1/2 Punkte 6 - 6 Punkte .75d - 1/2 Punkte, doppelt 1.5d - 1 1/2 Punkte, doppelt 2.25d - 2 1/4 Punkte, doppelt .75g - 3/4 Punkt, grau .75gd - 3/4 Punkt, grau gestrichelt Wert 3 - Linienfarbe - Eine von: aut - automatisch blk - schwarz blu - blau cyn - zyan grn - grün mag - magenta red - rot yel - gelb whi - weiß dbl - dunkles blau dgn - dunkles grün dmg - dunkles magenta drd - dunkles rot dyl - dunkles gelb dgy - dunkles grau lgy - helles grau Wert 4 - Abstand zwischen Rahmen und Text (in Leerzeichen-Einheiten) Wert 5 - Gültigkeit: a - Alle (oder nur die) ausgewählten Absätze haben diese Einstellungen. f - Der erste ausgewählte Absatz hat diese Einstellungen, sonst kein anderer. c - Der aktuelle Absatz hat diese Einstellungen. |
Fehler: | "" und setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist kein Handle |
Ein RichEdit-Control zeigt keine Rahmen an, aber hier erstellte Rahmen werden in Word angezeigt.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlRichEdit_SetParaBorder
Suche nach EM_GETPARAFORMAT in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $iStep = 0, $idBtnNext
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 250, 310, 60, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($g_hRichEdit, "Erster Absatz")
Report("0. Erster Absatz: Standardeinstellungen")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Zweiter Absatz")
_GUICtrlRichEdit_SetParaBorder($g_hRichEdit, "o", 3, "mag", 0.25)
Report("1. Zweiter Absatz: mit Rand (sollte in Word angezeigt werden)")
Case 2
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, -1)
Report("2. Einstellungen des ersten Absatzes in der Markierung")
Case 3
_GUICtrlRichEdit_SetParaBorder($g_hRichEdit, "l", 6, "blu")
Report("3. Einstellungen beider Absätze geändert")
Case 4
_GUICtrlRichEdit_SetParaBorder($g_hRichEdit, Default, ".75gd")
Report("4. Zeilenstil geändert")
Case 5
; Streamt den kompletten Text in eine Datei auf dem Desktop. Die Rändereinstellungen können in Word eingesehen werden
_GUICtrlRichEdit_Deselect($g_hRichEdit)
_GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Funktionsrückgabe " & @CR & _GUICtrlRichEdit_GetParaBorder($g_hRichEdit)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report