_GUICtrlRichEdit_SetModified

Beschreibung anzeigen in

Setzt oder löscht das Änderungsflag

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetModified ( $hWnd [, $bState = True] )

Parameter

$hWnd	Handle des Controls
$bState	[optional] Legt den neuen Wert für das Änderungsflag fest: True - zeigt an, dass der Text geändert wurde (Standard) False - zeigt an, dass sich nichts geändert hat.

Rückgabewert

Erfolg:	True
Fehler:	False und setzt das @error Flag auf ungleich null
@error:	101 - $hWnd ist kein Handle 102 - $bState muss True oder False sein

Bemerkungen

Das System setzt das Änderungsflag automatisch auf False, wenn das Control erstellt wird.
Falls sich der Text des Controls ändert, entweder durch den Benutzer oder durch das Programm, so wird das Flag auf True gesetzt.
Es ist _GUICtrlRichEdit_IsModified() aufzurufen, um den aktuellen Status des Flags zu erhalten.

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_SETMODIFY in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    Report("Status nach Erstellung")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Ein Absatz")
                        Report("Text hinzugefügt")
                    Case 2
                        _GUICtrlRichEdit_SetModified($g_hRichEdit, False)
                        Report("Nach dem Löschen des Änderungsflags")
                    Case 3
                        GUICtrlSetData($g_idLblMsg, "Gib etwas ein und klicke dann auf 'Weiter'!")
                    Case 4
                        Report("Nach der Eingabe")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CR & "Verändert: " & _GUICtrlRichEdit_IsModified($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report