Setzt die Attribute markierter Absätze oder, falls keine markiert sind, des am Einfügepunkt eingefügten Absatzes
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaAttributes ( $hWnd, $sStatesAndAtts )
$hWnd | Handle des Controls |
$sStatesAndAtts | Ein String, bestehend aus durch Semikola getrennten Werten ";". Jede Gruppe besteht aus: Erstes Zeichen - Zustand: + - Setzt das Attribut - - Setzt das Attribut nicht Zeichen 2 bis 4 fpg - Erzwingt die Ausgabe dieser Absätze auf eine neue Seite (anfänglich aus) hyp - Automatische Silbentrennung (anfänglich an) kpt - Halte diese Absätze auf einer Seite zusammen (anfänglich aus) kpn - Halte diese Absätze und die nächsten zusammen auf einer Seite (anfänglich aus) pwo - Verhindere Verwaisungen, z.B. eine einzelne Zeile eines Absatzes auf einer Seite (anfänglich aus) r2l - Zeige Text von rechts nach links an (anfänglich aus) sbs - Zeige Absätze seitlich nebeneinander an (anfänglich aus) sln - Unterdrücke Zeilennummern in Dokumenten oder Sektionen mit Zeilennummern (anfänglich aus) row - Absätze sind Tabellenzeilen (anfänglich aus) |
Erfolg: | True |
Fehler: | False und setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist kein Handle 1021 - Ein Zustands-Zeichen in $sStatesAndAtts ist ungültig. Dieses ist in @extended 1022 - Ein Attribut-Kürzel in $sStatesAndAtts ist ungültig. Dieses ist in @extended 1023 - Länge von $sStatesAndAtts ist ungültig |
Die Resultate werden in Word angezeigt, aber nicht in RichEdit
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlRichEdit_GetParaAttributes
Suche nach EM_SETPARAFORMAT in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($g_hRichEdit, "Erster Absatz")
Report("Erster Absatz: Standardeigenschaften")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Zweiter Absatz")
_GUICtrlRichEdit_SetParaAttributes($g_hRichEdit, "-hyp")
Report("Zweiter Absatz: Silbentrennung aus")
Case 2
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, -1)
_GUICtrlRichEdit_SetParaAttributes($g_hRichEdit, "-hyp;+fpg;+kpn")
Report("Eigenschaften des ersten Absatzes der Auswahl")
Case 3
; Zeichnet allen Text in einer Datei auf dem Desktop auf, um dessen Eigenschaften in Word anzuzeigen
_GUICtrlRichEdit_Deselect($g_hRichEdit)
_GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Die Rückgaben der Funktion " & @CR & _GUICtrlRichEdit_GetParaAttributes($g_hRichEdit)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report