Setzt oder entfernt den Status "schreibgeschützt"
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetReadOnly ( $hWnd [, $bState = True] )
$hWnd | Handle des Controls |
$bState | [optional] einer der folgenden Werte: True - Setzt das Control auf schreibgeschützt (Standard) False - Setzt das Control auf read-write |
Erfolg: | True |
Fehler: | False und setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist keine Handle 102 - $bState ist weder true noch false 700 - Befehl fehlgeschlagen |
- - - - - - - - Erklärung der Controls - - - - - - - -
Suche nach EM_SETREADONLY in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $hRichEdit, $iStep = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
For $i = 1 To 5
_GUICtrlRichEdit_AppendText($hRichEdit, "Zeile " & $i & @CR)
Next
_GUICtrlRichEdit_AppendText($hRichEdit, "Zeile 6")
Report("Standard")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetReadOnly($hRichEdit)
Report("Auf 'Nur Lesen' gesetzt")
Case 2
_GUICtrlRichEdit_SetReadOnly($hRichEdit, False)
Report("Zurück auf 'Lesen und Schreiben' gesetzt")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
GUICtrlSetData($g_idLblMsg, $sMsg & @CR & "Versuche etwas zu schreiben")
EndFunc ;==>Report